*temp walking
*set walking 1
*temp next_chapter
*set next_chapter ""
*temp circle
*set circle ""
*set chapter + 1
CHAPTER ONE: THE SALTFLAT

	
A white ball is hovering in the sky, directly over your head. Around you stretches the saltflat, spreading outwards from you until it meets the pale blue sky in a sharp line, impossibly distant.
*line_break
You have been walking. You don't know how much time has passed since ... Since what? There is no beginning, there is hardly even the idea of time. All you are is here, now, your past and future as empty as the desert around you. One foot steps in front of the other, your body obediently following it, maybe out of habit, maybe because it can't do anything else. Maybe it never could.
*page_break
You couldn't even say if you're really moving. There is no frame of reference but your own body and the monotonous pattern of cracks in the ground below you.
*choice
	#Keep walking
		*goto walking
	#Stop
		*goto stop
*label walking
*set walking + 1
*if walking = 4
	*set stubborn true
	It becomes harder to remember what colors are. Is the desert around you really white and the sky blue, or are those just names for concepts that have ceased to matter?
	*goto walking2
*else
	You keep setting one foot in front of the other, hoping to find -something-, but nothing changes. Ever.
	*goto walking2
*label walking2
*line_break
You can feel your mind fade, being washed out by the emptiness around you.
*choice
	#Keep walking
		*goto walking
	#Stop
		*goto stop
*label stop
You stop walking and almost stumble, your feet not accustomed to the lack of movement.
*line_break
"Hey, why are you stopping?"
*choice
	#What was that voice?
		"I'm down here, numbnuts!"
		*goto necro
	#"Who are you?"
		"Your fearless companion, who else?"
		*goto necro
	#"Because I decided to."
		"Well it's a dumb decision"
		*goto necro	
*label necro
The voice seems to come from your arm. You pull up the wide sleeve of your linen shirt and let out a startled gasp. From your forearm, the hideous tattoo of a skull looks up at you, its jaw moving as it speaks.
*line_break
"Don't tell me you forgot about me again!"
*choice
	#"I ..."
		*goto destination
	#"Well ..."
		*goto destination
	#"AAAAH!"
		The skull rolls its eyes at your outburst.
		*goto destination	
*label destination
"Do you at least remember where we were going?"
*choice
	#"What?"
		*goto lost
	#"No, I ..."
		*goto lost
	#"Yes."
		"Well, tell me, then."
		*choice
			#"Um ..."
				*goto lost
			#"Well ..."
				*goto lost
*label lost
*temp why_again
*set why_again false
*temp what_demon
*set what_demon false
*temp what_favor
*set what_favor false
*temp how_demon
*set how_demon false
*temp lets_go
*set lets_go false
"No wonder we're lost. You need to have a goal to get anywhere here. Gods, I hate this desert."
*label explaining
*choice
	*hide_reuse #"Where is 'here'?"
		"Look around you, we're obviously in the salt flats. -Again-. Now we need the demon thing to get us out. He won't be happy about it, I can tell you that much."
		*set why_again true
		*set what_demon true
		*goto explaining
	*hide_reuse *if ( why_again ) #"What do you mean, 'again'?
		"It's not the first time you got us stuck here. I can't stand another second, let alone an eternity in this white hell."
		*goto explaining
	*hide_reuse *if ( what_demon ) #"Demon?"
		"You remember demons, right? Immortal monsters from beyond the veil of reality? Well, this one owes you a -huge- favour, so basically we've been using him as a ferryman to get us out of here. Now we use him again."
		*set what_favor true
		*set how_demon true
		*set why_again true
		*goto explaining
	*hide_reuse *if ( what_favor ) #"What does the demon owe me a favour for?"
		"I think you told me once, but I didn't really listen. You get really boring when you go on about the past. Well you used to, it seems your memory is gone for good this time."
		*goto explaining
	*hide_reuse #"Why can't I remember anything?"
		"It's the desert. I can't believe you still don't get it. I mean, I know you're not bright, but it seems now you're just being dumb on purpose."
		*goto explaining
	*hide_reuse #"What -are- you?"
		"I am Necro, you advisor and companion. And I'm tired of your constant questioning. I've explained this countless times. Let's just get on with the demon summoning."
		*set what_demon true
		*goto explaining
	*hide_reuse *if ( how_demon ) #"So, how do I summon that demon?"
		"Easy. We just need to find a circle, like a circle of stones for example. Then you call the thing by its true name - that's 'Eekyl' - and it'll come."
		*choice
			#"How do I find a circle?"
				"Just go to one. Keep your goal in mind and visualize it, then we'll be there in no time."
				*set lets_go true
				*goto explaining
			#"Can I just draw a circle into the ground?"
				"No, it needs to be natural. Besides, you'd need a plow or a cup of water to draw anything into this salt."
				*choice
					#"How do I find a circle, then?"
						"Just go to one. Keep your goal in mind and visualize it, then we'll be there in no time."
						*set lets_go true
						*goto explaining
	*if ( lets_go ) #"Ok, let's go."
		*goto circle_search
