*temp sypheel
*set sypheel 3
*temp conf
*set conf 1

The journey to Raleigh is uneventful, for the most part. Surprisingly enough, other than the driver of the carriage, no one accompanies Syphel and yourself. While you were still Reaver Harking's Second, he never allowed you to go anywhere without an escort of guards. Whether this was for your safety, or because he didn't trust you, you were never sure of. 

In addition to the lack of escort, the fact that you didn't have to make the trip on foot is also a pleasant change. Syphel explained that without the carriage, the trip would have taken too long. As it stands, he seems fairly restless most of the time. 

You've managed a few interesting conversations out of him so far. He's explained that each of the Reavers were responsible for one third of the expansion progress of the Empire. Reaver Harking handles things in the west, though you were vaguely aware of this before. Syphel took over the northern expansion after the execution of Reaver Plorina four months ago. You've deciphered that Syphel was Plorina's Second, but he refuses to comment on the former Reaver other than to express his extreme dislike of the woman. 

You, apparently, will be expected to take over Reaver Triolo's expansion efforts to the south. What happened to the man, even Syphel doesn't seem to know. 

*page_break

Thankfully, Syphel has been very pleasant company throughout this trip.

"Hey, I've a question for ya," he suddenly asks as you cross the border separating the Empire from Raleigh,   
*if origin = "Monaire"
  "Ya grew up in the Empire, right?"
  
  "The country of Monaire, actually, before it became the Empire," you correct.
  
  "Yeah, but ya joined the Imperial Forces when ya had the chance, right?" he seems intent on concentrating on something out of the speeding carriage's window rather than look at you.
  
  "I did," you answer, remembering your days as an overly eager youth.
  
  "Why?" he finally asks, still turned away from you.
  
  *choice
    #"I wanted to get out of my hometown."
      *set sypheel 3
      "I think I can sympathize with that," Syphel says, letting a small smile show, "Do ya regret it at all?"
      *choice
        #"Of course not."
          *set sypheel -1
          "Understandable," he frowns, though he doesn't go further into the conversation.
          *goto syop
        #"...Sometimes, yes."
          *set sypheel +1
          "Yeah, can definitely sympathize," he frowns, not bothering to ask what your regrets might even be.
          *goto syop
    #"I believed in the Emperor."
      *set sypheel 3
      "Still do?" he quietly asks.
      *choice
        #"I do."
          "Dain's a good guy," Syphel lets a small smile show, but makes no further comments.
          *goto syop
        #"I don't know anymore."
          *set sypheel +1
          *set rebelcount + 1
          "Ya probably don't want to talk like that to anyone else in the Empire," Syphel casually comments, though he doesn't seem to feel the need to try to correct or reprimand you afterwards.
          *goto syop
    #"He was Dain, the god of success. As his follower, I felt obligated to join."
      *set sypheel 3
      "I guess no one can fault ya for that," Sypheel seems to consider what you've said, but makes little effort to continue his questioning.
      *goto syop
    #"My family needed the money."
      *set sypheel 3
      "Oh," he sounds surprised, as if he didn't expect that answer, "Are you still sending them money?"
      *choice
        #"I am."
          *set sypheel +1
          "I'm sure they appreciate it," he quietly comments. He seems to consider what you've said, but makes no further comment on it.
          *goto syop
        #"Not anymore. They're doing fine now."
          *set sypheel -1
          "That's good to hear," Syphel seems to consider what you've said, but makes no further comment on it.
          *goto syop
    #"I wanted to make something out of myself."
      *set sypheel 2
      "And now ya're a Reaver," he points out, "Proud'a yaself?"
      *choice
        #"I am."
          "I see," Syphel seems to consider what you've said, but makes no further comment on it.
          *set sypheel -1
          *goto syop
        #"No. I'm not."
          *set sypheel +1
          "Hm," Syphel seems to consider what you've said, but makes no further comment on it.
          *goto syop
