*set krel 0
*set nilrel 0
*set adrel 0
*set rorel 0
*temp tlm
*set tlm 0
*temp elf
*set elf 0
*temp sha
*set sha 0
*temp roeel
*set roeel 0
*temp nileel
*set nileel 0
*temp keel
*set keel 0
*temp rostress
*set rostress 1
*temp rechoice
*set rechoice 0

It isn't long before you reach your destination in Raleigh. Syphel immediately drags you to impressively large shop of an armorer friend of his, as if it were the most exciting place to have ever existed.
As you browse the extensive collection, you consider your options and the advantages of each.

*if syrel > 70
  *if origin = "Sedel"
    Syphel recommends full plate armor, much like the type he seems fond of, but ultimately leaves the decision to you.
  *if origin = "Monaire"
    Syphel recommends light plate armor, but ultimately leaves the decision to you.
  *if origin = "Capel"
    Syphel recommends that you obtain Sage's robes from the tailor down the street, but ultimately leaves the decision to you.
  *if ((origin = "Ehl") or (origin = "Asylia"))
    Syphel expresses some concerns about you actually engaging in combat, and recommends that you stay away from armor so as not to draw attention to yourself, should any fighting start. He points out the tailor down the street, but leaves the decision ultimately up to you.
  *goto armorchoice
*elsif syrel > 50
  Syphel recommends the light plate armor, but mentions that you should forgo the armor if you aren't comfortable with fighting.
  *goto armorchoice
*else
  Syphel recommends that you not choose anything too ridiculous, but ultimately leaves the choice up to you.
  *goto armorchoice
*label armorchoice

What kind of armor would you like to look at?

*choice
  #Light plate armor.
    This armor does a decent job of protecting you, and still allows you more agility than full plate armor would.
    
    Is this what you buy?
    *choice
      #Yes.
        Very well.
        *set armor "plate"
        *set armortype "light"
        *goto armorcolor
      #No.
        *goto armorchoice
  #Full plate armor.
    This is the best type of armor you can find in the place. It is a bit restrictive of your movements, though.
    
    Is this what you buy?
    *choice
      #Yes.
        Very well.
        *set armor "plate"
        *set armortype "full"
        *goto armorcolor
      #No.
        *goto armorchoice
  #There was this set with spikes...
    Syphel points out the impracticality of this particular set of intimidating heavy plate armor, citing that the spikes would be more likely to injure the wearer than anyone else. Do you buy it anyway?
    *choice
      #Of course. It's my choice to make, not his.
        I hope you know what you're doing.
        *set armor "plate"
        *set armortype "heavy"
        *goto armorcolor
      #No, he's right. It's clearly impractical.
        *goto armorchoice
  *hide_reuse #I go to look at the tailor's instead.
    *label tailorchoice
    What do you want to look at?
    *choice
      #Sturdier traveling clothes. I would rather blend in than stand out.
        While not much protection, normal clothing is comfortable and helps you to not draw attention to yourself.
        
        Is this what you buy?
        *choice
          #Yes.
            Very well.
            *set armor "clothing"
            *set armortype "none"
            
            Unfortunately, your clothing won't be ready for a few days, but you manage to secure a couple of rooms at a nearby inn.
            *goto barscene
          #No.
            *goto tailorchoice
      *if male
        #I prefer the dignified appearance of well tailored coats.
          These are useless for any type of protection, but they relay your standing as a prominent figure in the Empire quite nicely.
          
          Are these what you buy?
          *choice
            #Yes.
              Very well.
              *set armor "coat"
              *set armortype "none"
              
              Unfortunately, your clothing won't be ready for a few days, but you manage to secure a couple of rooms at a nearby inn.
              *goto barscene
            #No.
              *goto tailorchoice
      *if female
        #I prefer the dignified appearance of well tailored gowns.
          These are useless for any type of protection, but they relay your standing as a prominent figure in the Empire quite nicely.
          
          Are these what you buy?
          *choice
            #Yes.
              Very well.
              *set armor "gown"
              *set armortype "none"
              
              Unfortunately, your clothing won't be ready for a few days, but you manage to secure a couple of rooms at a nearby inn.
              *goto barscene
            #No.
              *goto tailorchoice
      *if origin = "Capel"
        #I prefer traditional Sage's robes.
          Sage's robes are magically armored, and, if well made, can help you focus your own magic better. These seem to be of exceptional quality.
          
          Is this what you buy?
          *choice
            #Yes.
              Very well.
              *set armor "robes"
              *set armortype "magic"
              
              Unfortunately, it will take some time to enchant your robes, but you manage to secure a couple of rooms at a nearby inn.
              *goto barscene
            #No.
              *goto tailorchoice
      #There's a very interesting set of leather armor being worked on...
        While it isn't a full set of leather armor, it does cover all of your vulnerable areas and it is reinforced with iron plates. It seems this is a joint effort between the armorer and tailor to make durable, yet unhindering protection that can be worn comfortably over normal traveling clothes.
        
        Is this what you buy?
        *choice
          #Yes.
            Very well.
            *set armor "leather"
            *set armortype "leather"
            
            Unfortunately, your leather armor won't be ready for a few days, but you manage to secure a couple of rooms at a nearby inn.
            *goto barscene
          #No.
            *goto tailorchoice
      #There were better options with the armorer. I go back there.
        *goto armorchoice
