*label SettingAlpha

*if GotDoctor 
	*if gender = "male"
		*set alpha "Michael"
		*goto Intro
	*else
		*set alpha "Michelle"
		*goto Intro
*elseif GotSurvivalist 
	*if gender = "male"
		*set alpha "Brian"
		*goto Intro
	*else
		*set alpha "Bonnie"
		*goto Intro
*else
		*goto Intro

*label Intro

*if firstchoice = "front"
	*if GotUseless
		*goto UselessIntro
	*else
		*goto DidntRescueUseless
*else
	*if GotKid
		*goto KidIntro
	*else
		*if rescuestudent
			*goto transfer
		*else
			*goto nottransfer


*label UselessIntro

You're quite a ways down the road before your heart settles down.

How are you feeling about the gas station, by the way?

*choice

	#Fantastic! This zombie killing stuff really makes you feel alive.
		*set squeamish %-50
		*goto UselessIntro2

	#Sober. I did what I had to do.

		*set squeamish %-20
		*set selfish %-20
		*goto UselessIntro2

	#If I could go somewhere and throw up, I totally would. I just don't like killing things that look human, even if they aren't any more!

		*set squeamish %+20
		*set selfish %-20
		*goto UselessIntro2

*label UselessIntro2

*if GotDoctor = true

	${Doctor} 
	*if car = "Civic"
		insists that you pull over.
	*if car = "Jeep"
		pulls over to the side.
	$!{He} quietly but firmly instructs the ${man} you rescued from the gas station to strip and be examined for bite marks. ${Doctor} finds none, to everyone's relief. The ${man} introduces ${him}self as ${Useless}.

*if GotDoctor = false

	After a while you think of something. You pull over, and you and the ${man} you rescued strip to prove to each other that you haven't been bitten. It seems like the thing to do.

	$!{He} says ${his} name is ${Useless}.

"Where are we going?" ${he} asks. 

You explain about the ${tempsafespot}. 

"Oh." $!{He} sounds disappointed. 

"Why?"

"I was hoping we were headed for the interstate. Do you know about ${Student} Murray?" $!{He} waves a smartphone. 

*if (GotKid = true) or (GotDoctor = true)

	"Yes."

*if (GotKid = false) and (GotDoctor = false)

	"No."

	"I've been following the Zombiepocalypse Survivors group on Facebook," ${he} explains. "There aren't, um, aren't so many of them posting as there used to be, but ${Student}'s still updating ${his} status every couple of hours."

	$!{He} shows you the smartphone screen. ${Student}'s status updates are all almost the same. "COME GET ME! If you provide transportation to the Cedar Junction Correctional Facility, I can keep you safe from zombies on the way! I know what I'm talking about--look how long I've stayed alive!"   

	"Interesting."

"I've been messaging with ${him}," ${Useless} says. "$!{he}'s at the transfer center off exit 13. That's where I was headed when my car ran out of gas, and then I hiked to the service station, and then. . . " $!{He} shrugs. "Then I got backed into a corner by a zombie. Just my luck. So, um, what do you say? I mean, if you don't want to, I can't force you or anything, it's your car. .  ."

Do you sidetrack to rescue ${Student}?

