*comment "gargoyle" by simon dremel - prologue

*temp no_deathmagic_taught
*set no_deathmagic_taught false
*temp no_dragonmagic_taught
*set no_dragonmagic_taught false

*comment TODO: More opportunities for relationship with Lorena
*comment TODO: More impact of name / gender
*comment TODO: More opportunities to learn spells / skills

PROLOGUE

In the east, waves are splashing against the sheer cliff on which castle Ravenrock is perched. In the west, a narrow road slopes down towards the forest. You are a Gargoyle, the monstrous guardian of this fortress. The daylight has hardened your skin and given it a stone grey color. Watching the sun settle in the forest, you long for the moment when the dark of night will soften your skin and allow you to move again.
*page_break
What is your name?
*input_text name
And are you male or female?
*choice
    #male
        *set gender "m"
        *goto introduction
    #female
        *set gender "f"
        *goto introduction
    #neither nor
        *set gender "n"
        *goto introduction
*label introduction
As you wait for dusk, your thoughts begin to wander. You remember your childhood. The duke, ruler of the castle and the lands around it, bought you at a very young age from a travelling warlock and you have yet to meet another of your kind.
*line_break
Still, your childhood was a good one. You spent your time ...
*choice
    #practicing flight
        *goto 2o1
    #playing with the human children
        *goto 2o2
    #studying in the library
        *goto 2o3

*label 2o1
Your flying skill increases.
*set flight %+ 30
*line_break
You soar above the treetops as a sudden cry for help catches your attention. You silently land in the crown of a tree and spot a girl that has fallen into the river that snakes its way through the forest. It is spring, the current is strong and the girl weak. She tries to swim to the bank, but she won't be able to make it. You don't think you've seen her before, but then all human children look alike.
*line_break
The girl's pouch is lying on the grass, a little further up the river.
*line_break
You ...
*choice
    #... aid the girl to escape the floods
        *goto 2o1o1
    #... watch her drown
        *goto 2o1o2
    #... run for help
        *goto 2o1o3

*label 2o1o1
You jump from the treetop and hurry towards the helpless child. As she sees you coming, she screams, either in terror or for help. The flood is too strong even for you to swim back out should you fall in.
*line_break
You ...
*choice
    #... fly in and try to snatch her from the air
        As fast as you can, you dig your claws into a tree trunk and clamber up to gain some height. Then you soar down and grasp for the girls outstretched hand. Trusting you, she lets go of the branch she was holding on to and grabs your hand. For a terrible instant, you feel as if her weight will drag you down into the river with her. Then your momentum rips her from the water's grasp and the two of you hit the bank.
        *line_break
        Your flying skill increases.
        *set flight %+ 15
        *line_break
        You learn a new maneuver: Dive.
        *set flying_dive true
        *page_break
        *goto 2o1o1a
    #... rip a branch from a tree to pull her out
        With all your considerable strength you rip a large branch out of the next tree's trunk. For a crazy moment, you think you hear the plant screaming in agony. Then you are at the waters edge and extend the branch as far as you can. The girl manges to grab it and with a considerable effort you pull her out of the floods.
        *line_break
        Your strength increases.
        *set strength %+ 10
        *page_break
        *goto 2o1o1a

*label 2o1o1a
The two of you lie gasping in the grass for a while. "Thank you for rescuing me" the girl says when she catches her breath, "The other children said you were an evil monster and ate children, but I didn't believe them. Also my father says you will protect his castle when you are all grown up. And now you have saved my life. Thank you!"
*line_break
She hugs you and you are a bit shocked and embarassed. No human barely ever touches, let alone hugs you.
*page_break
On the next day, as you sit on your perch, turned rigid by the sun, the duke comes to sit next to you. "Thank you, gargoyle. I knew I was doing the right thing when I took you into my castle." He puts a hand on your shoulder and stands next to you for a while, looking over the woods. Then he leaves you alone.
*set lorena_friend true
*set allies_homecastle + 1
*page_break
*goto 3

*label 2o1o2
From your treetop you watch as the puny human looses her strength and is pulled under by the current. Good riddance. You jump off the tree and start rummaging through the pouch, where you find a couple of large, shining gold coins.
*page_break
As you return to the castle in the early hours of the morning, a guard tells you that the duke's daughter would have drowned in the wood's river, were it not for one of the duke's champions returning from a quest just in time to pull her out of the water.
*line_break
You wander the path towards darkness!
*set darkness %+20
*set wealth +5
*page_break
*goto 3