*label armorcolor

And is this standard steel plate armor or...

*choice
  #It's gilded.
    *set armorc "gold"
    *goto barscenep
  #It's bronzed.
    *set armorc "bronze"
    *goto barscenep
  #It's silvered.
    *set armorc "silver"
    *goto barscenep
  #It's tinted red.
    *set armorc "red"
    *goto barscenep
  #It's tinted blue.
    *set armorc "blue"
    *goto barscenep
  #It's tinted green.
    *set armorc "green"
    *goto barscenep
  #It's tinted white.
    *set armorc "white"
    *goto barscenep
  #It's tinted black.
    *set armorc "black"
    *if armortype = "heavy"
      So, you have scary impractical armor.
      
      Sure. Noted.
    *goto barscenep
  #It's the standard steel coloration.
    *set armorc "steel"
    *goto barscenep
*label barscenep

Unfortunately, your ${armorc} ${armortype} ${armor} armor won't be ready for a few days, but you manage to secure a couple of rooms at a nearby inn.
*label barscene

Now, you sit idly at the tavern, waiting for Syphel to finish picking out the newest additions to his collection of armor.

*if ((origin = "Monaire") or (origin = "Capel"))
  Raleigh is bit chillier than it tends to be in the Empire, but the people in this town seem friendly enough.
*if ((origin = "Sedel") or (origin = "Asylia"))
  You've noticed some suspicious glances in your direction, but for the most part people in this town have left you alone.
*if origin = "Ehl"
  You've noticed that people in this town seem to be avoiding you, but you're accustomed to such things.
That being said, you and Syphel haven't exactly gone around announcing that you were from the Empire.

Your time here will probably be one of the few peaceful trips you will ever get to take out of the Imperial boundaries. You may as well make the most of it.

*choice
  #That's right! I find someone to talk to.
    There aren't many people in the tavern at the moment, but a few of them do stand out.
    
    There's a man, probably a local, at the table next to yours staring absentmindedly at a pint of ale in front of him. He looks a bit nervous, but otherwise harmless.
    
    You also spot an Elf sitting alone at a table in the middle of the tavern.
    *if origin = "Sedel"
      In all of your time outside of Sedel, you've never seen another Elf.
    *if origin != "Sedel"
      Elves rarely leave their home in Sedel without good reason.
    She seems to be grimacing as she takes in the surroundings of the tavern.
    
    In the far corner closest to the door you spot a suspicious looking individual in a dark cloak. The person certainly wasn't in here when you entered the tavern, and they haven't moved since you noticed them.
    
    Which one do you approach?
    *choice
      #The local man
        *label tttlm
        *set tlm 1
        You make your way to the local harmless looking man's table and ask to take a seat.
        
        He quickly glances up, as if surprised that you're talking to him. "What? No," he responds. "No, I mean yes," he quickly corrects, gesturing for you to take an empty seat.
        
        He seems even more nervous by your presence, although it's unlikely that he knows you're from the Empire.
        Are you sure you want to take that seat?
        *choice
          #Yes I sit down and introduce myself.
            *set bc "Wrou"
            *goto bcsage
          *selectable_if (elf = 0) #Nevermind. I'll go talk to the elf.
            *goto ttelf
          *selectable_if (sha = 0) #Nevermind. I'll go talk to the suspicious person in the corner.
            *goto ttsha
          #Nevermind. I'll go sit back down alone at my table.
            *goto bckle
      #The Elf
        *label ttelf
        *set elf 1
        You make your way to the Elf's table, and ask to take a seat.
        
        *if origin = "Sedel"
          She nods, but says nothing, instead continuing to glance around at everything else in the room with a frown on her face.
        *if origin != "Sedel"
          "No one's stopping you," she grimaces, only taking a quick glance at you before looking away.
        
        It's only now that you notice the large claymore propped up against the table next to her.
        Are you sure you want to talk to her?
        *choice
          #Yes. I sit down and introduce myself.
            *set bc "Nil"
            *goto bcelf
          *selectable_if (tlm = 0) #Nevermind. I'll go talk to the harmless looking guy.
            *goto tttlm
          *selectable_if (sha = 0) #Nevermind. I'll go talk to the suspicious person in the corner.
            *goto ttsha
          #Nevermind. I'll go sit back down alone at my table.
            *goto bckle
      #The cloaked figure
        *label ttsha
        *set sha 1
        You make your way to the corner table and ask to take a seat.
        
        No response comes, however. The person doesn't even move to acknowledge you.
        
        "Either sit down or go away," you hear a fierce feminine whisper come from under the hood after a few moments, "You're drawing attention."
        *choice
          #I sit down and introduce myself.
            *set bc "Adika"
            *goto bcsha
          *selectable_if (tlm = 0) #Nevermind. I'll go talk to the harmless looking guy.
            *goto tttlm
          *selectable_if (elf = 0) #Nevermind. I'll go talk to the elf.
            *goto ttelf
          #Nevermind. I'll go sit back down alone at my table.
            *goto bckle
  #I think I'll just mind my own business and wait for Syphel.
    *goto bckle