*elsif origin = "Ehl"
  "What's Ehl like?"
  
  "You want to know about the Ehl Empire?" you ask, surprised that anyone bothered to tell him about where you came from.
  
  "Yeah. I thought Gillen and Dain were joking when they told me that ya were from another continent. Until I saw ya, I mean," he pauses to to take a quick glance at you, "Does everyone in Ehl look like ya?"
  
  "Not all of us," you answer, "Just those of us with ancestry from the mainland."
  
  "I see," he seems to consider this for a moment before continuing, "What's the mainland like?"
  
  You spend quite some time telling Syphel about the bustling cities that dot the temperate landscapes of Ehl, and of the skyships that have recently sprung into being in the past couple of years. You mention the grand public universities, hospitals, and cathedrals that have been standing for centuries. While Syphel may look a bit restless at times, he seems to take a great amount of interest in what you're telling him. Unfortunately, this recounting of the many nice things that exist in Ehl has left long buried feelings of homesickness threatening to resurface again. You're forced to cut your tales of home short. 
  
  For a time, you and Syphel ride in silence.
  
  "Ya miss it, don't ya?" Syphel quietly asks after a few minutes.
  
  *choice
    #"I do."
      "It's hard being in a strange place," he murmurs, frowning. 
      *set sypheel 3
      *goto psyop1
    #"I'm over it."
      *set sypheel 2
      "Forgive me if I don't believe ya," he lets a small smile show. 
      *goto psyop1
  *label psyop1
  
  "You're from Raleigh, right?" you ask, changing the topic of the conversation away from you.
  
  Syphel shoots you a quick surprised look.
  
  "Your dialect," you explain.
  
  He chuckles. "Ya can't speak the common tongue without an accent, but ya can tell what region mine is from?"
  
  "Linguistics professor," you remind him, though you hadn't realized that you're still speaking the common language of this continent with an accent.
  
  "I'm from Nuvinter. It's pretty far south in the region," Syphel admits, "I haven't been back for a while, so I can understand being homesick."
  
  *choice
    #"Why did you leave?"
      *set sypheel -1
      "I was... stupid," he frowns, "It's complicated."
      
      *goto psyop4
    #"Why don't you go back?"
      *set sypheel +1
      "Ya ever hear'a anyone leaving the Empire? It doesn't happen," he frowns, "Anyway, it's complicated."
      
      *goto psyop4
  *label psyop4
  He goes back to silently staring out of the window, as if to indicate that he's done talking about it.   
  *goto syop
*elsif origin = "Capel"
  "Ya're a Sage, right?"
  
  "I am," you answer.
  
  "Elemental?" he asks.
  
  "I'm a Fate Sage," you correct, "I can trace the paths of a person's life."
  
  "So ya can see the future?" he glances at you.
  
  "Sort of," you explain, "Sometimes it's the past. The paths are kind of blurry to me and it's hard to tell exactly what I'm seeing."
  
  He turns his full attention to you and grins. "Impressive, Sage $!{surname}. Any chance I could get ya to trace my fate?"
  
  You don't currently have any of your scrying mirrors with you, but you've learned to manage with the surface of a pool of liquid. There's nothing technically stopping you from tracing Syphel's fate, but your attempts to scry after the destruction of the Temple have been a bit odd. This may be due to the fact that you've never been particularly spectacular at the task, but you seem to be inexplicably getting worse at it as time goes by. 
  
  *choice
    #"I'll give it a try."
      *set sypheel 4
      *set magic %+2
      You pour a cup of water, set it on your lap, and concentrate. This proves a little difficult as the constant movement of the carriage disrupts the surface of the water. Still, you think you've pinpointed Syphel's path. 
      
      You touch your finger lightly to the surface of the water and concentrate. You're able to trace the path in two directions, up and down. It's reasonable to assume that one way leads to the past and the other to the present, but you can't make out which is which. 
      
      Which do you trace?
      
      *fake_choice
        #Up
          You trace the path upward, but it seems to disconnect, like it's somehow suddenly not Syphel's path anymore.
          
          This is... new. Fate is notoriously shifty, but it's always solid, not whatever this is. 
          
          You trace your way back down to find the point where you started, and slowly trace up again. The same disconnect happens. 
          
        #Down
          You trace the path downward, but it seems to disconnect, like it's somehow suddenly not Syphel's path anymore. 
          
          This is... new. Fate is notoriously shifty, but it's always solid, not whatever this is. 
          
          You trace your way back up to find the point where you started, and slowly trace down again. The same disconnect happens. 
          
      You go back to your starting point and try the opposite direction. 
      
      Disconnect. 
      
      You try to concentrate harder. 
      
      Disconnect.
      
      No matter what you do, you can't trace Syphel's fate without it suddenly changing into something unrecognizable.
      
      Slowly you withdraw your finger from the surface of the water.
      
      "What did ya see?" Syphel asks.
      
      "I don't know," you reply.
      
      "Is that a good 'I don't know' or a bad 'I don't know'?" he frowns.
      
      "I don't know," you state once again, "The carriage is moving too much for me to see anything straight."
      
      You're fairly certain that isn't the problem, but it takes the pressure off of you trying to explain what just happened.
      
      "Oh. Don't worry about it, then," Syphel sends a reassuring grin your way, "Maybe I'll ask ya sometime later."
      
      You nod in agreement. Maybe you just aren't having the best of luck with it today. 
      *goto psyop3
    #"I... can't."
      *set sypheel 2
      "What do ya mean ya can't," Syphel curiously asks.
      
      "My ability to scry has been..." you take a moment to search for the proper word, "...erratic, lately."
      
      "What does that mean?" Syphel raises an eyebrow.
      
      "It means, I can't," you grimly explain, "Not reliably, anyway."
      
      "Huh," Syphel looks confused, but it's unlikely he realizes how big of a problem this actually is for a Sage, "Don't worry about it, then." He turns his attention back to the view outside of his window. 
      
      You nod in acceptance of his understanding.
      *goto psyop3
    #"I'd rather not."
      *set sypheel 1
      "Okay..." Syphel frowns and turns back to the view outside of his window. He doesn't look upset, just disappointed. 
      *goto psyop3
  *label psyop3
  
  "Another question. Why did ya leave yar Temple?" he questions.
  
  "It's... not there anymore," you quietly respond, "When the Empire took over Capel, they decided they didn't like the Temple of Anoe, for some reason."
  
  Syphel shoots a concerned glance in your direction, but says nothing on the issue. Instead, he settles for staring contemplatively out of the window once again. 
  *set sypheel +1
  
  *goto syop
