*if GotSurvivalist
	*goto UselessBack

*else
	*goto WhereTo

*label WhereTo

*if GotKid

	"So," Kayden says. "Um. . . where are we going?"

	That's a very good question. 

	*label Radio

	In search of ideas, you switch on the radio. ". . . have upgraded the Zombie Watch to a Zombie Warning for the following counties," the radio says, and then the announcer rattles off a long list. The announcer seems pretty rattled herself. "I repeat, this is a serious and life-threatening situation. If you are in this area, you are in the path of the zombiepocalypse and should take shelter immediately. Zombies can break through glass and can climb stairs, so we are advising all residents to leave their homes while they still can. Groups of survivors have been forming at various locations throughout the state. Within the last hour, we have heard from the group at Maple Valley Mall, Cedar Junction Correctional Facility, and First Church of Fulton, so we can confirm that those are still viable sanctuaries for state residents fleeing the zombiepocalypse. Here is a list of school and business closings as a result of the zombiepocalypse. . . "

	Static engulfs the station again. 

	It seems you have a decision to make.     

	The church, the prison, and the mall are all in different directions. The church is about half the distance away as the other two sanctuaries.  
	*if firstchoice = "back"
		The prison is the one ${Survivalist} was heading to.
	Which one will you head for?

	*choice

		#The mall.

			The mall it is. Why mess with tradition, after all? You head for the main road that will take you to the mall.

			*set tempsafespot "mall"
			*page_break
			*goto BigHouse

		#The prison.

			The prison it is. You probably couldn't be safer. You head for the main road that will take you to the prison.

			*set tempsafespot "prison"
			*page_break
			*goto BigHouse

		#The church.

			The church it is. An unconventional choice, but if the group is still safe there, they must have some excellent defense system. You head for the main road that will take you to the church.

			*set tempsafespot "church"
			*page_break
			*goto BigHouse

*else

	You speed long down an increasingly rural main road. On either side is open land. No people. No zombies. 

	Right. Where are you going?

	*goto Radio

*label BigHouse

*if GotKid

	"We're heading for the ${tempsafespot}," you tell Kayden.

You've still got a ways to drive through the country before you can pick up a main road, though. At least it's peaceful. No zombies. Just farmland. Old New England at its finest. 

You wonder what Lovecraft would have made of the zombiepocalypse.

In some places, great big McMansions sit up on hills looking over acres of manicured lawn that used to be farmland but was sold to some rich person. You're coming up on one now, off to the left.

*if GotKid

	"Who lives there?" Kayden wants to know.

	You have no idea.

	"Should we tell them what's happening?"

Do you head for the house?

*choice

	#No, can't risk it. They could already have turned, and I need to put my own safety first.
		*set selfish %+20
		*goto ContinueToDrive

	#Yes, to warn them.

		*set selfish %-20
		*goto BigHouse2

	*if GotKid

		#Yes, maybe I can leave Kayden with them.

			*goto BigHouse2

	#Yes, that house looks defensible.

		*goto BigHouse2

*label BigHouse2

A enormous driveway sweeps up the hill, past a lawn that looks like a golf course, around some artistically-shaped shrubberies, and finally to a front door flanked by statues of stone lions.

You hesitate, engine idling, wondering how best to approach. What if there are zombies inside?

*choice

	#I leave the car, take the snowpocalypse shovel from the trunk, and go ring the bell. But I keep the car running.

		The bell doesn't go "ding-dong" like any normal doorbell. Instead, you can chimes tolling inside--ding dong dong ding, dong ding ding dong. Like bells on a church tower. Wow. That's a pretty impressive level of pretension going on here.

		It takes several nervewracking minutes before anyone answers. You've just about decided to give this up as both useless and unsafe when the door is suddenly jerked open by the healthiest-looking fifty-year-old ${man} you've ever seen. $!{His} short graying hair is standing all on end, and ${he} is wearing a silk bathrobe and an irritated expression.

		"What the hell do you want?" ${he} demands. 

		"There's a horde of zombies on the loose," you say. "I stopped to warn you."

		*goto BigHouse3

	#I honk the horn.

		You lean on the horn until an upstairs window opens and the healthiest-looking fifty-year-old ${man} you've ever seen pokes ${his} head out. $!{His} short graying hair is standing all on end, and ${he} is wearing a silk bathrobe and an irritated expression.

		"What the hell do you want?" ${he} demands. 

		"There's a horde of zombies on the loose," you say. "I stopped to warn you."

		*goto BigHouse3

	#To hell with this. I leave.
	
		You continue on your way.

		*finish