*label 2o1o3
You push yourself from the treetop and fly towards the castle as fast as you can. Halfway there, a metallic glimmer catches your eye in the woods below. You soar down to get a closer look and meet a knight returning home from a quest for the duke.
*line_break
You quickly explain the situation and together you rush to the river to rescue the girl. Thankfully, you are not too late.
*page_break
As you return to the castle, it turns out the girl is the duke's daughter. The knight is richly rewarded for his deed and you also get some gold pieces.
*line_break
You wander the path towards light!
*set darkness %-10
*set wealth +10
*page_break
*goto 3

*label 2o2
You play with the human children, who are delighted to have a playmate with the ability to fly. New games are devised to make use of your flying skills and you're having a lot of fun.
*page_break
One day, an older boy joins your group. He is the son of the stablemaster, a thin, cruel man who likes to beat the horses in his care. The boy, his name is Johnny, calls you names and tells the other children that you have been sent from hell to devour them. Whenever you try to defend yourself, he manages to twist your words around.
*line_break
After a while, the other children start avoiding you. Whenever Johnny sees you, he points you out and calls you a demon. Sometimes he throws stones at you.
*line_break
You ...
*choice
    #... ignore Johnny
        Staying out of Johnnies way proves to be easy, since you have something he doesn't: a pair of wings. You don't like to run, but you get used to it.
        *line_break
        Your flying skill increases.
        *set flight %+ 25
        *page_break
        *goto 3
    #... try to reason with him
        You try to reason with him, but it is of no use. Johnny keeps pestering you, but the other children realize you are not the monster he makes you out to be. Nobody tries to defend you since no one wants to confront the stable masters son, a strong and wicked fighter. Still, their obvious disapproval of his behaviour makes it more bearable.
        *line_break
        You wander the path towards light!
        *set darkness %-5
        *page_break
        *goto 3
    #... fight him
        You ...
        *choice
            #... attack him when he's not looking
                When Johnny turns around, you jump on his back and knock him onto the ground where he tries to defend himself. He is a fierce fighter, but your supernatural strength gives you the advantage.
                *line_break
                You easily subdue him and are considering what to do with your helpless opponent as an adult guard separates you and brings you to the guard   commander. Both of you are scolded and warned to stay away from each other. This is the end of your torments from the boy.
                *line_break
                Your strength increases.
                *set strength %+ 10
                *line_break
                You learn a new combat move: Sneak Attack.
                *set sneak_attack true
                *page_break
                *goto 3
            #... challenge him to a duel
                The boy is not eager to start a fight with a Gargoyle, but he has no choice if he doesn't want to loose his face in front of the other children. He lunges himself at you, but you are too strong. You soon have him subdued and the other children cheer for your victory. The stable boy does not seem to be liked very much and you feel a sting of pity.
                *line_break
                He leaves you alone from now on.
                *line_break
                Your strength increases.
                *set strength %+ 10
                *line_break
                You wander the path towards light.
                *set darkness %- 5
                *set allies_homecastle + 1
                *page_break
                *goto 3
    #... follow him to find out more about him
        You silently follow Johnny to his home after the children stop playing and go to bed.
        *line_break
        He lives with his father, the stable master. As he comes home, the stablemaster smacks him on the head hard and sends him to bed without dinner for coming home late.
        *line_break
        You fly up to Johnnys window and look in. The boy is lying on the bed, crying into his pillow. You are not afraid of him in the least anymore.
        *line_break
        You ...
        *choice
            #... tell the other children about "crybaby Johnny"
                The other children start making fun of Johnny with a cruelty only children possess. He starts to avoid them and leaves you alone.
                *line_break
                You wander the path towards darkness.
                *set darkness %+ 5
                *page_break
                *goto 3
            #... coerce him into leaving you alone.
                Afraid his secret might come out, Johnny stops picking on you.
                *line_break
                Your wits increase.
                *set wits %+ 10
                *page_break
                *goto 3
            #... extort money from him
                Afraid his secret might come out, Johnny stops picking on you. In addition, you force him to give you half his allowance.
                *line_break
                You wander the path towards darkness.
                *set darkness %+5
                *line_break
                Your wits increase.
                *set wits %+ 10
                *set wealth + 3
                *page_break
                *goto 3
            #... keep quiet about it
                You don't tell anyone about what you found out. Johnny keeps picking on you, but you bear it like a gargoyle. After a while, Johnny is old enough to start his combat training and loses interest in you.
                *line_break
                You wander the path towards light.
                *set darkness %- 20
                *page_break
                *goto 3

