*temp KaydenGasStation
*set KaydenGasStation false


*if (firstchoice = "front") and (gender = "male")
	*set Student "Chris"
	*goto Intro
*elseif (firstchoice = "front") and (gender = "female")
	*set Student "Carrie"
	*goto Intro
*elseif (firstchoice = "back") and (gender = "male")
	*set Student "Lev"
	*goto Intro
*else
	*set Student "Lisa"
	*goto Intro

*label Intro
*if GotSurvivalist
	*goto GasStationBack
*else
	*goto GasStation


*label GasStation

*page_break

*if GotKid

	Out of the corner of your eye, you see Kayden playing around with what looks like a smartphone. "What are you doing?" you ask.

	"I thought my phone fell out of my jacket when I was up the tree," Kayden says, "but it didn't. And I thought maybe the internet was still there. And it is. Look, Facebook has a zombiepocalypse survivor group! That way you can tell people you're okay. I'll put my name on it, and yours, 
	*if (GotDoctor = true) 
		and ${Doctor}'s, 
	okay?"

	"Sure," you say. 

	"Hey, this is weird," Kayden says after another few minutes. 

	"What's weird?"

	"So, there's all these posts, from the last few days--they're from all different people, and they all say, 'I'm still okay!' and 'Not zombified yet!' Except there aren't any from yesterday or today. Except from one ${guy}-- ${Student} Murray. $!{He}'s posted over and over again, every couple of hours, the same status--'COME GET ME! If you provide transportation to the Cedar Junction Correctional Facility, I can keep you safe from zombies on the way! I know what I'm talking about--look how long I've stayed alive!'" Kayden bends over the phone, a look of concentration on ${his} face. "I'm going to message ${him} and find out where ${he} is."

	*goto GasStation2

*elseif (GotDoctor = true) and (car = "Civic")

	Beside you in the passenger's seat, ${Doctor} is messing around with ${his} smartphone. "What are you doing?" you ask.

	"Internet," ${Doctor} says briefly. "Useful tool, have you heard of it? I figured I'd just check and see what was out there. . . Yeah, look at this. Googling 'zombies' turns up all kind of useful stuff. Looks like the ${tempsafespot} is still up and running. . . Oh, and look at that. There's a 'zombiepocalypse survivor' Facebook group. Of course there is. Huh. . . that's interesting."

	"What is?"

	"There are lots of posts over the last few days, from lots of different people, and they all say, 'I'm still okay!' and 'Not zombified yet!'"

	"And?"

	"And there aren't any more recent than midday yesterday. Except from one ${guy}--${Student} Murray. $!{He}'s still there, and every couple of hours ${he} posts the same status--'COME GET ME! If you provide transportation to the Cedar Junction Correctional Facility, I can keep you safe from zombies on the way! I know what I'm talking about--look how long I've stayed alive!' Idiot doesn't say where ${he} is, though. Well, maybe I can figure it out. . . "

	*goto GasStation2

*elseif (GotDoctor = true) and (car = "Jeep")

	Driving with one hand, ${Doctor} pulls a smartphone out of ${his} pocket with the other, and tosses it to you. "Here. Why don't you see if the internet's still there. Might be some useful information."

	You poke around, and discover that the internet is indeed still there, and that there are a number of results returned when you Google "zombiepocalypse." One tells you that the survivor group at ${tempsafespot} is still up and running. Another is a Facebook group, of all things. Zombiepocalypse survivors. 

	It isn't a bad idea, really. Status after status, all over the last few days, all saying things like, "I'm still okay!" and "Not zombified yet!" You think about adding your name to it. Not that you use Facebook for much, but you do have an account. 

	Then you notice that all the status updates stopped about noontime yesterday. 

	Which can't possibly be good.

	Except for one ${guy}. ${Student} Murray is apparently still there, because ${he}'s updating ${his} status every couple of hours--the last time only twenty minutes ago--with almost exactly the same words: "COME GET ME! If you provide transportation to the Cedar Junction Correctional Facility, I can keep you safe from zombies on the way! I know what I'm talking about--look how long I've stayed alive!"

	What do you do?

	*choice

		#Tell ${Doctor} about ${Student}.

			${Doctor} seems mildly interested. "Where is ${he}?"

			You check. "Doesn't say."

			*choice

				#I message ${Student} to find out.

					*goto MessageStudent

				#I let the topic drop.

					*goto GasStation2

		#Message ${Student}.

			*label MessageStudent

			You send ${Student} a Facebook message.

			"Hey, I saw your post. Where are you?"

			Almost immediately, you get a reply. 

			"The transfer center just off exit 13 on the interstate."

			You think you know where ${he} means. The transfer center is certainly out of your way if you're headed straight for ${tempsafespot}, but it's not hours out of your way. 

			*set studentlocation true

			*goto GasStation2

		#Nothing.

			*goto GasStation2

*else

	*goto GasStation2


*label GasStation2

