*temp hide_why
*set hide_why false
*temp hide_moment
*set hide_moment false
*if (lady_killer)
	*goto lady_killer1
*else
	*goto regular

*label lady_killer1
*set chapter + 1
*page_break
CHAPTER THREE: THE LAKE
*goto post_title
*label regular
*page_break
*set chapter + 1
CHAPTER TWO: THE LAKE
*label post_title

One after another, your senses return. You hear the timid chirping of birds and the soft prattle of rain falling on a roof of leaves. A cool gush of wind brushes the back of your neck. The smell of wet grass reaches your nose.
*line_break
Carefully, you sit up and look around you. You are on a meadow at the edge of a lake, low willows protecting you from a light rain. A thin fog rises from the black waters.
*choice
	#Walk to the edge of the lake
		*goto lake
	#Leave the lake and explore the area
		*goto village
	#"Necro?"
		"Still here."
		*choice
			*if (lady_killer) #"Where are we?"
				"This is the lady's domain, the Lake of Eternal Peace. My guess would be that Gorath expects us to kill the lady. To be fair, you kind of promised you'd do it the last time we talked to him."
				*choice
					#"Who's the lady?"
						"'Who's the lady?' As if you don't know, you rascal, you."
						*choice
							#"I don't."
								"Oh, right, memory loss. Well, the lady doesn't really like visitors, so we should either kill her or get going."
								*choice
									#"All right, let's take off."
										*goto village
									#"I have no intention of killing her, but I think I'd like to meet that lady." (Walk towards the edge of the lake)
										*goto lake
									#"I think I'm gonna kill her." (Walk towards the edge of the lake)
										*goto lake
									#"Any suggestions on how the killing should be done?"
										*goto how_to_kill
									#"Do you think we should kill her?"
										*goto necros_opinion
					#"I'm not killing anyone."
						*label not_killing_anyone
						"Then we should probably get going. The lady doesn't like visitors."
						*choice
							#"All right, let's take off."
								*goto village
							#"Actually, I'd like to meet her."
								*goto lake
					#"How do we kill her?"
						*label how_to_kill
						"What do you think Gorath's dagger is for? You probably just stick it in her heart or something."
						*choice
							#"All right, let's do this." (Walk towards the edge of the lake)
								*goto lake
							#"I changed my mind. I'm not killing anyone."
								*goto not_killing_anyone
					#"Do you think we should kill her?"
						*label necros_opinion
						"I think we should just run and steer clear of both this lake and the bloody mountains in the future. You have a great talent for getting into trouble with people far too powerful to mess with. I mean, Gorath could crush you with one hand and commands an army, while the lady is something like a half-goddess, at least as far as I know. The fact that I don't know what she actually is should be warning enough not to cross her."
						*choice
							#"Anything else?"
								*if (demon_mark)
									"I can't believe you managed to promise your soul to a demon. What is wrong with you?"
									*page_break
									*goto lethal_decision
								*else
									"Not at the moment."
									*page_break
									*goto lethal_decision
							#"I appreciate your opinion."
								*goto lethal_decision
							#"Put a lid on it Necro."
								*label lethal_decision
								"So what are you gonna do?"
								*choice
									#"Kill her." (Walk towards the lake)
										*goto lake
									#"Leave her alone."
										*goto village
									#"I'm not going to kill her, but I'd still like to meet her."
										*goto lake
			*if (lady_killer = false) #"Where are we?"
				*goto where_are_we
			*if (lady_killer = false) #"I think we need to have a talk."
				*label talk
				"That's how most of my nightmares start. What did you want to talk about?"
				*choice
					#"Where are we?"
						*label where_are_we
						"Well, the demon took us to the Lake of Eternal Peace, like you asked him to. That's not something to take for granted, by the way: once he took us to the Dungeon of Perpetual Screaming just because you called him a 'fat toddler'. Anyway, this is the lady's domain, so we better take off. There's a village nearby."
						*label ladyvillage
						*choice
							#"What lady?"
								"'What lady?' As if you don't know, you rascal, you."
								*choice
									#"I don't."
										"Oh, right, memory loss. Well, the lady doesn't really like visitors, so we'd better get going."
										*choice
											#"All right, let's take off."
												*goto village
											#"I think, I'd like to meet that lady." (Walk towards the edge of the lake)
												*goto lake
							#"A village?"
								"Yeah, the people there are really friendly and we can figure out what to do next."
								*choice
									#"All right, let's take off."
										*goto village
									#"Actually, I'd like to meet that lady." (Walk towards the edge of the lake)"
										*goto lake
							#"All right, let's take off."
								*goto village
					*hide_reuse #"Who am I, Where do I come from and what the hell are you doing on my arm?"
						"I can't tell you stuff like that."
						*choice
							#"Why not?"
								*label why_not
								"It's pretty complicated. There are certain -conditions- that bind me, preventing me from disclosing certain information to you. The more I explain, the more questions you'll have, so let's just drop it."
								*choice
									#"All right."
										*goto alright
									#"I think you're lying to me."
										"I wish I were - not because it would change anything, but because of the satisfaction of lying to you - but I'm not. I can't talk about those kind of things."
										*choice
											#"All right."
												*goto alright
											#"Then I'll just have to -make- you talk."
												"And how are you going to do that? Threaten to chop your own arm off?"
												*choice
													#"Well, no."
														*goto alright
													#"Yes."
														*goto armchop
													#"..."
														*label armchop
														"You -wouldn't-."
														*choice
															#"You're right"
																*goto alright
															#"Try me."
																"Look, I really can't tell you. I swear. It is impossible for me to tell you."
																*choice
																	#"All right, I believe you."
																		*goto alright
																	#Look for something to chop your arm off with
																		"Hey, where are you going?"
																		*line_break
																		You search the ground, soon finding a sharp stone.
																		*line_break
																		"Hey, put that down!"
																		*choice
																			#Drop the stone
																				*goto alright
																			#Start chopping your arm off
																				You raise the storm, then bring it down on your right arm with all your might. It digs deep into your flesh, causing unbearable pain.
																				*choice
																					#"ARRRGH!"
																						*goto pain
																					#"HRNNNN!"
																						*goto pain
																					#"GRRRRK!"
																						*label pain
																						"Ahhh!" Necro cries out. "Look, I feel your pain, I -literally- do, but I wasn't lying! Please stop this madness!"
																						*choice
																							#Stop
																								You pur down the stone and press your hand against your bleeding wound. It hurts like hell, but it doesn't look live-threatening.
																								*set wounded true
																								*set wounded_string "arm"
																								*set stubborn true
																								*goto alright
																							#Continue
																								You try to hit yourself again, but your limbs won't obey. You drop your makeshift amputation device and press your hand against your bleeding wound. It hurts like hell, but it doesn't look live-threatening.
																								*set wounded true
																								*set stubborn true
																								*goto alright
							#"'Can't' or 'won't'?
								"I -can't-, so I -won't-.
								*choice
									#"All right."
										*goto alright
									#"What do you mean?"
										*goto why_not
							#"Can you at least tell me where we are?"
								*goto where_are_we
							#"All right."
								*label alright
								"Well, I'm glad that's settled then. Now let's get out of here before the lady gets us. There's a village nearby."
								*goto ladyvillage