*label ContinueToDrive
You keep driving, casting an eye towards the mansion and wondering if they have actually turned or not.
*finish

*label BigHouse3

*set GotDoctor true

*page_break

Shortly thereafter, you
*if GotKid
	and Kayden
are installed at a breakfast nook table so spotless you're sure it can't be used very much. The entire house, in fact, looks so spotless it can't be used very much. The ${man} in the bathrobe lives here alone. $!{He}'s a surgeon, as it turns out--works in the hospital one city over. $!{His} name is ${Doctor}.

$!{He} frowns as you describe your morning. It's the first ${he}'s heard of a zombie horde nearby. $!{He}'s been at the hospital the last two days, because somebody infected with zombieism committed suicide by parking his car on railroad tracks, so there were many severe injuries requiring ${Doctor}'s surgical expertise. $!{He} only got home and to bed a few hours ago. When you're done talking, ${he} nods slowly. Then ${his} eyes drift to contemplate the wall over your head as ${he} thinks.

So what are you going to say next?

*choice

	*if GotKid
		#"Look, I'm going on to the ${tempsafespot}, but I think it would be better if I left Kayden with you. A doctor would be better able to take care of a child."

			$!{His} eyebrows go straight up. "Oh no, you're not. Just because I have a medical degree doesn't mean I have nuturing instincts, and anyway, I don't plan to stay here myself. I'll come with you to the ${tempsafespot}." Dryly, ${he} adds, "You look like you could use all the help you can get."
			*if outofshape
				$!{He} eyes your waistline in a frankly insulting manner.
			*goto DoctorDiplomacy

	#"I was thinking of going to the ${tempsafespot}, but when I saw your house I thought maybe it would be better to try to defend a place like this."

		$!{His} eyebrows go straight up. "Oh no, you're not staying here and turning my house into a stronghold. It's a bad idea anyway--we'd be much better off joining a larger group. I'll come with you to the ${tempsafespot}." Dryly, ${he} adds, "You look like you could use all the help you can get."
		*if outofshape
			$!{He} eyes your waistline in a frankly insulting manner.
		*goto DoctorDiplomacy

	#"I'm headed for ${tempsafespot}. You should come too."

		$!{He} hesitates. "I was thinking of going back to Newbridge. . . but there's no cure for zombieism. There isn't anything I could do for the people still there. . .  Yes, all right, I'll come with you." $!{He} says it like ${he}'s conferring a favor, not like you just did ${him} one by stopping at ${his} house to warn ${him}. $!{His} lips quirk with something like amusement, and ${he} adds dryly, "You can use all the help you can get, right?"
		*if outofshape
			$!{He} eyes your waistline in a frankly insulting manner.
		*goto DoctorDiplomacy

*label DoctorDiplomacy

Right, so this asshole is pretty full of ${him}self. How are you going to handle it?

*choice

	#Snap back.

		*set RelDoctor %+20

		"Actually," you say, "I'm doing fine, thanks. 
		*if GotKid
			I rescued Kayden with nobody's help, didn't I? 
		Don't do me any favors."
		
		${Doctor} looks at you, possibly just a little startled. Maybe not a lot of people snap back. But when ${he} speaks, ${he} sounds more amused than anything else. "Fine, I won't. I'll come with you anyway, though. Let me get dressed and pack some medical supplies."

		*goto LeavingTheBigHouse

	*if medical > 50

		#Point out my own qualifications.

			"Actually," you say pleasantly, "I'm an EMT, Doctor. 
			*if GotKid
				And I managed to rescue Kayden with nobody's help, didn't I?
			I think I can manage fine by myself. But you can come along anyway if you want."

			${Doctor} doesn't seem overly impressed by your qualifications--more amused than anything. "Thanks, I will. Let me just get dressed and pack some medical supplies."

			*set RelDoctor %+10
			*goto LeavingTheBigHouse

	#Flatter ${his} ego.

		*set RelDoctor %-10
		*comment decreases because the doctor respects strength and views flattering etc as weakness

		"Yes, it would be a really big help to have a doctor along. I'd appreciate it."

		${Doctor} nods. "Let me just get dressed and pack some medical supplies."

		*goto LeavingTheBigHouse

	#Ignore ${his} tone of voice.

		"Yes, it would be a really big help to have a doctor along. I'd appreciate it."

		${Doctor} nods. "Let me just get dressed and pack some medical supplies."

		*goto LeavingTheBigHouse