*elsif origin = "Asylia"
  "Ya're Asylian, aren't ya?"
  
  You immediately tense. This kind of questioning has never led to anything good in the past. 
  
  "I am," you cautiously answer, bracing yourself for the verbal strike against you that you normally receive.
  
  "I knew it," he turns his eyes to you, "I heard that the Asylian warriors are amazing. Sari-, Sali-, what do ya call them?"
  
  "The combat Sirilas?" you correct him.
  
  "That was it," he lets a grin show, "Ya one'a those?"
  
  "A Sirilas, yes," you explain, "but I got my title for painting, not combat skills."
  
  The grin on Syphel's face turns into a look of disbelief. "Painting?" he questions.
  
  "Painting," you affirm.
  
  "Oh," he disappointedly turns his attention toward the window again.
  
  You don't know whether to find it amusing or insulting that he has a problem with you being a painter, but seems perfectly fine with you being Asylian.
  
  "What happened there?" he quietly asks.
  
  "You're in charge in the north," you frown, "Don't you know?"
  
  "The country was occupied before I ever even entered the Empire," he explains, "I don't think Plorina was a Reaver yet when that happened."
  
  *choice
    #I don't want to drudge up bad memories again. I tell him to drop the subject.
      *set sypheel 4
      "That bad, huh?" he frowns.
      
      The conversation ends there, though you notice Syphel looking rather contemplatively out of the window. 
      *goto syop
    #I'll tell him exactly what atrocities were committed there. He should know.
      *set sypheel 5
      *set rebelcount + 1
      You go into length about how your small border town was attacked without warning, and how the combat Sirilas didn't even have time to respond before the Imperials arrested or killed everyone in sight. You tell him about the dirty cell you had to stay in for three days before anyone told you what would happen to you. You recount the long cold march south you and other imprisoned Asylians were forced to take, and the supposed "battle" the Imperials wanted you to fight with broken and sub par weaponry and no armor. Your captors claimed you were being "integrated" into the Imperial Combat Forces, but you knew better. You were the only one in that "battle" lucky enough to survive. 
      
      Syphel says nothing while you speak, but he seems to be paying very close attention to what you're telling him. 
      
      "That's not normal Imperial procedure," he says when you finish, "What happened to yar family?"
      
      You simply shrug. "I haven't seen them since the initial attack."
      
      "I'll look into it for ya," he offers, a serious look of concern on his face.
      
      You make no response, unsure if knowing their fates would make you feel any better. The ride continues in silence. 
      *goto syop