*label lake
You approach the lake. Raindrops are causing small ripples, disturbing the smooth surface. The lake is clean and empty. There are no water lillies, no insects or fish or frog. A cool silence seems to be emanating from the water. You lower your gaze to look at your reflection, but there is nothing to see.
*line_break
"We really shouldn't be here, master" Necro sounds scared. "Let's just take off, all right?"
*choice
	#"Ok, let's go."
		*goto village
	#Touch the water
		*label water_touching
		The surface is smooth like silk and cool to the touch. Water encloses your fingers and you feel a sense of peacefulness spreading in your mind. A woman's hand, white like snow, rises from the deep and catches your hand. Instinctively, you pull back and fall to the ground.
		*page_break
		Nude but for the long, wet hair falling from her shoulders, a woman steps out of the water. As her steel blue gaze meets yours, a splinter of memory races through your mind, gone before you can hold on to it.
		*line_break
		"My love. You have returned."
		*choice
			#"Who are you?"
				She kneels beside you, slender fingers caressing your face.
				*line_break
				"You have forgotten" A single tear runs down her cheek and drops to the ground, mingling with the rainwater. "I can feel the emptiness of the desert in your heart."
				*page_break
				"I am Neruna, goddess of the lake. You came here, a long time ago. You came to slay me, but the beauty of my soul swayed you. We are lovers. The emptiness has consumed your mind, but in your heart you still carry our love."
				*temp ask_home
				*set ask_home false
				*temp ask_traitor
				*set ask_traitor false
				*label ask_the_lady
				*choice
					*hide_reuse *if ( ask_home ) #"Where is my home?"
						"You never told me. Too painful a memory to share, even with the one you love."
						*goto ask_the_lady
					*hide_reuse *if ( ask_traitor ) #"Necro is a traitor?"
						"A traitor to some, a misfit to others. He is your servant and as such I shall accept him."
						*goto ask_the_lady
					*if ((lady_killer = false) and (hide_why=false)) #"Why did I want to kill you?"
						*set hide_why true
						"You were corrupted. An evil man by the name of Gorath wanted me dead. You fell for his lies but I showed you the truth. You love me and I love you. In eternity, we will be united."
						*goto ask_the_lady
					*if (lady_killer) #"Gorath sent me to kill you again."
						*goto here_to_kill
					*hide_reuse #"Do you know who I am?"
						"You are a wanderer. Exiled from your home, never to return. But all is good, because you found me. We are one."
						*set ask_home true
						*goto ask_the_lady
					*hide_reuse #"What do you think about this, Necro?"
						"You still carry him with you?" Neruna pulls up your sleeve, revealing the tattoo. Necro is not speaking or moving. He seems smaller than the last time you saw him. "When I speak, he must be still. I am peace, he is chaos. The traitor is silenced in the presence of the goddess."
						*set ask_traitor true
						*goto ask_the_lady
					*if (lady_killer = false) #"What happens now?"
						"Now you fulfill your promise, my love" She takes a deep, soft breath and the willows' leaves rustle. "Gorath, the evil ruler of the mountains, stole my water lily. Without it, I am but a husk. You promised to bring it back to me, a wedding present before we are joined for eternity."
						*label quest_questions
						*choice
							*hide_reuse #"A water lily?"
								"Not -a- water lily" Neruna's voice is suddenly sharp. "-My- water lily. Without it, I can not be, we can not be. It must be returned here."
								*goto quest_questions
							*hide_reuse #"How can I find it?"
								"It will call to you, as I called to you. Gorath will try to protect it, but you have bested him before. I trust you, my love. I trust myself to you."
								*goto quest_questions
							#"Where do I start my search?"
								Neruna giggles, a beautiful sound coming from all around you. "Well, in the realm of Gorath of course. I will await your return, but before you go, take this." She slips a small vial made of some cool, dark material into your hand. "It contains a drop of water from my lake. Carry it with you, and you'll carry me with you."
								*set water_vial true
								*line_break
								She leans forward and her cool, wet lips touch yours. "Good bye, my love."
								*line_break
								Once again, you are enveloped by darkness.
								*goto hound_gorath
							
					*if ((lady_killer = false) and (hide_moment = false)) #"I need a moment to absorb these news."
						*set hide_moment true
						"Of course, my love. Without a doubt you will want to ask the traitor about this." She looks at your arm, where Necro lies under your shirt. Then she is gone, swallowed by the black waters.
						*page_break
						"We need to get out of here NOW." Necro's voice trembles.
						*label talk_necro
						*choice
							*hide_reuse #"Who is she?"
								"She is a mad sorceress who lives in a lake. Let's go before she eats our souls, shall we?"
								*goto talk_necro
							*hide_reuse #"You were unusally quiet just there."
								"I tend to be in the presence of mad sorceresses."
								*goto talk_necro
							# "Actually, I'd like to talk to her some more." (Call out Neruna's name)
								In an instant, the lady of the lake is before you again.
								*line_break
								"I return, my love."
								*goto ask_the_lady
							#"Ok, let's go toward the village."
								"NO."
								*line_break
								Startled, you turn around. The lady is right behind you, grabbing your arm with surprisingly strong fingers.
								*line_break
								*label stay_my_love
								"Stay, my love."
								*choice
									#"I -do- have some more questions ..."
										*goto ask_the_lady
									#"I'd rather not."
										Tears start streaming down Neruna's face. Her voice is pleading. "Please stay. You must have many more questions."
										*choice
											#"You're right, I do."
												*goto ask_the_lady
											#"No. I am leaving."
												You try to free yourself, but the grip around your hand remains strong. Neruna pulls you towards her with an iron grip. Her face is wet with tears.
												*line_break
												"Why do you do this to me, my love?" She takes a step backwards, pulling you towards the lake. "Why do you hurt me so much?"
												*choice
													#Try to free yourself
														*label free_yourself
														You summon all your strength in a desperate attempt to free yourself, but Neruna is too strong. She pulls you into the lake. Cold water closes above your head and you feel darkness closing in on you.
														*goto hound_dungeon
													#"I am sorry, love ..."
														"No!" her scream pierces your ears. "No more excuses!"
														*goto free_yourself
			*if (lady_killer) #"Gorath sent me here to kill you."
				*label here_to_kill
				"Again?" She sadly shakes her head. "And are you goin to fulfill his wish?"
				*choice
					#"Yes."
						*goto attack_the_lady
					#"No."
						"I am glad."
						*choice
							#"What happens now?"
								"Now you fulfill your promise, my love" She takes a deep, soft breath and the willows' leaves rustle. "Gorath stole my water lily. Without it, I am but a husk. You promised to bring it back to me, a wedding present before we are joined for eternity. I have recently learned that he keeps it in the Dungeon of Eternal Screaming. I do not send you there lightly, but it must be done. Take this." She slips a small vial made of some cool, dark material into your hand. "It contains a drop of water from my lake. Carry it with you, and you'll carry me with you."
								*set water_vial true
								*set lily_thief true
								*line_break
								She leans forward and her cool, wet lips touch yours. "Good bye, my love."
								*line_break
								Once again, you are enveloped by darkness.
								*goto hound_dungeon
					#Plunge the dagger into her chest
						*goto attack_the_lady
			*if (lady_killer) #Plunge the dagger into her chest
				*label attack_the_lady
				*set willing_lady_killer true
				You try to stab the lady, but she grips your hand with surprising force.
				*line_break
				"Why are you doing this to me, my love?" She whispers, as she pulls you into the lake with her. Cold water closes over your head and everything goes dark.
				*goto hound_dungeon
	#Wait
		The bird's song seems to have stopped. The only sound you hear is the soft prattle of the rain on the surface of the lake. An urge to step into the cold water starts to grow inside you. The lake seems to call out to you, promising peace and bliss in its soft embrace.
		*choice
			#Touch the water
				*goto water_touching
			#Tear yourself away and leave the lake
				*goto village
*label village
A small, winding path leads through the willows, away from the lake, but you can not bring yourself to move into that direction. Something is drawing you towards the lake. The raindrops are whispering to you: "Come. Come."
*page_break
You kneel down at the edge of the lake and reach down to touch the water.
*goto water_touching
*label hound_dungeon
*page_break
INTERLUDE: THE HOUND


The night is cold at the edge of the Lake of Eternal Peace. The Hound's hot breath forms clouds of steam in the darkness. Red eyes search the pouring rain. The prey was here, not long ago.
*line_break
The hunt has just begun.
*goto_scene dungeon
*label hound_gorath
*page_break
INTERLUDE: THE HOUND


The night is cold at the edge of the Lake of Eternal Peace. The Hound's hot breath forms clouds of steam in the darkness. Red eyes search the pouring rain. The prey was here, not long ago.
*line_break
The hunt has just begun.
*set lily_thief true
*goto_scene gorath