*if car = "Jeep"

	"Shit," ${Doctor} mutters.

	That puts you instantly on alert. "What?"

	"We're, um. . . " $!{He} looks sheepish. "Almost out of gas."

	How do you respond?

	*choice

		#"We're WHAT? You didn't freaking check before we left?"

			*set RelDoctor %+10
			${Doctor}'s face turns red with anger or embarrassment or both. "No, I didn't."

			How do you respond?

			*choice

				#"This stupid all-terrain vehicle you wanted us to take is going to get us killed. We would have been okay with my Civic."

					$!{Doctor} looks even redder. "Well, it doesn't matter now."

					$!{He}'s right there. What do you say?

					*choice

						#"Oh my God, we're dead, we're so dead. We're going to get stranded and eaten."

							*set RelDoctor %-20
							*goto Stranded

						#I don't say anything. I just check the apps menu to see if there's a GPS app that can take us to a gas station.
							
							*set RelDoctor %+20

							And there is.

							*goto GPS

		#"Oh my God, that's it. We're going to get stranded and eaten."

			*label Stranded
			*set RelDoctor %-20
			*if GotKid
				In the back seat, Kayden starts to cry.

			${Doctor} looks exasperated. "No, of course we're not. My phone has a GPS app. Go to the main menu and open it and tell it to find us a gas station."

			You do.

			*goto GPS

		#I don't say anything. I just check the apps menu to see if there's a GPS app that can take us to a gas station. 

			*set RelDoctor %+20

			And there is.

			*label GPS

			You read out the directions, and ${Doctor} manuevers the Jeep into a deserted gas station along a lonely stretch of highway just as it begins to splutter and choke and stall. 

			*goto GasStation3

*else

	You see a gas station coming up on your right, and out of reflex you look down at your gas gauge--the smart thing to do when you're driving through back country roads. It's just over half full. 

	Under any other circumstances, you'd stop and fill up. But these aren't any other circumstances. There's no way to tell whether zombies will swarm out of the woods if you stop to fill the tank. 

	What do you do?

	*choice

		#Fill the tank. It's deserted around here; few people mean few zombies. And getting stranded because the car has run out of gas could be tragic.

			You manuever the car into the parking lot and alongside a gas pump. 

			*if GotDoctor

				${Doctor} looks at you. 

				"We need gas," you say. 

				"I thought we took this little tin can because it's fuel-efficient."

				You grit your teeth a little. How do you respond?

				*fake_choice

					#Pleasantly.

					#Sarcastically.

				"It is. But it needs fuel first." 

			*goto GasStation3

		#Keep going. There's something about the look of the place that gives me the creeps. 

			You continue on your way to the ${tempsafespot}.

			*if tempsafespot != "church"

				. . . and some time later, realize you do not have enough gas to make it there. You think you have enough gas to make it to the church instead, if you turn around now. Do you turn around now?

				*choice

					#Yes.

						*label AlmostOutOfGas
						*set tempsafespot "church"
						You drive through the falling darkness toward the church, one eye nervously on the yellow gas light on the dashboard, the other watching for zombies to come running out of the woods. 

						Just as the engine splutters to a halt, you come within sight of the steeple.

						*finish 

					#No. 

						*label OutOfGas
						You drive through the falling darkness toward the ${tempsafespot}, one eye nervously on the yellow gas light on the dashboard, hoping. . . hoping. . . 

						Hoping in vain, as it turns out. Your car engine splutters to a halt in the middle of absolute nowhere. You sit on the road, surrounded by darkness and pine trees, trying to decide what to do next.

						*choice

							#I leave the car and look for shelter in the woods.

								The woods are eerily quiet--no birds chirping or wind blowing. On one hand, that's probably a good thing; at least you'll hear anyone or anything coming for quite some distance. On the other hand, if all the critters have gone then there's probably a good reason for it. You're nervous.
								
								You try to move quietly through the underbrush with limited success. You think you see things moving in your peripheral vision and you're constantly looking left to right and front to back. Keep moving, you think. Keep moving.
								
								*page_break
								
								Damn. You may not be making too much noise but several zombies happily chowing down on a meal wouldn't be making a lot of noise either--and that is in fact exactly what you stumble upon. Four zombies are crowded around what is certainly a human body. Maybe someone who also ran out of gas? The zombies stop tearing apart the poor soul and turn towards you.  
								
								There's a moment of dead stillness with your eyes locked on their blood-stained faces and theirs locked on all parts of you. Torn flesh hangs from their mouths and internal organs dangle from their hands.
								
								*page_break
								
								You sprint off into the woods, zombies screaming bloody murder behind you as they careen after their new meal. Knowing you should never look back, you do anyway. A quick glance says you are outrunning the beasts--good--
								
								--but you spin your head back to find that the tree in front of you isn't running at all. You hit it full-on and drop to the ground, dazed. Get up and run, you say to yourself, get up, damn it, run--
								
								But you can't. Hungry mouths full of teeth appear above your swimming head. Your last thought is to wish you hadn't run out of gas.
								
								*set dead true

								*goto_scene WrapUp

							#I stay in the car until morning. 

								
								Right. You take a deep breath. Until morning. You'll be fine. 
								
								What was that noise?
								
								A deer, maybe? 
								
								The brush an arms-length from your window shivers.
														
								And it's not a deer. Any deer with any sense departed long ago. It's a zombie. And a few of the zombie's closest friends. 
								
								The undead surround the car, bashing their heads against the windows until the glass begins to crack. Torn and bloody limbs scrabble inside grasping for you. There's no chance--they drag you kicking and screaming through the broken driver's-side window. Zombies 1, you 0.
								
								*set dead true
								*goto_scene WrapUp
								

			*else

				About halfway there, the yellow gas light on the dashboard springs to life, and your blood runs cold.

				But there's nothing you can do now, except hope you have enough gas to get to the church. 
				*page_break

				*temp gas
				*rand gas 1 4
				*if gas = 1
					*goto OutOfGas
				*else
					*goto AlmostOutOfGas

 
*label GasStation3

You get out of the car. Seems quiet enough. 

*if GotKid
	"I'm hungry," Kayden says.