*choice

	
	#Yes.

		*if car = "Jeep"
		
			You're going to have to convince ${Alpha}. $!{He} says ${he} thinks it's a bad idea--mostly, you get the impression, because ${he} finds ${Useless} annoying and wants to contradict ${him}.

			What are you going to do?

			*choice

				#Let it drop--let ${Alpha} call the shots.

					*set RelUseless %-20
					*set selfish %+20
					*set rescuestudent false

					Very well. You do not make any effort to rescue the student. Your car continues on its way to ${tempsafespot}.
				
					*if diplo
				
						You think ${Useless} is pretty upset with you for letting it drop, but that can't be helped.

					*goto nottransfer

				#Make a forceful argument.

								
					${Alpha}, persuaded by your conviction, turns the car in the direction of the transfer center, to rescue the student.
				
					*if diplo
				
						You note that ${Alpha} seems to respond well to a forceful argument, to someone taking the upper hand and acting "alpha." You file that away for future reference. And ${Useless} is pleased you sided with ${him}. That went well.
					
					*if firstchoice = "back"
						*set RelSurvivalist %+20
					*if firstchoice = "front"
						*set RelDoctor %+20
					*set RelUseless %+10
					*set rescuestudent true
					*goto transfer

				#Make a logical argument.

					You make a long-winded and overly elaborate statement of your reasons for in this particular circumstance, all things being equal, prefering to take the risks involved in rescuing the student because of the advantages ${his} presence might provide, as well as the arguments of honor and duty. . . 

					${Alpha} is distinctly unimpressed, and informs you that you'll be continuing on your way to the ${tempsafespot} without stopping to rescue the student. 
				
					*if diplo
				
						Which gives you some useful information. Long logical arguments aren't the way to persuade ${Alpha}. That may be good to know later, although it would have been better to know before now. You hope someone else rescues that poor student.

					*if firstchoice = "back"
						*set RelSurvivalist %+10
					*if firstchoice = "front"
						*set RelDoctor %+10
					*set rescuestudent false
					*goto nottransfer

				#Make a deferential argument.

					${Survivalist} is distinctly unimpressed. $!{He} brushes off your tentative suggestion, and you continue on your way to the ${tempsafespot} without stopping to rescue the student.
				
					*if diplo
				
						Which gives you some useful information. You may need to use more force to persuade ${Survivalist}. That may be good to know later, although it would have been better to know before now. You hope someone else rescues that poor student.

					*set rescuestudent false
					*if firstchoice = "back"
						*set RelSurvivalist %-10
					*if firstchoice = "front"
						*set RelDoctor %-10
					*goto nottransfer
					
		*else
		
			*set selfish %-20
			*set rescuestudent true
			
			You head for the transfer station.
			
			*goto transfer

	#No. 
		*set rescuestudent false
		*set RelUseless %-10
		*set selfish %+20

		Very well. You do not make any effort to rescue the student. 

		*goto nottransfer



*label DidntRescueUseless

*if (GotDoctor = true) and (studentlocation = true)

	*if car = "Jeep"

		After a while, you notice the Jeep isa headed in the wrong direction for the ${tempsafespot}. You point this out to ${Doctor}.

		$!{He} looks at you in surprise. "I'm going to the transfer center to pick up ${Student}."

		*goto transfer

	*else

		"We should go pick up that kid at the transfer center," ${Doctor} says. "$!{He} sounds like ${he}'d be useful to have along. And ${he}'s still there--I texted ${him}. Shouldn't be hard to find."

		What do you say?

		*choice

			#I agree. We need to save ${him}.

				*set selfish %-20        
				*goto transfer

			#I agree. $!{He} could be useful.

				*set selfish %+20
				*goto transfer

			#I disagree. It's too great a risk. 

				*set selfish %+20

				"I don't want to take the risk," you say. "It's more important we get to ${tempsafespot}."

				${Doctor} looks at you furiously. "Wait, what? This kid's stayed alive all this time. Clearly ${he}'d be useful. It's absolutely worth the risk. Here's the turnoff for the interstate--turn right, right now."

				What do you do?

				*choice

					#Turn right.

						*set RelDoctor %-20
						
						*if diplo
						
							As you turn the wheel, you reflect that you've knuckled under in an alpha struggle. It will be harder to get Doctor to follow your orders later.
						*goto transfer

					#Keep going straight.

						"Turn around," ${Doctor} says coldly.

						"It's my car," you say, and keep driving towards ${tempsafespot}.

						*if diplo
						
							As you drive, you wonder how this interaction will affect your relationship later. You've obviously made ${him} angry, but you may also have impressed ${him} but not knuckling under to ${him}.
							
						*goto Nottransfer

*elseif (GotKid = true) and (studentlocation = true) 

	"Are we going to get ${Student}?" Kayden asks. "We've been texting. $!{He}'s at the transfer center--" Kayden reads carefully off the screen. "--near exit 13 off the interstate, and ${he}'s waiting for us."

	Are you going to get ${Student}?

	*choice

		#Yes, we need to save ${him}.

			*set RelKid %+20
			*set selfish %-20
			*goto transfer

		#Yes, ${he} might be useful.

			*set RelKid %+20
			*set selfish %+20
			*goto transfer

		#No, it's too great a risk. 

			Kayden looks at you with wide eyes. "Are we going to leave ${him} to get zombified?"

			Are you?

			*choice

				#Yes, I am leaving ${him} to get zombified. 

					*set selfish %+20
					*set RelKid %-50
					*goto Nottransfer

				#Oh, all right. We'll go get ${him}.

					*set selfish %+10
					*set RelKid %+10
					*goto transfer


*else

	*goto Nottransfer


*label KidIntro

You're quite a ways down the road before your heart settles down. "You should probably put your seatbelt on," you say to the kid. ${Survivalist} snorts a little, apparently considering seatbelts to be a wussy invention of the modern era.