*label LeavingTheBigHouse

It doesn't take ${Doctor} long to get ready. "It's not like I work out of my house," ${he} says when ${he} sees you eyeing ${his} very small box of medical supplies. "Some are better than none, right? So what is it you're driving?" $!{He} looks out the window and makes a face at your little Civic. "We'd better take my car. It's an off-road vehicle--I like to go hiking in out of the way places when I'm not working--and we might have to drive off-road before this is all over."

What do you say?

*choice

	#$!{He}'s right. It would be better to have an off-road vehicle.

		"Sure, that makes sense." You pack up ${his} big-ass Jeep and head out. $!{He} insists on driving, of course.

		*set car "Jeep"
		*finish

	#$!{He}'s wrong. Off-road capability might be useful, but running out of gas will get us killed, and the Civic is more fuel-efficient.

		Right. So what do you say?

		*choice

			#"Yeah, but running out of gas will get us killed, and my Civic is more fuel efficient."

				"Fair enough," ${he} says. You pack up the Civic and head out.
				
				*if diplo
				
					Saying what you mean seems like a good way to convince ${Doctor} to do things your way.

				*set RelDoctor %+10
				*set car "Civic"               
				*finish

			#"We won't get far enough to need off-roading capability in that big gas-guzzler. We're taking my Civic."

				*set RelDoctor %+20
				*set car "Civic"

				"Fine, have it your way," ${he} says. You pack up the Civic and head out.
				
				*if diplo
				
					Oddly enough, you think you may have gottne ${his} respect by being forceful and kinda rude. Interesting.

				*finish

			#"Yeah, you might be right. . . On the other hand, it might be better to have a fuel-efficient car."

				*if diplo
					"Oh, right, good point," ${he} says grudgingly. "We'll take your car." You pack up the Civic and head out.
					
					*set car "Civic"
					*finish
					
				*else
				
					$!{He} rolls ${his} eyes. "No, it would be better to take the Jeep."
					
					It's interesting that ${he} doesn't seem to respond well to typical diplomacy.

					*set car "Jeep"
					*finish

	#I don't care strongly either way, but I agree with ${him} for the sake of building a relationship.

		*set car "Jeep"
		*set RelDoctor %-20

		"Sure, that makes sense." You pack up ${his} big-ass Jeep and head out. $!{He} insists on driving, of course.
		
		*if diplo
		
			And you're not sure if you actually succeeded in building a positive relationship, after all. $!{He} doesn't seem to respect your opinions any more now than ${he} did when you deferred to ${him}.

		*finish


	#$!{He}'s probably right, but I resent ${his} tone of voice, so I argue.

		*set car "Civic"

		Right. So what do you say?

		*choice

			#"Yeah, but running out of gas will get us killed, and my Civic is more fuel efficient."

				"Fair enough," ${he} says. You expected ${him} to argue more. Looks like you're taking the Civic. 
				
				*if diplo
				
					That's interesting. $!{He} seems to be more responsive to a forceful argument than you would have thought.
				
				You pack up the car and head out.

				*set RelDoctor %+10
				*finish

			#"We won't get far enough to need off-roading capability in that big gas-guzzler. We're taking my Civic."

				*set RelDoctor %+20

				"Fine, have it your way," ${he} says. You expected ${him} to argue more. Looks like you're taking the Civic. 
				
				*if diplo
				
					That's interesting. $!{He} seems to be more responsive to a forceful argument than you would have thought.
				
				You pack up the car and head out.

				*finish


*label UselessBack

${Survivalist} takes the road that skirts around the edge of town, so you only pass a few houses.

You try not to look too hard at the scenes playing out on the various lawns. Some zombies cluster around first floor windows, matter-of-factly marching through shrubbery and glass to get at the tasty humans inside. Others cluster around tasty humans already dragged outside. A few chase your car for a while, but soon give it up in favor of pursuing the sounds or movements that signal easier prey. 

You really try not to look, but you can't help noticing that partially-eaten humans rise from the grass within a few moments of becoming partially-eaten, and join the throng of hungry zombies. Only if the hungry zombies have ripped their meal to pieces in the process of dining does the human appear to stay dead. 