*else
  "Ya're an Elf."
  
  "That isn't a question," you point out.
  
  "No, I know," he quickly corrects, "It's just that I've never seen an Elf before. How did ya even end up in the Empire?"
  
  "I didn't want the Empire in Sedel, so I went to make sure the invasion wouldn't get that far," you state.
  
  A slow smile spreads across Syphel's face. "Ya tried to play hero, didn't ya?" he asks.
  
  He didn't have to be so smug about it. You honestly tried your best back then.
  *choice
    #"I tried and I failed."
      *set sypheel 5
      You explain your defeat at Reaver Triolo's hands.
      
      "At least it was only Triolo ya had to deal with," Syphel mentions, frowning, "I tried to play hero and ended up facing Plorina."
      *goto psyop2
    #"I succeeded, in a way."
      *set sypheel 3
      You explain the deal you made with Reaver Harking that is currently protecting Sedel from invasion. Perhaps things didn't go according to plan, you accomplished what you set out to do.
      
      "Gillen did that for ya?" he shoots you a questioning glance, "No one ever offered me anything like that. Then again, I had to deal with Plorina when I tried to play hero." 
      *goto psyop2
  *label psyop2
  You see him cringe at her name. "Have I ever told ya how much I hated that woman?"
      
  "I've noticed," you nod. Syphel had never mentioned that he had tried to fight against the Empire himself. "What happened? How did you end up her Second?" 
  
  "She had a sadistic sense'a humor," he grimaces, "Look, I don't want to talk about it. Just be glad Gillen was there to help ya. I don't doubt Triolo would've tried to do something just as bad to ya." 
  
  Whatever happened obviously got him a bit shaken up. It is strange that he seems so loyal to the Empire now, however. 
  
  You force yourself to discontinue your questioning, the ride continuing on in silence. 
  *goto syop
*label syop

"I'll be honest," Syphel starts after several quiet minutes, "I asked ya to come with me so that I could get a better understanding'a the kind'a person ya are."

"You were testing me?" you question.

"Yeah," he admits, 
*if sypheel = 1
  "Ya're not so bad. At least, ya're better than a lot'a people I've met in the Empire." 
  *set syrel %- 5
  *goto firstbattle
*elsif sypheel = 2
  "and I'm glad ya're with us. I'd rather deal with ya than Triolo, anyway." 
  *goto firstbattle
*elsif sypheel = 3
  "Ya're alright by me. If there's anything ya need help with, just ask me." 
  *set syrel %+ 5
  *goto firstbattle
*elsif sypheel = 4
  "and I think ya need a friend. If ya ever need anything, I'm here for ya." 
  *set syrel %+ 30
  *goto firstbattle
*else
  "and... I don't even know what to say, other than I'm sorry. If ya need anything, just ask." 
  *set syrel %+ 50
  *goto firstbattle
*label firstbattle
*page_break
Your conversation is disrupted when you notice the carriage coming to a slow stop.

"We've already arrived?" you ask, glancing out of the window. It still looks like you're in the middle of nowhere.

"No... Come on, $!{name}," Syphel opens the carriage door and steps out.

You cautiously follow, to see what the problem is.

"Oh, this is rich," Syphel gestures to the four armed people standing in front of your terrified driver, "They're trying to rob us."

Despite the danger of the situation, Syphel looks more annoyed than concerned.

"Ya want to handle this, Reaver $!{name}?" he shoots you a sly smile.

*if intel >= 10
  You notice a slightly frantic whispering coming from the group ahead of you, though they stop as soon as they figure out you've noticed them. They seem a bit more nervous now, however. 
  
*if combat >= 10
  You've had some combat training, but are currently unarmed. 
  *if combat > 20
    You're fairly certain that you can obtain one of the thieves' weapons if you're careful, though. 
    