"Oh," the kid says. "Yeah." $!{He} does.

"What's your name?" you ask.

"Kayden."

"I'm ${given_name}," you say. "Where are your parents, Kayden?"

"Don't know," Kayden says. After a while, ${he} adds, "That was my sister, inside."

"Oh." You can't think of anything else to say.

"It's okay."

*if gotturninfo
	*goto KaydenWhere
	
*else
	*goto ProbablyNotTrue

*label ProbablyNotTrue
That's probably not true. But you're not quite sure how to say that. 

You also realize that the kid might be able to tell you how fast ${his} sister turned into zombies after being bitten, and a number of other useful pieces of information. But you might traumatize ${him} or something by asking. 

Is it more important to find out or to not traumatize the kid (further)? 

What do you say?

*choice

	#"That's probably not true."

		*set RelKid %-20

		Kayden just blinks at you.
		*if diplo
		
			That was probably coming on too strong, considering you're talking to a kid who just lost ${his} family.
			
		*label FurtherQuestion

		Are you going to question ${him} any further?

		*choice

			#Yes.

				"How did your sister turn into a zombie?" you ask bluntly.

				*set RelKid %-20
				
				*if diplo
				
					You see Kayden flinch a little.
					
				*goto How

			#No, I just let it go.

				You don't say anything else. Neither does ${he}. It's quiet for a while.

				*finish

			*if diplo

				#Only if I can figure out a way to do it gently.

					*goto Gentlequestion


	#"It doesn't have to be okay."

		*set RelKid %+20

		Kayden just blinks at you.
		
		*if diplo
		
			But at least ${he} isn't flinching away. That's not bad for a beginning.

		*goto FurtherQuestion     

	#"I'm really sorry."

		*set RelKid %+20

		Kayden just blinks at you.
		
		*if diplo
		
			But at least ${he} isn't flinching away. That's not bad for a beginning.

		*goto FurtherQuestion

	#"How did your sister turn into zombie?"

		*label How

		*set RelKid %-30

		Kayden doesn't answer.
		
		*if diplo
		
			You see ${his} jaw set, as though ${he} is trying not to cry.

		Are you going to question ${him} any further?

		*choice

			#Yes.

				"Look, Kayden, I really need to know this," you say. "It could be really important later."

				$!{He} doesn't say anything.

				*choice

					#I let it go.

						You don't say anything else. Neither does ${he}. It's quiet for a while.

						*goto KaydenWhere

					#I push harder.

						*set RelKid %-10

						"Come on, kid, I saved your life!"

						Kayden sets ${his} teeth. "She got me out of bed early this morning. She wouldn't say what happened to Mom and Dad. I guess. . . But I don't know. We started walking. We stopped to get food, and she. . . changed."
						
						"Did you meet anybody between when you left home and the gas station?"
						
						"No."
						
						So the sister must have been bitten by the parents. That means if somebody gets bitten and killed, they change almost instantly, but if they just get bitten, it takes longer. How much longer? "How long were you walking?"

						"I dunno. A while."
						
						Even though you press, Kayden can't (or won't) give you any further information than that. Finally you let it go. 

						It's quite for a while.

						*goto KaydenWhere

			#No, I just let it go.

				You don't say anything else. Neither does ${he}. It's quiet for a while.

				*goto KaydenWhere

			*if diplo 
				#Only if I can figure out a way to do it gently.

					*goto Gentlequestion

*label Gentlequestion

"It must have been really scary."

Out of the corner of your eye, you can see Kayden blinking back tears. "Yeah."
*if diplo

	But ${his} shoulders seem to be relaxing a little.

*set RelKid %+30

*fake_choice

	#I ask if ${he} wants to talk about it.

	#I don't say anything. 

"She got me out of bed early this morning. She wouldn't say what happened to Mom and Dad. I guess. . . But I don't know. We started walking. We stopped to get food, and she. . . changed."

"Did you meet anybody between when you left home and the gas station?"

"No."

So the sister must have been bitten by the parents. That means if somebody gets bitten and killed, they change almost instantly, but if they just get bitten, it takes longer. How much longer? "How long were you walking?"

"I dunno. A while." $!{He} thinks, then offers, "I listened to five songs on my phone. How long is that?"

Fifteen minutes, maybe? Depending on the length of the song? So if you just get bitten, you have at least fifteen minutes before you turn into a zombie. That might be good to know.

*set gotturninfo true

"About fifteen minutes, I guess?" you say. "Thanks, Kayden."

"Sure." 

It's quiet for a while.

*goto KaydenWhere