*label circle_search
You try to visualize a circle.
*choice
	#A circle of stones, lying on the salty ground
		*set circle "earth"
		You close your eyes and let your imagination take over. Six rocks, arranged in a rough circle by chance, their grey surfaces a stark contrast against the white salt.
		*choice
			#Ouch!
				You hit your big toe on one of the rocks that, a moment ago, only existed in your mind.
				*line_break
				*goto demon_calling
	#A circular trench, filled with water
		*set circle "water"
		You close your eyes and let your imagination take over. A natural circle of water in the middle of a salt desert is a bit of a stretch, but you make it work. As you open your eyes, the water-circle lies before you, about two steps in diameter.
		*line_break
		*goto demon_calling
	#A circular pattern in the cracks of the ground
		*set circle "fire"
		You stare at the ground hard and continue walking. After a little while, you arrive at a spot where wider cracks in the salt sort of form a circle.
		*line_break
		*goto demon_calling
*label demon_calling
"We did it! Now call the demon!" Necro's voice is somewhat muffled through your shirt, but he seems to be able to look through the fabric.
*label demon_calling_2
*choice
	*hide_reuse #"Keelyl!"
		*goto keelyl
	#"Eekyl!"
		*goto eekyl
	*hide_reuse #"Steve!"
		You hold your breath, but nothing happens. After a moment, you hear Necro through your sleeve. He sounds angry.
		*line_break
		"Have you broken down completely, you idiotic Kah-spawn? What kind of a name is 'Steve'?"
		*goto demon_calling_2
	#"What was the name of that thing again?"
		"I really don't want to say it next to a circle, but it starts with "Ee" and ends with "kyl".
		*choice
			#"Eekyl!"
				*goto eekyl
			#"Why don't you want to say Eekyl?"
				*goto eekyl
*label keelyl
"NO!" The skull's scream is smothered by a deep, earthy rumbling. The ground in the circle cracks open, blue flames gushing up from the freshly formed crater. You feel the hairs on your arm stand up and your ears start ringing.
*page_break
Four arms, black like coal and with too many joints, stretch out from the depth and a grotesque figure, twice as tall as you, pulls itself up. Its body is that of a naked woman, too many muscles bulging under the glistening skin. At the end of a long neck, a bull's massive head sways left and right, taking in its surroundings. Yellow smoke fumes from its nostrils and red eyes settle on you.
*line_break
"Wrong demon" Necro whispers intimidated.
*page_break
"FOOLISH MORTAL!" The voice booms across the plain, instantly causing a splitting headache.
*choice
	#"Sorry, I ..."
		*goto angry_demon
	#"Hello, ..."
		*goto angry_demon
	#"..."
		*goto angry_demon
	#Run
		You turn to run, but one of the thing's hands catches your ankle and pulls you back towards the circle.
		*goto angry_demon
*label angry_demon
"TELL ME MORTAL: IS THERE A REASON I SHOULDN'T EAT YOUR FLESH AND CONSUME YOUR SOUL RIGHT NOW?"
*choice
	#Explain your mistake.
		"DAMN THAT MEDDLING IMP AND THE SIMILIARITY BETWEEN OUR NAMES!" The demon cocks its head to one side, thinking. "VERY WELL THEN. I SHALL GRANT YOU YOUR PITIFUL EXISTENCE. BUT I CAN NOT LET SUCH FOOLISHNESS GO WITHOUT A PUNISHMENT."
		*goto gain_demon_mark
	#"I could do you a favor or something?"
		"A FAVOR IT IS."
		*goto gain_demon_mark
