
*set cloth "armor"
*temp destination
*set destination ""
*temp actcounter
*set actcounter 0
*temp defcounter
*set defcounter 0
*temp lostsy
*set lostsy true
*temp syphel
*set syphel true
*set currentweap (weapon)
*temp prox
*set prox 2
*if intel = 0
  *set intel 1
*label beginning
A moment of rest, at last.

There was always something slightly relieving about being back in your own quarters, out of the eyes of everyone else.

The Imperial Palace had always struck you as a quiet and solemn place, far different from the busy streets of the Imperial City, far beyond it's walls.
The Palace's halls are normally silent, save for the echoing of your footsteps when you walk through them. It's corridors are noticeably void of life, only allowing the occasional guard or doorman.

Your thoughts and unpacking are abruptly disturbed by a light rapping at your door.

You answer it to find a young... maid, you think? She's dressed very plainly and greets you with a deep curtsy, her eyes cast respectfully downward.

"$!{lord}
*if origin = "Capel"
  Sage,"
*if origin != "Capel"
  $!{surname},"
she quietly starts, "A message from the Emperor. He wishes to see you in his study at your earliest convenience."

You barely contain a groan. Why does no one seem to ever want you to have a moment of peace when you return from a trip?
*page_break
You can only assume that "at your earliest convenience" means "immediately", so you waste little time in making your way to the study.
As you exit your room, however, you realize that you have no idea where the study is.
You don't think you found it when you were searching for rooms, but you also weren't exactly looking for it at the time.

"Down stairs, in this wing," the maid chimes in, as if reading your thoughts. You catch her eyes for a brief instant before she snaps them back to the floor. "Um, $!{lord}
*if origin = "Capel"
  Sage,"
*if origin != "Capel"
  $!{surname},"
she adds courteously, almost as an afterthought.

*choice
  #I warmly thank her and continue on my way.
    *set inspiring %+ 3
    *set maid 3
    She fidgets uncomfortably, but politely curtsies as you leave.
    *goto study1
  #I nod a quick thanks to her and continue on my way.
    *set maid 4
    She responds with a quick curtsy as you leave.
    *goto study1
  #Someone should teach her to not speak out of turn.
    *set inspiring %- 3
    *set maid 5
    You would reprimand her yourself, but you have somewhere to be.
    A quick look of disapproval is all you can spare for her before you continue on your way.
    *goto study1
*label study1

You find the study without much difficulty, and enter to meet the musty smell of books.
Inside, you see that the walls are lined with shelves filled with tome after tome.
*if origin = "Monaire"
  
  Your family had been too poor to afford access to the libraries in Monaire when you were growing up.
  Free public access was instituted when the Empire came into power, but by then you were too busy training to take advantage of it.
*if origin = "Capel"

  The dusty shelves bring back memories of the modest collection of texts that the priests in your Temple maintained.
  You found their endless insistence that you study somewhat burdensome at the time, but there's little you wouldn't do to have those days back again.
*if origin = "Ehl"

  You had a comparable collection of your own back at the university in Ehl.
  A few of the volumes you had even written yourself.
  
  Even more interesting than the books themselves is the collection of artwork and mechanical devices on display.
  While still primitive by Ehlish standards, these pieces are far more advanced than anything you've seen on this continent, thus far.
*if origin = "Asylia"
  
  It's what decorates the walls between the shelves that catches your attention, however.
  
  Artwork.
  
  Not just any artwork. You recognize many of the pieces from the museum in Asylia's capital.
  As you look around, you notice that it's not only artwork, but several devices from the museum of technology are present as well.
  Much of it looks like it has smoke damage.

  Your gaze stops immediately as you recognize one of your own paintings.
  
*if origin = "Sedel"

  You've never actually seen anything like this.
  Elves rarely invest in books, functioning better from a more involved form of learning.
  
"See something you like?" a steady voice barely registers with you.

You suddenly become aware of Emperor Dain's presence, seated at an ornate wooden desk across the room, and perform a nervous
*if ((male) or (armor = "plate"))
  bow.
*if ((female) and (armor != "plate"))
  curtsy.
An open book occupies the space in front of him, though he doesn't look to be very interested in it.
You doubt that he's the type that ever looks interested in anything, though.

*choice
  *if ((origin = "Asylia") or (origin = "Ehl"))
    #I ask him about the artwork and machinery.
      *if origin = "Asylia"
        "That's my painting," you end up tactlessly blurting out, pointing to the framed piece on the wall.
        
        "It is," he acknowledges, "Your museums were demolished, so I saved what I could."
        
        You feel yourself tense.
        First he massacres your people, then he takes over your country and demolishes your museums, and to add insult to injury, he takes whatever priceless treasures were inside and claims that he saved them?
        By sheer willpower alone, you manage to stop yourself from saying anything that would surely get you imprisoned, or worse.
        
        "I have a certain appreciation for the masterwork pieces of the Sirilas," he says, a small amused grin developing disturbingly easily on his usually expressionless face.
        "You held that title once, did you not?"
        
        That title stayed with a person, even after death. You STILL have it, not that you would dare argue that point with the Emperor.
        
        "I did," you dryly reply.
        
        "Do you still paint?" he asks.
        
        You have canvas and brushes in your room, but have never had the time or inspiration to paint since you became involved with the Empire.
        
        "No," you honestly answer.
        
        "A shame," he goes back to looking bored, "Perhaps I can convince you to start again one day."
        
        If your choice was to either paint for the Empire, or never paint again, you're not entirely sure which one you would choose.
        
      *if origin = "Ehl"
        "Asylian," he states, but makes no further remark about it.
        
        You've heard of Asylians, although by the popular descriptions of their society, one would think that they would be too busy cavorting with demons and spitting on holy relics to have time to develop such an advanced culture.
        
      "If you ever want to come in here, feel free to do so," he adds.
      
      You nod your appreciation.
      *if origin = "Asylia"
        At least, if nothing else, you have something of your home accessible to you.
      *goto introtopo
  #I ask him about the books.
    "Nothing of import," he casually waves off your question, "However, the study is open to you if you have any inclination to use it."
    
    He goes no further into the issue.
    *goto introtopo
  #I ask what he wanted to see me about.
    *goto primaryobjective
    *label introtopo
    *page_break
    "Was there something you wished of me?" you ask, moving toward the subject at hand.
    *label primaryobjective
    
    "Yes. You will act as my envoy," he states, abruptly.
    
    "...Envoy, my Emperor?" you question. You're not exactly sure of what he's talking about, and have never heard of an envoy for the Empire.
    
    "Yes. I need you to convince certain rulers that joining their countries to the Empire is in their best interests," he explains turning back to his reading.
    
    "I'm... not trained in that sort of thing," you try to argue as inoffensively as possible.
    
    *if origin = "Ehl"
      You had been sent to translate FOR an envoy, but you've never had to make any diplomatic decisions yourself.
      
    "You'll manage," he flatly assures, "Gillen has some experience in the task. You can ask for his advice. Otherwise, I need you to acquire the country of Barith for me."
    
    *choice
      #"I'll ask Reaver Harking, then."
        *set destination "training"
        *goto dismissed
      #"I'll go directly to Barith, then."
        *set destination "barith"
        *goto dismissed
*label dismissed
*if rebel <10
  "You hardly need to tell me what you're going to do," the
*if ((rebel >= 10) and (rebel < 40))
  "I'm sure you will," the
*if rebel >= 40
  The
Emperor shows a rare half-smile, far more naturally than you would think he could, "Just tell me when the task is done."
        