You think of how best to handle this. 
*label fight1
*choice
  #Syphel's crazy if he thinks I'm going to fight these guys. I let him handle it.
    There is no way you're dealing with this by yourself. 
    *set renown -5
    *if renown < 1
      *set renown 1
    
    *if origin = "Ehl"
      "Professor, remember?" you point to yourself. 
      
    *if origin = "Capel"
      "Fate Sage, remember?" you point to yourself. 
      
    *if origin = "Asylia"
      "Painter, remember?" you point to yourself. 
      
    *if combat = 0
      "Wait a minute," he frowns at you, "Ya're telling me ya have no combat ability?
      
      "Pretty much," you answer.
      
      "What the hell was Gillen thinking making ya a Reaver?" he grumbles.
    
    "I'm sure you can handle this yourself," you say, stepping back.
    
    "Fine, I'll deal with it," he frowns before walking toward the group of thieves, "Ya guys have got to be idiots trying to rob two Reavers."
    
    As Syphel comes within a few steps of the one you figure is leading this group, the thief points a short sword toward your companion. "I'm warning ya," he speaks in a raspy, yet distinctly desperate voice, "We're not above-"
    
    Before the man can even finish his sentence, Syphel quickly grabs the sword, reverses it's direction, and runs it through it's owner. 
    
    "Anyone else want to point something sharp at me?" he scowls at the remaining three.
    
    The scrawniest one suddenly bolts away, quickly followed by a second thief. Without the advantage of numbers, the last thief runs as well.
    
    Syphel returns to the carriage, still scowling.
    
    "Impressive," you comment.
    
    The look on his face softens after a few moments.
    
    "I can teach ya, if ya want," he opens the door of the carriage, "but for now, just get in." 
    *goto continueride
  *hide_reuse #There's only four of them. I think I can handle it.
    Are you sure? You're completely unarmed. 
    *choice
      #No problem. I can do it.
        "I've got this," you step forward, grinning confidently. 
        *set syrel %+ 10
        *goto fight1bat
      #I might be able to do it. I can at least try.
        "I'll give it a shot," you offer. 
        *set syrel %+ 5
        *set conf 0
        *goto fight1bat
      #Maybe not. Let me think of something else.
        Very well. 
        *goto fight1
  *if intel >= 10
    #Let's see if I can intimidate them.
      *set syrel %+ 10
      *set renown +10
      *set inspiring -10
      "What should I do with them, Reaver Syphel?" you test. 
      
      One of the thieves jabs his friend in the ribs nervously as soon as you say the word "Reaver". That must be what they're afraid of. 
      
      "I don't know. They must be pretty stupid to attack two Reavers," Syphel crosses his arms, "I think they need to learn what they're doing wrong the hard way." He seems to be playing along with your attempt, causing the four thieves to flinch again at the mention of "Reaver". 
      
      Seeing the group squirm is almost amusing. Unfortunately, the fun is cut short when one of four simply drops his weapon and runs. This is quickly followed by a second thief following behind the first. Without the advantage of numbers, the remaining two make a hasty retreat as well. 
      
      "Nicely done, $!{mister} $!{name}," grins toward you. 
      
      "Thank you for your participation, Mr. Syphel," you return a knowing smile. 
      
      The two of you return to your carriage and the journey resumes.
      
      "Let me ask ya, though," Syphel starts, still grinning, "Think ya could've taken them? 
      
      *if origin = "Monaire"
        "I don't know. Maybe," you shrug. 
        
      *if origin = "Ehl"
        "Professor, remember?" you point to yourself. 
        *set syrel %+ 5
        
      *if origin = "Capel"
        "Fate Sage, remember?" you point to yourself. 
        *set syrel %+ 5
        
      *if origin = "Asylia"
        "Painter, remember?" you point to yourself. 
        *set syrel %+ 5
        
      *if origin = "Sedel"
        "Probably," you answer. 
        
      "That's what I thought," he nods in acknowledgement, "Well, if ya ever want someone to train ya for when ya can't bluff yar way out of something, ya know where to find me."
      
      It wouldn't hurt to at least consider his offer. He's absolutely right in thinking that bluffing won't always work. 
      *goto continueride
*label fight1bat
*set inspiring -5
You take a deep breath and start walking forward. 

There's four thieves in total. None of them look particularly strong. In fact, the one to the left looks pretty scrawny. 

*if origin = "Sedel"
  You've certainly gone against worse before. 
  
*if origin = "Monaire"
  You've been trained to deal with situations like this. 
  
As you come within a few steps of the one you figure is leading this group, he points a short sword toward you. "I'm warning ya," he speaks in a raspy, yet distinctly desperate voice, "We're not above killing the lot'a ya." 