*label bcsage
"I'm Wrou," he replies,
*if ((origin = "Asylia") or (origin = "Ehl"))
  staring at you rather intently. It looks like he wants to say something, but is restraining himself.
  *set roeel 1
*if ((origin = "Monaire") or (origin = "Capel"))
  staring at his drink rather intently. He only rarely takes glances up at you.
*if origin = "Sedel"
  showing you a small smile before turning his attention back to his drink.
  *set roeel 1
*if origin = "Ehl"
  It's clear from his lack of a Raleigh accent, that he isn't a local. He sounds very Imperial, actually.

Some time goes by in silence. Perhaps you should say something?
*label bcsageq1
*choice
  *if ((origin = "Asylia") or (origin = "Ehl"))
    #I ask why he's staring at me.
      *if origin = "Asylia"
        *set roeel +1
        "You're Asylian," he says, squinting.
        
        Instinctively, you avert your gaze.
        
        "Uh, not that there's anything wrong with that," he franticly, corrects, defensively waving his hands in front of him, "Or that there should be. I like Asylians! Not in a weird fetish way, or something odd like that. Your eyes are extremely attractive. Not yours, specifically. Other Asylians. Well, you're obviously attractive, too. Your eyes are, I mean.  Asylian eyes are rare, is what I'm getting at. I don't collect them, or anything, like in a jar. A jar of eyes would be... bad..."
      *if  origin = "Ehl"
        *set roeel +1
        "You're different," he states. "Different good, not different bad. I don't mean that being different is bad," he franticly corrects, defensively waving his hands in front of him, "or that it can be, really. It's just, not normal. Again, not in a bad way. Plenty of odd things are fantastic. Like you... or... lizards..."
      *goto bcsageq2
  #I ask what he's doing here.
    *if rostress = 1
      "Nothing!" he immediately responds. "Well, drinking. Not heavily, I mean. I'm not a drunkard. But this is a tavern. It says so on the sign outside. I'm not saying that you can't read the sign. You're probably not that stupid. Or, er, stupid at all! I wish I could stop talking sooner..."
      *goto bcsageq2
    *if rostress = 0
      "I'm... I'm hiding," Wrou mumbles, eyes downcast.
      
      "From who?" you question.
      
      "Fate... isn't on my side," he slowly answers. He seems to be picking his words extremely carefully. "It's a situation where... no matter what you do, you know things are going to end badly for you."
      
      *choice
        #"Tell me what's wrong. I might be able to help."
          *set roeel +1
          "I doubt anyone can really help me," he frowns, taking a long drink of his ale, "And, with due respect, $!{mister} $!{name}, we've just met. Please don't burden yourself with my problems."
          *goto bcsageendb
        #"Sometimes, it's better to stop struggling."
          *set rofatalist true
          *set roeel +2
          Wrou seems to think this over for a moment. "Sometimes, maybe..." A small smile suddenly pulls at his lips, "Honestly, I'm getting tired of running. Thank you for that bit of insight, $!{mister} $!{name}."
          *goto bcsageendb
        *if origin = "Capel"
          #"Fate isn't as static as people think. It can easily shift, little by little, with each decision that we make."
            *set magic +3
            This is the one lesson that the priests at your Temple drilled into you until you had it firmly comitted to memory.
            
            You glance at Wrou, who's giving you a peculiar look. For a moment, you wonder if you've said something strange.
            
            "That's... insightful of you, $!{mister} $!{name}," he says, after a brief silence, "but I think you have a far more optimistic view of the world than I do."
            *goto bcsageendb
      *label bcsageendb
      
      Wrou quietly finishes his drink, wearing the look of someone lost in their own dark thoughts.
      
      "I'm sorry," he finally says, setting his empty ale glass down, "I shouldn't have brought up something strange, but thank you for hearing me out. I feel... better." He stands and bows politely to you before leaving the Tavern.
      *goto barend
  *hide_reuse #He seems nervous. Maybe some small talk will calm him down before I start questioning him.
    *set rostress 0
    *set roeel +1
    You spend some time talking about nothing in particular, and only manage to get muted responses from Wrou. He does seem to be making more eye contact with you now, however, and he at least looks calmer.
    *goto bcsageq1