*label gain_demon_mark
*line_break
A deep pain burrows into your left palm. You look at it and see the depiction of a closed eye in a circle, the black lines burning like hellfire. The pain grows stronger and you feel the world crashing down on you. Just before you lose conciousness, the agony is gone, as is the symbol.
*line_break
"YOU HAVE BEEN MARKED, MORTAL. AFTER YOUR DEATH, YOU WILL SERVE ME FOR TWO SEEMING ETERNITIES.
*set demon_mark true
*line_break
A huge plume of yellow smoke envelops you. As it clears, the demon is gone and the circle looks just as before.
*line_break
"Gods, that was close. You got off easy, she once damned a man for five eternities for summoning her in a circle of bird droppings. Now call the other demon."
*goto demon_calling_2
*label eekyl
As you pronounce the last syllable, a bolt of lightning strikes the center of the circle from the clear sky, blinding you momentarily.
*line_break
"WHO DARES TO DISTURB ME? I SHALL REND YOUR FLESH ... Oh, it's you. Again."
*line_break
Your vision returns, dots of red light dancing in front of your eyes. A plump being sits on the salty ground in the middle of the circle, its thin legs strechted out in front of it. The body is that of a toddler with red skin and strong arms, the round head topped by two little horns. It looks up at you with black, beady eyes. As its mouth opens, you can see it has a split tongue like a snake and several rows of sharp, pointed teeth, like those of a shark.
*line_break
"So you managed to get yourself trapped here again. Who sent you here this time? The magus? Gorath? The lady?"
*line_break
Before you can answer, it prattles on. "I don't really care. Listen, I'm sick of ferrying you around. But I've got good news! Well, good news for me. And for you, kind of. Remember our deal? Of course you don't. Well, this is the last time you call me, because I found a way to repay my debt. Take this."
*line_break
The demon throws a small object at you, the sun reflecting off metal. As you try to catch it, it closes around your finger, forming a thin metal ring. 
*line_break
"It will help you keep your mind together and your memories intact, even here or in the dungeon. At least for a while. Well, that's settled then. Just tell me where to take you. To the domain of Gorath the Slayer or to the Lake of Eternal Peace?"
*choice
	#"To the domain of Gorath."
		*set next_chapter "gorath"
		*goto hound
	#"To the Lake of Eternal Peace."
		*set next_chapter "lake"
		*goto hound
	#"Actually, I have a few questions."
		"Well, I don't have time for your incessant inquiring. I have people to torture, you know? Decide now or I'll decide for you. And I assure you, you wouldn't like my decision."
		*choice
			#"To the domain of Gorath."
				*set next_chapter "gorath"
				*goto hound
			#"To the Lake of Eternal Peace."
				*set next_chapter "lake"
				*goto hound
			#"I really think you should answer some of my questions."
				"If you're going to be difficult, I'll just decide for you. Say hello to the lady for me."
				*set next_chapter "lake"
				*goto hound
*label hound
You feel reality pulling at your limbs. The world is inverted, the salt suddenly black under an orange sky. You are pulled upside down and sucked into a vortex made of confusion. At last, thankfully, you lose consciousness.
*page_break
INTERLUDE: THE HOUND


Black spittle, festering with desease, drops on the salt and dissolves age-old crystals. A wet nose sniffs at 
*if (circle = "earth")
	a circle of stones.
	*goto endif
*elseif (circle = "water")
	a circular trench of water evaporating beneath the relentless sun.
	*goto endif
*elseif (circle = "fire")
	a circular pattern of cracks in the dry ground.
	*goto endif
*label endif
Canine lips pull back to reveal sharp teeth.
*line_break
The Hound has picked up the scent of its prey.
*if (next_chapter="gorath")
	*goto_scene gorath
*elseif (next_chapter="lake")
	*goto_scene lake
	
*label todo
still stuff to do here

		
		
		
		
		
		
		
		
		