You sense that you're dismissed, and take your leave.
*page_break
*if destination = "training"
  You make your way to Reaver Harking's office.

  "$!{lord}
  *if origin = "Capel"
    Sage,"
  *if origin != "Capel"
    $!{surname},"
  Reaver Harking's attendant standing next to the door greets you with a bow, "Master Sage Harking is expecting you."
  
  You nod and pull open the door to the small office.
  Roughly half the size of the study you were previously in, this office is more familiar to you than the rest of the Imperial Palace.
  You walk in and greet your former superior, who sits patiently at an over-sized and well used desk.
  
  He looks you over appraisingly for a moment before speaking.
  *if ((armor = "coat") or (armor = "gown")) or (armor = "robes")
    
    "After a visit to Raleigh with Syphel, I half expected you to come back wearing some ridiculous set of armor, he comments, "You might actually pass a proper
    *if ((armor = "robes") and (origin = "Capel"))
      Sage
      *goto oneday
    *elsif male
      gentleman
      *goto oneday
    *elsif female
      lady
    *goto oneday
    *label oneday
    one day."
  
    "Might?" you question.
  
    "One day," he repeats, showing a hint of a smile that you're certain anyone other than you would overlook.
  *if armor = "plate"
  
    "What are you wearing, and why?" he looks to your ${armorc} armor.
    
    "$!{armorc} plate armor," you answer, "Syphel took me to Raleigh to have a set made."
    
    "I assumed as much," he sighs.
    
    "Syphel told me I should wear it as much as possible to get used to the weight," you add.
    
    This is normally where Reaver Harking would inform you of his disapproval of your decisions, but he doesn't say a word about it this time.
    
  *if ((armor = "clothing") or (armor = "leather"))
    
    "I had hoped Syphel hadn't tried to encourage you to join him in his plate armor obsession," he says, looking the slightest bit relieved.
    
    *if armor = "leather"
      "I think I'll stick with something lighter," you rap your knuckles against your leather chest-piece.
      
    *if armor = "clothing"
      "No point in drawing that much attention to myself, right?" you smooth out the sturdy fabrics of your new clothing.
      
    "A surprisingly wise decision, coming from you," Reaver Harking remarks. If you didn't know better, you'd think he was teasing you.
  "I take it you've spoken to Dain?"
  
  You nod in confirmation.
  *label askem
  *fake_choice
    #"What does he need an envoy for?"
      
      "Any country we intend to absorb into the Empire has to be given the choice to join us willingly.
      To do this, we can either send a written message directly to the ruling force, or send a messenger.
      Written messages rarely turn anyone to our cause, but messengers succeed from time to time," he explains,
      "when they're not killed on sight, anyhow.
      I can only assume that Dain wants to send you instead to see if you'll fare any better."
      
      "So... I'm back to messenger duty again," you summarize.
      
      "Only a slightly more risky version," Reaver Harking corrects you, looking suspiciously amused.
      
    #"Why me?"
      "You are a Reaver," he explains, "Who else would you have take on such an important task?"
      
      "An expendable messenger?" you offer, "Approaching a king in his own castle and demanding that he give you his country, or else, doesn't sound safe."
      
      "I doubt Dain would have tasked you with this if he didn't believe you could succeed," Reaver Harking assures you, looking suspiciously amused.
      
    #"How am I supposed to do this?"
      "It isn't impossible. I'm sure you'll figure something out," Reaver Harking coolly assures you.
      
      "That's not as helpful as you think it is," you frown.
      
  He looks you over for a few seconds before continuing.
  
  "Do you honestly believe you need my help?" he asks.
  
  *choice
    #"Yes, Reaver Harking."
      He taps a finger slowly on the hard surface of his desk, his eyes set contemplatively on you.
      
      "Then I will arrange a coach for Jeon tomorrow evening," he finally breaks the silence.
      
      "Jeon?" you question. The country of Jeon is in the west, nowhere near your destination. "I need to go take Barith, not Jeon."
      
      "You asked for my help, did you not?"
      
      You nod an affirmative.
      
      "Pack your bags and meet me here tomorrow evening, if you still want it. Otherwise, you and I both have other things to do." He turns his attention to opening a letter on his desk.
      
      You aren't entirely sure of what Reaver Harking expects you to do in Jeon, but he's never steered you wrong before.
      *goto convodone
    #"No, Reaver Harking."
      "Of course, you don't," Reaver Harking agrees, "You are fully capable of handing any country on this continent to Dain."
      
      Reaver Harking seems to have more confidence in you than you do, but his confidence has to stem from something he sees in you.
      Perhaps you truly have been underestimating yourself.
      
      *set effort + 0.25
      *if effort > 1.5
        *set effort 1.5
      *set destination "barith"
      "Barith is already yours," he adds, "Your duty as a Reaver is to let the former owner know."
      
      Reaver Harking has a point. The Empire will take whatever it wants, one way or another.
      As far as you know, Reavers have no restrictions on how to do their jobs, either.
      You're starting to feel that this will be easier than you thought.
      
      "I'll get it done, Reaver Harking," you say, much more confident than you were before.
      *goto convodone
  *label convodone
  
  "One more thing, $!{name}," he calls to you, as you turn to leave, "You and I are equals in this
  *if ((origin = "Asylia") or (origin = "Sedel"))
    realm, despite what anyone may say.
  *if ((origin = "Capel") or (origin = "Monaire")) or (origin = "Ehl")
    realm.
  Call me Gillen."
  
  It's a bit unexpected for the rigidly formal man to allow you to address him informally.
  You've seen him give several people a firm lecturing for attempting to do so.
  This is as clear a sign of acceptance from him as anything.
  
  "Yes, Re- er, Gillen." This may take some getting used to, however. Without another word, you take your leave.
  *set gil "Gillen"
  *goto onitgoes
*label onitgoes
*page_break

You return to your isolated spot of the Palace to find the maid still standing next to your door.
She greets you with a respectful curtsy, eyes humbly lowered.

"Did you need something?" you ask, confused as to why she's still here.

"No, $!{lord}
*if origin = "Capel"
  Sage,"
*if origin != "Capel"
  $!{surname},"
she nervously responds, "I was assigned to attend to your needs during your stays."

This is... not something anyone ever told you about.
*goto maidintrochoice
*label maidintro

You get the distinct feeling that your attendant is slightly afraid of you.
*goto maidintrochoice
*label maidintro2

Your attendant takes a quick glance at you before lowering her eyes again.
She seems inexperienced at her position.
*goto maidintrochoice
*label maidintro3

$!{duska} fidgets nervously, her heartbeat pounding loud enough for you to hear in the otherwise silent halls.
*goto maidintrochoice
*label maidintro4

$!{duska} stands anxiously, awaiting any orders you may have for her.
*label maidintrochoice
*choice
  *hide_reuse #"So, you're just going to stand there in case I need something?"
    "Yes, my $!{lord}," she politely answers.
    *goto maidintro4
  *hide_reuse #"Isn't there someone more professional who can do this?"
    *set maid + 0.25
    "I... do not think so, my $!{lord}," she frowns,
    "But I am a fast learner. If anything I do displeases you, I will not repeat the mistake."
    *goto maidintro3
  *hide_reuse #"I don't need you annoying me."
    *set maid + 0.25
    "I will remain outside of your chambers, $!{lord}
    *if origin = "Capel"
      Sage,"
    *if origin != "Capel"
      $!{surname},"
    she assures you, a worried frown on her delicate features.
    *goto maidintro
  *hide_reuse #"What's your name?"
    *set maid - 0.25
    *if maid < 1
      *set maid 1
    "Duska, my $!{lord}," she immediately answers.
    *set duska "Duska"
    *goto maidintro2
  *hide_reuse #"Can you make sure no one bothers me again, today? I just came back from a long trip."
    "Certainly, $!{lord}
    *if origin = "Capel"
      Sage,"
    *if origin != "Capel"
      $!{surname},"
    she answers.
    
    Finally, maybe you can have some peace for once!
    
    "Anything else, my $!{lord}?"
    *goto maidintro4
  *hide_reuse #"Carry on, then."
    "Yes, my $!{lord}," she quickly curtsies as you enter your chambers and shut the door behind you.

    
*comment transition to a day to do whatever
*page_break
A brand new day and you awaken well rested in your new accommodations for the first time.

*label readying
As you ready yourself, you think of what requires your attention today.
*if destination = "training"
  Gillen had offered some sort of help if you go to Jeon, but you don't have to meet him until later this evening.
  You should also consider getting your task at Barith done as soon as possible.
*if destination = "barith"
  You should get your task at Barith done as soon as possible.
  *label tobarithnow
  
  You've never left the Imperial Palace of your own account before, however, and are unsure of who to talk to about acquiring the use of a carriage.
  You open your chamber door and immediately spot ${duska} in the hall.
  
  "$!{lord}
  *if origin = "Capel"
    Sage,"
  *if origin != "Capel"
    $!{surname},"
  she greets, never looking up at you.
  
  "I need a carriage to Barith," you state, hoping she can point you in the right direction.
  
  "As you wish, my $!{lord}," she curtsies before scurrying off down the hall, her footsteps barely making a sound.
  
  Well, that was easy.
  
  With that matter taken care of, you step back into your room and begin packing again.
  A life constantly on the go can be difficult at times, but you grew rather accustomed to such things during your time as $!{gil}'s Second.
  
  It isn't long before you hear a light rapping on your door.
  
  "$!{lord}
  *if origin = "Capel"
    Sage,"
  *if origin != "Capel"
    $!{surname},"
  ${duska} addresses you, slightly out of breath when you answer the door,
  "Your carriage will be ready tomorrow morning to take you to the fort outside of Barith.
  General Velont has been sent word of your arrival."
  
  Perhaps an attendant is useful to have around after all.
  
  $!{duska} stands in the hall, as if awaiting some sort of feedback on her performance.
  
  *choice
    #She's done a good job. I'll praise her."
      "Thank you, my $!{lord}," she barely contains a smile.
      She practically bounces back to her post next to your door
      *goto didit
    #She only did what was expected, but I'll thank her anyway.
      She respectfully curtsies and returns to her post next to your door.
      *goto didit
    #She shouldn't expect any sort of reward from me for simply doing her job. I'll ignore her.
      It's hard to ignore the clear disappointment on her face, but you do.
      She quietly returns to her post next to your door.
      *goto didit
*label didit

Since you don't have to be anywhere for a time, you think of what to do with the rest of your day.
*if trained
  *set actcounter 0
  *goto secondfreetime