*if squeamish > 50

	Bile rises to the back of your throat at the sights--and sounds, and oh God, smells--all around you. You turn off the car's fan and turn on the air conditioning. You turn it way up, hoping to filter out the smell and drown out the sounds. 

	${Survivalist} glances at you and rolls ${his} eyes. You can't throw up in front of ${him}. You can't. 

*set RelSurvivalist %-10

*page_break

${Survivalist} turns on the radio at this point, distracting you. 

". . . have upgraded the Zombie Watch to a Zombie Warning for the following counties," the radio says, and then the announcer rattles off a long list. The announcer seems pretty rattled herself. "I repeat, this is a serious and life-threatening situation. If you are in this area, you are in the path of the zombiepocalypse and should take shelter immediately. Zombies can break through glass and can climb stairs, so we are advising all residents to leave their homes while they still can. Groups of survivors have been forming at various locations throughout the state. Within the last hour, we have heard from the group at Maple Valley Mall, Cedar Junction Correctional Facility, and First Church of Fulton, so we can confirm that those are still viable sanctuaries for state residents fleeing the zombiepocalypse. Here is a list of school and business closings as a result of the zombiepocalypse. . . "
    
Static engulfs the station again.  

That's interesting. 

The church, the prison, and the mall are all in different directions. The church is about half the distance away as the other two sanctuaries. ${Survivalist} said you were headed for the prison, but it seems as though there are other options. You might be able to convince ${him} to go to the mall or the church instead. Do you want to try?

*choice

	#Yes, I want to go to the mall.

		There's a good argument for going to the mall instead of the prison--a mall will have plenty of food and water, plenty of space, and this particular mall, because it has a sporting goods store, will also have weapons. And it will not have large violent former prisoners competing with you for the food, water, and weapons. 

		But it might matter how you make this argument. What sort of tone do you choose to use?

		*choice

			#Deferential.

				${Survivalist} is distinctly unimpressed. $!{He} brushes off your tentative suggestion, and you continue on your way to the prison. 
				
				*if diplo
				
					Thinking about it, you realize that there's some evidence to suggest ${Survivalist} isn't impressed by those who make arguments without conviction. You may need to be more forceful to carry your point, next time.

				*set RelSurvivalist %-10
				*goto UselessBack2

			#Forceful.

				${Survivalist} argues with you initially, but is persuaded by your conviction.
				
				*if diplo
				
					Which is interesting. ${Survivalist} seems to be persuaded by those who make arguments forcefully. You file that away for future reference. 

				*set tempsafespot "mall"

				"All right, you've convinced me. We'll go to the ${tempsafespot}."

				*set RelSurvivalist %+20
				*goto UselessBack2

			#Logical. 

				You make a long-winded and overly elaborate statement of your reasons for in this particular circumstance, all things being equal, prefering the advantages of the mall and being somewhat concerned over the disadvantages presented by the prison. . . 

				${Survivalist} is distinctly unimpressed, and informs you that you'll be continuing on your way to the prison.
				
				*if diplo
				
					You note for future reference that ${Survivalist} isn't swayed by long-winded logical arguments. You'll have to try something else next time. 

				*set RelSurvivalist %-10
				*goto UselessBack2


	#Yes, I want to go to the church.

		There's a good argument for going to the church instead of the prison--the church is much closer. And while it initially might not seem as defensible as a mall or a prison, a large stone structure isn't a bad starting point, and the survivors gathered there must be doing something right to still be surviving. Also, a church has one huge advantage over a prison: no prisoners. No large violent men competing with you for the available food, water, and weapons.

		But it might matter how you make this argument. What sort of tone do you choose to use?

		*choice

			#Deferential.

				${Survivalist} is distinctly unimpressed. $!{He} brushes off your tentative suggestion, and you continue on your way to the prison. 
				
				*if diplo
				
					Upon further consideration, you don't think ${Survivalist} is impressed when people are deferential. Perhaps a different tactic would prove more useful with ${him}. It's something to keep in mind for next time.

				*set RelSurvivalist %-10
				*goto UselessBack2

			#Forceful.

				${Survivalist} argues with you initially, but is persuaded by your conviction.
				*if diplo				
					It would seem ${Survivalist} is impressed by those who give their opinions forcefully. That's something to remember for later.

				*set tempsafespot "church"

				"All right, you've convinced me. We'll go to the ${tempsafespot}."

				*set RelSurvivalist %+20
				*goto UselessBack2

			#Logical. 

				You make a long-winded and overly elaborate statement of your reasons for in this particular circumstance, all things being equal, prefering the advantages of the church and being somewhat concerned over the disadvantages presented by the prison. . . 

				${Survivalist} is distinctly unimpressed, and informs you that you'll be continuing on your way to the prison.
				
				*if diplo
				
					Maybe a long-winded logical explanation wasn't the best way to persuade this particular individual. You file that away for future reference. 

				*set RelSurvivalist %-10
				*goto UselessBack2


	#No, I think the prison is the best bet.

		*set tempsafespot "prison"
		*goto UselessBack2

	#No, I don't want to anger ${Survivalist}. I need ${him} to survive.

		*set selfish %+20
		*set tempsafespot "prison"
		*goto UselessBack2