*label KaydenWhere

"Where are we going?" Kayden asks after a while.

*if rescuestudent

	"To rescue someone else," ${Survivalist} says.
	
	"Oh," Kayden says. "That's good."
	
	*goto transfer
	
*else
        
	"To a ${tempsafespot}," ${Survivalist} says.

	*if tempsafespot != "church"

		${Useless} makes a little sniffing noise.

	*goto nottransfer


*label transfer

Spring flowers are blooming along the either side of the exit ramp--bright red and gold tulips rippling in the late afternoon breeze, some wildflower that is an almost impossible shade of purple-pink. New England at its finest. It should look lovely. 

But there are cars crashed and deserted all along the interstate, and you're pretty sure that's a hand there among the tulips, and it really isn't lovely at all. 

*if GotUseless

	"Ohhhhh God," ${Useless} moans.

*page_break

The car rolls slowly into the entrance of the transfer station and comes to a stop. In front of you is large paved area surrounded by a perimeter fence topped with razor wire. The paved area is FREAKING OVERRUN with zombies. At the its far side, within the fence, stands the transfer building itself--a multi-story building like an oversized shed. 

There are two double-wide openings in the front into which--on an ordinary day--trucks would reverse to dump their loads on the pit floor. There is a single truck parked halfway into the building with its bed slightly raised. It may have been in the process of unloading its trash when its driver, um, exited the cab. 

To the right of the double-wide openings is the employee parking lot, with employee cars parked up against the fence. You guess it's the former drivers of those cars who are shuffling and drooling right near the employee entrance. You wonder where the rest came from--there are way too many to be accounted for by the employee cars. A herd must have come from somewhere else. Attracted by the smells of rotting meat from the pit floor? You don't want to think too hard about it. 

*page_break

To the left of the transfer building rises the smoke stack of what you think is probably the incinerator, surrounded by a smaller razor-wire-topped fence. Running up the 150-foot-tall stack is a ladder enclosed with a protective scaffolding and leading up to a catwalk about three-quarters of the way up. Standing on the catwalk is a figure in a black t-shirt and blue jeans. ${Student}, you assume. 

A half a dozen or so zombies surround this fence, slowly pulling the metal back and forth while gazing up at the potential meal. They're not being particularly efficient about it, but they'll have the fence down eventually. They must have run out of everything else to eat. 

The smartphone cheaps. "Are you guys here?" the message reads. "I can see your car. I'm on top of the smokestack."

What do you do?

*choice

	#Get the hell out of here while the getting is good. 

		*if (GotDoctor = true) and (car = "Jeep")

			"Absolutely not," ${Doctor} says, and starts texting back.

			*goto Tower

		*elseif (GotSurvivalist = true)

			"Absolutely not," ${Survivalist} says. "We said we would do this. We're not wimping out now."
			*goto Tower

		*else

			*set selfish %+20
			*goto Nottransfer

	#Text back.

		*goto Tower

*label Tower

The phone rings almost as soon as the "send" button is hit. "Hi," the voice on the other end says, tinny through the speakerphone. "This is ${Student}."

"${given_name}," you say, keeping a wary eye on the various hordes of zombies.

"You want to be careful," ${Student} says. "This place is full of zombies." As if you had missed that fact somehow. "Inside and out. I think a couple of people came into work infected. The incubation time from a bite is about an hour, as far as I can tell from the sample size I've had to observe. If you're not killed. If you are, the incubation is almost instantaneous. Anyway, it spread through here pretty fast. I knew my only chance was to get up to the tower and barricade myself in."
*if firstchoice = "front"
	$!{He} adds, "I've seen all the movies. I know how this works."

$!{He} sounds pretty proud of ${him}self. Has ${he} noticed that ${he} has put ${him}self in a position where there are several floors and more than several zombies between ${him} and safety?

You say something to this effect.

"It's okay," ${Student} says. "I have a plan."

*page_break

"I've had a lot of time to observe them. They're really distractable. They go after the nearest shiny thing. Or loud thing. And I can see everything from up here. So here's the plan. 

"See that truck? The keys are in it. I can help you sneak to it. You start it and get it pointed downhill, and fix a block of wood or something to hold the gas pedal down. Maybe get the horn to beep too. The zombies will all flock after it, and as soon as they're drawn away from the incinerator fence, I'll come down the ladder and we'll get out of here."

