"The Loneliest House" by Tabitha O'Connell

Part 1 - Story

Include Basic Screen Effects by Emily Short.
Release along with an interpreter.
Release along with cover art ("cornice and cupola of an Italianate style house against a blue sky").
Release along with source text.

The release number is 2.

[a late autumn afternoon with the sunlight slanting golden across your face]

Chapter 1 - Misc

After reading a command:
	if the player's command matches the regular expression "^\p|^<*#+=.'>":
		say "(Noted.)";
		reject the player's command;

Chapter 2 - Setup

When play begins:
	say "You've always been drawn to the lonely old house on the hill outside your town. It's been abandoned for as long as you've lived here; you've never seen it get any care or attention. To everyone else, it's just a part of the scenery. But to you it's always been something more--a mystery, an omen, a promise.";
	wait for any key;
	say "[line break]Today, on a bright autumn afternoon, you've felt compelled to climb the hill and take a closer look."

After printing the banner text, say "[line break][italic type](Type 'About' for information about the game. Type 'help' or 'hint' if you're feeling stuck. See the game's itch.io page for a full walkthrough.)"

The description of yourself is "Unlike the lonely old house on the hill, you are perfectly ordinary."

Section 1 - Conditions

A person can be swayed. A person is usually not swayed.
A person can be tempted. A person is usually not tempted.
A person can be spelled. A person is usually not spelled.
A person can be gone. A person is usually not gone.

Something can be discussed.
The sounds are not discussed.

A thing can be seen. A thing is usually not seen.

Every turn when the turn count is even and the player is in Outside the lonely old house on the hill:
	if the sounds are not discussed and the player is not swayed:
		say "[one of]The browning leaves on the trees beyond the house rustle in the wind.[or]A dog barks in the distance.[or]A flock of geese flies by, honking plaintively.[or]From somewhere far away, you hear the playful shouts of children.[in random order]";
	now the sounds are not discussed.
	
Section 2 - Progression
	
Check listening to:
	If the player is swayed:
		say "You think you can hear the house creaking.";
		stop the action;
	otherwise:
		say "[one of]The browning leaves on the trees beyond the house rustle in the wind.[or]A dog barks in the distance.[or]A flock of geese flies by, honking plaintively.[or]From somewhere far away, you hear the playful shouts of children.[in random order]";
		now the sounds are discussed;
		stop the action.

Check smelling:
	if the player is swayed:
		say "The odor of old wood fills your nostrils.";
		stop the action;
	otherwise:
		say "You catch the scent of rotting leaves and the odor of old wood.";
		stop the action.
	
Check looking:
	if the player is spelled:
		say "All you can see is the lonely old house.";
		now the player is gone;
		stop the action.

Check examining the oldhouse:
	now the oldhouse is seen.

After looking:
	if the oldhouse is seen, try examining the oldhouse;
	if the player is swayed:
		if the player is not tempted:
			say "It's gotten a bit chillier since you arrived.";
	if the player is tempted:
		if the player is not spelled:
			say "The sun has sunk low in the sky, bathing you and the house in golden light."

Instead of doing anything when the player is gone:
	say "You blink, and suddenly you aren't looking at the house anymore. You're somewhere high up, seeing out over your town and the mountains beyond. The view is as gorgeous as you imagined.

Redirecting your awareness, you find that you can see inside the cupola too. Not just see it, but feel it--the wood of the walls, the coolness of the windowpanes, the draftiness of the roof. The stories below, as well--the rooms, the stairs, the floorboards, the porch, down to the very texture of the doorknobs. You know every inch of this house now.";
	wait for any key;
	end the story finally saying "You are the lonely old house on the hill."

Chapter 3 - Outside

Outside the lonely old house on the hill is a room. "You are standing outside the lonely old house on the hill. An ancient fence around it bars you from entry."

The oldhouse is in Outside the lonely old house on the hill. The oldhouse is scenery. The description of the oldhouse is "The house is a large, once-grand, Italianate-style residence. A porch stretches across the front, sheltering the entrance, and atop the roof is a cupola."
Understand "house" as the oldhouse.
Understand "residence" as the oldhouse.

The leaves are in Outside the lonely old house on the hill. The leaves are scenery.
The geese are in Outside the lonely old house on the hill. The geese are scenery.
Understand "flock" as the geese.
The trees are in Outside the lonely old house on the hill. The trees are scenery.
The sign is in Outside the lonely old house on the hill. The sign is scenery.
The ground is in Outside the lonely old house on the hill. The ground is scenery.
The hill1 is in Outside the lonely old house on the hill. The hill1 is scenery.
Understand "hill" as the hill1.
Understand "hillside" as the hill1.
Check examining the hill1:
	say "You see nothing special about the hill."; 
	stop the action.