*label firstfreetime
*choice
  *if ((destination = "training") and (actcounter = 0))
    #Barith is my priority. I'll prepare to make my journey there.
      *set destination "barith"
      *goto tobarithnow
  *hide_reuse #I'll go to the study.
    You enter the study half expecting to find the Emperor there, but it's completely empty.
    
    After a quick look around, you find something interesting enough to read.
    *if origin = "Asylia"
      Being in this room is almost comfortable, and you find that you can concentrate well.
      *set intel %+ (effort*2)
    *set intel %+ (effort*3)
    *set actcounter + 1
    *if actcounter = 2
      *goto secondactdone
    *goto firstactdone
  *hide_reuse #I'll see if I can get Syphel to train me.
    "Ya want me to train ya?" Syphel asks before you can even say anything.
    *if lostsy
    
      Finding Syphel wasn't hard. Your attendant directed you toward a private training room near the military training wing of the Imperial Palace.
      This wing has a different energy than the rest of the Palace, which seems to suit someone as lively as Syphel well.
      
      "Fine. Pick a weapon."
        
      He gestures to the weaponry mounted on the wall of the training room.
      
      *if origin = "Sedel"
        You've had training with longswords and bows, and feel relatively comfortable with them.
      *if origin = "Monaire"
        You've had training with a shortsword, and feel relatively comfortable with the weapon.
      *if origin = "Ehl"
        The only weapons you've ever held in your life were a shortsword, which you never used, and a gun, which this continent utterly lacks.
      *if ((origin = "Capel") or (origin = "Asylia")) and (unarmed > 0)
        You have next to no experience with any weaponry, but Syphel did teach you some hand-to-hand moves.
      *if ((origin = "Capel") or (origin = "Asylia")) and (unarmed = 0)
        You have next to no experience with any weaponry, so one weapon is probably as good as any another.
      *label pickyourweapon2
      *choice
        #Take the longsword.
          *if sword = 0
            *set sword 1
          *set weapon "longsword"
          *set weapontype "sword"
          You take the longsword
          *goto trainim
        #Take the shortsword.
          *if sword = 0
            *set sword 1
          *set weapon "shortsword"
          *set weapontype "sword"
          *goto trainim
        #Take both swords.
          *if sword = 0
            *set sword 1
          *set weapon "dual swords"
          *set weapontype "sword"
          *goto trainim
        #Take the battle axe.
          *if axe = 0
            *set axe 1
          *set weapon "battle axe"
          *set weapontype "axe"
          *goto trainim
        #Take the pollaxe.
          *if axe = 0
            *set axe 1
          *set weapon "pollaxe"
          *set weapontype "axe"
          *goto trainim
        #Take a dagger.
          *if dagger = 0
            *set dagger 1
          *set weapon "dagger"
          *set weapontype "dagger"
          *goto trainim
        #Take two daggers.
          *if dagger = 0
            *set dagger 1
          *set weapon "dual daggers"
          *set weapontype "dagger"
          *goto trainim
        #Take a longbow.
          *if bow = 0
            *set bow 1
          *set weapon "longbow"
          *set weapontype "bow"
          *goto trainim
        #I don't need anything but my fists.
          *if unarmed = 0
            *set unarmed 1
          *goto trainim
        *hide_reuse #Ask Syphel for his recommendation.
          *if syrel >= 40
            "Well, what kind of fighting style do you want to use?"
            *goto syrec2
          *if syrel < 40
            "I don't know," he shrugs, "Just pick something it looks like ya want to use."
          *goto pickyourweapon2
      *if (lostsy = false)
        "Not a problem, $!{name}," he easily agrees.
      *label syrec2
      *choice
        #I want to completely overpower my opponents.
          *if armor = "plate"
            "Battle axe," he grins, "It's pretty slow, but if ya can take a few hits, use it."
            *goto pickyourweapon2
          *else
            "Longsword," he gestures to the weapon, "Faster than an axe, but still has some weight to it."
            *goto pickyourweapon2
        #I want to be faster than my opponents.
          "Shortsword, then," gestures to it, "Or a dagger. Hell, two daggers if ya think ya can handle it."
          *goto pickyourweapon2
        #I want to keep a distance between me and my opponents.
          "Pollaxe," he nods, "Or a longbow if ya want to be even further away."
          *goto pickyourweapon2
        #I just want to look like I can do something.
          *if origin = "Sedel"
            "Longbow," he says with a grin. "Elves look particularly menacing when holding one."
            *goto pickyourweapon2
          *else
            "Battle axe, then," he nods, "Or ya can try to double wield swords, but ya'll probably hurt yarself showing off."
            *goto pickyourweapon2
    *label trainim
    *if (lostsy = false)
      "Not a problem, $!{name}," he easily agrees.
    *set currentweap (weapon)
    You find that Syphel is quite skilled with a variety of weapons and techniques.
    
    *if weapon = "longsword"
      "It's not really a one handed weapon," he explains, as you practice on a training dummy, "If ya want to put the kind of force ya're supposed to into it, use both hands."
      
    *if weapon = "shortsword"
      "A one handed sword like that is pretty easy to get the hang of," he explains, as you practice on a training dummy, "Ya'll be an expert in no time."
      
    *if weapon = "dual swords"
      "Dual wielding anything takes a lot'a practice," he explains, as you practice on a training dummy, "Just try not to use them in an actual battle until ya get more practice in. I don't want to find out ya lost a hand because'a this."
      
    *if weapon = "battle axe"
      "An axe like that can slow ya down if ya're not used to it's weight," he explains, as you practice on a training dummy, "Ya'll get faster with it the more ya use it, though.
    
    *if weapon = "pollaxe"
      "This thing may not look like it, but it can punch through armor with a good enough swing," he explains, as you practice on a training dummy, "It's easy to block or counter with it, too."
      
    *if weapon = "dagger"
      "Slicing is good and all, but stabbing is more effective on armored targets," he explains, as you practice on a training dummy, "Just be smart and look for a weak point."
      
    *if weapon = "dual daggers"
      "Ya better learn to be quick with those," he explains, as you practice on a training dummy, "Figure out what ya're doing with the second dagger while ya're swinging the first."
      
    *if weapon = "longbow"
      "The important thing to remember is to not get yarself stuck in a small area with that thing," he explains, as you practice on a training dummy, "Also, if yar enemies get too close to ya, don't panic. There's always something ya can do."
      
    *if weapon = "unarmed"
      "If ya want to be up close and personal like this, ya're going to want to be fast," he explains, as you practice on a training dummy, "Or at least be able to take a few hits."
      
    By the time your training session ends, you're feeling pretty good about holding your own in a fight.
    
    "Might as well keep it," Syphel shrugs when you try to return your borrowed equipment, "I've got tons. Also, here."
    He tosses something shiny at you, which you reflexively catch without thinking. Luckily, it's just a key.
    
    "If ya ever want to come in here to train, go ahead," he explains, "I'm usually not here, anyway."
    *if combat = 0
      *set combat 1
    
    *if weapon = "shortsword"
      *set sword + (effort*5)
    *if weapontype = "sword"
      *set sword + (effort*5)
    *if weapontype = "axe"
      *set axe + (effort*5)
    *if weapontype = "dagger"
      *set dagger + (effort*5)
    *if weapontype = "bow"
      *set bow + (effort*5)
    *if weapontype = "none"
      *set unarmed + (effort*5)
    *if weapon = "dual swords"
      *set sword %- 1
    *set lostsy false
    *set keyaccess true
    *set weaponpicked true
    *set actcounter + 1
    *if actcounter = 2
      *goto secondactdone
    *goto firstactdone
  *if origin = "Capel"
    *hide_reuse #I'll practice fate tracing.
      Regardless of how hard you try, you cannot properly trace any of the fate lines.
      
      You do feel as if you're finding the lines of fate much more quickly when you scry, however.
      *set magic %+ (effort*2)
      *set actcounter + 1
      *if actcounter = 2
        *goto secondactdone
      *goto firstactdone
  *if origin = "Asylia"
    *hide_reuse #I haven't painted in a long time. I'll give it a shot while I still have the time.
      You feel utterly uninspired, but manage to make a few decent sketches, at least.
        
      Despite your failure to actually paint anything, you do feel calmer and more at ease.
      *set inspiring %+ (effort*3)
      *set actcounter + 1
      *if actcounter = 2
        *goto secondactdone
      *goto firstactdone
  *if ((origin = "Monaire") or (tgdiscovered))
    *hide_reuse #I'll visit the training grounds.
      *set tgdiscovered true
      You've never actually enrolled to be trained here.
      *if origin = "Monaire"
        Everything you learned was at a small outpost on the outskirts of the capital city.
        The Imperial training grounds were reserved for officers much higher ranked than you had been.
      *if origin != "Monaire"
        In fact, the Empire didn't train you at all.
        For a moment, you wonder if this is standard for all Imperial guardsmen, or just you.
      
      You spot several groups scattered about, undergoing rigorous drills.
      There is also an area where you can practice with training swords.
      *choice
        #I'll watch the troops for while.
          *set renown %+ 5
          Even if you mean to just watch, the troops are immediately at attention as soon as you approach.
          
          "Reaver $!{surname}," the Sergent in charge of the group greets you with crisp salute.
          
          All eyes set on you, waiting for some sort of response.
          
          *choice
            #I encourage them to keep up the good work.
              "Yes, ${sir}," the Sergent proudly grins.
              The troop go back to their training, though you notice that they seem more enthusiastic now.
              *set inspiring %+ 5
              *goto trainingyard
            #I point out whatever flaws I find in their formation.
              *set intel %+ 3
              *set inspiring %- 3
              The Sergent frowns as you point out your observations, and the soldiers themselves seem to get more and more nervous as you continue talking.
              
              By the end of it all, you've extracted several promises from the Sergent in regards to getting the group up to your standards.
              They return to their training, more vigorous than before.
              *goto trainingyard
            #I tell them a witty joke. They need to lighten up.
              *set intel %+ 3
              *set inspiring %+ 3
              You get a few anonamous snickers, but for the most part, the soldiers just look uncomfortable, as if unsure of how to respond.
              
              "...Good one, ${sir}," the Sergent hesitantly says, followed by an unconvincing chuckle.
              
              Some people just don't appreciate good humor.
              The troop returns to their training, but you notice that you're getting more curious glances from the soldiers than before.
              *goto trainingyard
            #Why are they wasting time talking to me instead of doing something useful?
              You tell them as much, and they immediately go back to their training.
              You notice that they seem to be putting forth more effort than before.
              *set inspiring %- 5
              *goto trainingyard
        #I'll go train by myself.
          *if combat = 0
            *set combat 1
          *if sword = 0
            *set sword 1
          You grab a dull training sword and practice your swordsmanship on a training dummy in a corner of the yard.
          
          By the time your muscles start burning, you feel as if the fluidity of your movements have improved.
          *set combat %+ (effort*2)
          *set sword %+ (effort*5)
          *goto trainingyard
      *label trainingyard    
      *set actcounter + 1
      *if actcounter = 2
        *goto secondactdone
      *goto firstactdone
  *if origin = "Ehl"
    *hide_reuse #I think I'll write a book.
      *set book (effort*5)
      *set intel %+ (effort*3)
      You've written books before, most of them sitting in your study in Ehl.
      Now's as good a time as any to write another covering the strange and interesting things you've discovered in this strange land.
      
      You sit at the fine crafted desk in your chambers and start the long process.
      *set actcounter + 1
      *if actcounter = 2
        *goto secondactdone
      *goto firstactdone
  *if ((combat > 0) and (weaponpicked)) or (origin = "Sedel")
    *hide_reuse #I think I'll challenge Syphel to a spar.
      *if lostsy
        Finding Syphel wasn't hard. Your attendant directed you toward a private training room near the military training wing of the Imperial Palace.
        This wing has a different energy than the rest of the Palace, which seems to suit someone as lively as Syphel well.
        *goto sparintro1
      *label sparintro1
      *if syspar = 1
        
        "Again?" he asks when you propose the challenge.
        *goto sparintro2
      *if syspar = 0
        
        "Ya sure ya want to do that?" he asks when you propose the challenge. 
        *goto sparintro2
      *label sparintro2
      *if lostsy
        "Fine. Pick a weapon."
        
        He gestures to the weaponry mounted on the wall of the training room.
        
        *if origin = "Sedel"
          You've had training with swords and bows, and feel relatively comfortable with them.
          *goto pickyourweapon
        *elsif origin = "Monaire"
          You've had training with a sword, and feel relatively comfortable with the weapon.
          *goto pickyourweapon
        *elsif origin = "Ehl"
          The only weapons you've ever held in your life were a sword, which you never used, and a gun, which this continent utterly lacks.
          *goto pickyourweapon
        *elsif ((origin = "Capel") or (origin = "Asylia")) and (unarmed > 0)
          You have next to no experience with any weaponry, but Syphel did teach you some hand-to-hand moves.
          *goto pickyourweapon
        *else
          *goto pickyourweapon
        *label pickyourweapon
        *choice
          #Take the longsword.
            *if sword = 0
              *set sword 1
            *set weapon "longsword"
            *set weapontype "sword"
            *goto sparim
          #Take the shortsword.
            *if sword = 0
              *set sword 1
            *set weapon "shortsword"
            *set weapontype "sword"
            *goto sparim
          #Take both swords.
            *if sword = 0
              *set sword 1
            *set weapon "dual swords"
            *set weapontype "sword"
            *goto sparim
          #Take the battle axe.
            *if axe = 0
              *set axe 1
            *set weapon "battle axe"
            *set weapontype "axe"
            *goto sparim
          #Take the pollaxe.
            *if axe = 0
              *set axe 1
            *set weapon "pollaxe"
            *set weapontype "axe"
            *goto sparim
          #Take a dagger.
            *if dagger = 0
              *set dagger 1
            *set weapon "dagger"
            *set weapontype "dagger"
            *goto sparim
          #Take two daggers.
            *if dagger = 0
              *set dagger 1
            *set weapon "dual daggers"
            *set weapontype "dagger"
            *goto sparim
          #Take a longbow.
            *set weapon "longbow"
            *set weapontype "bow"
            *if bow = 0
              *set bow 1
            *goto sparim
          #I don't need anything but my fists.
            *if unarmed = 0
              *set unarmed 1
            *goto sparim
          *hide_reuse #Ask Syphel for his recommendation.
            *if syrel >= 40
              "Well, what kind of fighting style do you want to use?"
              *goto syrec
            *if syrel < 40
              "I don't know," he shrugs, "Just pick something it looks like ya want to use."
              *goto pickyourweapon
        *label syrec
        *choice
          #I want to completely overpower my opponents.
            *if armor = "plate"
              "Battle axe," he grins, "It's pretty slow, but if ya can take a few hits, use it."
              *goto pickyourweapon
            *else
              "Longsword," he gestures to the weapon, "Faster than an axe, but still has some weight to it."
              *goto pickyourweapon
          #I want to be faster than my opponents.
            "Shortsword, then," gestures to it, "Or a dagger. Hell, two daggers if ya think ya can handle it."
            *goto pickyourweapon
          #I want to keep a distance between me and my opponents.
            "Pollaxe," he nods, "Or a longbow if ya want to be even further away."
            *goto pickyourweapon
          #I just want to look like I can do something.
            *if origin = "Sedel"
              "Longbow," he says with a grin. "Elves look particularly menacing when holding one."
              *goto pickyourweapon
            *else
              "Battle axe, then," he nods, "Or ya can try to double wield swords, but ya'll probably hurt yarself showing off."
              *goto pickyourweapon
      *if (lostsy = false)
        *label sparim
        *set currentweap (weapon)
        Syphel grins as he pulls a large axe
        *if weapon = "battle axe"
          of his own
        down from the wall. "Now that ya have a fighting chance, I don't mind.
        Ready, $!{name}?" he asks, a determined glint in his eyes.
        
        *if weapon != "unarmed"
          "Ready," you confirm, wielding your ${weapon}.
          *goto sparstart
        *if weapon = "unarmed"
          "Ready," you confirm.
          *goto sparstart
        *label sparstart
        
        He comes at you fast, head on.
        
        *label onthedefense
        *set defcounter +1
        *choice
          *hide_reuse #I brace myself to take the full impact of the hit and get ready to counter.
            *set combat %+ (effort*2)
            You prepare to take the blow.
            *label ohwell
            *if armor != "plate"
              It never comes, however. Syphel stops the swing just before it hits you.
              He doesn't look happy, either.
              
              "Are ya crazy?" he asks.
              
              You blink in confusion.
              
              *if ((armor = "gown") or (armor = "coat"))
                "As nice nice as yar fancy clothes are, unless someone's attacking ya with a chilly breeze, they're not going to help ya. Dodge!"
                *goto nowin1
              *elsif armor = "robes"
                "I think I understand the concept'a 'magic' armor, but what makes ya think that robe's going to stop an axe swing?"
                
                "...It's magic?" you respond, not knowing a better answer.
                
                "I'm not testing that on ya, and don't ya test it yarself in a battle either. Dodge!"
                *goto nowin1
              *elsif armor = "clothing"
                "What the hell makes you think ya can take a hit from an axe with no armor on?! Dodge!"
                *goto nowin1
              *else
                "That kind of reinforced armor will stop a lot'a things, but axes aren't one of them, in case ya didn't figure that out. Next time, dodge!
                *goto nowin1
              *label nowin1
              He pulls the axe away from you. "The last thing I want to hear is that ya died somewhere because you did something stupid like this. Spar over. My win."
              *goto sparendlose
            *elsif armortype = "light"
              *if combat >= 15
                The sheer force knocks you back a step, but you manage to maintain your balance.
                This closes the opportunity to counter, however, as you find yourself on the defensive now.
                *set combat %+ (effort*2)
                *set scratched true
                *goto sparbdef
              *else
                The sheer force of it knocks you flat on your back.
                It take you a second to notice the startling image of Syphel's axe wedged in your armor.
                Syphel frowns as he pulls it out.
                
                "Ya know," he starts talking as he helps you to your feet, "against a normal person with normal weapons, ya would've been fine.
                If someone looks like they have a well made heavy weapon, and seems to know how to use it, don't let them hit ya with it. I could've killed ya."
                
                You inspect yourself, but find that you're completely alright.
                There is, however a deep superficial notch in your armor from the blow.
                
                "You couldn't tell me that before we started?" you ask, "I just bought this."
                
                "Let it be a reminder to dodge, next time," he smirks, "Spar over. My win."
                *set combat %+ (effort*2)
                *set knicked true
                *goto sparendlose
            *elsif armortype = "full"
              The axe lands a solid blow on you, but your armor is good enough to take it.
              It'll bruise, but at least you have an opening to counter now.
              *set combat %+ (effort*2)
              *goto sparboff
            *else
              *set combat %+ (effort*2)
              The axe doesn't hit you with full force, instead striking one of the hard spikes and glancing off to the side.
              Syphel looks honestly surprised.
              So surprised, in fact, that you easily catch him off guard by
              *if ((weapontype = "sword") or (weapontype = "axe")) or (weapontype = "dagger")
                pointing a blade at his neck.
                *if weapontype = "sword"
                  *set sword %+ (effort*2)
                *if weapontype = "axe"
                  *set axe %+ (effort*2)
                *if weapontype = "dagger"
                  *set dagger %+ (effort*2)
                *goto sparwin3
              *elsif currentweap = "unarmed"
                sending him backward with a good punch.
                You've got the offensive now.
                *set unarmed %+ (effort*2)
                *goto sparboff
              *else
                pointing an arrow at his neck.
                *set bow %+ (effort*2)
                *goto sparwin3
              *label sparwin3
              
              "Wait a minute, that's not how this was supposed to turn out," he frowns.
              
              "Your fault for thinking my that my armor's 'impractical', isn't it?" you point out.
              
              "Well... How was I supposed to know? It looks ridiculous," Syphel defensively shoots back, "Fine, fine, I yield. You win."
              He drops his weapon and raises his hands in defeat.
              *goto sparendwon
          *hide_reuse #I'll move out of the way at the last second and look for a better opportunity.
            *if ((armortype = "heavy") or (armortype = "full"))
              Your lack of agility in ${armortype} plate armor prevents you from dodging in time.
              
              *set combat %+ (effort*2)
              *goto ohwell
            *elsif ((armortype = "light") and (combat < 10))
              Unfortunately, you wait just a bit too late to give yourself enough time to dodge.
              You take the full impact of the blow.
              
              The sheer force of it knocks you flat on your back.
              It takes you a second to notice the startling image of Syphel's axe wedged in your armor.
              Syphel frowns as he pulls it out.
              
              "Ya know," he starts talking as he helps you to your feet, "against a normal person with normal weapons, ya would've been fine.
              If someone looks like they have a well made heavy weapon, and seems to know how to use it, don't let them hit ya with it. I could've killed ya."
              
              You inspect yourself, but find that you're completely alright.
              There is, however a deep superficial notch in your armor from the blow.
              
              "You couldn't tell me that before we started?" you ask, "I just bought this."
              
              "Let it be a reminder to dodge better, next time," he smirks, "Spar over. My win."
              *set combat %+ (effort*2)
              *goto sparendlose
            *elsif ((armortype = "light") and (combat >= 10))
              The axe only lands a glancing blow as you barely move out of the way in time.
              *set combat %+ (effort*2)
              *set intel %+ (effort*2)
              *goto sparcont3
            *elsif ((armortype = "leather") or (armortype = "magic"))
              You manage to move out of the way just in time.
              *set combat %+ (effort*2)
              *set intel %+ (effort*2)
              *goto sparcont3
            *else
              Without the hindrance of armor, you do so easily.
              *set combat %+ (effort*2)
              *set intel %+ (effort*2)
              *goto sparcont3
            *label sparcont3
            *if intel >= 10
              *set intel %+ (effort*2)
              *goto sparboff2
            *else
              Unfortunately, Syphel is quickly on the offensive once again.
              *goto sparbdef
          *hide_reuse #I swing at him before he can get to me.
            *set combat %+ (effort*2)
            *if currentweap = "unarmed"
              You don't have near the reach to pull this off.
              
              Apparently, that doesn't stop you from trying.
              You're rewarded with a painful hit to the fist from the flat side of the axe.
              
              The sting replaces all feeling in your hand, rendering it basically useless for the moment.
              
              Syphel doesn't even try to continue the spar, frowning intently at you instead.
              "That was reckless," he comments, "Do me a favor and try anything else but that if ya ever get in a fight against something longer than yar arm. Spar over. My win."
              *set unarmed %+ (effort*2)
              *goto sparendlose
            *elsif currentweap = "dagger"
              You don't have near the reach to pull this off.
              
              Apparently, that doesn't stop you from trying.
              You're rewarded with a painful hit to the hand from the flat side of the axe.
              
              The sting replaces all feeling in your hand, and your dagger goes flying across the room.
              
              Syphel doesn't even try to continue the spar, frowning intently at you instead.
              "That was reckless," he comments, "Do me a favor and try anything else but that if ya ever get in a fight against something longer than yar arm. Spar over. My win."
              *set dagger %+ (effort*2)
              *goto sparendlose
            *elsif currentweap = "dual daggers"
              You don't have near the reach to pull this off.
              
              Apparently, that doesn't stop you from trying.
              You're rewarded with a painful hit to the hand from the flat side of the axe.
              
              The sting replaces all feeling in your hand, and your attacking dagger goes flying across the room.
              Situations like this are why you have another one.
              *set dagger %+ (effort*2)
              *set currentweap "dagger"
              *goto sparboff
            *elsif currentweap = "dual swords"
              *if ((sword < 10) or (combat < 10))
                You try, but aren't fast enough.
                Syphel easily sidesteps your attack.
                
                He's a lot faster in that plate armor, than you gave him credit for.
                *set sword %+ (effort*2)
                *goto sparendlose
              *else
                Syphel stops his attack to dodge.
                He's surprisingly fast in his plate armor, but you have the offensive advantage now.
                *set sword %+ (effort*2)
                *goto sparboff2
            *elsif currentweap = "longbow"
              Surprisingly, your longbow makes for an excellent improvised staff.
              
              Syphel has to stop his attack to dodge.
              He's surprisingly fast in his plate armor, but you have the offensive advantage now.
              *set bow %+ (effort*2)
              *goto sparboff2
            *elsif ((currentweap = "longsword") or (currentweap = "shortsword"))
              *if sword >= 5
                Syphel stops his attack to dodge.
                He's surprisingly fast in his plate armor, but you have the offensive advantage now.
                *set sword %+ (effort*2)
                *goto sparboff2
              *else
                You try, but aren't fast enough.
                Syphel easily sidesteps your attack and readies himself oncemore.
                
                He's a lot faster in that plate armor, than you gave him credit for.
                *set sword %+ (effort*2)
                *goto sparbdef
            *elsif currentweap = "pollaxe"
              Your pollaxe does the job beautifully, thanks to it's extended length.
              
              Syphel has to stop his attack to dodge.
              He's surprisingly fast in his plate armor, but you have the offensive advantage now.
              *set axe %+ (effort*2)
              *goto sparboff2
            *else
              *if axe >= 5
                Syphel stops his attack to dodge.
                He's surprisingly fast in his plate armor, but you have the offensive advantage now.
                *set axe %+ (effort*2)
                *goto sparboff2
              *else
                You try, but aren't fast enough.
                Syphel easily sidesteps your attack and readies himself once more.
                
                He's a lot faster in that plate armor, than you gave him credit for.
                *set axe %+ (effort*2)
                *goto sparbdef
          *hide_reuse #I'll block the attack, and look for a chance to counter.
            *if ((weapontype = "dagger") and (dagger < 10)) or ((weapontype != "axe") and (weapontype != "sword"))
              *set combat %+ (effort*2)
              Syphel's axe comes down on your defense, but the blow never connects.
              He seems to have stopped the swing just before it could hit anything.
              He doesn't look particularly happy, either.
              
              "Ya want to tell me what's wrong with this picture?" he cocks an eyebrow at you.
              
              You blink, confused.
              
              *if currentweap = "dagger"
                "This is an axe. A big axe," he emphasizes, "Yar dagger isn't going to help ya much with this coming at ya. Against anything else, that might'a worked."
                *goto sparlose3
              *elsif currentweap = "dual daggers"
                "This is an axe. A big axe," he emphasizes, "Yar daggers aren't going to help ya much with this coming at ya. Against anything else, that would've worked fine."
                *goto sparlose3
              *elsif currentweap = "longbow"
                "Ya're using a piece'a wood to block an axe," he answers for you, "How did that seem like a good idea to ya?" 
                *goto sparlose3
              *else
                "Ya can't block an axe with yar hands," he answers for you, "Trust me. I've seen people try."
                *goto sparlose3
              *label sparlose3  
              
              He sets the head of his axe down on the floor next to him. "I'd better not ever hear that ya died because ya did something stupid like that. Spar over. My win."
              *goto sparendlose
            *elsif ((combat < 10) or (sword < 20)) and (currentweap = "dual swords")
              You use both sword to block the impact of the axe, and immediately regret it.
              
              Syphel skillfully maneuvers the axe to strike your attempted defense downward, leaving you wide open to a second attack.
              Unfortunately, he takes full advantage of this, and you soon find a sharp curved blade shoved in your face.
              
              "That was actually a pretty good try," Syphel says with a chuckle as he lowers the head of his axe to the floor.
              "When ya have two weapons, try not to render them both useless at the same time. You'll figure these things out with experience, I guess. Spar over. My win."
              *set combat %+ (effort*2)
              *set sword %+ (effort*2)
              *goto sparendlose
            *elsif ((currentweap = "dual daggers") and (dagger >= 10)) and (combat >= 10)
              You manage to block the attack with one of your daggers, but not without some difficulty.
              Still, your other dagger is free for an attack.
              *set combat %+ (effort*2)
              *set dagger %+ (effort*2)
              *goto sparboff
            *elsif currentweap = "battle axe"
              You manage to block the attack, but not without some difficulty.
              Still, your plan is relatively successful.
              *set combat %+ (effort*2)
              *set axe %+ (effort*2)
              *goto sparboff
            *elsif currentweap = "pollaxe"
              You manage to block the attack surprisingly easily with your pollaxe.
              *set combat %+ (effort*2)
              *set axe %+ (effort*2)
              *goto sparboff
            *elsif ((currentweap = "dual swords") and (sword >= 20)) and (combat >= 10)
              You manage to block the attack with your shortsword, but not without some difficulty.
              Still, your longsword is free for an attack.
              *set combat %+ (effort*2)
              *set sword %+ (effort*2)
              *goto sparboff
            *else
              You manage to block the attack with your ${currentweap}, but not without some difficulty.
              Still, your plan is relatively successful.
              *set combat %+ (effort*2)
              *if sword = 0
                *set sword 1
              *set sword %+ (effort*2)
              *goto sparboff
          *if currentweap = "longbow"
            #I stand my ground, grab an arrow and draw my bow as fast as possible.
              *set combat %+ (effort*3)
              Surely no one would be stupid enough to try and keep fighting with that in their face.
              *if intel = 0
                *set intel 1
              *set intel %+ (effort*3)
              *if bow < 10
                *set combat %+ (effort*2)
                Unfortunately, you aren't skilled enough to do this, yet.
                You barely nock the arrow before the axe blade comes at you.
                
                Luckily, Syphel stops the swing just before it reaches you.
                He looks almost impressed.
                
                "If ya had actually managed to draw that thing, I would've been screwed," he comments, setting the head of the axe on the hard floor,
                "A bit more practice, and I'm sure ya'll get it. Looks like a win for me, though."
                *goto sparendlose
              *else
                *set combat %+ (effort*2)
                *set bow %+ (effort*2)
                You manage to do so, though barely in time.
                As soon as your arrow is aimed at Syphel, he slides to a stop, drops his weapon, and puts his hands up.
                
                "Whoa, I'm not facing that," he says, "Not by myself, anyway. Ya win."
                
                "That's all it took?" you asked, surprised at the speed in which the spar was over.
                *if origin = "Sedel"
                  
                  "I know better than to expect to win a fight against an Elf with a bow in ${his} hands," Syphel admits.
                  
                  "Reaver Triolo didn't seem to have a problem with me trying to shoot him," you frown.
                  
                  Syphel merely shrugs. "Some people are more skilled than I am, I guess," he mumbles, looking rather unhappy.
                  *goto sparwin4
                *else
                  
                  "Expecting an epic battle?" he quirks his eyebrow at you, "This plate armor's pretty strong, but I don't think I want to test it against projectile piercing weapons while I'm in it. Not at this range."
                  *goto sparwin4
                *label sparwin4
                
                You relax your bow and put your arrow away.
                
                "Just don't expect that to work against multiple opponents," he cautions, "A group can take ya down and they'll probably know it."
                *goto sparendwon
          *if defcounter >= 2
            #I give up.
              "Just like that?" Syphel asks after you lower your weapon in defeat. "No, actually, sometimes it's good to be able to recognize when you can't win.
              *if syrel >= 60
                We'll just call it a draw. No wins, no losses," he grins.
                *set syrel %+ (combat/3)
                *goto sparendlose
              *else
                Guess that's a win for me," he grins.
                *set syrel %+ (combat/5)
                *goto sparendlose
        *label sparbdef
        
        Well, that didn't work as well as you'd hoped...
        
        Syphel positions himself for another direct attack.
        
        *goto onthedefense
        *label sparboff
        
        Syphel is in no position to immediately attack now, but he is still rather close to you and the situation will quickly change if you don't act fast.
        *set prox 0
        *goto sparboff3
        *label sparboff2
        *set prox 1
        
        Syphel is off balance, and will likely not attack immediately. This will change soon if you don't act now.
        *label sparboff3

        *choice
          #I'll take this chance to get some distance between us.
            *if ((armortype = "heavy") or (armortype = "full"))
              Your armor makes it hard to move quickly, and you don't get as much distance as you'd like before Syphel is attacking you again.
              *set combat %+ (effort*2)
              *goto sparbdef
            *else
              It may have seemed like a good idea at the time, but now, Syphel is charging at you again and you're right back where you started.
              *set combat %+ (effort*2)
              *goto sparbdef
          *if ((currentweap = "dual daggers") or (currentweap = "dual swords")) and ((intel >= 5) and (prox < 2))
            #I've got my opening. Having two weapons will easily let me take advantage of that.
              *if prox = 0
                With Syphel's axe momentarily out of the way, you easily move one of your ${weapontype}s to his neck.
                
                Seeing this, Syphel conceeds the spar by placing the head of his axe on the floor.
                
                "Nice counter, $!{name}," he ernestly praises you, "Pretty soon, no one will be able to beat ya with those ${weapontype}s.
                *goto sparwin5
              *else
                You move one of your ${weapontype}s to an attack position while moving the other to the only position Syphel could reasonably move to in order to dodge the first.
                
                Syphel freezes in place, clearly seeing his lack of options.
                After a moment, he grins and sets the head of his axe down on the floor. "Clever, $!{name}," he ernestly compliments, "I think those ${weapontype}s suit ya perfectly. Your win."
                *goto sparwin5
              *label sparwin5
              *set combat %+ (effort*2)
              *if currentweap = "dual daggers"
                *set dagger %+ (effort*5)
              *if currentweap = "dual swords"
                *set sword %+ (effort*4)
              *goto sparendwon
          *if ((intel > 15) and (armor != "plate"))
            *hide_reuse #He may be fast, but his actions aren't fluid. I'll dodge until I find a good opening.
              Syphel begins his direct attacks again, though you manage to stay out of the way, if barely.
              It seems that he is fully capable of moving faster, but is limiting himself, probably in an attempt to take it easy on you.
              Why else would he be sparing you with fully sharpened weaponry, unless he didn't believe that you would hit him, and he did not intend to hit you?
              
              Perhaps you can take advantage of his overconfidence with something so simple that it's unexpected.
              
              You stop abruptly and
              *if currentweap = "pollaxe"
                thrust the butt end of your pollaxe directly in front of his feet.
              *if currentweap != "pollaxe"
                thrust your foot directly in his path.
              
              Easily enough, he takes a dive. Syphel is back on his feet as quickly as he fell, a look of pure surprise on his face.
              *if currentweap = "unarmed"
                Luckily, by this time you have your fist looming threateningly close to his face, though you're unsure if you should hit him in a friendly spar.
                *goto sparwin6
              *else
                Luckily, by this time you have your weapon pointed threateningly at him.
                *goto sparwin6
              *label sparwin6
              
              "My win?" you ask.
              
              "That was... suspiciously cheat-like," he raises an eyebrow at you, conflicting emotions easily readable on his face. "That was... my fault, I guess. Ya win... surprisingly..."
              *set combat %+ (effort*2)
              *if currentweap = "pollaxe"
                *set axe %+ (effort*2)
              *goto sparendwon
          *if ((inspiring <= 55) and (intel >= 10))
            *hide_reuse #I'll taunt him. Maybe he'll get angry enough to make a mistake.
              "Having trouble?" you smirk.
              
              "Trouble?" Syphel immediately disengages you and steps back, looking like you just took a cheap shot at him.
              "Why would I be having trouble with ya? I'm taking it easy on ya to give ya a chance."
              
              "Or you aren't as good as you think you are," you chime in.
              
              At this, Syphel's jaw ticks. "Ya want to test that?" He throws his axe to the floor, "We'll do this the hard way, then."
              
              Syphel comes at you faster than before, completely unarmed.
              *if unarmedspecial
                
                You grin. Syphel himself taught you how to deal with this before.
                
                Using his own speed and weight against him, you manage to throw him off balance and to the ground.
                Syphel doesn't move from where he landed. After a moment, it occurs to you that you might have injured him.
                
                "Crafty, ${surname}," he exhales sharply before getting up. It doesn't look like you wounded anything other than his pride.
                "I forgot that I taught ya that," he grimaces, "I guess ya win this one."
                *set combat %+ (effort*5)
                *set intel %+ (effort*5)
                *set unarmed %+ (effort*5)
                *set syrel %- 5
                *set inspiring %- 5
                *set renown %+ 5
                *goto sparend
              *else
                In a moment, his full rage is upon you.
                You don't even have time to react before you find yourself disarmed and pinned face down on the ground, your arm twisted painfully behind you.
                
                "Let's get this straight, ${surname}," he practically growls, "I'm the best damned fighter in this Empire, and there's nothing
                *if origin = "Monaire"
                  some nobody
                *if origin = "Ehl"
                  a foreign parasite
                *if origin = "Capel"
                  some useless Sage
                *if origin = "Asylia"
                  Asylian garbage
                *if origin = "Sedel"
                  some pointy eared freak
                like ya is ever going to be able to do against me. Got it?"
                
                You nod, if only to get him to release your aching arm.
                
                "Great," he instantly releases you. "Now, instead'a tauting each other, I think we should go back to being friends."
                
                You pick yourself up and instantly feel like his intense gaze set on you, as if he's expecting you to agree with him.
                
                *choice
                  #I nod.
                    His usual grin quickly replaces his previous scowl, but he says nothing further to you.
                    *set syrel %- 20
                    *set combat %+ (effort*2)
                    *set inspiring %- 10
                    *goto sparendlose
                  #I shake my head.
                    He regards you with an unusual smile, not his normal happy grin, but says nothing further to you.
                    *set syrel %- 50
                    *set combat %+ (effort*2)
                    *set inspiring %- 10
                    *goto sparendlose
          *hide_reuse #Now's the time to attack relentlessly until I win.
            *set combat %+ 2
            You put everything you have into unleashing a flurry of attacks.
            
            Syphel fluidly dodges everything you throw at him.
            In fact, after a time he actually starts laughing, as if he's genuinely enjoying himself.
            
            *choice
              #Well, this isn't working. I'll try something else.
                *goto onthedefense
              #How dare he laugh at me?! I attack more agressively!
                You boost your attacks with your newfound fury.
                Unfortunately, this only adds a new level of enjoyment to Syphel's fun.
                
                Eventually, you wear yourself out and cannot continue the spar.
                
                "I think that's my win," Syphel smiles brightly as you stand, hands on knees, panting.
                *if ((sword >= 15) and (weapontype = "sword")) or ((dagger >= 15) and (weapontype = "dagger"))
                  "Actually, ya're pretty good with a blade. That might actually work on someone that isn't me.
                *if ((sword < 15) and (weapontype = "sword")) or ((dagger < 15) and (weapontype = "dagger"))
                  "Once ya get more experience with yar ${weapon}, I'm sure ya'll be fine with that tactic.
                *if ((axe >= 15) and (weapontype = "axe"))
                  "Actually, ya're pretty good with a ${weapon}. That might actually work on someone that isn't me.
                *if ((axe < 15) and (weapontype = "axe"))
                  "Once ya get more experience with yar ${weapon}, I'm sure ya'll be fine with that tactic.
                *if ((bow >= 15) and (weapontype = "bow"))
                  "Actually, ya're pretty good with a bow. That might actually work on someone that isn't me.
                *if ((bow < 15) and (weapontype = "bow"))
                  "Once ya get more experience with yar ${weapon}, I'm sure ya'll be fine with that tactic.
                *if ((unarmed >= 15) and (weapontype = "none"))
                  "Actually, ya're pretty good with yar fists. That might actually work on someone that isn't me.
                *if ((unarmed < 15) and (weapontype = "none"))
                  "Once ya get more experience with unarmed fighting, I'm sure ya'll be fine with that tactic.
                Rage fighting can be useful, as long as ya try not to do something stupid."
                *set combat %+ (effort*2)
                *if weapontype = "none"
                  *set unarmed %+ (effort*3)
                *if weapontype = "sword"
                  *set sword %+ (effort*3)
                *if weapontype = "dagger"
                  *set dagger %+ (effort*3)
                *if weapontype = "axe"
                  *set axe %+ (effort*3)
                *if weapontype = "bow"
                  *set bow %+ (effort*3)
                *goto sparendlose
          #I don't know what to do...
            During your hesitation, Syphel comes in for another attack.
            *goto sparbdef
      *label sparendwon
      *page_break
      *set renown %+ 3
      
      Winning a spar against a Reaver is nothing to scoff at, but part of you can't help but wonder if Syphel wasn't taking it easy on you...
      *goto sparend
      *label sparendlose
      
      You may not have won this time, but you feel like you've learned something from it, at least.
      *set combat %+ (effort*2)
      *goto sparend
      *label sparend
      *if scratched
        
        It's only after you leave that you notice a long groove in the chestpiece of your armor.
        It's purely superficial, and you doubt it's the last your armor will recieve, but it reminds you of how glad you are to have some sort of protection.
      *set lostsy false
      *set syspar +1
      *set actcounter + 1
      *if actcounter = 2
        *goto secondactdone
      *goto firstactdone
  *if ((rebel >= 10) or (rebelcount > 3))
    *hide_reuse #I want to just leave the Imperial Palace on my own for a while.
      For once, you're able to leave the Imperial Palace without guards stopping and questioning you.
      
      There isn't much around the Palace, but just being outside of it's walls is liberating.
      *choice
        #Run away!
          You smile at the thought, but know that you can't. Not without a solid plan, at least.
          The Empire would hunt you down relentlessly, and eventually, you'd run out of places to hide.
          *if origin = "Sedel"
            Without your service as leverage, Sedel would be doomed as well.
            
          Maybe one day, you'll have a better opportunity.
          *set rebelcount + 1
          *goto aloner1
        #See what's around.
          Off in the distance, you can see the tall white walls of the Capital.
          *if origin = "Monaire"
            Your family is somewhere within those walls, but you haven't seen them in some time.
          Sadly, it's too far for a casual trip right now.
          
          To the south is some sort of building that almost looks like a temple.
          It looks fairly rundown, as if it had been through some sort of disaster.
          There's a strange, large structure that surrounds it, but you have no idea what it's for.
          
          You also spot a small stream that goes into a heavily forested area near the strange building.
          You think it runs down from the mountains in the distance and leads to somewhere beyond the capital.
          
          There isn't much around other than that, besides open expanses of vivid green grass.
          *set woodsdiscovered true
          *goto aloner1
      *label aloner1
      *set rebel + 2
      *set actcounter + 1
      *if actcounter = 2
        *goto secondactdone
      *goto firstactdone
  *hide_reuse #I'll familiarize myself with the inside of the Imperial Palace.
    This place is, more or less, your place of residence.
    It's about time you figured out where all of the important places in it were.
    
    You're already fairly familiar with the guest wing of the palace.
    
    The the wing that you've claimed a room in is almost completely abandoned, except for the study on the first floor.
    You note that
    *if duska = "Duska"
      Duska
    *if duska = "the attendant"
      your attendant
    has claimed one of the small rooms down the hall from your chambers.
    Also, directly across from your room is a dusty mess that could be made into an office or parlor with a bit of work.
    
    *choice
      #I could use an office.
        *set space "office"
        *goto secondarea
      #I could use a parlor.
        *set space "parlor"
        *goto secondarea
      #I'll just keep looking around.
        *goto continuetour
    
    *label secondarea
    Now, are you actually going to do this yourself? You do have an attendant that isn't doing anything particularly useful most of the time.
    *choice
      #I'll let her do it, then.
        *set spaceproj 100
        You tell your attendant exactly what you want done, and she immediately gets to work on the project as you continue your tour.
        *goto continuetour
      #I'll have her help me, but I won't make her do it by herself.
        Though she does willingly help, you find that your attendant is noticably wary of you and looks nervous in your presence.
        *choice
          #I don't want her afraid of me. I'll see if some small talk will help.
            You coerce her into something like a conversation, although she will only speak when spoken to and keeps her answers brief.
            Still, she looks a bit more relaxed in your presence as time goes on.
            *set maid - 0.25
            *goto djd
          #She's my servant, not my friend. This is how things should stay.
            As she works in complete silence, you can't help but notice that everything she does is done extremely carefully, as if she's doing everything she can to avoid making a mistake in your presence.
            *goto djd
        *label djd
        
        Eventually, the two of you get about halfway done, but the rest will have to wait for another day.
        *set inspiring %+ 3
        *set spaceproj 50
        *goto theplacedone
      #It's my project. I'll do it myself.
        While you aren't able to finish as much as you wanted on your own, you take a certain pride in what you do get done.
        Eventually, you notice that ${duska} has repositioned herself to a spot where she can see what you're doing.
        She makes no actual move to offer you help, however.
        *set inspiring %+ 3
        *set spaceproj 25
        *goto theplacedone
      *if syrel >= 80
        #This isn't somthing ${duska} should be concerned with. I wouldn't mind Syphel's help, though.
          He happily agrees to help, and the two of you very nearly finish your task.
          *set spaceproj 75
          *set syrel %+ 5
          *goto theplacedone
    *label continuetour
    
    You continue walking around, and manage to find an elegant dining hall, a large ballroom, the training yard, and a small area used for detainment.
    *set tgdiscovered true
    
    *if spaceproj = 100
      By the time you get around to check on ${duska}'s progress, your ${space} is already set up.
      She shows you the result, and waits for your assessment of her work.
      
      It's obvious that she must've gotten help from someone in order to have your ${space} ready so fast.
      *if maid < 4
        It isn't quite how you directed her to arrange things, but it is close.
      *if maid >= 4
        Everything is exactly the way you envisioned it, the furniture carefully pollished, and not a speck of dust anywhere.
      *choice
        *if maid < 4
          #This isn't right at all. I make her fix it.
            $!{duska} blanches, but quickly apologizes and gets right to work fixing her errors.
            *set maid + 0.25
            *goto theplacedone
        *if maid < 4
          #Close is good enough for me. I thank her for her work.
            $!{duska} politely excuses herself and retakes her post next to your chamber door.
            *set maid - 0.25
            *goto theplacedone
        #She probably put a lot of effort into making sure this gets done. I make sure she knows it's appreciated.
          $!{duska} tries to restrain a warm smile as she excuses herself back to her post.
          *set maid - 0.25
          *set inspiring %+ 3
          *goto theplacedone
        *if maid >= 4
          #I'll thank her, at least, but nothing else.
            $!{duska} politely excuses herself and retakes her post next to your chamber door.
            *goto theplacedone
        *if maid >= 4
          #It's acceptable, and I let her know, but that's it.
            $!{duska} looks a little disappointed as she excuses herself and retakes her post next to your chamber door.
            *set maid + 0.25
            *goto theplacedone
        *if maid >= 4
          #It's perfect, but I make up something for her to fix. 
            $!{duska} blanches and for a second, it looks like she may even try to correct you.
            However, she stays silent and simply complies, apologizing for her "mistakes" before moving to repair them.
            *set inspiring %- 3
            *set maid + 0.25
            *goto theplacedone
    *label theplacedone
    *set actcounter + 1
    *if actcounter = 2
      *goto secondactdone
    *goto firstactdone