*label UselessBack2

You've almost reached the town limits, and there aren't many buildings lining the street now. Mostly woods and fields. You're getting into real farming territory. Sometimes you see a car abandoned on the side of the road, but you don't see any people. There aren't many people out here at all, which you hope means fewer zombies. . .

. . . except there are three of them, right there in front of you.

*page_break

On the left side of the road is a large oak tree. I mean, a really large tree--it's locally famous; the base is something like twenty feet around. Three zombies are pressed up against the base, looking up into the branches like dogs who have just treed a squirrel.

Which is an apt comparison, you realize a moment later. High up in the branches is a ${guy}, you think maybe your age. As you come closer, you see that one of the zombies is jumping, and another trying to crawl up the tree trunk. The third seems to be experimenting with all the moving parts necessary to actually climb the tree, but hasn't worked them out yet. 

Still, it's very likely only a matter of time. You can see the ${guy}'s face clearly now. $!{He} looks terrified, and ${his} mouth is open as though ${he} is screaming for help.

$!{He}'s looking at you.

What do you say to ${Survivalist}?

*choice

	#"We've got to help that ${man}!"

		$!{He} glances at you. "Damn right. Get the shotgun out of the back. I'll drive, you shoot."

		*goto Shotgun

	#"Step on the gas before the zombies start chasing us!"

		*set RelSurvivalist %-20

		$!{He} looks at you in disgust. "No, we're going to get that ${man} down first. Get the shotgun out of the back. I'll drive, you shoot."

		*label Shotgun

		*if firearms <= 50

			*label CantShoot

			Perhaps you should mention you can't actually shoot a gun.

			*choice

				#Yeah, I probably should.

					"What do you mean, you can't shoot a gun?"

					You explain again that you mean you don't know how to shoot a gun.

					"Oh, for-- It's not that hard! Look, that's the dangerous end. You point it at the zombie and then press down that little lever and--"

					Do you think you're going to be able to hit those zombies your first time shooting a gun?

					*choice

						#Sure!

							*set RelSurvivalist %+20
							*set firearms %+50

							"Good," ${Survivalist} says approvingly. "Wrap your hand solidly around the forend."

							"The what?"

							"The wooden part under the barrel. Put the stock--that's the end the shot DOESN'T come out of--firmly up against your shoulder. Take the safety off."

							"Where's the--"

							"The little switch near the trigger. Right. Now point the dangerous end. When I tell you to, pull the trigger--and hold the gun firmly when you do it, because it's going to buck. Pull the trigger gently. All right. Aim for the female one, and I'll tell you when to fire." The car approaches the tree, and the zombies turn their attention from the ${guy} to you. "Three," ${Survivalist} says, "two... one..."

							*page_break

							"Fire!"

							You press the trigger, and the gun kicks back against your shoulder. Hard. 

							And the zombie does not fall over. 

							You missed.

							"That's okay," ${Survivalist} says. "Try again. Pull back on the forend to load another round," he adds before you can ask.
							
							You give the forend a sharp pull and with a satisfying chi-chink you're reloaded and ready to try again. You put the stock to your shoulder, take a firm grip on the forend, and pull the trigger.

							This time, the female zombie's arm twitches.

							"You hit it!" ${Survivalist} says. "Good!" $!{He} stops the car. The female zombie advances purposefully toward your window, arm dangling, teeth bared. "You're going to have to blow its head off. We're not moving; it won't be that hard. Pull back on the forend. Now aim for the head. Relax. Put your finger on the trigger. Three... two... one..."

							*page_break

							You don't quite see what happens to the head, but you do see the female zombie's body drop down flat onto the ground.
							
							*set zombieskilled +1

							"Good!" ${Survivalist} says. "Okay, quick now, switch your aim to the young male. Don't worry, I'll get us out of here if you miss. You've got two shots. Breathe easy, brace the gun, and on three... two... one..."

							That time, you hit the head on the first try. You see the shower of brains go up as the zombie falls over.
							
							*set zombieskilled +1

							Then ${Survivalist} hits the gas hard and you whirl away. "We'll come back for another pass," ${Survivalist} says. "Put more shells in the gun." $!{He} glances at you out of the corner of ${his} eye. "You don't know how to do that either, do you. Okay. Pull back on the forend, so the receiver is open. Right. There are shells in that box at your feet. Take four out. Flip the gun upside down. See the hole in the bottom by the trigger? Put the cartridge in, metal bit to the back, then push it up the tube. Right. Do the same thing with the other three." $!{He} is driving the whole time ${he} is talking, one eye on your hands and one on the road, jerking the steering wheel so the Jeep veers around in circles. This is probably so the last remaining zombie can't catch up, but you're not sure, since you're attention is focused on the gun in your hands.

							"Okay," ${Survivalist} says. "I'm going to spin us right around, and you'll have a perfect shot. Blow its head right off. Ready? Now!"

							The Jeep spins in a circle.

							*page_break

							*label LastShot

							And you find yourself face-to-face with a grinning, snarling, drooling zombie, not more than an arms'-length from your open window.

							You blow its head off.

							It falls over.
							
							*set zombieskilled +1

							"Nice," ${Survivalist} says, and jumps out and runs over to the tree to get the ${guy} you've saved. 

							You okay?

							*choice

								#. . . no. I stare down at the things that used to be human beings, and then I get the car door open just in time to throw up.

									*set squeamish %+20
									*goto SurvivalistUseless

								#More or less okay. That was. . . that was upsetting, but it was necessary. I'm glad we saved the ${guy} in the tree.

									*set squeamish %-10
									*set selfish %-10
									*goto SurvivalistUseless

								#Hell yeah! That was awesome!

									*set squeamish %-20
									*set selfish %+10
									*goto SurvivalistUseless
						#No. We need another plan.

							"You shoot," you tell ${Survivalist}. "I'll drive."

							*label YouShoot

							*set reflexes %+20
							*set RelSurvivalist %+20
							
							"Lead the zombies away from the tree," ${Survivalist} tells you. "Don't let them get too close but don't leave them behind or they might lose interest. When I'm ready I'll signal you--I want you to turn side on to the zombie so that I've got a direct shot."
							
							You give the engine a rev and watch as the zombies gaze in your direction. You edge forward and two of them--the female and the young male--break from the tree and start moving towards you. With a dozen feet or so to spare, you swing left and start to move around the tree. The zombies change direction, pulling farther from the tree and following a dozen or so yards behind.
							
							"Ready!"
							
							You bring the wheel hard right, stomp on the clutch, and pull on the handbrake.
							
							*page_break
							
							The car executes a perfect ninety-degree turn and slides a few feet sideways on the grass. ${Survivalist} sights on the lead zombie and in a puff of bloody mist its head is gone. Its body flails a moment, then falls forward onto the ground. 
							
							*set zombieskilled +1
							
							The second zombie is close now, so you release the brake and start the stumbling meat monster on another wild human chase. 
							
							"Same again," says ${Survivalist}.

							"No problem," you reply, yanking on the wheel again and grabbing the hand brake. The car slides sideways and ${Survivalist} lets loose another round of high velocity lead. Damn, he's a good shot.
							
							"One more," ${Survivalist} says. 
							
							*set zombieskilled +1
							
							*page_break

							You throw the wheel hard left and get the car spinning around its own front wheels. The last zombie plows headlong into the rear quarter panel as you swing the car like a baseball bat. You slam on the brakes and ${Survivalist} leaps from the car, finishing off the crippled zombie as it crawls across the grass.
							
							*set zombieskilled +1
							
							"Nice driving," ${Survivalist} says, and jumps out and runs over to the tree to get the ${guy} you've saved. 

							You okay?

							*choice

								#. . . no. I stare down at the things that used to be human beings, and then I get the car door open just in time to throw up.

									*set squeamish %+20
									*goto SurvivalistUseless

								#More or less okay. That was. . . that was upsetting, but it was necessary. I'm glad we saved the treed ${guy}.

									*set squeamish %-10
									*set selfish %-10
									*goto SurvivalistUseless

								#Hell yeah! That was awesome!

									*set squeamish %-20
									*set selfish %+10
									*goto SurvivalistUseless

				#Nah.

					*set RelSurvivalist %-50
					
					Really? 

					. . . okay, whatever you want.

					You pick up the shotgun and point it out the window.

					"What the hell are you doing?" ${Survivalist} growls. "Brace it against your shoulder!"

					"Oh, right." You brace it against your shoulder and fumble around for the trigger. The Jeep is hurtling toward the tree and the zombies, and the female zombie has turned around to watch the Jeep come. Looks like a perfect shot to you.

					You pull the trigger, and nothing happens.

					"The safety's on!" ${Survivalist} snaps, jerking the wheel to take the Jeep away from the tree again. The zombies begin to amble after it.

					"Oh--right." You've heard the term "safety" before, but you're not quite sure what it is you do to take the safety off. You look for something obvious.

					"Have you ever shot a gun before?" ${Survivalist} demands.

					"Well," you admit, "no."

					"Some reason you didn't mention that? Oh, never mind." ${Survivalist} stops the Jeep with a jerk, sets the brake, and grabs the gun out of your hands. "You drive. I'll shoot."

					*goto YouShoot

		*else

			*if hobby = "videogames"
			
				*set firearms %+20

				You pick up the gun. It's heavier than you thought it would be, but otherwise, this can't be much different than playing a video game. You've played enough of those to know that shooting directly at a moving target is pretty hard but figuring out where the target will be in a second or so means you can estimate their trajectory and prepare a fraction in advance of where they'll be. You think that these zombies cannot possible be smarter than the AI modern Xbox have. You can do this.
				
				You brace the gun against your shoulder and fumble around for the trigger. The Jeep is hurtling toward the tree and the zombies, and the female zombie has turned around to watch the Jeep come. Looks like a perfect shot to you.

				You pull the trigger, and nothing happens.
				
				*page_break
				
				"The safety's on!" ${Survivalist} snaps, jerking the wheel to take the Jeep away from the tree again. The zombies begin to amble after it.

				"Oh--right." That's not a problem you have in video games, and you're not quite sure what it is you do to take the safety off. You look for something obvious.

				"Have you ever shot a gun before?" ${Survivalist} demands.
				
				"Not a real gun, but Xbox--"
				
				${Survivalist} sighs. "The safety is the little switch near the trigger. Right. Now pull on the forend to load a round. No 'auto-load' in the real world. Right. Now you're set. It's going to kick like hell, remember."
				
				You aim the gun.
				
				*goto Shoot		


			*elseif hobby = "hunting"

				You brace the shotgun against your shoulder and flick the safety off. Five shells. Three zombies. You can do this. You've been shooting guns since you were a kid.

				Not that you generally shoot deer from the windows of Jeeps screaming in circles, though. And the deer aren't generally trying to eat you while you do. You feel your palms sweat as the three zombies look away from the tree and at the approaching Jeep. 
				
				*label Shoot

				"Ready?" ${Survivalist} says, and slams on the brakes before you can answer. 

				The lurch of the Jeep spoils your aim, and your first shot goes wide. 

				The female zombie starts briskly towards the Jeep.

				You raise the gun again and blow her head off. You see the shower of brains go up as she falls over.

				One down. 

				*page_break

				${Survivalist} hits the gas hard and you whirl away. "We'll come back for another pass," ${Survivalist} says, and only then do you see how close to the window the other two zombies got. Both are male--or were, in life. One young, one older. 

				"Ready?" ${Survivalist} says again, and slams on the brakes.

				Three shells, two zombies. This time, you are ready. You hit the younger male on the first try, and are whirling to face the older male before the younger body has hit the ground. The older male stumbles away, spoiling your aim--your shot goes wide--${Survivalist} swings the Jeep around to give you another pass--

				*page_break
				*goto LastShot

			*else
				*goto CantShoot

*label SurvivalistUseless

*set GotUseless true

${Survivalist} comes back to the car, towing along a ${man} who looks extremely pale and limp. "This is ${Useless}," ${Survivalist} says briefly. "${Useless}, ${given_name}." And you are off again.

*finish