*if alpha != "alpha"

	"I think I hate this plan," ${Alpha} says.

	The plan doesn't seem absolutely stupid to you, but it does seem really risky.

	"Got a better idea?" you ask ${Alpha}.

	"Drive away from the door, blare the horn, attract attention. They'll follow us. We can run them down and then get back to the door to meet ${Student}."
	
	Well, maybe you can, but there are an awful lot of them.

	*goto Tower2

*else

	The plan doesn't seem absolutely stupid to you, but it does seem really risky.

	You try to think of an alternative, but all you can come up with is to be the distraction yourself--drive away from the door, blaring the horn, and attracting the zombies' attention. You could then maybe run them down with the car and get back to the door to meet ${Student}? This also seems really risky.

	*goto Tower2

*label Tower2 

What do you want to do?

*choice

	#Follow ${Student}'s plan.

		"Okay," ${Student}'s voice says quietly in your ear. "You're going to have to approach the truck from the pit floor. I can see everything from here, and there are no zombies in the lunch area behind the building. So you could climb the perimeter fence near the lunch area and then run into the transfer building. Or if you don't want to climb, there's a hole in the fence near the employee cars. You could hide behind the cars and sneak into the building."
		
		You consider the options. Scaling a high fence with razor wire at the top seems dangerous but it does drop you exactly where you need to be without the risk of being seen. Playing leapfrog past the cars puts you perilously close to the zombies currently ambling the parking lot like stoned valets, but if you're quiet enough, it should be possible.
		
		What do you do?
		
		*choice
		
			#Take the direct route, scale the fence, and hopefully avoid being lunched upon in the lunch area.
			
				Grasping your fingers into the wire mesh above your head you raise a leg and push the toe of your running shoe into the fence. The mesh digs into your hands a bit but your shoe remains wedged into the fence, taking some of the weight. A few more of these and you end up face to face with the razor wire. You have to get over it without being caught by it.

				You grab the top rail of the fence firmly and walk your feet up until they are about 2 feet under your hands. You wedge the toes in good and tight and start bouncing up and down. That's definitely going to attract the locals so it's now or never. With a final push off you rotate up and over the top of fence.
			
				*set athletics %+20
				*set leginjury true
				
				Your left leg gets caught on the way over and the razor wire opens a nasty gash. You worry that the rattling of the fence and your grunt of pain (and maybe the smell of fresh salty blood) will attract some shambling friends, but so far ${Student} is right, and the lunch area is clear. You head for the inside of the building.
					
				*goto Inside
					
			#Go the longer way through the hole and leapfrong behind the cars. 
			
				*set reflexes %+20
			
				You slip through the hole in the fence, heart pounding as you listen to the sound of zombies milling about just on the other side of the parked cars. The cars shield you somewhat, but there will be a few gaps where you will have to sprint and hope none of them see you. 
				
				You make it past the first car. Past the second car. Here's the first gap. You peek very carefully around the bumper. There are two zombies so close you could almost touch them, but they're looking in the other direction.
				
				You dash.
				
				You freeze.
				
				None of them chase you.
				
				You sneak past a third car, and dash again.
				
				On the third dash, you make it into the lunch area. Zombie heads turn in your direction, but you duck into the building.
				
				*goto Inside
			
			#Try running zombies over instead.
			
				*goto runthemover
			
	#Try running zombies over instead.
	
				*label runthemover

				"Well," ${Student}'s voice says doubtfully, ". . . okay. . . If you think that'll work."

				*if car = "Jeep"

					${Alpha} guns the engine and you go screaming across the parking lot,
					*if GotUseless
						${Useless} screaming in the back seat,
					zombies staggering and then running after you. 

					You watch nervously in the rearview mirror. They pour from all sides of the building, from crevices and cracks like rats. You've collected quite the pursuing zombie horde by the time you hit the other end of the parking lot and ${Alpha} swings the wheel around.

					$!{He} mows back through the crowd of zombies. Bam! they go, and splat! under the wheels of the big-ass gas-guzzling Jeep. The ones that aren't hit back off just a bit, seemingly out of respect. It really does seem as though they have enough intelligence or instinct to back away from they perceive as predators.
					
					*set zombieskilled +12

					How are you feeling about this, by the way?

					*choice

						#Still with the wanting to throw up.

							I completely understand.

							*set squeamish %+20

							*page_break

							*label NotTruck

							In any event, you make it back to the door (a somewhat reduced, but now recovering, zombie horde stumping along a little ways behind you) just as it opens and the black-shirt-clad young ${man} shoots out of it. 

							*if GotUseless

								$!{His} eyes go wide in terror as ${he} reaches for the back door and it doesn't open. 

								"${Useless}!" 
								*if alpha != "alpha"
									${Alpha} shouts,
								*if alpha = "alpha"
									you shout,  
								and ${Useless} jumps. "Open the door!"

								"Oh!" ${Useless} fumbles to unlock and open the door. "I'm so sorry! You didn't tell me I had to unlock it! I didn't know!"

							${Student} makes it inside just ahead of a zombie's straining jaws, and you tear out of the parking lot.

							*goto Student

						#Yeah, got another one! I think I'm starting to get the hang of this.

							Rock on.

							*set squeamish %-20
							*goto NotTruck

				*else

					You gun the engine and your little Honda goes screaming across the parking lot,
					*if GotUseless
						${Useless} screaming in the back seat,
					zombies staggering and then running after you. 

					You watch nervously in the rearview mirror. They pour from all sides of the building, from crevices and cracks like rats. You've collected quite the pursuing zombie horde by the time you hit the other end of the parking lot and swing the wheel around.

					*if reflexes > 50

						*set reflexes %+20

						You manage to hit a couple of them and to manuever the car so that the rest have no chance to swamp you. The ones that aren't hit back off just a bit, seemingly out of respect. It really does seem as though they have enough intelligence or instinct to back away from what they perceive as predators.
						
						*set zombieskilled +3

						*goto NotTruck

					*else

						Your reflexes just aren't up to this task. Or maybe your car isn't--rather than it plowing through the zombie horde, the horde stops it as effectively as a brick wall. And then there's a wall of zombies on every possible side to the car, smashing through the windows. You hit your head hard on something--you're not sure what, but it's probably a good thing that you're not conscious to know what happens next.

						*set dead true
						*goto_scene WrapUp


		