*label firstactdone

It's mid-afternoon. You can do something else, if you'd like.
*goto firstfreetime
*label secondactdone
As you notice the sun setting outside, you conclude that that's enough for today.
A good meal and some rest should help prepare you for your trip tomorrow morning.
*page_break
*if destination = "barith"
  *goto lastnight
*goto trainingrun
*label secondfreetime
*choice
  *hide_reuse #I'll go to the study, for now.
    The study is unoccupied right now.
    
    *if origin = "Asylia"
      *set intel %+ (effort*2)
      You feel a bit more at peace in here, especially with no one to bother you.
    The collection of books is extremely varied, and it isn't difficult to find one you want to read.
    *set intel %+ (effort*3)
    *set actcounter + 1
    *if actcounter = 2
      *goto twondactdone
    *goto onestactdone
  *if syphel
    *hide_reuse #I'll see if I can get Syphel to train me.
      Syphel doesn't seem to be around.
      Maybe you should do something else.
      *set syphel false
      *goto secondfreetime
  *if origin = "Capel"
    *hide_reuse #I'll practice fate tracing.
      You haven't felt this awful about your inability to trace fate since you were five.
      At least back then, you had the priests at the Temple to help you with your problems.
      
      You don't think you've improved much, if any at all.
      *set magic %+ (effort*2)
      *set actcounter + 1
      *if actcounter = 2
        *goto twondactdone
      *goto onestactdone
  *if origin = "Asylia"
    *hide_reuse #I'll work on my art.
      You manage to make a sketch that you're quite proud of, but are uninspired to do much else.
        
      Despite your failure to actually paint anything, you do feel calmer and more at ease.
      *set inspiring %+ (effort*3)
      *set actcounter + 1
      *if actcounter = 2
        *goto twondactdone
      *goto onestactdone
  *if ((origin = "Monaire") or (tgdiscovered))
    *hide_reuse #I'll practice at the training grounds.
      TODO: Practice
      *set actcounter + 1
      *if actcounter = 2
        *goto twondactdone
      *goto onestactdone
  *if ((origin = "Monaire") or (tgdiscovered))
    *hide_reuse #I'll inspect the troops at the training grounds.
      TODO: Inspection
      *set actcounter + 1
      *if actcounter = 2
        *goto twondactdone
      *goto onestactdone
  *if ((combat > 0) and (syphel))
    *hide_reuse #I think I'll challenge Syphel to a spar.
      Unfortunately, Syphel doesn't seem to be here.
      You should probably do something else.
      *set syphel false
      *goto secondfreetime
  *if book > 0
    *hide_reuse #I'll do some writing.
      You get a few pages done. While this isn't your usual subject, your knowledge will be highly valued when, or if, you return to Ehl.
      *set book + (effort*3)
      *set intel %+ (effort*3)
      *set actcounter + 1
      *if actcounter = 2
        *goto twondactdone
      *goto onestactdone
  *if keyaccess
    *hide_reuse #I'll go train by myself in Syphel's training room.
      *if (syphel)
        Syphel doesn't seem to be around, but that's why he gave you a key.
      *if weapon != "unarmed"
        You practice with your ${weapon} alone.
      *if weapon = "unarmed"
        You practice on a training dummy alone.
      
      After a few hours, you feel like you've improved some, though you felt like you learned more when Syphel was teaching you.
      *set combat %+ (effort*2)
      *if weapontype = "sword"
        *set sword %+ (effort*3)
      *if weapontype = "dagger"
        *set dagger %+ (effort*3)
      *if weapontype = "axe"
        *set axe %+ (effort*3)
      *if weapontype = "bow"
        *set bow %+ (effort*3)
      *if weapontype = "none"
        *set unarmed %+ (effort*3)
      *if weapon = "shortsword"
        *set sword %+ (effort*2)
      *if weapon = "dual swords"
        *set sword %- (effort*1)
      *set syphel false
      *set actcounter + 1
      *if actcounter = 2
        *goto twondactdone
      *goto onestactdone
  *if ((rebel >= 10) or (rebelcount > 3))
    *hide_reuse #I want to just leave the Imperial Palace on my own for a while.
      No one says a thing about you leaving, though you do see some questionable glances coming your way.
      You spend some time wandering a small forested area, strangely peaceful compared to the constant warring at the Empire's edge.
      *set rebel + 2
      *set woodsdiscovered true
      *set actcounter + 1
      *if actcounter = 2
        *goto twondactdone
      *goto onestactdone
  *if ((spaceproj > 0) and (spaceproj < 100))
    *hide_reuse #I'll work on my ${space}.
      *if spaceproj = 75
        You're almost done converting the room into your own private ${space}.
        You can probably finish it today on your own.
      *if spaceproj = 50
        You're about halfway done converting the room into your own private ${space}.
        With some help, you can probably get it done today.
      *if spaceproj = 25
        You haven't accomplished much on your own, and you doubt you'll finish today whether you get help from anyone or not.
      *label roomchoice
      *choice
        #I'll work on my own today.
          You continue your task alone, making slow, but steady progress.
          *set spaceproj + 25
          *goto donefortoday
        #I'll have ${duska} help me today.
          *if maid >= 4
            She obediantly complies, and silently joins you in the task.
          *if maid < 4
            She happily joins you, though she continues the work in silence.
          *set  spaceproj + 50
          *goto donefortoday
        *if ((syphel) and (syrel >= 80))
          #I'll see if Syphel can help me today.
            Unfortunately, Syphel doesn't seem to be around.
            *set syphel false
            *goto roomchoice
      *label donefortoday
      *if spaceproj >= 100
        *set spaceproj 100
        
        You manage to complete the finishing touches on your ${space}.
        The room seems to radiate with your own unique energy, a nice change from the unnerving stillness of the rest of the Imperial Palace.
      *if spaceproj = 75
        
        You manage to get quite a bit done, and estimate that it shouldn't take more than another day to finish up here.
      *if spaceproj = 50
        
        You manage to reach what you aproximate to be the halfway mark before you call it a day.
      *set actcounter + 1
      *if actcounter = 2
        *goto twondactdone
      *goto onestactdone
