🧗 [b]Asteroid Colony Employment Office[/b]

*if sound
	*sound door.wav

You push open the door and find yourself in a small waiting room.

Looking around, you see several scuffed chairs and a low table piled with tattered magazines.

Written on the wall, you see a poster of a person flexing their biceps and the words "Make a fresh start for your family today!  Sign up to become an Asteroid Colonist and get a head start on tomorrow's riches!"

On the far side of the room is a glass window, behind which you see a well-nourished individual wearing a blue smock.

::: What do you want to do, Captain?

*fake_choice
	#🗣️ Speak to the person behind the window
	#↩️ Go back to the spaceport
		*goto_scene spaceport leave_market
	
🧗 [b]Asteroid Colony Employment Office[/b]

"${greetings}, I'm here to see about hiring a colonist," you tell the individual behind the window.

🙎 [i]"Quadrant?"[/i]

"I'm sorry, what?" you say.

🙎 [i]"Are you deaf? What quadrant?"[/i]

"Oh, you mean what quadrant is the asteroid colony for which I want to hire the colonists?" you say.

🙎 [i]"Obviously."[/i]

*label mustard

*temp truth_teller 0

[b]:::[/b] In which quadrant is the asteroid colony?

*input_number truth_teller 1 111

*temp pass false

*if truth_teller = asteroid1_quadrant
	*set pass true
	
*if truth_teller = asteroid2_quadrant
	*set pass true
	
*if truth_teller = asteroid3_quadrant
	*set pass true
	
*if pass = false
	*goto expel

🧗 [b]Asteroid Colony Employment Office[/b]

*if sound
	*sound bing.wav

The person types on their computer for a lengthy period before finally looking up at you.

🙎  [i]"Okay, I found that asteroid in the registry.  How many colonists do you want to hire?"[/i]

"What salaries are they asking?" you say.

🙎 [i]"We've got a special, today.  You can hire as many colonists as you like for just one hundred credits apiece in signing bonuses.  After that, they'll work for just three credits a week."[/i]

🛏️  Berths available on the ${ship_name}: ${berths_available}

[b]:::[/b] What do you want to do, Captain?

*fake_choice
	*selectable_if (berths_available > 0) #🧑‍🏭 Hire some colonists
	#↩️ Go back to the spaceport
		🧗 [b]Asteroid Colony Employment Office[/b]
		
		"Sorry, but those hiring bonuses are way too high," you say.
		
		🙎 [i]"Come back when you're ready for the responsibilities of running an asteroid colony."[/i]
		
		*page_break 🙋‍♂️
		*goto_scene spaceport leave_market
	
*label hire
	
🧗 [b]Asteroid Colony Employment Office[/b]

🛏️ Berths available on the ${ship_name}: ${berths_available}

🙎 [i]"How many colonists do you want to hire?[/i]

*temp hire_number 0 

*input_number hire_number 0 berths_available

*if hire_number = 0
	*comment ERROR NEEDS FIXING

*temp hiring_bonus 0
*set hiring_bonus (hire_number * 100)

*if hiring_bonus > credits
	🧗 [b]Asteroid Colony Employment Office[/b]
	
	*if sound
		*sound warningbleep.wav
		
	You attempt to swipe over the ${hiring_bonus} credits, but you realize, to your dismay, that you do not have enough cash.
	
	🙎 [i]"Come back when you're ready for the responsibilities of running an asteroid colony."[/i]
		
	*page_break 🙋‍♂️
	*goto_scene spaceport leave_market

*check_achievements
*if choice_achieved_hr = false
	*achieve hr


*set credits - hiring_bonus
*set berths_available - hire_number
*set colonists_carrying + hire_number

🧗 [b]Asteroid Colony Employment Office[/b]

*if sound
	*sound cardswipe.wav

You swipe over the ${hiring_bonus} credits.

🙎 [i]"Okay, your money cleared.  What's the name of your ship?"[/i]

"It's the ${ship_name}.  It's parked right here at the spaceport," you say.
	
*if hire_number = 1
	🙎 [i]"I've instructed the colonist to meet you at the dock.  Have a nice day."[/i]
	
*if hire_number > 1
	🙎 [i]"I've instructed the colonists to meet you at the dock.  Have a nice day."[/i]
	
[b]:::[/b] What do you want to do, Captain?

*fake_choice
	*selectable_if (berths_available > 0) 	#🧑‍🏭 Hire some more colonists
		*goto hire
	#↩️ Go back to the spaceport
		*goto_scene spaceport leave_market

*label expel

🧗 [b]Asteroid Colony Employment Office[/b]

*if sound
	*sound warningbleep.wav

The person types on their computer for a lengthy period before finally looking up at you.

🙎  [i]"I cannot find any asteroid at that quadrant in the registry."[/i]

[b]:::[/b] What do you want to do, Captain?

*fake_choice
	#💁‍♂️ Apologize for mixing up your quadrants
		🧗 [b]Asteroid Colony Employment Office[/b]
		
		"Oh my gosh, I am terribly sorry.  I know where the asteroids are, I just got them mixed up a bit," you say.
		
		🙎 [i]"Whatever."[/i]
		
		*goto mustard
	#↩️ Go back to the spaceport
		*goto_scene spaceport leave_market
	


*input_number