*label bcsageq2

*choice
  #I don't know if I should be offended by that or not, but I tell him to relax.
    *set roeel +1
    "Um, right," he nods.
    *goto bcsageq3
  #I'll just stay silent and see where this goes.
    You sit back in your chair and look expectantly at him.
    
    *goto bcsageq3
*label bcsageq3
"I'm sorry. I ramble when I'm nervous," he takes another long drink. "Not that you're making me nervous.
*if origin = "Sedel"
  *set roeel +1
  I'm sure you don't mean any harm."
  
  "Someone means you harm?" you question.
  
  "No! Well, um... no," he corrects, "I just meant that Elves are the least of my concern right now."
  
  "Excuse me?" you raise an eyebrow at him, wondering exactly what that was supposed to mean.
  
  "Uh, no. What I meant was that I have bigger problems than you," he tries to clarify, "You're not a problem. I don't have any problems with you. I... I'm going to go now."
  
  He stands and hurries out of the bar before you can say another word.
  *goto barend
*if origin = "Asylia"
  Um, I'm sorry."
  
  "No, it's fine," you start.
  
  "Er, I meant about Asylia," he frowns, "I mean, I heard about what happened, and it's not easy losing everything and everyone like that."
  
  Wrou's eyes convey a look of true sympathy as he glances quickly at you.
  
  *choice
    #"Thank you."
      Wrou shoots you a sad smile, but says no more on the subject.
      *goto bcsageenda
    #"That's in the past now."
      *set roeel -1
      Wrou quickly shakes his head. "That still doesn't make it right," he points out.
      *goto bcsageenda
    #"You're right. It isn't. It never will be."
      *set roeel +1
      Wrou looks back at you and slowly shakes his head. "No, it won't," he quietly agrees.
      *goto bcsageenda
*if origin = "Ehl"
  If you don't mind me asking, where are you from?"
  
  "Ehl," you state, "It's across the eastern ocean."
  
  He gives you a questionable look. "There's something across the ocean? Er, not that I don't believe you, or that I think you're lying. I just-"
  *choice
    #Let me just stop him right there, for his own sake."
      *set roeel +1
      "Yes, there's a lot across the ocean," you interupt, "The Ehl Imperium itself spans three continents."
      
      Wrou turns his complete attention to you. "That's... That's certainly impressive," he speaks in awe, "I think I'd like to see that some day."
      
      It's not completely impossible for him to do so, especially since the Imperium has already decided to make contact with this continent. If only the weather in the waters surrounding it weren't so unpredictably violent...
      *goto bcsageenda
    #I really want to see where this is going...
      "I just didn't realize there was something else out there," Wrou franticly continues, "Then again, we didn't realize the Elves were in Sedel for a long time, either. Not to say that you were hiding like the Elves, or that I have anything against the Elves. Elves are... Elves..."
  *goto bcsageend
I just have a bad habit of... speaking." 

A long silence passes between the two of you.
"You look like something's troubling you," you point out.

"Trou- Um, no," he quickly shakes his head, "Well, no. Yes is obviously the right answer. It's nothing. No, it's obviously something. Um... I'm having problems with... people."

"Is someone bothering you?" you casually ask.

"Um," he looks around the bar for a moment, "Bandits. There were bandits."

