*set cloth "norm"

You push with all of your might on the side of the wardrobe, but only manage to move it a few centimeters. Reaver Harking had informed you this morning that you could move into a more permanent room of your choosing in the palace. You managed to find a very nice room in a rather secluded and rarely used part of the building. It merely needed some cleaning and rearranging to make it habitable. 

Unfortunately, you only figured out that the fine-crafted furnishings in the room were also twice as heavy as regular furnishings AFTER you claimed the room and moved all of your belongings halfway across the palace.

You take in a determined breath and go for another hard shove on the wardrobe. Surprisingly, it moves a full meter forward, nearly knocking you off balance.

"Whoa, sorry about that," a head pops out from the other side of the wardrobe.

You immediately recognize him as the unknown man at the meeting with the Emperor yesterday. You note, however, that his armor today is white and silver.

He steps toward you and happily stretches his hand forward, "Name's Syphel. We sort'a met yesterday." 

*choice
  #Shake his hand.
    "$!{title} $!{surname}," you say aloud for the first time, offering him a handshake. 
    You can't help but notice some awkwardness in the way you announced your name.
    
    Syphel, however, doesn't seem to take note of it.
    *set syrel 50
    *goto meetsy
  *if male
    #Bow in greeting.
      "$!{title} $!{surname}," you say aloud for the first time, offering him polite bow. You can't help but notice some awkwardness in the way you announced your name.
      
      Syphel's cheeriness visibly diminishes as he retracts his hand and returns some semblance of a proper bow. 
      *set syrel 25
      *goto meetsy
  *else
    #Curtsy in greeting.
      "$!{title} $!{surname}," you say aloud for the first time, offering him polite curtsy. You can't help but notice some awkwardness in the way you announced your name. 
      
      Syphel's cheeriness visibly diminishes as he retracts his hand and returns some semblance of a proper bow. 
      *set syrel 25
      *goto meetsy
  #Ignore his greeting.
    "$!{title} $!{surname}," you say aloud for the first time, before turning your attention back to straightening the wardrobe. You can't help but notice some awkwardness in the way you announced your name. 
    
    Syphel's cheeriness visibly diminishes as he dejectedly retracts his hand. 
    *set syrel 5
    *goto meetsy
*label meetsy

"Ya're $!{name}. I know," he casually mentions as you get back to trying to push the wardrobe into the exact perfect spot. "Ya know, ya can get someone to do this for ya," he adds.

"Like you?" you ask, making a few more centimeters of progress. Another good push should move it to the right place.

"Sure," he grins and takes your place. One hard push and the wardrobe stands in the exact right spot.

"Perfect," you nod, admiring it's placement.

You notice that Syphel is speaking a strange dialect of the common tongue, but are unable to place where it's from. His accent forces you to listen intently when he's speaking in order to clearly understand him.

As far as you can tell, under that armor is only a man of average build, yet he seems to have the strength of someone at least twice his size.

"Anything else?" Syphel asks, almost as if he's taking the task of moving furniture as some sort of challenge.

"Well, that bed could stand to be a bit farther from the window."

"Done," he immediately gets on the task. It takes little more than one good push to move the large wooden framed bed.

"Great," you nod in approval, "What was it that you do here again?"

"Reaver," he grins.

The realization of how inappropriate what you've just done is suddenly hits you.

*page_break
*fake_choice
  #I should apologize.
    "I'm sorry," you immediately apologize, "I didn't know... I just thought... I'm sorry."
    
    He waves off your clumsy attempts at an apology. "It's alright," he assures you, "Ya probably didn't know because I didn't tell ya."
    
    "Er... Thank you, then," you sheepishly mumble,
  #I'll just play it off as if nothing happened.
    "Erm, right," you quietly respond before changing the subject, 
  #Why didn't he say that in the first place?! This is his own fault.
    "Why didn't you say so, then?" you challenge.
    
    "Didn't think about it?" he sheepishly offers, scratching the back of his neck, "I don't go around habitually telling people, unlike..."
    He suddenly stops talking and looks to you.
    
    "Unlike me, you mean?" you finish for him,
"But aren't there only ever three Reavers at a time?"
You've met all three Reavers during your time with the Empire. Syphel was not one of them.

"Yep. Ya, me, and Gillen," he easily answers.

*if origin="Ehl"

  Hearing him speak a bit more, you're finally able to recognize his accent and dialect as being from the region of Raleigh, south of the current borders of the Empire. What someone from outside of the Empire is doing as a Reaver perplexes you nearly as much as why you're one.

"What happened to Reaver Triolo?" you question.

"Dunno," Syphel casually shrugs.

Reaver Triolo was famous for being the greatest swordsman of the era.
He was also known for being ruthless and excessively cruel, usually choosing to be at the front of a battle rather than direct it from the sidelines.
The fact that he chose to wear the most intimidating set of armor he could find certainly didn't help soften his image.

You had previously worked in his section of the Imperial Combat Forces, and the few times you'd ever seen him he was either insulting you or one of your fellow guardsmen.

The other Reaver you'd met was a Sage of some importance, although you can't remember her name.
It seemed that she hadn't been a Reaver for long.
You had only met her for a brief time, and can only clearly remember that she carried herself with a certain elegance that only people of high stature possessed.

"Wasn't there a woman that was a Reaver?"

"Reaver Plorina?" Syphel frowns.

That was the name. "Yes. What happened to her?"

"Don't care. Look, I wouldn't worry about it. Triolo and Plorina weren't the best people in the world, and hopefully they got what they deserved."