*if conf = 0
  He looks about as unsure as you feel. 
*if conf = 1
  He looks fairly unsure of himself. 

You make a grab for the sword pointed at you,  
*if combat >= 10
  taking a skilled strike to the hand holding it, and manage to gain possession of the weapon. By the time you can turn it back on it's owner, however, three more short swords are pointed at you. 
  
  Now things get tricky. 
  *page_break
  You sidestep the attack from your left, quickly block the swing coming from directly in front of you,  
  *if combat < 20
    and down you go. 
    
    You didn't even see what hit you, but the blinding pain radiating from your right temple tells you it was not something soft. By the time you're able to figure out what's going on around you, two thieves are face down in the dirt, one of them dead with a short sword through him, and the rest are nowhere to be seen. Syphel is standing next to you with his arms crossed. 
  
    *if conf = 1
      "Handled that really well, didn't ya?" Syphel grins, giving you a hand up. 
    
    *if conf = 0
      Syphel lets out an exasperated breath as he gives you a hand up. 
    
    He leads you back to the carriage where you safely check yourself for any injuries. As far as you can tell, other than the blow to the side of your head, you're fine. 
    
    *if origin = "Monaire"
      "I thought the Empire would've trained ya better than that," Syphel complains. 
    
      *if conf = 1
        "So did I," you agree. Whatever you picked up during your training was obviously not as impressive as you'd been made to believe. 
        
      *if conf = 0
        "There's a reason I was never promoted past guard captain," you admit. Although you would've liked a better posting at the time, judging by what just happened, you would've likely gotten killed. 
        
    "Ya were doing pretty well for a moment, there," Syphel acknowledges, "I can help ya with some training, if ya want."
    
    You see little reason to not at least consider his offer. 
    *set syrel %- 5
    *if conf = 0
      *set combat +5
    *if conf = 1
      *set combat + (effort*5)
    *set renown +5
    *goto continueride
  and skillfully dodge the blow coming in from your right. 
  
  From here it's just a matter of sidestepping around the attacker in front of you, knocking down the attacker on your left with a solid kick, running the leader through, and... 
  
  Wait, where's the scrawny one? He must've taken off at some point. The last thief standing notices this as well and quickly flees before you can kill him. 
  
  Now all that's left is for you to dispose of the last one rolling on the ground in pain. 
  
  *if conf = 1
    It seems that you do know what you're doing after all. 
    
  *if conf = 0
    This turned out far easier than it seemed. 
    
  "Nicely done," Syphel compliments as you return to the carriage. 
  
  Once inside, you check yourself over, but you don't seem to have sustained any injuries. 
  
  "A little more training and ya might just be a proper Reaver," Syphel smirks as he crosses his arms on the seat across from you. 
  
  "I think I did fine," you note. 
  *set syrel %+ 5
  *if conf = 0
    *set combat +5
  *if conf = 1
    *set combat + (effort*5)
  *set renown +10
  
  "Fine, yeah. Amazing, no," he points out, "If ya want, I'll help ya train. Just think about it." 
  
  Taking him up on the offer couldn't hurt. It would at least give you the chance to gauge your abilities against another Reaver. 
  *goto continueride
*if combat < 10
  but before you even realize what's happening, you're face down in the dirt, a blinding pain radiating from your temple. 
  
  By the time you're able to figure out what's going on around you, two thieves are face down in the dirt, one of them dead with a short sword through him, and the rest are nowhere to be seen. Syphel is standing next to you with his arms crossed. 
  
  *if conf = 1
    "Handled that really well, didn't ya?" Syphel frowns, giving you a hand up. 
    *set syrel %- 10
    
  *if conf = 0
    Syphel lets out an exasperated breath as he gives you a hand up. 
    *set syrel %- 5
    
  He leads you back to the carriage where you safely check yourself for any injuries. As far as you can tell, you were taken down by a single blow to the side of the head. 
    
  "Ya have no combat training, do ya?" Syphel asks, arms crossed accusingly as he sits across from you. 

  "No," you admit. 

  "Then ya just did something really stupid," he explains, as if you hadn't already noticed, "If ya ever want, I can train ya." 

  Taking him up on that offer sometime doesn't seem like a bad idea at this point. 
  *goto continueride
*label continueride
*if rebel = 0
  *set girel %+ 5
*finish Next