*label Intro

You really aren't awake yet. You never are until at least your second cup of coffee, and this is only your first. You're having a hard time getting your eyes to focus. But it certainly looks like there's a man in your front yard, crouched down on all fours, gnawing at a leg.

A human leg. Definitely. It's still wearing a sneaker. And a sock. 

The man gnawing on the human leg suddenly stops chewing, as though some sound disturbs him. He slowly looks up from his meal. His eyes don't blink, and they seem to be too large for his face. His mouth hangs open. Drool and blood trail down his chin.

You heard about the outbreak in Millbury, of course. You just hadn't thought it was as serious as the eleven o'clock news made it out. They get hysterical about everything. A couple of inches of snow, and it's THE SNOWPOCALYPSE. You can't really be blamed for putting their ZOMBIEPOCALYPSE warnings in the same category. Boy who cried wolf, right?

But it seems the newscasters were at least a little right, because there's a zombie chowing down on a human leg in your front yard. 

Shit.

*page_break

And just then you catch a glimpse of movement out of the corner of your eye, and a herd of at least twenty more zombies come staggering around the bend in the road. They are covering ground pretty steadily. Faster than you would have thought.

The zombie with the leg sees them coming. He rises from his crouch, teeth bared, leg in hand. Some of the zombie herd move towards him. (Herd? Is that the right word? Maybe a flock? A decomposition of zombies or an infestation perhaps? ANYWAY...) They start a messy tug of war with the leg, mostly using teeth. 

Others look around for different prey. One goes for a squirrel. Some seem to be eyeing your front windows, though you're standing far enough back that you don't think they can actually see you. 

Still, this is really not good. Your house is on one floor, and the news footage made it pretty clear that zombies can break through glass with no trouble, zombifying some humans and eating others. And it seems that they've already started doing just that in your neighborhood, because those two zombies there have glass shards sticking out of their faces. And you recognize one of them--that annoying woman who always cuts in line at the coffee shop. She is moving towards your windows. So are about five others.

You obviously can't stay in your house. What are you going to do?

*choice

	#Sprint out the back door and into the woods.
    
		You slam down your coffee mug. Oddly enough, you don't really feel like you need it any more; your heart is hammering like you've just downed a triple espresso. You shove your feet into your running shoes and bolt for the back door. You snap open the lock, yank the door open, and run like hell across your yard and into the woods. 
        
		As you run, you can hear growling and screaming from your front yard and your neighbors' front yards. It decreases doppler-fashion the farther into the trees you get.
        
		*set firstchoice "back"
		*goto Startup

	#Slip out the side door and try to sneak past them to my car, while they're all occupied with legs and squirrels and windows. 
    
		You very carefully set down your coffee mug. Oddly enough, you don't really feel like you need it any more; your heart is hammering like you've just downed a triple espresso. You ease backward, moving carefully so the zombies approaching the window won't notice you. You duck out of sight into the kitchen, pause to slip your shoes on, and quietly unlock the side door. 
        
		"Argh," you hear from the front room. It is followed by a sticky sound, probably from a wet hand (wet with what? ugh) slapping against your window. 
        
		Ever so carefully, you turn the knob and open the door. You hear more hammering behind you, and now you can hear the growls of the zombies fighting over the human leg in your front yard. Your car is just ahead of you, backed into its usual parking space against the shed. You hope the front yard zombies are so obsessed with their leg-of-war that they won't catch sight of you tiptoeing across the driveway.
        
		The ten steps it takes you to reach the car are the ten most nervewracking of your entire life. But you manage to be quiet enough--the tangle of zombies in your front yard doesn't look up until the thud of the closing driver's side door.
        
		Then all their wide eyes go wider and they start for you, but you drive with your foot to the floor, tires squealing, out of your driveway and down your side street, heading for the main road.
        
		*set firstchoice "front"
		*goto Startup

       

*label Startup

We should pause here to get straight a few details about you. First of all, are you male or female?

*choice

	#Male.
    
		*set gender "male"
		*set he "he"
		*set he_opp "she"
		*set his "his"
		*set his_opp "her"
		*set him "him"
		*set him_opp "her"
		*set doctor "Michael"
		*set engineer "Lev"
		*set survivalist "Brian"
		*set useless "Justin"
		*set gamer "Chris"
		*set boy "boy"
		*set man "man"
		*set guy "guy"
		*set Mr "Mr."
		*goto Firstname
    
	#Female.
    
		*set gender "female"
		*set he "she"
		*set he_opp "he"
		*set his "her"
		*set his_opp "his"
		*set him "her"
		*set him_opp "him"
		*set doctor "Michelle"
		*set engineer "Lisa"
		*set survivalist "Bonnie"
		*set useless "Jennifer"
		*set gamer "Carrie"
		*set boy "girl"
		*set man "woman"
		*set guy "girl"
		*set Mr "Ms."
		*goto Firstname
    
    

*label Firstname

What's your first name?

*input_text given_name

*goto Profession


*label Profession

What's your profession? I mean, your profession now appears to be "zombiepocalypse survivor." But what was your profession before the world went to hell?