*label Inside
*page_break
The inside of the transfer station reeks of meat and slimy things and vomit and diapers and whatever else is in people's trash. In front of you is the pit where the trucks dump their loads, full of disgusting things macerating together and zombies shoveling disgusting things into their mouths. The floor to either side of the pit looks like a a big garage with faint lanes running from the entrance to a long concrete pit. There are six zombies wandering around the floor for no particular reason. On the far side of the floor is the truck you want.

To your right are steps leading up to onto a second level, which you can see runs all the way around the rear of the building, ending with stairs that would put you right next to the truck. 

You could sneak to the truck via the second level, where the zombies on the floor might be able to see you but won't be able to do anything about it. Then again, the situation could change once you're on the second level. Maybe it would be better to just sprint for the truck. . . 

The situation has changed while you contemplated it. A movement on the second level draws your eyes upward, and you see a solitary zombie shuffling along it. 

Still, it's only one. . . and there's a fire extinguisher on the wall to your left. 

What do you do?

*temp ext
*set ext false

*choice

	#Grab the extinguisher, creep up the stairs, and go toe to decaying toe with the zombie.
	
		*set reflexes %+20
		*set handtohand %+20
		
		Luck is on your side. Like a useless guard in a bad movie, the zombie happens to be staring towards the other end as you approach it from behind. You swing the extinguisher. THUNK. 
		
		*set zombieskilled +1

		The fire-red metal gains the added red of coagulated blood and brain. The zombie topples sideways and cartwheels over the railing. You look over in time to see the other zombies swarm into the pit to gnaw on the new trash. 

		You quickly cover the remaining distance to the truck, run down the stairs, carefully open the passenger door, and slide into the driver's seat. 
		
		*set ext true
		*goto Truck


	#Grab the extinguisher, take a deep breath, and barrel out across the tip floor, spraying any zombies that get too close.

		*set athletics %+20
		*set handtohand %+20

		You take one deep breath and sprint.
			
		You dodge around the first zombie, which looks almost startled, and plow straight towards the second.
		The foam from the fire extinguisher blinds it and you move on. The third zombie is almost on top of you--you swing the fire extinguisher, and it makes a satisfying thud as it hits the floor. The red of the extinguisher turns out to be the shade as the red of the blood now splattered on it. The fourth zombie steps back, looking uncertain. You hurl the extiguisher at the fifth and launch yourself through the open driver's-side door of the truck. 
		
		*set zombieskilled +1
		*goto Truck

*label Truck

*set engineering %+20

*page_break

Zombies cluster around the truck, banging useless fists on the metal. The keys are in the ignition; you start the truck. 