*label onestactdone
*page_break
It's late afternoon. You can do something else, if you'd like.
*goto secondfreetime
*label twondactdone
*page_break
*goto lastnight

*page_break
*comment The optiona training run 
*label trainingrun
It isn't more than a few days later that you stand at the makeshift Imperial fort on the edge of the Jeon capital with Gillen.
Despite what he's been telling you, you doubt that the country is going to simply be handed to you, regardless of how much Gillen helps.

At the very least, this will be a good practice before you have to go off and do this alone.
*finish
*comment TODO: Training Run remove above finish

*set trained true
*set destination "barith"
*page_break
*goto readying





*comment before the real run

*label lastnight

You awaken in the night to the sound of frantic rapping at your door.

"$!{lord}
*if origin = "Capel"
  Sage,"
*if origin != "Capel"
  $!{surname},"
you hear ${duska}'s voice quietly through the door.

Something tells you she won't stop until you answer it, so you begrudgingly get up and do so.

She quickly curtsies, eyes glued to the floor.
"Lord Isoshu insists on seeing you."

"Lord Isoshu?" you try to think of who that is, but your mind is still in a muddled sleepy state.

"I can tell ${him} myself. $!{he}'s right there," the annoyed accent that could only belong to Syphel echos from somewhere down the hallway.