He's clearly lying, something he doesn't seem to be good at or used to doing.

"Bandits? Really?" you further ask.

"Six of them with... weapons... of some sort," he tries to explain further, "I-I wouldn't bother asking around about them, or anything, if I were you. Someone's probably taken care of it by now."

"Yeah, you're a really bad liar," you point out.

"I know," he admits, frowning.

*label bcsageend
Wrou quickly gulps down the rest of his ale and stands up. "It was nice meeting you, $!{mister} $!{name}, but I have... obligations," he politely bows before rushing to the door.
*goto barend
*label bcsageenda
Wrou glances to the door, then back at you. "I really hate to leave this charmingly... awkward conversation, but I have... obligations," he states, rising to his feet, "It was a pleasure meeting you, $!{mister} $!{name}," he adds, politely bowing before hurridly making his way to the door.
*goto barend
*label bcelf
She gives you a suspicious look before crossing her arms and turning her attention away from you.
*if origin = "Sedel"
  *set nileel 3
*if origin != "Sedel"
  *set nileel 2

"Nil," she eventually responds with her own name, "But don't expect me to be friendly with you just because I let you sit here."

*label bcelfq1
*choice
  *hide_reuse #I question what she's doing outside of the Elven territory.
    *if origin != "Sedel"
      "I can do whatever I want," she huffs, giving you a nasty look.
    *if origin = "Sedel"
      "I would ask you the same thing, but I don't care," she huffs, "What I'm doing is none of your business."
      
    That certainly didn't end well. Perhaps you should try something else.
    *set nileel -1
    *goto bcelfq1
  *hide_reuse #I ask her about her sword.
    At this, she instantly perks up.
    *set nileel +1
    
    "Made it myself," she claims, a proud grin spread across her face.
    
    *choice
      #"You're a blacksmith?"
        *set nileel -1
        "No, I used the combined powers of love and friendship to wish it into existence," she snarks. "Yes, I'm a blacksmith. And before you even ask, no, I'm not making you anything. You're..." Nil shoots you a quick conflicted look, "...annoying."
        *goto bcelfcont
      #"It's well made."
        "Darn," she grins, "And here I was thinking I made something substandard to defend myself with." She shrugs and looks away. "Thanks," she responds more quietly, "I put a lot of effort into that."
        *set nileel +1
        *goto bcelfcont
      #"Can you make me a weapon?"
        "Sure," she grins, "I'll just pull out my portable forge and anvil... Oh, wait, that doesn't actually exist." Nil shrugs. "Would if I could. Not because we're friends. Because we're not. You'd have to pay me," she amends, "A lot. Weapons are hard to make."
        *goto bcelfcont
  *hide_reuse #Nice girl, there. I make a blatant comment about her attitude.
    *set nileel +1
    *if origin != "Sedel"
      "You're the one who came to me," she accusatively points at you, "I don't know what your problem with me is, or if you even have a problem with me, or if you're just some creepy ${guy} looking for company in a tavern.
    *if origin = "Sedel"
      "I didn't ask you to come over here," she points out. "
    I am not your friend, and there's nothing that says I have to be nice to you."
    
    "Then why did you let me sit down?" you question.
    
    "I..." she stops to think for a moment, "Because... You're irritating, you know that?"
    
    She turns away again, but you can clearly see that she's no longer frowning. Maybe you should try something else.
    *goto bcelfq1
*label bcelfcont

She goes on for some time about how she made her claymore. Not being a blacksmith yourself, you easily get lost in the details.
It's easy to tell from Nil's facial expressions that she is actually enjoying herself, despite what she may say.

Your conversation is cut short, however, when a man you hadn't noticed before approaches your table.

"$!{he}'s not my friend," Nil immediately tells the man, nodding toward you.

"Sure, Nil," he says, his tone indicating that he gives little credit to this claim, "We're heading out."

"It's about time," the Elf quickly stands up, straps her claymore to her back, and follows the man to the door.

She doesn't bother to say goodbye to you, but you do notice that she looks back at you before the two exit the tavern.

*goto barend
*label bcsha
"I know who you are," she bluntly whispers before you can even get your name out.

While it's highly unlikely, it's still possible that she recognizes you from somewhere.

"How-"

"Small town. People talk," she cuts you off, "I'm a good listener."

You've only been in town for a few hours, and haven't even spoken to anyone other than the armorer and the innkeeper. Unless Syphel said something...

