*temp lily_deal
*set lily_deal false

*if (lily_thief)
	*goto lily_thief1
*else
	*goto regular
*label regular
*page_break
*set chapter + 1
CHAPTER TWO: THE MOUNTAIN KING


You are lying on your back in the dirt, at the foot of a great mountain range. The world seems to be spinning around you.
*line_break
"Why did we have to end up here again?" Necro whines. "Here, of all places. I'd rather ..."
*line_break
The skull's monologue is interrupted by a loud cry.
*goto guard_arrives
*label lily_thief1
*page_break
*set chapter + 1
CHAPTER THREE: THE MOUNTAIN KING


You are lying on your back in the dirt, at the foot of a great mountain range. The world seems to be spinning around you. You still feel the wetness of the lady's kiss on your lips.
*line_break
"Say what you want about this mode of transportation, at least we get where we want. Or at least, where other people want us."
*choice
	#"Shut up, Necro."
		"Don't tell me to shut up. The only reason ..." The skull is interrupted by a loud cry.
		*goto guard_arrives
	#"And were would that be?"
		"This is the domain of Gorath, the Mountain King. In case you weren't ..." The skull is interrupted by a loud cry.
		*goto guard_arrives
*label guard_arrives
*temp stick
*set stick false
You scramble to your feet as fast as you can and look around you. An ape-like figure is coming towards you from the mountains. It is very fast, running on two legs but using its long arms for additional speed. It repeats its half-human cry, but you can't make out any words.
*choice
	#Stay and wait
		There's a large stick lying on the ground. If the creature is hostile, you may have to defend yourself
		*choice
			#Pick up the stick
				*set stick true
				*goto guard_confrontation
			#Leave it on the ground
				*goto guard_confrontation
	#Run
		You turn around and start running as fast as you can, over an empty plain towards a forest in the distance.
		*line_break
		Again, your pursuer cries, much closer this time. You give it all you got, but it is not enough. The creature catches up to you and grabs you, bringing you to a fall. The moment you hit the ground, a large, hairy hand grabs your neck and pulls you up again.
		*goto guard_confrontation2
*label guard_confrontation
As the creature reaches you, it comes to a stop and stands in front of you.
*label guard_confrontation2
Its physical appearance is that of a large ape, but the creature is wearing chainmail and wielding a large, wooden club. Foam drips from its mouth as it screams at you. This time, you think you can make out a name: Gorath. It gestures towards the mountain, where you can see a wooden guard post and a stairwell carved into the stone. It obviously wants you to go there.
*choice
	#Comply
		*goto stairs_walking
	#Fight
		You have no intention of surrendering so easily.
		*if stick
			Furiously, you swing your stick at the beast's head. There is a loud cracking noise as your makeshift weapons breaks into two pieces. The creature just looks angry as it retaliates by knocking you out with its cudgel.
			*goto stairs_carried
		*else
			Furiously, you jump at the beasts, swinging your fists. But you are no match for an armed giant ape monster. The cudgel comes down on your head, knocking you out cold.
			*goto stairs_carried
*label stairs_walking
You are led to the guard post at the foot of the mountain. Another one of the ape-like creatures watches your approach through a window and exchanges some unintelligeble grunts with its colleague.
*line_break
You pause a moment to take in the giant, stone-carved stairwell that leads up the slope, seemingly continuing all the way up to the mountain peaks.
*page_break
The apemonster disapproves of your stopping. Its giant wooden cudgel comes down hard on your head and you loose consciousness.
*goto stairs_carried
*label stairs_carried
*page_break
You regain consciousness, slumped over the shoulder of the creature that is carrying you up the mountain. You can't see the bottom of the stairs anymore, but judging by the strained grunting of your captor, you've been travelling for a while.
*line_break
You are set down in front of an iron gate set into the mountain. Two of the ape-creatures stand guard at the entrance, armed with long spears. A shove in the back makes you move through the gate, into a long corridor that burrows deep into the mountain. Torches light the walls and smaller tunnels lead into other directions like in a giant anthill, but you move further along the main corridor until you reach a large hall.
*page_break
The ceiling is too high to see, supported by natural stone pillars. In the back, a giant man sits on a throne of bones. He is more than twice as tall as you and heavily built, wearing nothing but an embroiderd loincloth. He seems to have just finished a meal - a cow carcass lies at his feet and he is picking his teeth with what you think is a human bone.
*line_break
"YOU'VE COME BACK, PUNY ONE" his voice booms through the hall and echoes off the walls and ceiling. "I WOULD HAVE THOUGHT YOU'D BE SMARTER THAN THAT. JUST TELL ME WHY YOU CAME BACK AND I'LL CALL MY SHAMAN SO HE CAN THROW YOU BACK INTO THE DUNGEON."
*label what_you_want
*choice
	#"I've come to serve you, mighty one."
		*goto servitude
	#"I have a proposal for you, Gorath."
		*goto proposal
	#"I am here to end your reign, Gorath. Prepare to die."
		*goto death_threat
	*hide_reuse #"I have some questions."
		"I WILL ANSWER NO QUESTIONS FOR YOU, PUNY ONE! WHAT DO YOU WANT?"
		*goto what_you_want
	*if(lily_thief) #"I am here to recover what you have stolen."
		The ground shakes with booming laughter. Nervously, the ape creature behind you joins in.
		*line_break
		"WHAT I HAVE STOLEN?" Gorath shows his teeth, filed to points, in a terrifying grin. "I DO NOT STEAL. I TAKE WHAT I WANT. I AM THE MOUNTAIN KING, AND ALL I DESIRE IS MINE."
		*choice
			#"I beg to differ."
				*goto death_threat
			#"I am here to take back the lily you have stolen from Neruna, lady of the Lake of Eternal Peace."
				Gorath grows serious and leans forward, interested. "-SHE- SENT YOU? TO GET HER PRECIOUS FLOWER?"
				*choice
					#"Yes."
						*goto where_is_it
					#"Where is it?"
						*label where_is_it
						"I HAVE THE LILLY. SHE CAN HAVE IT BACK, BUT I ASK FOR SOMETHING IN RETURN. YOUR SERVITUDE."
						*choice
							#"So be it."
								*set lily_deal true
								*label servitude
								*if (lily_thief = false)
									*goto something_you_can_do
								"VERY WELL THEN" he turns to the creature that brought you in. "BRING ME WUGROL."
								*line_break
								The ape grunts something, then runs off, only to return with an old man, moments later.
								*line_break
								"WUGROL. THE PUNY ONE WISHES TO SERVE ME. BRAND HIM."
								*choice
									#"What?"
										*goto what_no
									#"No!"
										*label what_no
										*if demon_mark
											"I would, master" The old man's voice is thin and cracked like old paper. "But he has already been marked by a demon."
											*line_break
											"WHAT?" Gorath voice booms even louder. "I WILL HAVE NO DEMON-TAINTED IN MY HALLS! SEND HIM TO THE DUNGEON!"
											*goto dungeon
										*else
											Before you can react, the old man's hand jerks forward as fast as a snake and touches your palm. A deep sliver of pain burrows into your hand.
											*line_break
											*if lily_deal
												"I WILL CALL ON YOU WHEN I NEED YOU. I KEEP THE FLOWER HIDDEN SAFELY IN THE DUNGEON OF ETERNAL SCREAMING. YOU CAN GET IT THERE YOURSELF. WUGROL?"
												*goto dungeon
											*else
												"I WILL CALL ON YOU WHEN I NEED YOU. UNTIL THEN, YOU CAN ROAM THE DUNGEON. WUGROL?"
												*goto dungeon
							#"No deal."
								"VERY WELL THEN" he turns to the creature that brought you in. "BRING ME WUGROL."
								*line_break
								The ape grunts something, then runs off, only to return with an old man, moments later.
								*line_break
								"What is it you wish of me, master?" The old man's voice is thin and cracked like old paper.
								*line_break
								"SEND THIS PUNY ONE TO THE DUNGEON AGAIN. MAYBE HE WILL STAY THERE THIS TIME."
								*goto dungeon
			#"Your time of taking things is over, Gorath. I am here to end your reign."
				*goto death_threat