You blink, unable to respond to his sudden harshness. Reaver Triolo was admittedly a horrible and brutal man.
The one time you had met Reaver Plorina, however, she was genuinely nice to you. 
*if origin="Asylia"
  She seemed especially enamored by the green flecks in your eyes, not bothered in the least with the country they marked you as being a part of. 
*if origin="Ehl"
  She seemed especially enamored by the Ehlish coloration of your skin, probably seeing it as a novelty rather than an oddity. 
*if origin="Sedel"
  She seemed especially enamored by the shape of your ears, mentioning they were something to be proud of rather than something you had to hide. 
It was hard to think that she would deserve any sort of awful fate.

"The past is in the past," Syphel interrupts your thoughts, "Look forward instead'a bothering with it."

*choice
  #He's right. The future is all that matters now.
    *set effort +0.25
    Nothing can be done to change the past, but you've been given a chance to shape what happens from here.
    *goto firstorder
  #I understand what he means, but the past is important, too.
    *set intel +5
    *if origin = "Capel"
      *set magic +5
    From the past, we can learn what mistakes should be avoided in the future. A tool like that shouldn't be forgotten so easily.
    *goto firstorder
  *if integrate
    #The past is all I have, since the Empire decided to take everything else from me.
      *set rebelcount + 1
      You realize that this isn't the healthiest attitude, but you can't let the crimes committed against you to go unforgotten.
      *goto firstorder
*label firstorder

"That reminds me," Syphel starts, "I came by to see if Dain had given ya any assignments yet."

Aside from Reaver Harking offering you the chance to change rooms this morning, no one had told you anything about what you were supposed to be doing. You explain as much to Syphel.

"Figures," he crosses his arms as if this sort of thing is common place, "Ya should come with me to Raleigh, then."

"I should?" you ask, confused as to where this recommendation came from.

"Definitely," he nods with assurance, "Can't be a proper Reaver without looking the part, and the best armorer I know is in Raleigh."

Now that you think about it, Reavers did always have their own unique appearances. It seems that they are granted more independence than anyone else working for the Empire. The days of you wearing a drab grey uniform truly are gone.

*choice
  #I'll go. If I'm going to play the part, I may as well look the part.
    *set syrel %+ 20
    "I take it Raleigh is usually were you get your armor?" you gesture to the well crafted set he's wearing today.
    
    "All fifteen sets," he proudly grins.
    
    "Count me in, then," you accept his invitation.
    
    "Great. I knew from the moment I saw ya that we'd be friends," he nods, "It's going to be a good two weeks on the road, so pack what ya need."
    
    He leaves your room looking slightly happier.
    *goto firstdayend
  #I'll go. Syphel seems like a good ally to have and I should get to know him better.
    *set syrel %+15
    "Sounds like a plan," you casually agree.
    
    "Great. It'll be fun," he grins, "Make sure ya bring what ya need for a two week journey."
    
    He gives you a quick wave before leaving your room.
    *goto firstdayend
  #I'll go. Anything to get me away from the heart of the Empire is fine with me.
    *set syrel %+ 10
    *set rebelcount + 1
    "Sure, I'll go," you easily agree, "Raleigh sounds nice."
    
    "Actually, it's a frozen wasteland most'a the year," Syphel comments.
    
    "Nicer than here, I mean," you explain.
    
    "Oh, that? No kidding," he shrugs, his smile fading.
    
    Before you can think too far into his exact meaning, he gives you a disruptive tap on the forehead.
    
    "Instead'a daydreaming, maybe ya should pack," he recommends, walking out of your room, "It's a two week journey, so take whatever ya need."
    *goto firstdayend
  #I don't particularly want to go, but I don't know what else to do with myself. I'll go.
    "I guess I'll go, if no one needs me for anything else," you shrug.
    
    "If they need ya, they'll send for ya," he grins, "Trust me. I leave all the time."
    
    "If you insist," you reply. Syphel is the senior Reaver here, and probably knows how they are supposed to operate better than you do.
    
    "It'll be a couple'a weeks on the road, so pack what ya need," he waves as he exits your room.
    *goto firstdayend
  #I don't think I should be leaving. I find an excuse to not go.
    *set syrel %- 20
    "Wouldn't my leaving cause problems?" you argue.
    
    Syphel casually shrugs. "If anyone needs ya, they'll send a message. If ya've got free time, no one's going to stop ya from doing something with it."
    
    "I don't think that's a good idea," you continue to disagree.
    
    His grin diminishes a bit. "Ya seem to forget that I'm the senior Reaver here," he reminds you, a serious look in his eyes for once, "Dain's going to make ya go anyway, so ya may as well be my friend and go with me."
    
    Something about his posture tells you that his friendly nature toward you has it's limits, and you're about to cross them. Surely, there's some rule somewhere against Reavers attacking other Reavers, but since no one has told you anything about it, this situation remains tricky to navigate through. In any case, Syphel doesn't come off as someone who would adhere to strict rules and regulations.
    
    "May as well," you slowly repeat his words, finally relenting.
    
    "Great. Pack up," he says, his cheerful disposition suddenly returning, "We'll be gone for two weeks."
    
    "If anyone says anything about it, I'm blaming you for this," you warn.
    
    "Ya worry too much," Syphel casually waves off your comment as he leaves you to get your things in order.
    *goto firstdayend
*label firstdayend
*if rebel = 0
  *set girel %+ 5
*finish Next