*if GotDoctor

	${Doctor} looks with distaste at the gas station. "What they sell in there isn't really food, but it's better than starvation. Here--" $!{He} gets out of the car and says to you, "I'll pump, you go pick out whatever stuff you usually eat. Get me some bottled water and some nuts. Or plain granola bars. Something without high-fructose corn syrup."

	What a pain in the ass. 

	*choice

		#I leave ${him} to pump gas, and I go to get munchies.

			*goto GasStation4

		#Since ${he}'s so particular, I send ${him} to get munchies. 

			With how much of an edge in your voice?

			*choice

				#None at all. The best way to handle this jerk is pleasantly.

					*set RelDoctor %-10
					"Since you know exactly what you want, why don't you go get the food and I'll pump the gas?" you say pleasantly. ${Doctor} gives the gas station another contemptuous look and goes inside. You pump the gas. 

					*goto GasStation4B

				#Just a little, to hopefully communicate that ${he}'s crossing a line.

					"Since you know exactly what you want, why don't you go get the food and I'll pump the gas?" you say, in that over-precise tone people use when they are annoyed. ${Doctor} doesn't seem to notice it. $!{He} gives the gas station another contemptuous look and goes inside. You pump the gas. 

					*goto GasStation4B

				#Edge, nothing. I snap back that I'm not ${his} servant.

					"Right, we need to get something clear. I'm not your servant, and you don't give me orders. Now, since you're so particular, you go get the food. I'll pump the gas."

					The expression that crosses ${his} face is something between amusement and maybe respect. $!{He} heads for the gas station.
					
					*if diplo
					
						You contemplate the expression that might have been respect. Interesting. There are some people who don't respond well to traditional diplomacy--who see it as weakness. Alphas, who need to be out-alpha'd. Maybe ${Doctor} is one of those. Food for thought.

					*set RelDoctor %+20
					*goto GasStation4B

				#Edge, nothing. I communicate calmly and directly that I would appreciate ${him} making requests instead of issuing orders. 

					"Right." You face ${him}. "${Doctor}, we need to get something clear. You keep speaking to me as though I work for you, or something, and you can just tell me what to do. If there's something you would like me to do for you, I would appreciate it if you would say, 'Would you do x please' instead of 'Do x.' Am I making myself clear?"
					
					*if diplo
					
						$!{He} raises ${his} eyebrows mockingly, but ${he} seems at least a little impressed by your calm tone. "You are."
						*goto GasStation4B
						
					*else
					
						$!{He} smirks at you. "Did you learn that from the Oprah Winfrey show?"
						
						After you stop feeling furious, you realize that you did learn something from the encounter. ${Doctor} isn't impressed by the diplomatic methods of communication that are supposed to work with everyone. You may need to try something else.
						*goto GasStation4B

*if (GotKid = true) and (GotDoctor = false)

	What do you say?

	*choice

		#"Okay, why don't you go inside and pick out some munchies. Get some bottled water, too."

			*goto GasStation4C

		#"Okay, I'll go inside and get some munchies after I pump the gas."

			*goto GasStation4

		#"Okay, we'll go inside and get some munchies after I pump the gas."

			*set KaydenGasStation true
			*goto GasStation4

*if (GotKid = false) and (GotDoctor = false)

	You fill the tank, and then you think about other things you might need. The food sold by gas stations isn't really food, but it's better than starvation. But there's something about the deserted look of the place that kinda gives you the creeps.

	Do you go inside?

	*choice

		#Yes.

			*goto GasStation4

		#No.

			*finish


*label GasStation4

You walk into the gas station, in search of munchies.

And you find--probably you should have expected this--a zombie inside, also in search of munchies. 

In fact, the zombie has found munchies. 

*page_break

The zombie appears to have someone cornered in the very back of the store, between the ice cream cooler and the shelf of artifically-flavored-and-colored "potato" chips. 