*label proposal
"WHAT COULD A PUNY HUMAN LIKE YOU OFFER A MIGHTY KING LIKE ME?
*choice
	#"I wish to serve you."
		*goto servitude
	#"I have gold."
		"YOUR GOLD IS OF NO USE TO ME. IMAGINARY COINS DO NOT BUY FOOD FOR MY SOLDIERS" Gorath tilts his head to the side and stares into the air, thinking. "I COULD USE SOME ENTERTAINMENT. CAN YOU PROVIDE THAT?"
		*label entertainment
		*choice
			#"I ..."
				*goto death_threat
			#"No, but ..."
				*goto death_threat
			#"Yes, ..."
				*goto death_threat
	#"What do you need?"
		*if (lily_thief)
			"I COULD USE SOME ENTERTAINMENT. CAN YOU PROVIDE THAT?"
			*goto entertainment
		*else
			*label something_you_can_do
			"Maybe there is something you can do for me" Gorath says, lowering his voice as he leans forward, smiling softly.
			*line_break
			Instinctively, you draw closer.
			*line_break
			"YOU CAN FINISH THE JOB I GAVE YOU LAST TIME!" he screams loudly, spittle raining on your face. He throws an ebony dagger to the ground in front of you. "OH, ONE MORE THING: IT WOULD BE MARVELOUS IF YOU COULD TRY NOT TO BETRAY ME THIS TIME, MAGGOT!"
			*line_break
			You pick up the dagger, confused, and feel it pulling at your mind. In an instant, the world around you vanishes.
			*set gorath_dagger true
			*set lady_killer true
			*goto hound
*label questions
*label death_threat
"A DUEL TO THE DEATH IT IS" Gorath jumps up from his throne and hits you in the chest, robbing you of your breath and sending you flying across the hall.
*line_break
You land at the feet of an old man, who looks down at you with a hint of sadness in his eyes.
*line_break
"WUGROL, SEND THIS FOOL TO THE DUNGEON."
*line_break
"Very well, my liege" The old man's voice is thin and cracked like old paper.
*goto dungeon
*label dungeon
*page_break
*if lily_thief
	The old man slaps your forehead with the back of his hand and you are sucked into the ground. The last thing you hear is Gorath's hideous laughter and a whisper, from the old man: "I am sorry, wanderer. I have not forgotten what you did for me. The lily you seek is kept in the heart of the dungeon, guarded by the soul-hydra."
	*goto hound
*else
	The old man slaps your forehead with the back of his hand and you are sucked into the ground. The last thing you hear is Gorath's hideous laughter and a whisper, from the old man: "I am sorry, wanderer. I have not forgotten what you did for me. Seek the lily in the heart of the dungeon, but beware: it is guarded by the soul-hydra."
	*goto hound
*label hound
*page_break
INTERLUDE: THE HOUND

Half-human cries rip through the night. Minions of Gorath rush to the scene, weapons at the ready, only to find their dead comrade, lying slain at the feet of a beast made of darkness. The fight lasts only seconds.
*line_break
The Hound's tongue darts out of its mouth to lick the sweet blood off its nose. The taste only serves to augment its craving for the life of its prey.  The trail is still fresh.
*if (lady_killer)
	*goto_scene lake
*else
	*goto_scene dungeon