"Relax," the cloaked woman interrupts your thoughts, no longer whispering, but keeping her voice low enough to not be heard by anyone other than you, "It's not common knowledge. Just unfounded rumors of a very scared thief." She shifts ever so slightly toward you. "I'm Agent Adika, under the service of Her Majesty, Queen of Zevin. A pleasure to meet you, Reaver $!{surname}."
*label bcshaq1
*choice
  *hide_reuse #I think I've heard of the Zevin Kingdom's Agents before...
    Rumors of them are widespread. Supposedly, they're skilled assassins, spies, and infiltrators. No solid facts are known about these Agents, however.
    *goto bcshaq1
  *hide_reuse #I don't know how much she knows, but I make sure she keeps it to herself.
    "Your secret's safe with me," Adika assures you, "Public knowledge of your presence here would cause a panic. Not what I want to do."
    *goto bcshaq1
  #This is suspicious. I demand to know what she's doing here.
    *goto bcshacont
*label bcshacont
"That man with the battle axe strapped to his back," she subtly nods toward a patron across the tavern currently engaged in conversation with what you would guess to be a couple of farmers, "came in with that Elf," she gestures to the Elf you spotted earlier. "Dangerous. Both of them. I've been following them."

"How-"

"You really are inquisitive, aren't you?" she cuts you off again. "I believe your main concern from him is his intention to kill your precious Emperor."

A plot to kill Emperor Dain? You're not sure how often plots like this develop, but it would seem impossible to kill an immortal god.
*if ((origin = "Asylia") or (origin = "Ehl"))
  This is assuming Emperor Dain is actually a god, as is claimed...

"No need for concern," Adika snaps you out of your thoughts once more, "I doubt he'll get far, and the situation is under control."

"I think it's in my job description to be concerned," you quietly point out as you watch the man with the axe and the Elf leave the tavern together.

"Unnecessary, but do as you will. I'll keep in contact, ${mister} $!{surname}," she says, standing. She silently exits the tavern, exhibiting all the grace of a skilled predator stalking it's prey.
*goto barend
*label bckle
*set bc "Klein"
*set keel +1
You sit alone, wondering exactly how long it takes Syphel to pick a set of armor.

You're not sure how much time has passed before you find a pint of ale set down in front of you. An athletic, yet otherwise unremarkable man takes a seat across the table from you without even asking. He has the look of someone who spends a great deal of time outdoors. It's doubtful that he's a local, and you figure him to be more of the wandering adventurer type. You confirm this when you notice the large battle axe strapped to his back.

You shoot him a questioning glance.

"You look like you could use it," he explains, a friendly smile on his face.

*choice
  #I explain to him that I don't drink.
    *set nonalcoholic true
    "Suit yourself," he shrugs, and pulls the pint across the table to sit next to his own drink.
    *goto bcklecont
  #The drink could be poisoned for all I know. I refuse it.
    *set keel -1
    "Suit yourself," he shrugs, and pulls the pint across the table to sit next to his own drink.
    *goto bcklecont
  #Actually, I could use it.
    *set keel +1
    Who could pass up free ale? Certainly not you. You nod a small thanks and take a swig of the cool drink.
    *goto bcklecont
*label bcklecont

"I'm Klein Logan, by the way," he adds after taking a drink of his ale, "And you are...?"

So much for being alone. This Klein seems to be the pushy, intrusive type.

"$!{name}," you casually state.

"$!{name}," he repeats, as if trying it out, "I met a $!{name} once. Big ${guy}. Complete coward. Name didn't really fit ${him}, though..." He trails off as he takes another drink. "Anyway, I came here with a friend of mine to see about getting some armor made, but it costs more gold than I have. More than I've ever had, now that I think about it. It's as if the further north you are, the more expensive things get," he complains, a serious look of concern on his face. "I don't guess you know of any profitable jobs?"

*choice
  #I suggest that he join the Imperial Combat Forces. They pay decently well.
    *set keel +1
    *set rebel -5
    "Heh. Good one," an amused grin crosses his face, "The way things are going, I may just have to one day. But we'll call that plan B until then."
    *goto bcklecont2
  #I give him the gold for a new set of armor. The Empire pays me more than I can spend, anyway.
    *set keel +3
    "Really?" he perks up, showing you a wide smile. "You're a saint, you know that? May the gods look favorably upon you. If we ever meet again, remind me that I owe you one."
    *set kfav 1
    *set renown +5
    *set inspiring +5
    *goto bcklecont2
  #I suggest that he keep looking. I've got nothing for him.
    "Heh. Don't worry about it, then," he smiles, "I'm sure I'll think of something."
    *goto bcklecont2