*label 2o3
You are not particularly interested in the humans. Instead, you spend your time in the castles library, where you help the Magus sort books and parchments. In exchange for your help, the Magus teaches you how to read and write and gives you books to study. You learn a great deal about legends, science and magic.
*line_break
Your wits increase.
*set wits %+ 30
*page_break
One day, you rip a page out of a book you are placing on a shelf. It is covered in ancient runes you can not read.
*line_break
You ...
*choice
    #... hide the page in the book and put it on the shelf. With the great number of volumes in the library, it is unlikely the Magus will consult this book in the near future and notice the damage.
        You hide your accident and hope the Magus will not need to consult this particular book.
        *line_break
        Your wits increase.
        *set wits %+ 10
        *page_break
        *goto 3
    #... tell the Magus about the accident. This might result in punishment, but it is surely preferable to carrying the burden of a lie.
        The Magus is not angered by the destruction. "I can fix it with a simple repair spell" he says, "The important thing is that you told me about it and thus proved worthy of my trust. I am lucky to have you as a pupil and assistant."
        *line_break
        You wander the path towards light.
        *set darkness %- 5
        *set magus_starpupil true
        *page_break
        *goto 3
    #... bring the page to the travelling sorcerer who is staying in the castles inn and paid you to steal this particular page.
        You enter the inn at night. The travelling sorcerer sits in a dark corner. As he draws on his pipe, his face is illuminated by the glow of the tobacco. Concealing yourself in the shadows, you sneak over to his table.
        *line_break
        "Ah, hello my friend" he greets you, "I trust you have brought me what I wanted?"
        *line_break
        You hand him the page and he cackles maliciously. "Good. As a reward, you can have the agreed upon amount of money - or I will teach you a mighty spell."
        *choice
            #Take the money
                The sorcerer hands you a pouch of coins and you leave to return to your post.
                *set wealth + 10
                *page_break
                *goto 3
            #Learn the spell
                The sorcerer makes you memorize incantations until the sun is almost up. As you leave the tavern to return to your post, your mind swirls with dark images of evil deeds.
                *line_break
                You learn a new spell: Bestow Harm.
                *set spell_death + 1
                *page_break
                *goto 3

*label 3
As you reach the Age of 14, the duke decides you should get the same training as every human child in the castle, so you can reach your full potential. Most youths spend their training years in the courtyard, training with the castle guards and knights to become fighters, but a few study the art of magic under the Magus.
*if magus_starpupil
    *line_break
    The Magus encourages you to learn more about the art of magic and leave fighting to the less gifted.
*if lorena_friend
    *line_break
    The duke's daughter urges you to take up combat training with her and fight at her side.
*line_break
You ...
*choice
    #... start as the Magus' apprentice
        *goto 3o1
    #... train with the knights
        *goto 3o2

*label 3o1
"Welcome to the halls of wisdom", the Magus greets you as you enter his tower, "Here you will learn the art of magic and how to wield it to benefit your friends and punish your enemies.
*line_break
There are three schools of magic: The magics of life, death and the mind.
*line_break
The powers of each school are bestowed by spirits from different realms. A mightier mage can summon mightier spirits to do his bidding, but all of the spirits ask a price."
*line_break
*set wits %+ 25
Your wits have increased.
*page_break