*if ext

	You gun the engine to get it ticking over and attract the attention of those zombies who haven't yet realized something is happening. With the fire extinguisher, you wedge the accelerator down. Then you press in the clutch, engage first, and shift yourself over to the other side of the cab as far as possible without letting the clutch go.

	You reach over, swing open the passenger door, release the clutch and jump. The zombies who were in front of the truck are now flat on their backs being used as speed bumps, and the ones in back are being dragged off across the pavement. You land heavily but unnoticed as the zombies not attached the truck start chasing it like it's the local lunch wagon.
		
	*set zombieskilled +12
		
	*goto Truck2
	
*else

	Okay, now you need something to jam the accelerator down. You take a quick look around but there are no random blocks of wood or bricks in the cab. Damn, what now?

	Now, apparently, is when a hand seizes your shirt.
 
	The hand belongs to a zombie that has climbed up on the door sill and reached an arm through the open window. It's trying to pull you out, mouth opened like a baby bird. You fumble for the power switch to get the window
	moving up. The window's motor groans and strains. The decaying flesh of the zombie's arm gives way with a sickening pop and the window moves another inch or so up before striking bone. The fingers let go of your shirt and the zombie turns its attention to trying to pull its arm back through the window. 

	Right. Now back to the truck problem. Maybe you can get it moving with just the engine idling. No need to get it moving fast. . . so maybe you don't need to jam the accelerator after all. . . on the other hand, maybe the engine will stall if you try that. 

	Speaking of hands, there's a spare hand right there jammed up against the cab's roof, held by the still slightly open window. Maybe that hand could be a helping hand and hold the acclerator down.

	What do you do?

	*choice

		#Rip off the zombie hand and use it to weigh down the acclerator.
	
			*set squeamish %-50
		
			You grab the zombie's hand. It looks at you through the glass, startled. You twist and pull and the zombie's hand comes off. What a wonderful role reversal. 

			You gun the engine to get it ticking over and attract the attention of those zombies who haven't yet realized something is happening. With your new third hand, you wedge the accelerator down. Then you press in the clutch, engage first, and shift yourself over to the other side of the cab as far as possible without letting the clutch go.
		
			You reach over, swing open the passenger door, release the clutch and jump. The zombies who were in front of the truck are now flat on their backs being used as speed bumps, and the ones in back are being dragged off across the pavement. You land heavily but unnoticed as the zombies not attached the truck start chasing it like it's the local lunch wagon.
		
			*set zombieskilled +12
		
			*goto Truck2
	
		#Do no such thing. The truck will move fast enough just rolling. 

			You fire up the truck, gun the engine and get it ticking over, press in the clutch, take off the emergency brake, slip it into low, and gently release the clutch. The truck jerks a few times and then starts to stagger forward. By this point, zombies have clustered all around it. Like honeybees in clover, or something. 
		
			The one caught in the window seems to recognize its tenuous situation--is that fear you see in its eye as you wave goodbye and jump out the passenger door? The truck idles off across the pavement dragging one zombie, trailing three others, and with a dozen mofe chasing it like it's the local lunch wagon. They didn't see you slip out the other side.
		
			*set zombieskilled +6
			*goto Truck2
		

*label Truck2

You shout into your cell phone, "${Student}, go!" 

You look outside the transfer building up to your right and see the black-shirt-clad young ${man} barreling down the circular stairwell around the tower. You meet at the car.

"Wow," ${he} says. "That was truly inspiring."

Frankly, you think so too. You might just have moved from "zombiepocalypse survivor" to "zombiepocalypse force-to-be-reckoned with."

*page_break

*label Student

And once again the car is on its way.
*if firstchoice = "front"
	*set GotGamer true
	
*if firstchoice = "back"
	*set GotEngineer true

*if firstchoice = "front"

	${Student} tells you ${he}'s a comp sci major, and works at the transfer station part-time to pay the bills. "And I'm a zombie expert. I've watched all the movies. I've played all the games. I know what to do. First rule of the zombiepocalypse: get to somewhere high. Second rule: plan your distractions well." 
	
*if firstchoice = "back"

	${Student} tells you ${he}'s in the last year of ${his} mechanical engineering degree, and works at the transfer station part-time to pay the bills. 
	
"So," ${he} says, "where are we going?"

"A ${Tempsafespot}," you say.