*label bcklecont2

Klein goes through another two pints of ale, telling you about how nearly everyone he's met has had some task they've asked him to do, despite the fact that he usually has no training or experience in that particular field. You notice that he doesn't seem to be seeking any sort of input from you, however.

Eventually, he rises from his seat. "As much fun as your company is, I need to fix this 'no armor' problem," he states, "Thanks for listening, $!{name}." Klein walks to the table of the Elf you saw earlier and they leave the tavern together.

*label barend
*if roeel < 1
  *set rorel 10
*if ((roeel >= 1) and (roeel < 3))
  *set rorel 20
*if ((roeel >= 3) and (roeel < 4))
  *set rorel 25
*if roeel >= 4
  *set rorel 30
*if nileel < 1
  *set nilrel 10
*if ((nileel >= 1) and (nileel < 3))
  *set nilrel 20
*if ((nileel >= 3) and (nileel < 5))
  *set nilrel 25
*if nileel >= 5
  *set nilrel 30
*if ((origin = "Monaire") or (origin = "Capel"))
  *set adrel 10
*if ((origin = "Asylia") or (origin = "Ehl")) and (rebel < 10)
  *set adrel 20
*if ((origin = "Asylia") or (origin = "Ehl")) and (rebel >= 10)
  *set adrel 25
*if origin = "Sedel"
  *set adrel 30
*if bc != "Adika"
  *set adrel -10
*if keel < 1
  *set krel 10
*if ((keel >= 1) and (keel < 3))
  *set krel 20
*if ((keel >= 3) and (keel < 4))
  *set krel 25
*if keel >= 4
  *set krel 30
*page_break
Once again, you sit alone at the Tavern.
Quite a bit of time passes before Syphel enters. He sits down at your table looking every bit as happy as he did when you left him at the armorer's shop.

*choice
  #It's about time! I ask him what took him so long.
    "I might have gotten carried away," he shrugs, "but when it comes to something that affects how people see ya, it's worth taking yar time on.
    *goto barend2
  *if (bc = "Adika") #I tell him about the Zevinian Agent I met, and the people she was following.
    Syphel simply shrugs. "Don't ask me. I wouldn't worry about it too much, though. It's not as if anything can actually harm Dain, and if the Zevinians want to help us, let them.
    *set syrel %+ 3
    *goto barend2
  #I'll let his lateness pass. I was fine without him.
    "Sorry that took so long," he shrugs, "I don't get down here often enough.
    *set syrel %+ 3
    *goto barend2
*label barend2
Anyway, we'd better go grab some rooms at the inn before-"

"Done," you say, sliding the key to his room across the table to him.

"Er... Nevermind," he grins at you, "Let's go then."
*page_break

*if ((armor = "plate") or (armor = "leather"))
  It takes a few days for your armor to be ready, leaving you with some free time in town.
*if armor = "robes"
  It takes a few days for your robes to be enchanted, leaving you with some free time in town.
*if armortype = "none"
  It takes a few days for your clothing to be made, leaving you with some free time in town.
*label timespent

How would you like to spend your time?