*label 3o1a
You want to hear more about ...
*choice
    #... the price the spirits ask
        "Every spirit demands a different sacrifice.
        *line_break
        The spirit of Life is kindest, and allows you to directly give your life energy to other  people without taking a payment. Using the powers of life costs you nothing but a bit of your own health."
        *page_break
        "The spirit of the Mind is unpredictable. It might give you its powers because it  is curious to see what you will do with them, but it also might take a spiritual or   material payment from you."
        *page_break
        "The spirit of death is the most gruesome. It demands a terrible price for its powers: a piece of your soul. With every favor you accept from it, you lose some of your humanity and become more like a devilish beast bent on death and destruction. To wield this power is a crime against nature and I will not teach you any of this dark magic."
        *set no_deathmagic_taught true
        *page_break
        *goto 3o1a
    #... the powers of life
        "The powers of life are bestowed by beneficial spirits from the celestial realm. They do not demand any payment, but they do not grant you the energy of life itself, just the ability to transfer your own life energy.
        *line_break
        With training, you can heal other people, manifest your life force as a helpful avatar or even give life to the dead."
        *page_break
        *goto 3o1a
    #... the powers of death
        "The powers of death hail directly from the underworld. Dark mages use them to inflict harm on people, sap their life force away or rip the souls from the dead.
        *line_break
        When using those powers, the mage's soul is lost to the beings he draws power from until he is no more than an evil shadow, a servant of hell with no mind of his own.
        *line_break
        This magic is forbidden and I will not teach it to you."
        *set no_deathmagic_taught true
        *page_break
        *goto 3o1a
    #... the powers of the mind
        "The powers of mind are a mighty tool, but the mage who hopes to use them must have a strong spirit. He can use the force of his psyche to subdue that of another man.
        *line_break
        An advanced mind mage can sense the thoughts and feelings of the people around him, wipe someone's memory or force others to submit to his will.
        *line_break
        The magic of the mind is mighty and to wield it is a great responsibility."
        *page_break
        *goto 3o1a
    #You've heard enough
        *goto 3o1o2
    
*label 3o1o2
Your training begins. The Magus makes you read book after book and memorize their contents, but all of them are about the theory of magic, myths and legends, or natural science.
*line_break
You ...
*choice
    #... go flying instead of reading
        Your flying skill increases.
        *set flight %+ 15
        *page_break
        *goto 3o1o3
    #... go train with the knights' students
        Your strength increases.
        *set strength %+ 20
        *page_break
        *goto 3o1o3
    #... study the books your master gave you. He will know what's the best way to proceed with your training
        *set magus_starpupil true
        *page_break
        *goto 3o1o3
    #... study the books your master gave you. You love learning new things
        Your wits increase.
        *set wits %+ 25
        *page_break
        *goto 3o1o3
    #... study REAL magic in secret
        You manage to "borrow" one of the spellbooks your master keeps in a locked cupboard. As you start reading it on your post by the light of the sinking moon, you quickly realize it's a book about the death magic your master warned you about.
        *line_break
        You ...
        *choice
            #... try to learn one of the spells
                *set darkness %+ 10
                You wander the path towards darkness.
                *line_break
                *set spell_death + 1
                *if spell_death = 1
                    You learn a new spell: Bestow Harm.
                    *page_break
                    *goto 3o1o3
                *elseif spell_death = 2
                    Bestow Harm, a spell you already know, is explained at the beginning of the book. You flip through it until you find a new spell.
                    *line_break
                    You learn a new spell: Absorb Vigor.
                    *page_break
                    *goto 3o1o3
                *goto 3o1o3
            #... secretly return the book to it's place
                You manage to return the book before the Magus notices it is gone.
                *page_break
                *goto 3o1o3

*label 3o1o3
One day, the Magus finally announces he will teach you a simple spell. He trusts you to make an informed choice about what school of magic you want to learn.
*page_break

*label 3o1o3a
You ...
*choice
    #... choose the magic of life
        *goto 3o1o3o1
    #... choose the magic of the mind
        *goto 3o1o3o2
    *if no_deathmagic_taught = false
        #... choose the magic of death
            *goto 3o1o3o3
    *if (wits > 20) and (no_dragonmagic_taught = false)
            #... ask the magus about other schools of magic you read about
                *goto 3o1o3o4
                
*label 3o1o3o1
The Magus smiles. "I was hoping you'd decide to follow this path."
*line_break
He takes a mouse out of a wall-mounted cage, then drops her to the ground and steps on her.
*if darkness < 50
    You gasp in shock.
    *goto 3o1o3o1a
*elseif darkness > 50
    You can not supress a light smile.
    *goto 3o1o3o1a