"I'm sorry,
*if male
  my Lords,"
*if female
  my Lady, my Lord,"
${duska} quickly apologizes, allowing Syphel to pass by her and into your room.

He shuts the door behind him, looking more than a bit peeved.

"Why are you here so late?" you mumble at him.

"Dain told me ya were going to speak to the King'a Barith," he frowns.

"What? Just now? In the middle of the night?"

"Well, no. Earlier, but I didn't get a chance to tell ya before now," he says, looking notably concerned, and speaking faster than usual.

"Tell me what?"

"The King'a Barith? Not a nice guy," Syphel warns,
*if ((origin = "Sedel") or (origin = "Asylia"))
  "He's especially not going to like ya. It's
*if ((origin = "Monaire") or (origin = "Ehl"))
  "Don't expect him to be too happy about ya making demands. It's
*if origin = "Capel"
  "As long as he knows ya're a Sage, ya'll probably be okay. Otherwise, it's
practically a suicide mission."

You try and register what Syphel just said. 

*choice
  #"And? I can't NOT go."
    *set rebel + 2
    *if rebel > 100
      *set rebel 100
    "I'm not saying ya shouldn't go," he says, a determined look on his face.
    *goto assistance
  #"Thanks for the warning, but I'm sure I can handle it."
    *set syrel %+ 3
    *set rebel - 2
    *if rebel < 0
      *set rebel 0
    *if ((origin = "Sedel") and (rebel < 10))
      *set rebel 10
    "Yeah, and ya're going to," he says, a determined look on his face.
    *goto assistance
  #"..What?"
    *set syrel %- 3
    "You. Are. Going. To. Die," he slowly enunciates. You notice that he can get rid of his accent when he wants to, though you probably shouldn't be focusing on that at the moment.
    *goto assistance