*choice
  #I'll see about doing some training with Syphel.
    "Sure," Syphel easily agrees when you ask, "Don't have any weapons, but I'll teach ya some unarmed techniques."
    
    *if rechoice = 1
      *goto rechoosedia
    "Why don't we have any weapons?" you question, finding that a bit odd.
    
    "I do better without them," Syphel grins, "Why ya don't, I have no idea. We'll fix it once we get back to the Empire."
    
    *label rechoosedia
    He takes you to the outskirts of town and shows you how to do a few things.
    Most of what he's teaching you is defensive, but by the time it's time to return to the Empire, you're confident you can take anyone down in a fistfight as long as you're prepared for it, and they're the one's attacking you.
    *set unarmed + (effort*5)
    *set combat + (effort*5)
    *set syrel %+ 5
    *set unarmedspecial true
    *goto barendit
  *if origin = "Sedel"
    *hide_reuse #I'll see about sparring with Syphel.
      Syphel considers your request for a spar with a questionable look.
      
      "Only if it's a hand to hand spar," he says after a moment, "We don't have any weapons with us anyway."
      
      "Why is that?" you question, finding that a bit odd.
      
      Syphel shrugs. "Did we need them?"
      
      So far, you hadn't, but traveling on the roads could potentially be dangerous. Syphel seems completely unconcerned with being unarmed, however.
      While you can manage just fine against a couple of bandits unarmed, you were trained with swords and bows back in Sedel.
      
      "What's it going to be, $!{name}?" Syphel asks, almost tauntingly.
      *choice
        #I agree to fight him unarmed.
          *set syspar 1
          Syphel leads you to a clearing on the outskirts of town.
          
          "Have it yar way, then," he grins broadly, "Just don't expect me to take it easy on ya just because ya're
          *if female
            a girl."
          *if male
            an elf."
            
          "I wouldn't expect you to," you respond, preparing yourself.
          
          You size up your oponent across the clearing.
          You know that Syphel's physically stronger than you.
          He's wearing his usual full plate armor, which you figure should slow him down a bit...
          
          Before you can further asess the situation, Syphel begins calmly walking toward you, wearing a confident smile.
          *choice
            #If I don't get the first strike, I'll lose any sort of advantage I have. I rush him before he can do anything.
              *set combat %+ (effort*3)
              You run forward to meet him, only to find the world around you flipping as your feet leave the ground.
              *goto spar1con
            #I can't do anything reckless and still expect to win. I ready myself and see what he does.
              *set intel +5
              You wait, prepared to react, but Syphel stops just out of your reach.
              
              "Are ya going to stand stand there until I get bored and leave, or are ya going to fight me?" he challenges.
              
              It seems that he's making you take the offensive this time.
              You reluctantly make a move toward him, only to find the world around you flipping as your feet leave the ground.
              *goto spar1con
          *label spar1con
          
          The next thing you know, you're laying on your back with your breath knocked out of you.
          
          You steady your thoughts and focus your vision on Syphel doubled over in front of you, laughing.
          
          "I'm... heh, I'm sorry $!{name}. Haha! I didn't hurt ya, did I?" he manages to ask, "I know how frail yar type can be. Haha!"
          
          You hurridly get to your feet, wincing at a dull pain from where you landed.
          It'll probably bruise, but you aren't seriously hurt.
          
          "I'm not frail," you defend, "I... How did you do that?"
          
          For the rest of your time in town, Syphel teaches you some defensive unarmed techniques.
          While it's not your strong point, you're confident you can take anyone down in a fistfight as long as you're prepared for it, and they're the one's attacking you.
          *set unarmed + (effort*5)
          *set combat %+ (effort*5)
          *set syrel %+ 5
          *set unarmedspecial true
          *goto barendit
        #I'll back out. This isn't going to end well.
          *set rechoice 1
          "Good choice," Syphel grins broadly, "Unarmed combat's my specialty. Ya wouldn't stand a chance."
          
          You leave his presence and find something else to do.
          *goto timespent
  *if origin = "Capel"
    #I'll try to practice fate tracing.
      You spend some time alone in your room at the inn, trying to scry in a bowl of water.
      
      No matter what fate you try to trace, however, it seems to slip out of your grasp the moment you try to see anything beyond where you started.
      You think that you're improving a bit, but it may just be wishful thinking.
      By the time you have to return to the Empire, you feel as if you've been wasting your time.
      *set magic %+ (effort*2)
      *goto barendit
  #I'll spend some time with Syphel.
    You spend some time visiting with Syphel.
    The more you are around him, the more you realize how far off he is from your average view of a Reaver.
    
    He's rather laid back and friendly, not only to you, but to everyone in town.
    If you didn't know any better, you'd think he was a genuinely nice guy.
    
    The fact still remains that he is one of the Empire's Reavers, and whatever he did to gain that title was probably no small feat.
    
    By the time the two of you return to the Empire, you feel that your friendship has grown significantly stronger.
    *set syrel %+ 10
    *goto barendit
  #I'll talk to some more people at the tavern.
    You don't ever see $!{bc} there again,
    *if ((origin = "Monaire") or (origin = "Capel"))
      but you do manage to meet some friendly locals and travelers.
      *set renown %+ 3
      *set inspiring %+ 3
    *if origin = "Ehl"
      but you do manage to meet a few friendly travelers that are willing to speak with you.
      *set renown %+ 3
    *if ((origin = "Asylia") or (origin = "Sedel"))
      and no one else seems willing to talk to you, or even comfortable in your presence.
      *if renown < 1
        *set renown 1
      *set renown %+ 1
    
    As you return to the Imperial Palace, part of you wonders how diferent their reaction to you would be if they knew you were one of the Empire's Reavers...
    *goto barendit
*label barendit
*if rebel = 0
  *set girel %+ 5
*finish