The sun is in Outside the lonely old house on the hill. The sun is scenery. 
Understand "light" as the sun.
Understand "sky" as the sun.
Check examining the sun:
	if the player is not swayed:
		say "The sun is several hours past its zenith, and will be setting before long.";
		stop the action;
	if the player is tempted:
		if the player is not spelled:
			say "It looks like you're going to get a beautiful sunset soon.";
			stop the action.
			
The view is in Outside the lonely old house on the hill. The view is scenery. The description of the view is "You glance over your shoulder, back the way you came. The scene is pretty, the town in the valley below and the fall colors of the hills beyond, but it would be even better from the house. Ah, well."
Understand "town" as the view.
Understand "scene" as the view.
Understand "hills" as the view.
Understand "landscape" as the view.

The fence is in Outside the lonely old house on the hill. The fence is scenery. The description of the fence is "A wire fence bearing an old, faded 'KEEP OUT' sign. You don't mind it; you just like looking at the house."

The dog is in Outside the lonely old house on the hill. The dog is scenery. The description of the dog is "You can't see it, but its bark rings out over the hillside."

Instead of going inside:
	say "You can't get into the house, but that's okay. You're just here to look."
	
Imagining is an action applying to one visible thing.
Understand "imagine [something]" as imagining.
Carry out imagining: say "You can imagine whatever you like."

Understand "look through [something]" as examining.

Section 1 - cupola

The cupola is in Outside the lonely old house on the hill. The cupola is scenery. The description of the cupola is "On the roof is the cupola, a smaller cube crowning the large cube of the house. The cupola's walls are mostly taken up by windows. You can imagine what excellent views it would provide."
Understand "cube" as the cupola.
Understand "roof" as the cupola.

The windows are in Outside the lonely old house on the hill. The windows are scenery. The description of the windows is "Each side of the cupola has a pair of tall, narrow windows with round-arched tops. Thin wooden muntins divide each window into four."
Understand "tops" as the windows.
Understand "arches" as the windows.
Understand "walls" as the windows.
Understand "window" as the windows.

The muntins are in Outside the lonely old house on the hill. The muntins are scenery. The description of the muntins is "Unlike the fake plastic ones these days that get stuck onto windows for show, these long, thin pieces of wood hold the windowpanes in place."
Understand "pieces" as the muntins.
Understand "pieces of wood" as the muntins.
Understand "muntin" as the muntins.

The panes are in Outside the lonely old house on the hill. The panes are scenery. The description of the panes is "The glass is slightly warped, a sign of its age. You can imagine the view through it, into a room with a hardwood floor and cozy window seats."
Understand "windowpanes" as the panes.
Understand "glass" as the panes.
Check examining the panes:
	if the panes are not seen:
		if the player is tempted:
			now the player is spelled;
			now the panes are seen;
		if the player is swayed:
			now the player is tempted;
			now the panes are seen;
		if the player is not swayed:
			now the player is swayed;
			now the panes are seen.

Section 2 - porch

The porch is in Outside the lonely old house on the hill. The porch is scenery. The description of the porch is "A full-width porch, large and airy, perfect for sitting outside on a nice day. The top is outlined by a row of decorative brackets."
Understand "front" as the porch.

The brackets are in Outside the lonely old house on the hill. The brackets are scenery. The description of the brackets is "Delicately carved, the brackets curve in a scroll-like shape. Their paint is flaking off."
Understand "bracket" as the brackets.
Understand "shape" as the brackets.
Understand "top" as the brackets.

The paint is in Outside the lonely old house on the hill. The paint is scenery. The description of the paint is "Once a bright yellow, the paint is faded and dull now, with bits peeling away to reveal the wood underneath."
Understand "bits" as the paint.

The wood is in Outside the lonely old house on the hill. The wood is scenery. The description of the wood is "Tinged gray where it's been left exposed to the elements. You can imagine how it would feel under your fingers, worn soft."
Understand "gray" as the wood.
Check examining the wood:
	if the wood is not seen:
		if the player is tempted:
			now the player is spelled;
			now the wood is seen;
		if the player is swayed:
			now the player is tempted;
			now the wood is seen;
		if the player is not swayed:
			now the player is swayed;
			now the wood is seen.

Section 3 - entrance