*choice

	#Advertising executive.

		You spent your early career writing ads that persuaded people to buy things they didn't actually want. Now that you're in management, you spend your life persuading your clients to go with your good ideas rather than their stupid ones, and persuading the people who work for you not to kill each other. This means you are both good at reading people and unusually persuasive. 

		*set diplo true
		*goto Hobby

	#Paramedic.

		You ride in an ambulance and are often the first on the scene of terrible accidents. That severed leg in your yard was not the first you've ever seen. You'd know how to amputate a limb yourself if you had to. More to the point, you know how to do the stuff necessary so amputating limbs isn't required. You're very good at CPR, setting broken bones, and stabilizing patients when hospitals are not available. 
    
		*set medical 80
		*goto Hobby

	#Software engineer.

		You spend your days designing solutions to problems. Writing code that implements your solutions. Fixing bugs in your code. Making shit work, in general. You are methodical, organized, good at defining a problem and assembling the information you need to solve it.
    
		*set engineering 80
		*goto Hobby

	#Plumber.

		You spend your days digging drains, laying new pipe, fixing old plumbing, pumping sewers. You are physically fit and, perhaps even more valuably, you are accustomed to dealing with the physical world. You may not have a fancy degree, but you have a practical understanding of physics and to a lesser extent mechanics.
    
		*set handtohand 80
		*goto Hobby


*label Hobby

And what do you most like to do in your spare time? 

*choice

	#Play sports.

		In spring and summer, you play softball. In fall and winter, you spend much of your non-working time sweating on the cardio machines and lifting weights at the gym. 
        
		You're in peak physical condition for your age. That's bound to come in handy when running from zombies.
    
		*set athletics %+20
		*goto Disad

	#Play video games.

		You have the largest collection of first-person shooter games known to mankind. (Your ex used to complain about all the time you spent in front of the screen.) You're good at shooting things. Particularly zombies. 
    
		This is good, because the scene in your front yard looked a whole lot like one of your games. 
    
		*set firearms %+20
		*set hobby "videogames"
		*goto Disad
        

	#Collect stamps.

		Really? I didn't think there was anyone under 90 who actually did that.
    
		Congratulations, you have the most boring hobby on the planet. But I guess it might come in useful when fleeing from zombies. . . somehow. After all, you must have good eyes to distinguish one valuable stamp from ten thousand worthless ones. Maybe those pattern recognition skills will be useful when fleeing from zombies. You can hope. 
    
		*set engineering %+10
		*goto Disad

	#Woodwork.

		You spend evenings and weekends in your workshop in the basement, making props for the local community theater and jewelry boxes that you sell on Etsy. Your fingers are accustomed to delicate work, and perhaps more even more valuably, your eyes and brain are accustomed to visualizing how things are put together. 
    
		*set engineering %+20
		*goto Disad
    
	#Hunting.

		You first went hunting with your dad when you were a kid, and now you go several weekends during the season, with friends. You love the deep quiet of the woods, and you're proud of your precision with a rifle.
        
		You wonder if shooting zombies will turn out to be more or less difficult than shooting deer. You expect you'll be finding out. Soon. You wish you'd had time to get your gun on the way out the door.
        
		*set firearms %+20
		*set hobby "hunting"

    
*label Disad

That tells us what you're good at, but you can't be perfect. What would you say is your worst quality?

*choice
           
	*if athletics <= 50
		#I'm terribly out of shape. I always say I'm going to do something about it, but I'm always so busy. . .
    
			Aren't we all. It's the curse of the modern era. 
        
			Don't worry, I'm sure the ability to run fast won't be important as you flee from. . . er. I mean, don't worry, it'll be fine.
        
			*set outofshape true
			*set athletics %-20
			*set handtohand %-20
			*goto InitialGroupStats
    
	*if engineering <= 50 
    
		#I'm not a visual sort of person at all. Sometimes I envy people who can easily read maps and put together puzzles.
        
			And for obvious reasons, your job and hobbies have been things that you think about conceptually rather than things that you visualize. That's okay. You've developed many important skills that way, and I'm sure they'll come in useful as you. . . er, run from zombies.
            
    
			*set engineering %-20
			*set firearms %-10
			*goto InitialGroupStats
    

	*if handtohand <= 50
	
		#I'm terribly uncoordinated. Always have been. I trip over stuff all the time.
    
			I'm sure that's embarrassing sometimes, but nothing to worry about. The ability to keep quiet isn't likely to be important when you're. . . er, running from zombies.
    
			*set reflexes %-20
			*set handtohand %-20
			*set clumsy true
			*goto InitialGroupStats
    
	*if (medical <=50) and (hobby != "hunting")
    
		#I'm squeamish. Blood makes me feel sick. Gory movies make me run for the toilet.
    
			I can't imagine that will be a problem when zombies are chewing on other people's body parts in your yard.
        
			Oh, sorry, I didn't mean to. . . um, do you need a bucket or something?
        
			*set medical %-20
			*set squeamish %-20
			*goto InitialGroupStats

    
*label InitialGroupStats

*if firstchoice = "front"

	*set reflexes %+15
    
	*goto InitialGroupStats2
    
*else

	*set athletics %+15 
	*goto InitialGroupStats2
    

*label InitialGroupStats2

*set grouphandtohand handtohand
*set groupfirearms firearms
*set groupathletics athletics
*set groupengineering engineering
*set groupmedical medical
*set groupstealth reflexes

Right, then! Now that we know who you are, we'll return to "flight from the zombies," already in progress!


*finish