*label 3o1o3o1a
*line_break
The magus picks up the twitching mouse, cups his hand around her and closes his eyes. He then mutters some words and a warm light appears around the mouse. After a few seconds, it starts to move again.
*line_break
"Now let me teach you this spell ..."
*line_break
You learn a new spell: Heal.
*set spell_life + 1
*line_break
You wander the path towards light.
*set darkness %- 10
*page_break
In several training sessions, the Magus teaches you more and more about life magic, until you master another spell.
*line_break
You learn a new spell: Avatar.
*set spell_life + 1
*page_break
*goto 4

*label 3o1o3o2
The magus eyes turn upwards until you can see only their white. He mutters some arcane formula, then cocks his head sideways, as if listening to something.
*line_break
"Yes ..." He says, finally, "I can feel your desire to learn this school."
*if darkness < 40
    A kind smile crosses his wrinkled face. "I can also feel that you will use this magic to do good."
    *goto 3o1o3o2a
*elseif darkness > 60
    A frown shows on his high forehead. "I am a bit concerned that you will use this magic for the wrong reasons, but I trust you will triumph over them."
    *goto 3o1o3o2a
*else
    A smile crosses his wrinkled face. "I can also feel that you are hungry, because you did not have any breakfast tonight."
    *goto 3o1o3o2a
*label 3o1o3o2a
*line_break
He opens his eyes and sees your astounded face. "Let me show you how it's done."
*line_break
You learn a new spell: Empathy.
*set spell_mind + 1
*page_break
The Magus goes on to show you more of the magic of the mind and in several confusing and difficult lessons, you learn how to wipe memories from the mind of another.
*line_break
You learn a new spell: Wipe Memory.
*set spell_mind + 1
*page_break
*goto 4

*label 3o1o3o3
*if spell_death > 0
    "I was afraid you'd ask about this" the Magus says concerned. "I sense there is the magic of death already in you, perhaps an innate ability of your kind. You must swear to me that you will never use your dark power!"
    *set no_deathmagic_taught true
    *line_break
    You ...
    *choice
        #... swear you'll never use the power
            The Magus seems relieved. "Well, choose another school then."
            *set oath_of_life true
            *set magus_starpupil true
            *page_break
            *goto 3o1o3a
        #... "swear" you'll never use the power
            The Magus seems relieved. "Well, choose another school then."
            *line_break
            You wander the path towards darkness.
            *set darkness %+ 5
            *set magus_starpupil true
            *page_break                
            *goto 3o1o3a
        #... tell the Magus it's none of his business what you do with your powers
            *goto 3o1o3o3b
        #... demonstrate your powers by using them on the Magus
            *goto 3o1o3o3c
*else
    "I will not teach you any of that magic, my pupil. It is far to dangerous and evil and I myself only know it so I am able to defend myself against it.
    *line_break
    Choose another school."
    *set no_deathmagic_taught true
    *page_break
    *goto 3o1o3a
*label 3o1o3o3b
"Then I will not tutor you any more. Begone with ye!" The Magus points towards the door.
*line_break
You ...
*choice
    #... return late at night to steal the Magus' book on death magic
        In the deepest night, when all but the night guards are sleeping, you climb the Magus' tower. Your claws dig into the stone easily and climbing up the steep stone wall comes to you as natural as walking, maybe more so.
        *line_break
        A cabinet in the main study contains the volumes on death magic. It is locked, but you know where the Magus hides the key. You open the door to the cabinet and a loud creaking noise cuts through the silence.
        *page_break
        You stand there motionless, holding your breath. Fortunately, nobody seems to have heard you. You grab the book and leave the study through the window. On the tower's roof, you study until dawn, then quietly return the book to it's place.
        *line_break
        *set spell_death + 1
        *if spell_death = 1
            You learn a new spell: Bestow Harm.
            *line_break
            You wander the path towards darkness.
            *set darkness %+ 10
            *page_break
            *goto 4
        *elseif spell_death = 2
            You learn a new spell: Absorb Vigor.
            *line_break
            You wander the path towards darkness.
            *set darkness %+ 20
            *page_break
            *goto 4
        *elseif spell_death = 3
            You learn a new spell: Harvest Soul.
            *line_break
            You wander the path towards darkness.
            *set darkness %+ 30
            *page_break
            *goto 4
        *goto 4
    #... turn your attention towards becoming a fighter
        The instructors and other students are a bit suspicious of you and you can only take part in the night combat training, but you still manage to learn something.
        *line_break
        *temp maneuver
        *set maneuver 0
        *rand maneuver 1 4
        *if maneuver = 1
            You learn a new combat move: Flurry.
            *set flurry true
            *page_break
            *goto 4
        *elseif maneuver = 2
            You learn a new combat move: Wrestle.
            *set wrestle true
            *page_break
            *goto 4
        *elseif maneuver = 3
            You learn a new combat move: Feint.
            *set feint true
            *page_break
            *goto 4
        *elseif maneuver = 4
            You learn a new combat move: Tailswipe.
            *set tailswipe true
            *page_break
            *goto 4
        *goto 4
    #... punish your master for denying your wish by using your dark powers on him
        *goto 3o1o3o3c
        