The entrance is in Outside the lonely old house on the hill. The entrance is scenery. The description of the entrance is "Within a large arch is a pair of doors. You can imagine how it would feel to walk through them, knowing as you left your beautiful house that it would be here waiting for you on your return."
Understand "front entrance" as the entrance.

Check examining the entrance:
	now the entrance is seen.

The housedoors are in Outside the lonely old house on the hill. The housedoors are scenery. The description of the housedoors is "The heavy wooden doors are a rich blue and have a symmetrical pair of metal knobs."
Understand "doors" as the housedoors.
Understand "door" as the housedoors.
Understand "arch" as the housedoors.
Understand "blue" as the housedoors.

Check examining the housedoors:
	if the entrance is not seen:
		try examining the entrance.

The knobs are in Outside the lonely old house on the hill. The knobs are scenery. The description of the knobs is "The knobs are roughly egg-shaped, and you can make out a pattern on them."
Understand "metal" as the knobs.
Understand "knob" as the knobs.

Check turning the knobs:
	say "You can't reach from here. That's okay; you're just here to look.";
	stop the action.

The pattern is in Outside the lonely old house on the hill. The pattern is scenery. The description of the pattern is "A raised design is imprinted on the metal. You can imagine how it would feel under your hand as you turned the knob to go inside."
Understand "design" as the pattern.
Check examining the pattern:
	if the pattern is not seen:
		if the player is tempted:
			now the player is spelled;
			now the pattern is seen;
		if the player is swayed:
			now the player is tempted;
			now the pattern is seen;
		if the player is not swayed:
			now the player is swayed;
			now the pattern is seen.

Part 2 - Meta

Abouting is an action out of world.
Understand "about" as abouting.
Understand "credits" as abouting.
Carry out abouting:
	say "A game by Tabitha O'Connell. Originally written and coded in under four hours for the La Petite Mort division of Ectocomp 2023. Cover photo by Tabitha O'Connell. Thanks to shiroyasha and Nulla for testing; thanks to Sophia and Rovarsson for play transcripts that helped improve this second release."

Hinting is an action out of world.
Understand "hint" as hinting.
Understand "help" as hinting.
Carry out hinting:
	say "You feel compelled to examine every detail of the house."

Chapter 1 - Standard rule mods

The can't go that way rule response (A) is "You don't want to leave here."
The report touching things rule response (A) is "You don't need to touch; looking is enough."
The standard report taking rule response (A) is "You don't need to take anything here."
The examine directions rule response (A) is "The landscape spreads out around you."
The can't take scenery rule response (A) is "You don't need to take anything here."
The parser error internal rule response (N) is "No need for that; you're just here for the house."
The can't turn what's fixed in place rule response (A) is "No need for that; you're just here for the house."
The parser error internal rule response (E) is "That's not here, or isn't important."

Check examining inside:
	say "You can't see inside.";
	stop the action.
Instead of examining up:
	try examining the sun.
Instead of examining down:
	try examining the ground.

Chapter 2 - Disabled actions

Understand nothing as removing it from.
Understand nothing as dropping.
Understand nothing as putting it on.
Understand nothing as inserting it into.
Understand nothing as eating.
Understand nothing as entering.
Understand nothing as exiting.
Understand nothing as getting off.
Understand nothing as looking under.
Understand nothing as searching.
Understand nothing as consulting it about.
Understand nothing as locking it with.
Understand nothing as unlocking it with.
Understand nothing as switching on.
Understand nothing as switching off.
Understand nothing as opening.
Understand nothing as closing.
Understand nothing as wearing.
Understand nothing as taking off.
Understand nothing as giving it to.
Understand nothing as showing it to.
Understand nothing as waking.
Understand nothing as throwing it at.
Understand nothing as attacking.
Understand nothing as kissing.
Understand nothing as answering it that.
Understand nothing as telling it about.
Understand nothing as asking it about.
Understand nothing as asking it for.
Understand nothing as waving.
Understand nothing as pulling.
Understand nothing as pushing.
Understand nothing as pushing it to.
Understand nothing as squeezing.
Understand nothing as saying yes.
Understand nothing as saying no.
Understand nothing as burning.
Understand nothing as waking up.
Understand nothing as thinking.
Understand nothing as tasting.
Understand nothing as cutting.
Understand nothing as jumping.
Understand nothing as tying it to.
Understand nothing as drinking.
Understand nothing as saying sorry.
Understand nothing as swinging.
Understand nothing as rubbing.
Understand nothing as setting it to.
Understand nothing as waving hands.
Understand nothing as buying.
Understand nothing as climbing.
Understand nothing as sleeping.