But the zombie doesn't seem to have actually started munching yet. It turns its head as you enter and studies you with interest. You're not quite sure why you'd seem like more attractive prey than the cowering ${man}, but it's possible that you do. To judge by the (sort-of) expression on (what's left of) the zombie's face. It sweeps its long hair out of its eyes to look at you better.

This one seems to have been a teenage girl.

*if KaydenGasStation

	"Kayden, run!" you say, and ${he} does. Now it's just you and the zombie and the cowering person.

So what do you do?

*choice

	#Try to save the cowering person.

		*set selfish %-20

		That's very brave. Heroic, in fact.

		You have a plan, right?

		*choice

			#I'll make a lot of noise and dance around a little, to distract the zombie long enough for the cowering ${guy} to run out the door. And then I'll figure out how to escape myself.

				*set selfish %-20
				*label WhichWay
				You look around the gas station. You are standing almost in one corner, with the counter and cash register behind you. The zombie and its potential victim are in the opposite corner. Along the wall to your left is a display of frisbees, beachballs, and wiffle balls and bats. Past it, in the left-hand corner, is a freezer with bags of ice. Along the wall to your right are shelves containing cat food cans, condiments, lighters, bags of charcoal, bags of hot dog and hamburger buns, and lighter fluid. (On some more relaxed occasion you might pause to wonder what the cat food is doing in the cookout display.) Perhaps out of fear regarding the lighter fluid, there is a fire extinguisher over the shelves. In the middle of the store, more towards your left than your right, are some rickety-looking stands holding candy, maps, and newspapers.

				Before you can decide quite what to do, the zombie charges across the center of the room at you.

				Which way do you run?

				*choice

					#Left.

						You dart to the left, and the zombie pursues you. 

						What do you grab?

						*choice

							#A whiffle bat.

								You seize a whiffle bat from the display, and whirl to hit the zombie in the head with it. 
								*set handtohand %+20

								It's much too light to be a great weapon, but you wield it well. You crack the zombie solidly across the forehead, and it reels back from you a little. 

								"Run!" you call to the cowering ${guy}.

								$!{He} doesn't. 

								You back around the candy-and-newspapers display, trying to keep it between you and the zombie. You don't manage all that well, but between your fancy footwork and hitting out with the bat, you at least manage to keep the zombie from touching you. You've got it enough off-balance to escape yourself, you think, if only the person you came to rescue would--

								"RUN!" you shout again.

								*page_break

								This time, the cowering ${guy} gets slowly to ${his} feet and wobbles towards the door. 

								*if gender = "female"

									You notice out of the corner of your eye that she's wearing high heels. 

									Of course she is.

									You hit the zombie harder out of frustration.

								*page_break

								The zombie seems to be getting irritated with being hit in the face over and over. It growls a little, and lunges for you, hands going for your throat in a determined manner.

								You drop the bat and run, nearly colliding in the doorway with the formerly-cowering ${guy}, who still isn't moving anywhere near as fast as ${he} needs to be. You grab ${his} arm and drag ${him} along with you.
								
								You slam the car door just as the enraged teenager comes charging out of the station and throws herself against it. Looks like she'll have make do with gas station munchies today. You smile.
								
								*set GotUseless true
							
								*finish
								
							#A bag of ice.

								You tear down the left-hand wall to the ice freezer, wrench it open, and pull out a bag of ice. 

								*set athletics %+20
 
								A bag of ice is a really heavy thing to throw, but you manage it. It knocks the zombie off-balance, and the zombie sits down hard. You're not sure if she looks surprised by it, or if that was always how she looked before she died. 

								"Run!" you call to the cowering ${guy}. 

								$!{He} doesn't.

								You grab a second bag of ice and use it as a club, whaling on the zombie's head and shoulders until it stops moving. 

								"Run!" you shout to the cowering ${guy} again, but ${he} still doesn't.

								When the zombie is still--at least for the moment--you drop the ice on its head, run to the far corner, physically haul the ${guy} to ${his} feet, and drag ${him} out the door.

								*label Heels
								*if gender = "female"

									She's wearing high heels. Of course she is.

								*set GotUseless true
								*finish

							#Neither--I duck around the display, planning to push it over.
								*set engineering %+20
								You manage to wait until just the right moment to push over the display. It falls on top of the zombie, pinning it to the ground. 
 
								Splat. 

								The zombie makes an irritated noise from beneath the display. You can see a hand flailing along the floor, flipping candy bars out of its way as it searches for purchase.

								There is no time to waste.

								*page_break

								"Quick, run!" you say to the ${guy} in the corner, but ${he} doesn't. So you run to the corner, physically haul the ${guy} to ${his} feet, and drag ${him} along with you to the door.
		
								*goto Heels

					#Right.

						You dart to the right, and the zombie pursues you.

						What do you grab?

						*choice

							#Cat food cans.

								*set athletics %+20

								A cat food can is a pretty reasonable weapon, actually. You hit the zombie square in the forehead with a can of Savory Salmon With Long Grain Rice, and follow it up with a can of Tuscan Tuna With Field Greens. The zombie reels back from you. This one appears to be a teenage girl.

								"Run!" you call to the cowering ${guy}.

								$!{He} doesn't. 

								You back around the candy-and-newspapers display, hurling cans of cat food whenever you have a clear shot and succeeding in keeping the zombie off-balance. You could escape yourself, you think, if only the person you came to rescue would--

								"RUN!" you shout again.

								*page_break

								This time, the cowering ${guy} gets slowly to ${his} feet and wobbles towards the door. 

								*if  gender = "female"

									You notice out of the corner of your eye that she's wearing high heels. 

									Of course she is.

									You throw a can of Florentine Tuna With Mushrooms particularly hard, out of frustration.

								*page_break

								The zombie seems to be getting irritated with being hit in the face over and over. It growls a little and lunges for you, hands going for your throat in a determined manner.
 
								You throw the last cat food can randomly, and run. In the doorway, you nearly collide with the formerly-cowering ${guy}, who still isn't moving anywhere near as fast as ${he} needs to be. You grab ${his} arm and drag ${him} along with you.

								*set GotUseless true
								*finish

							#The fire extinguisher.

								*set engineering %+20
								Great idea. You aim the thing at the zombie and let it have a facefull of foam.

								The zombie makes a noise of extreme irritation--though not pain, you notice. It waves ineffectively in front of itself, stumbling forward, trying to find you by its other senses now that you have blinded it.

								It doesn't seem to occur to the zombie to reach up and wipe the foam out of its eyes, but that's fine by you. You move as quietly as possible to sneak around past it and to the door. 

								*page_break

								*set reflexes %+20

								Sweat pours down your face, and your hands feel so cold you almost drop the fire extinguisher, but you manage to make it around the blind and fumbling zombie. You have a clear shot to the door.

								But the cowering ${guy} still hasn't moved.

								You gesture frantically, and ${he} finally drags ${him}self to ${his} feet and stumbles towards you.

								*if gender = "female"

									She's wearing high heels.

									Of course she is.

									The clop-clop sound attracts the attention of the zombie, who turns its head at once in your direction.

								You grab ${his} arm and drag ${him} through the door with you.

								*set GotUseless true
								*finish


							#A lighter and the lighter fluid. 

								*set squeamish %-20

								Your hands shake as you unscrew the cap. The zombie prowls purposefully towards you. 

								You swing the lighter fluid container, flinging the liquid inside in a long arc through the air. A good healthy splash lands on the zombie, which blinks at the liquid in its eyes.
								
								You swing the container again, pouring lighter fluid on the floor, in a straight line between yourself and the zombie.

								Then you flick the lighter on, touch it to the lighter fluid, and jump out of the way.
								
								*set zombieskilled +1

								*page_break

								You don't watch. You don't want to. Instead you stumble towards the cowering ${guy}, who still hasn't moved, physically haul ${him} to ${his} feet, and drag ${him} with you out the door.

								*goto Heels

					#I jump over the counter. 

						Behind the counter is the cash register, packets of cigarettes, lottery tickets, and no way out. 

						The zombie comes straight for you.

						And your eyes light on the final item on this side of the counter: a sawed-off shotgun.

						*page_break

						*if firearms > 50

							Which you, fortunately, know how to use. 

							The zombie is closing. 

							You only have one shot.

							But you only need one. You blow its head clean off. 
							
							*set zombieskilled +1

							It topples backward, and you're pretty sure it will stay dead. Just in case, though, you lose no time in running for the cowering ${guy}, physically hauling ${him} to ${his} feet, and dragging ${him} out the door with you.

							*goto Heels

						*else

							People use these things to blow zombies' heads off, right? In movies? You're pretty sure they do.

							Unfortunately, you're less sure as to how. You point the gun at the zombie and pull the trigger. . . and nothing happens.

							You try to figure out why not. Is it not loaded, maybe? Is the "safety" off? Where would the "safety" be? You look up from trying to figure that out. . .

							. . . just as two long-fingered, long-nailed, dirty-nailed hands shoot out and grab you around the throat. The zombie pulls you half over the counter. Holding your throat firmly in her hands, she opens her mouth wide for a big bite. Your last thought is to notice that she's wearing braces. 

							*set dead true    
							*goto_scene WrapUp 

			#I'll attack the zombie directly. 

				Right, then. You'll need a weapon.

				*goto WhichWay           


	#Run like hell.

		*set selfish %+20

		*if KaydenGasStation

			You follow Kayden out the door and race with ${him} to the car. You're both inside and driving away in record time. The zombie does not follow you. The prey inside was much easier to eat. 

			*finish

		*elseif GotDoctor

			"What. . . ?" ${Doctor} says, gas pump in hand. 

			"Zombie!" you say, and ${he} drops the pump, screws on the gas tank cap, and runs for the car door.

			You're quite a way down the road before your heart settles down, and only then do you realize that ${Doctor} stopped about halfway through the process of filling the tank. Still, better than nothing and much better than being zombie food. 

			*finish

		*else

			You sprint for the car and slam the door behind you. With another squealing of tires, you're off down the road. The zombie does not follow you. The prey inside was much easier to eat. 

			*finish

			
*label GasStation4B

A moment later, ${Doctor} comes tearing back outside, dead white. "Zombie!" ${he} snaps, and you scramble to get inside the car.

You're quite a way down the road before your heart settles down, and only then do you realize that you got no food out of the encounter (and only half the gas you wanted). Still, better than nothing and much better than being zombie food. 

*finish


*label GasStation4C

A moment later, Kayden comes tearing back outside, dead white. "There's a zombie after me!" ${he} shrieks, and you scramble to get inside the car.

You're quite a way down the road before your heart settles down, and only then do you realize that you got no food out of the encounter (and only half the gas you wanted). Still, better than nothing and much better than being zombie food.
*finish




*label GasStationBack

"So," you say to ${Useless}, "what's your story?"

"The two guys were my roommate and his son," ${Useless} says. "The woman was hitchhiking, and I _said_ we shouldn't pick her up, but Bob never did think I was worth listening to--he insisted. . . And then we stopped because I had to pee, and when I got back from the bushes, all of them had zombified. I was right. We shouldn't have picked her up."

"How long was she in the car with you first?" ${Survivalist} asks sharply.

"What? I don't know . . . what do you mean?"

"You know how long it takes for someone to turn, if they're not killed," ${Survivalist} says impatiently. "If they're killed, we know it's almost immediate, but we don't know exactly how long if you're just bit and left alive. . . "

"I don't know," ${Useless} says again. "I wasn't really paying attention."

"Well, ballpark then. An hour? A half hour? Five hours? Five minutes?"

"I said I don't know!" ${Useless} sounds defensive, almost teary.

Are you going to get involved here?

*choice

	#Yes. ${Survivalist} is obviously coming on too strong. I can get the information more gently.

		*goto SootheUseless

	#Yes. I don't want my two companions to be at each other's throats, and this beginning isn't promising.

		*set selfish %+20
		*goto SootheUseless

	#Nope. Not my problem. 

		*set selfish %+20
		*set RelUseless %-20
		*set RelSurvivalist %+10

		"Oh good Lord," ${Survivalist} says, looking at ${Useless} in the rearview mirror, "you're not _crying_ about me asking you a question, are you?"

		It seems that ${Useless} is. It's an uncomfortable ride for several miles thereafter. 

		*page_break

		After some time, ${Useless} says stiffly, "So where are we going?"

		*goto UselessStudentInfo

*label SootheUseless

"Easy does it," you say, and several other things along those lines, and finally ${Useless} remembers that it was about fifteen minutes between when they picked up the hitchhiker and when the hitchhiker started eating ${his} roommate.

*set RelUseless %+20
*set gotturninfo true

${Useless} seems calmer now, though ${he} has apparently decided to only talk to you, not ${Survivalist}. "Where are we going?" ${he} asks.

*goto UselessStudentInfo


*label UselessStudentInfo

You explain about the ${tempsafespot}. 

"Oh." $!{He} sounds disappointed. 

"Why?"

"I was hoping we were headed for the interstate. Do you know about ${Student} Murray?" $!{He} waves a smartphone. 

"No," ${Survivalist} says.
    
"I've been following the Zombiepocalypse Survivors group on Facebook," ${Useless} explains. "There aren't, um, aren't so many of them posting as there used to be, but ${Student}'s still updating ${his} status every couple of hours."

$!{He} shows you the smartphone screen. ${Student}'s status updates are all almost the same. "COME GET ME! If you provide transportation to the Cedar Junction Correctional Facility, I can keep you safe from zombies on the way! I know what I'm talking about--look how long I've stayed alive!"   
    
"I've been messaging with ${him}," ${Useless} says. "$!{he}'s at the transfer center off exit 13. Bob said we'd go there first, and then the church. . .  I think that's the best plan, but if you want to do something else, of course, it's your car, I can't do anything about it. . . "

*set studentlocation true
    
Do you want to sidetrack to rescue ${Student}?

*choice

	#Yes.

		You're going to have to convince ${Survivalist}. $!{He} says ${he} thinks it's a bad idea--mostly, you get the impression, because ${he} finds ${Useless} annoying and wants to contradict ${him}.

		What are you going to do?

		*choice

			#Let it drop--let ${Survivalist} call the shots.

				*set RelUseless %-20
				*set selfish %+20
				*set rescuestudent false

				Very well. You do not make any effort to rescue the student. Your car continues on its way to ${tempsafespot}.
				
				*if diplo
				
					You think ${Useless} is pretty upset with you for letting it drop, but that can't be helped.

				*goto GasStationBack2

			#Make a forceful argument.

								
				${Survivalist}, persuaded by your conviction, turns the car in the direction of the transfer center, to rescue the student.
				
				*if diplo
				
					You note that ${Survivalist} seems to respond well to a forceful argument, to someone taking the upper hand and acting "alpha." You file that away for future reference. And ${Useless} is pleased you sided with ${him}. That went well.
					

				*set RelSurvivalist %+20
				*set RelUseless %+10
				*set rescuestudent true

				*if tempsafespot != "church"

					*page_break

					Then ${Useless}, having apparently decided you are ${his} champion with regard to dealing with ${Survivalist}, reminds you that ${he} would prefer to head for the church. 

					Do you attempt to convince ${Survivalist} to do this?

					*choice

						#No, I don't think it's a good plan.

							You say so, gently. ${Survivalist} smiles. "Of course not," ${Useless} says. "No one ever thinks my plans are any good."
								
							*set RelSurvivalist %+10
							*set RelUseless %-20
							*goto GasStationBack2

						#No, I don't want to push my luck with ${Survivalist}.

							You say you don't think that's a good idea. ${Survivalist} smiles. "Of course not," ${Useless} says. "No one ever thinks my plans are any good."
							
							*set RelSurvivalist %+10
							*set RelUseless %-20
							*set selfish %+20
							*goto GasStationBack2

						#Yes. 

							*if RelSurvivalist > 70

								${Survivalist} argues with you initially, but is persuaded by your firmness and your solid arguments--the church is closer to the transfer center than anywhere else, and ${he} thinks you know what you're doing.

								*set RelUseless %+20
								*set tempsafespot "church"
								*goto GasStationBack2

							*else

								${Survivalist} flatly disagrees with you on this point and will not be persuaded. But at least your argument does not seem to at all damage your relationship with ${him}. ${Survivalist} appears to prefer people who speak their minds. 

								In the back seat, ${Useless} sulks.

								*goto GasStationBack2
				*else

					*goto GasStationBack2

			#Make a logical argument.

				You make a long-winded and overly elaborate statement of your reasons for in this particular circumstance, all things being equal, prefering to take the risks involved in rescuing the student because of the advantages ${his} presence might provide, as well as the arguments of honor and duty. . . 

				${Survivalist} is distinctly unimpressed, and informs you that you'll be continuing on your way to the ${tempsafespot} without stopping to rescue the student. 
				
				*if diplo
				
					Which gives you some useful information. Long logical arguments aren't the way to persuade ${Survivalist}. That may be good to know later, although it would have been better to know before now. You hope someone else rescues that poor student.

				*set RelSurvivalist %-10
				*set rescuestudent false
				*goto GasStationBack2

			#Make a deferential argument.

				${Survivalist} is distinctly unimpressed. $!{He} brushes off your tentative suggestion, and you continue on your way to the ${tempsafespot} without stopping to rescue the student.
				
				*if diplo
				
				
					Which gives you some useful information. You may need to use more force to persuade ${Survivalist}. That may be good to know later, although it would have been better to know before now. You hope someone else rescues that poor student.

				*set rescuestudent false
				*set RelSurvivalist %-10
				*goto GasStationBack2

	#No. 
		*set rescuestudent false
		*set RelUseless %-10
		*set selfish %+20

		Very well. You do not make any effort to rescue the student. Your car continues on its way to {tempsafespot}.

		*goto GasStationBack2



*label GasStationBack2

*page_break 

After a short while, a gas station comes up on your right. ${Survivalist} pulls in. "We'd better fuel up while we have the opportunity."

"I'm hungry," ${Useless} says. 

"There's MREs in the box beside you."

${Useless} makes a face. "No, I mean I want food. I can't eat that weird shit. Can't one of you get some real food from the gas station?"

You wouldn't have thought what was sold at gas stations counted as "real food", but apparently ${Useless} does. ${Survivalist} looks like ${he} wishes ${he}'d left this whiny brat to be eaten by zombies. What do you do?

*choice

	#I offer to get munchies.

		*set RelUseless %+20

		"That's like letting a dog have a taste of blood," ${Survivalist} mutters as you both get out of the Jeep.

		"What is?"

		${Survivalist} only rolls ${his} eyes, leaving you to figure it out for yourself. $!{He} goes to pump gas and you go to get ${Useless}'s munchies.

		*goto MunchiesBack        

	#I suggest ${Useless} go get ${his} own munchies.

		${Useless} looks hurt. "Fine." $!{He} flounces inside while ${Survivalist} starts pumping the gas. ${Survivalist} gives you what you think is a look of approval.

		*set RelUseless %-20
		*set RelSurvivalist %+10
		*goto UselessMunchies

	#I point out to ${Survivalist} that munchies would make the MREs last longer. 

		*if RelSurvivalist > 70

			$!{He} seems receptive to the argument when you're the one making it. "Fair enough. You pump the gas and I'll go get some."

		*else

			$!{He} rolls ${his} eyes. "Fine, go get some, then."

			*goto MunchiesBack

			
*label MunchiesBack

You walk into the gas station, in search of munchies.

And you find--probably you should have expected this--a zombie inside, also in search of munchies. 

In fact, the zombie has found munchies. 

*page_break

The zombie appears to have a kid cornered in the very back of the store, between the ice cream cooler and the shelf of artifically-flavored-and-colored "potato" chips. 

But the zombie doesn't seem to have actually started munching yet. It turns its head as you enter and studies you with interest. You're not quite sure why you'd seem like more attractive prey than the cowering kid--a ${boy} of about nine or ten--but it's possible that you do. To judge by the (sort-of) expression on (what's left of) the zombie's face. It sweeps its long hair out of its eyes to look at you better.

This one seems to have been a teenage girl.

So what do you do?

*choice

	#Try to save the kid.

		*set selfish %-20
		*set GotKid true

		That's very brave. Heroic, in fact.

		You have a plan, right?

		*choice

			#I'll make a lot of noise and dance around a little, to distract the zombie long enough for the kid to run out the door. And then I'll figure out how to escape myself.

				*set selfish %-20
				*label WhichWay2
				You look around the gas station. You are standing almost in one corner, with the counter and cash register behind you. The zombie and its potential victim are in the opposite corner. Along the wall to your left is a display of frisbees, beachballs, and wiffle balls and bats. Past it, in the left-hand corner, is a freezer with bags of ice. Along the wall to your right are shelves containing cat food cans, condiments, lighters, bags of charcoal, bags of hot dog and hamburger buns, and lighter fluid. (On some more relaxed occasion you might pause to wonder what the cat food is doing in the cookout display.) Perhaps out of fear regarding the lighter fluid, there is a fire extinguisher over the shelves. In the middle of the store, more towards your left than your right, are some rickety-looking stands holding candy, maps, and newspapers.

				Before you can decide quite what to do, the zombie charges across the center of the room at you.

				Which way do you run?

				*choice

					#Left.

						You dart to the left, and the zombie pursues you. 

						What do you grab?

						*choice

							#A whiffle bat.

								You seize a whiffle bat from the display, and whirl to hit the zombie in the head with it. 
								*set handtohand %+20

								It's much too light to be a great weapon, but you wield it well. You crack the zombie solidly across the forehead, and it reels back from you a little. 

								"Run!" you call to the kid.

								$!{He} doesn't. 

								You back around the candy-and-newspapers display, trying to keep it between you and the zombie. You don't manage all that well, but between your fancy footwork and hitting out with the bat, you at least manage to keep the zombie from touching you. You've got it enough off-balance to escape yourself, you think, if only the kid would--

								"RUN!" you shout again.

								*page_break

								This time, the cowering kid gets slowly to ${his} feet and wobbles towards the door. 

								*page_break

								The zombie seems to be getting irritated with being hit in the face over and over. It growls a little, and lunges for you, hands going for your throat in a determined manner.

								You drop the bat and run, nearly colliding in the doorway with the formerly-cowering kid, who still isn't moving anywhere near as fast as ${he} needs to be. You grab ${his} arm and drag ${him} along with you. 
								
								You slam the car door just as the enraged teenager comes charging out of the station and throws herself against it. ${Survivalist} floors it, leaving the lone zombie staggering futilely after. Looks like she'll have make do with gas station munchies today. You smile.

								*set GotKid true
								*finish

							#A bag of ice.

								You tear down the left-hand wall to the ice freezer, wrench it open, and pull out a bag of ice. 

								*set athletics %+20

								A bag of ice is a really heavy thing to throw, but you manage it. It knocks the zombie off-balance, and the zombie sits down hard. You're not sure if she looks surprised by it, or if that was always how she looked before she died. 

								"Run!" you call to the kid. 

								$!{He} doesn't.

								You grab a second bag of ice and use it as a club, whaling on the zombie's head and shoulders until it stops moving. 

								"Run!" you shout to the kid again, but ${he} still doesn't.

								When the zombie is still--at least for the moment--you drop the ice on its head, run to the far corner, physically haul the kid to ${his} feet, and drag ${him} out the door.

								*set GotKid true
								*finish

							#Neither--I duck around the display, planning to push it over.

								*set engineering %+20

								You manage to wait until exactly the right moment to push over the display at exactly the right moment. It falls on top of the zombie, pinning it to the ground. 

								Splat. 

								The zombie makes an irritated noise from beneath the display. You can see a hand flailing along the floor, flipping candy bars out of its way as it searches for purchase.

								There is no time to waste.

								*page_break

								"Quick, run!" you say to the kid in the corner, but ${he} doesn't. So you run to the corner, physically haul the kid to ${his} feet, and drag ${him} along with you to the door.

								*set GotKid true
								*finish

					#Right.

						You dart to the right, and the zombie pursues you.

						What do you grab?

						*choice

							#Cat food cans.

								*set athletics %+20

								A cat food can is a pretty reasonable weapon, actually. You hit the zombie square in the forehead with a can of Savory Salmon With Long Grain Rice, and follow it up with a can of Tuscan Tuna With Field Greens. The zombie reels back from you. This one appears to be a teenage girl.

								"Run!" you call to the kid.          

								$!{He} doesn't. 

								You back around the candy-and-newspapers display, hurling cans of cat food whenever you have a clear shot and succeeding in keeping the zombie off-balance. You could escape yourself, you think, if only the kid would--

								"RUN!" you shout again.

								*page_break

								This time, the cowering kid gets slowly to ${his} feet and wobbles towards the door. 

								*page_break

								The zombie seems to be getting irritated with being hit in the face over and over. It growls a little and lunges for you, hands going for your throat in a determined manner.

								You throw the last cat food can randomly, and run. In the doorway, you nearly collide with the formerly-cowering kid, who still isn't moving anywhere near as fast as ${he} needs to be. You grab ${his} arm and drag ${him} along with you. 
								
								You slam the car door just as the enraged teenager comes charging out of the station and throws herself against it. ${Survivalist} floors it, leaving the lone zombie staggering futilely after. Looks like she'll have make do with gas station munchies today. You smile.

								*set GotKid true
								*finish

							#The fire extinguisher.
								*set engineering %+20
								Great idea. You aim the thing at the zombie and let it have a facefull of foam.

								The zombie makes a noise of extreme irritation--though not pain, you notice. It waves ineffectively in front of itself, stumbling forward, trying to find you by its other senses now that you have blinded it.

								It doesn't seem to occur to the zombie to reach up and wipe the foam out of its eyes, but that's fine by you. You move as quietly as possible to sneak around past it and to the door. 

								*page_break

								*set reflexes %+20

								Sweat pours down your face, and your hands feel so cold you almost drop the fire extinguisher, but you manage to make it around the blind and fumbling zombie. You have a clear shot to the door.

								But the cowering kid still hasn't moved.

								You gesture frantically, and ${he} finally drags ${him}self to ${his} feet and stumbles towards you.
								
								You grab ${his} arm and drag ${him} through the door with you.

								*set GotKid true
								*finish

							#A lighter and the lighter fluid. 

								*set squeamish %-20

								Your hands shake as you unscrew the cap. The zombie prowls purposefully towards you. 

								You swing the lighter fluid container, flinging the liquid inside in a long arc through the air. A good healthy splash lands on the zombie, which blinks at the liquid in its eyes.

								You swing the container again, pouring lighter fluid on the floor, in a straight line between yourself and the zombie.

								Then you flick the lighter on, touch it to the lighter fluid, and jump out of the way.

								*page_break

								You don't watch. You don't want to. Instead you stumble towards the cowering kid, who still hasn't moved, physically haul ${him} to ${his} feet, and drag ${him} with you out the door.

								*set zombieskilled +1
								*set GotKid true
								*finish
								
					#I jump over the counter. 

						Behind the counter is the cash register, packets of cigarettes, lottery tickets, and no way out. 

						The zombie comes straight for you.

						And your eyes light on the final item on this side of the counter: a sawed-off shotgun.

						*page_break

						*if firearms > 50

							Which you, fortunately, know how to use. 
							
							The zombie is closing. 

							You only have one shot.

							But you only need one. You blow its head clean off. 

							It topples backward, and you're pretty sure it will stay dead. Just in case, though, you lose no time in running for the cowering kid, physically hauling ${him} to ${his} feet, and dragging ${him} out the door with you.

							*set zombieskilled +1
							*set GotKid true
							*finish

						*else

							People use these things to blow zombies' heads off, right? In movies? You're pretty sure they do.

							Unfortunately, you're less sure as to how. You point the gun at the zombie and pull the trigger. . . and nothing happens.

							You try to figure out why not. Is it not loaded, maybe? Is the "safety" off? Where would the "safety" be? You look up from trying to figure that out. . .

							. . . just as two long-fingered, long-nailed, dirty-nailed hands shoot out and grab you around the throat. The zombie pulls you half over the counter. Holding your throat firmly in her hands, she opens her mouth wide for a big bite. Your last thought is to notice that she's wearing braces. 

							*set dead true    
							*goto_scene WrapUp 

			#I'll attack the zombie directly. 

				Right, then. You'll need a weapon.

				*goto WhichWay2           

	#Run like hell.

		*set selfish %+20

		The zombie does not follow you. The kid is much easier to eat.

		"What. . . ?" ${Survivalist} says, gas pump in hand. 

		"Zombie!" you say, and ${he} drops the pump, screws on the gas tank cap, and runs for the car door.

		You're quite a way down the road before your heart settles down, and only then do you realize that ${Survivalist} stopped about halfway through the process of filling the tank. Still, better than nothing and much better than being zombie food. 

		*finish


*label UselessMunchies

A moment later, ${Useless} comes tearing back outside, dead white. "There's a zombie after me!" ${he} shrieks, and ${Survivalist} scrambles to get inside the Jeep.

You're quite a way down the road before your heart settles down, and only then do you realize that you got no food out of the encounter (and only half the gas you wanted). Still, better than nothing and much better than being zombie food.  

*finish