*label 3o1o3o3c
You summon your dark magic in combat for the first time.
*line_break
Which spell would you like to use?
*choice
    *if spell_death > 0
        #Bestow Harm
            You wander the path towards darkness.
            *set darkness %+ 10
            *line_break
            Your master screams in pain as black bubbles begin to appear on his skin. You laugh, delighted about your might. Then your master seems to concentrate. The bubbles recede and you are knocked across the room in a forceful blow.
            *line_break
            You lose 10 hitpoints.
            *set health - 10
            *page_break
            *goto 3o1o3o3d
    *if spell_death > 1
        #Absorb Vigor
            You wander the path towards darkness.
            *set darkness %+ 20
            *line_break
            You reach out for your master with tentacles made of pure shadow. The Magus' shoulders slump and his head falls onto his chin. He sways and for one moment you are sure he will fall to the floor. Then he steadies himself and looks at you. In a moment, your spell has fizzled and you loose your sense of direction. You stumble against the wall or the floor, then the Magus' face is next to yours.
            *page_break
            *goto 3o1o3o3d

*label 3o1o3o3d
"Fool!" The Magus screams. "Attack your master in his own domain? I will teach you to disobey me!"
*line_break
You feel your strength dwindling as black tentacles shoot out of the Magus' Palms and envelop you. Soon you loose consciousness.
*page_break
As you awaken, you are lying in the mud of the courtyard. Looking up at the Magus' tower, you know you can never enter that building again. You are banished.
*line_break
As you regain your strength and feel dark magic cursing through your veins once more, you notice that there is something that wasn't there before. It is as if the rage of the Magus and your own anger mingled with one another and the magic you used to attack each other. You cradle this new thing in your heart. It might come in handy some day.
*line_break
You learn a new spell: Fury
*set spell_dragon + 1
*page_break
*goto 4

*label 3o1o3o4
"You always were a very observant student" Your master nods satisfied. "There have been stories about many lost or secret schools of magic, but the only one I know to really exist is the school of dragon magic."
*line_break
He takes a breath and continues. "Dragons wield certain powers mere mortals can never hope to learn. It is said there draconic blood gives them a connection to a plane of fire and they are able to command this element and it's aspects.
*line_break
Since my blood is not draconic in nature" he gives a chuckle. "I can not teach you this kind of magic nor would you be able to learn it.
Choose another school."
*set no_dragonmagic_taught true
*page_break
*goto 3o1o3a

*label 3o2
The combat training takes place in the courtyard. You can only take part in the training sessions for night combat, but you seem to learn a lot faster than the other students, catching up to them quickly each session.
*page_break
After basic training is complete, you are asked to choose a specialization. You can either participate in unarmed combat training supervised by the captain of the guard or learn advanced weapon techniques taught by one of the duke's knights.
*line_break
You want to learn...
*choice
    #... unarmed combat
        The guard's captain is an excellent teacher and unarmed combat comes naturally to you. In short time, you are the top of the class, wrestling even adult soldiers to the ground with little effort.
        *line_break
        Your strength increases.
        *set strength %+ 20
        *line_break
        You learn a new combat move: Wrestle.
        *set wrestle true
        *page_break
        *goto 3o2a
    #... advanced weapon techniques
        The knight, his name is Sir Grilt, hands out short swords to all his student, then begins training. After learning basic moves, you practice them with mind-numbing minuity.
        *set weapon "short sword"
        *line_break
        As the knight inspects your moves, he smiles broadly. "You are very accurate. Now let me show you some advanced techniques."
        *line_break
        You quickly learn how to string several moves together to create a deadly flurry of sharp steel.
        *line_break
        Your strength increases.
        *set strength %+ 20
        *line_break
        You learn a new combat move: Flurry.
        *set flurry true
        *page_break
        *goto 3o2a