*if tempsafespot = "prison"

	*if firstchoice = "front"

		"Fantastic!" ${Student} says. "That's totally the right place to go. A prison is absolutely where you want to being during a zombiepocalypse--it has guns, it has food, and you can lock it down. Zombies are much stronger than your average alive human, you see, so we need a place the average body builder can't break into."
		
		"Yes," you say, "I--"
		
		"Going to a mall is a beginner's mistake, really," ${Student} continues. "It might seem like a good idea, but it's really not. Too many glass entrance ways and side doors that could be broken down with enough head bashing. And a church probably isn't that secure either, though I guess it depends how old the church is. Some of the older ones have really thick doors, like three inches of oak. And they're made out of stone rather than wood. It really depends where the windows are--if they're up high, I guess the church could be okay, because zombies can't shimmy up the wall. But I bet you didn't know that; most people don't know all that much about zombies."
		
		"No," you say, "I don't--"
		
		"They're strong, but they're not graceful. They operate at full peak exertion all the time. How they are doing that without a lot of energy is not clear, but the human muscle formations are capable of significant feats of strength beyond what we normally operate at, and. . . "

		${Student} talks without pausing for breath the entire journey to the prison.

		*finish
		
	*else
	
		"Oh, good," ${Student} says. "From my observations so far it looks like the dead humans are somewhat stronger than your average alive human. That means we really need a place that is secure, and nothing is more secure than a prison. Excellent choice on that." 

		"Yeah," you say, "it seems--"

		"I've been thinking about what makes them so much stronger than us. It looks to me like they're operating at full peak exertion--maybe even more. How they are doing that without a lot of energy is not clear, but the human muscle formations are capable of significant feats of strength beyond what we normally operate at."

		You try to interject at this point. "I'm not sure--"
		
		"We did some really interesting tests in one of my labs on the mechanics of the human body. You'd be amazed at the possible forces the larger muscle groups can exert. Most of us never get to that limit but somehow the zombies are right on that edge. I wouldn't be surprised to see them snap their own arms. So yeah, we need somewhere that the average body builder couldn't break into."

		"Hey," you say, "maybe--"
		
		"You have to wonder what chemical reactions are going on in those bodies to allow this to happen. Hey, it makes more sense now why they are after meat--it's high in protein and fat and probably a good source of energy. Makes me wonder if they might just burn themselves out--like a nuclear reactor--that would be good, except what will we do with all the corpses? Maybe we can put them in a huge hole with the spent uranium. That would burn up the bodies, too. . . "
		
		${Student} does not appear to pause once for breath on the whole journey to the prison.
		
		*finish

*else

		"Oh, no, no," ${Student} says. "We should go to the Cedar Junction Correctional Facility. They're still okay--I'm in touch with a guy there." $!{He} waves ${his} phone. "And a prison is totally where you want to be during a zombiepocalypse--it has guns, it has food, and you can lock it down. Going to a mall or a church is a beginner's mistake, really. The mall might seem like a good idea, but it's not secure. Too many glass entrance ways and side doors that could be broken down with enough head bashing. And a church probably isn't that secure either, though I guess it depends how old the church is. Some of the older ones have really thick doors, like three inches of oak. And they're made out of stone rather than wood. It really depends where the windows are--if they're up high, I guess the church could be okay, because zombies can't shimmy up the wall--at least, I don't know of any feat of dexterity that would indicate they could. But they're certainly much stronger than the average living human, so we really need a place we can secure, and since we don't know for sure the church meets the requirements, the prison is the best bet."

	*if (GotUseless = true) and (tempsafespot != "church")
		"No, we should go to the church," ${Useless} says. "It's closer. We need to get somewhere safe as soon as possible."
 
	*if alpha != "alpha"

		"We made a decision," ${Alpha} says, "and we're sticking to it."
 
		What do you think?

		*choice

			#I'm not getting involved in this.

				*set RelUseless %-20

				Unsurprisingly, ${Alpha} carries the day and your car proceeds to the ${tempsafespot}.

				*finish
 
			#I will side with ${Student}.

				*set RelUseless %-20
				*set tempsafespot "prison"

				Between the two of you, you manage to convince ${Alpha} to go to the ${tempsafespot} instead, but it's a near thing.

				*finish

			#I will side with ${Alpha}.

				*set RelUseless %-20

				The car proceeds to the ${tempsafespot}. 

				*finish

			*if (GotUseless = true) and (tempsafespot != "church")
				#I will side with ${Useless}. 

					${Alpha} remains unwilling to be convinced. The car proceeds to the ${tempsafespot}. 

					*set RelUseless %+20

					*finish

	*else

		So what are you going to do?

		*choice

			#Go to the prison.

				"Great!" ${Student} says, and continues to explain the advantages of a prison even though you've already agreed with ${him}. 

				For several miles.
				
				*finish

			#Go to the ${tempsafespot} like I was planning.

				${Student} frowns, and spends several miles trying to persuade you otherwise, but eventually settles down. You did save ${his} life, after all. 
				
				*finish

*label Nottransfer

*line_break

*finish