*label assistance
*if ((weaponpicked = false) and (syrel >= 70))

  You see Syphel hold out something toward you, and catch the glint of a small silvery blade.
  You are instantly awake as you reflexively take a step back.
  It's only then that you notice that he's handing you the handle of a small dagger.
  *set condag true
  
  "Concealable dagger," he explains, "Just keep it on ya, in case."
  
  You cautiously take possession of the weapon. It's small and light, and you should be able to hide it on you very easily.
  
  "Do me a favor and don't cut yarself on that. It's poisoned, and I don't think I have the antidote."
  *goto illtry
*else
  "Just be prepared when ya meet the guy, and try not to get yarself killed."
  *goto illtry
*label illtry

"I'll try. Thanks for the warning, Lord Isoshu," you grin, teasingly.

"And don't ya call me that, too," he groans as he opens the door again. "Take care'a yarself, $!{name}."

You let out a small sigh of relief as you think about finally getting some rest.
*page_break
"$!{lord}
*if origin = "Capel"
  Sage?"
*if origin != "Capel"
  $!{surname}?"

Or not...

"Should I expect frequent gentlemen visitors for you at this hour?" your attendant asks, her cheeks flushed with color.

*choice
  #Gentlemen, no. Ladies, perhaps.
    *set pref 1
    *goto dontpullawrou
  #Gentlemen, ladies, and whoever else.
    *set pref 3
    *goto dontpullawrou
  #Gentlemen, maybe. Certainly no ladies.
    *set pref 2
    *goto dontpullawrou
  #No one should be in my room at night, but me.
    *set pref 0
    *goto dontpullawrou
*label dontpullawrou

You're about to answer when it suddenly dawns on you what she's implying just happened.

"First of all, Syphel is my 
*if syrel >= 60
  friend. 
*if syrel < 60
  fellow Reaver.
Nothing else," you clearly explain.

"Certainly," she agrees unconvincingly, clearly not believing you.

"Secondly, I don't think that's any of your concern," you frown, walking back inside and shutting your door. You are much too tired to straighten her out right now.

The possible outcome of your task at Barith looms on the edge of your dreams that night, a shrouded weight you'll likely have to carry with you until the situation is resolved.
*label end
*if rebel = 0
  *set girel %+ 5
*finish Next