*label 3o2a
After learning the basics of combat, it is time to spar with the other trainees. Both the knight's and the guard's captain's students assemble to test their strength.
*page_break
Most of the humans quickly form pairs and start sparring, but no one seems to dare to fight you. The duke's daughter, carrying a training sword made from ebony, suffers the same fate.
*line_break
The knight, Sir Grilt, approaches you. "If you don't want to fight any of the others, I'd like you to show me your flying skills. Maybe we can incorporate them into your fighting style."
*line_break
You ...
*choice
    #... take Sir Grilt up on his offer
        Sir Grilt is impressed by your maneuverability. He quickly devises a flight maneuver you could use in combat.
        *line_break
        "See, your main advantage is the momentum of a fall from great height", he explains, "You could use this by diving at someone from flight, then slamming them to the ground or lifting them up to throw them."
        *line_break
        *if flying_dive
            Unfortunately, you have already figured this out for yourself. Still, showing off all your flight maneuvers was fun.
            *line_break
            Your flying skill improves.
            *set flight %+ 15
            *page_break
            *goto 4
        *else
            You try this a couple of times. It is a nice maneuver and should come in handy in combat.
            *line_break
            You learn a new maneuver: Dive.
            *set flying_dive true
            *page_break
            *goto 4
    #... challenge the duke's daughter
        *if lorena_friend
            The duke's daughter smiles at you broadly. "You want a piece of me?" She asks jokingly.
            *if gender = "m"
                "Come get it, though guy."
            *if gender = "f"
                "Come get it, though girl."
            *if gender = "n"
                "Come get it, though one."
        *line_break
        The two of you take your combat positions, then attack each other. The girl barely misses you, but her assault leaves her left side wide open. Sensing a weakness, you strike, but she quickly whirls around, ducking under your swing and squarely catching you in the chest with her shoulder.
        *line_break
        Before losing your balance, you manage to grab her wrist and pull her down with you. The two of you fall down and roll through the dust.
        *line_break
        As you come to a stop, you are on top and pin her to the ground. Her breath is hot in your face and smells like cinammon. She looks into your eyes and you hold her gaze.
        *line_break
        You ...
        *choice
            #... release her
                You see a hint of disappointment in her face, but it quickly passes. She gets up and brushes the dust from her clothes.
                *line_break
                "Nice combat move, huh?" She grins. "Want me to show it to you?"
                *line_break
                You learn a new combat move: Feint.
                *set feint true
                *page_break
                *goto 4
            #... kiss her
                Her lips are soft and warm and for a moment, she returns your kiss. Then her cheeks redden and she slips out from under you, throwing a glance at the other students.
                *set lorena_lover true
                *line_break
                "Nice combat move, huh?" She stammers. "Want me to show it to you?"
                *line_break
                You learn a new combat move: Feint.
                *set feint true
                *page_break
                *goto 4
    #... ask a pair of other students to fight you, two against one
        You find two students that are willing to team up on you. They are identical twins and their moves are well coordinated. One of them engages you from the front, while the other circles to your back, then they switch when you turn around.
        *page_break
        After a short while, they have taken several strikes at you and only dumb luck allows you to hold your stance.
        *line_break
        As the brother in your back lashes out again, you whirl around, this time letting your tail fly through the air like a whip. You catch one brother square in the chest, sending him to the ground, then tackle the other and pin him to the ground.
        *line_break
        After a moment of stunned silence, the defeated twins start laughing and slapping your back.
        *line_break
        "You're a good guy, gargoyle." One of them says grinning.
        *line_break
        You learn a new combat move: Tailswipe.
        *set tailswipe true
        *page_break
        *goto 4
*label 4
Your training was not always easy, but you learned a great deal. One time ...
*line_break
Your thoughts are interrupted as you feel a dagger on your throat.
*finish











