"Hercules!" by Leo Weinreb

Chapter 1 - Introduction and General Rules

[Rule for printing a parser error:
	say "[italic type](The [latest parser error] happened.)[Roman type][line break]";
	continue the activity.]
	
Wetting is an action applying to one thing. Understand "wet [something]" and "soak [something]" and "drench [something]" and "wet [something] with mop" and "soak [something] with mop" and "drench [something] with mop" and "wet [something] with the mop" and "soak [something] with the mop" and "drench [something] with the mop" and "wet [something] with the magimop" and "soak [something] with the magimop" and "drench [something] with the magimop" and "wet [something] with magimop" and "soak [something] with magimop" and "drench [something] with magimop" as wetting. Understand "splash [something]" and "put water on [something]"as wetting.

Check wetting:
	if the player carries the mop:
		say "If you're planning on soaking something with the mop, you may as well just clean with it instead." instead;
	else if the player is in Elis or the player is in the Gates of Hades or the player is in the Underworld or the player is in Lake Lerna or the player is in the Peloponnesian Shore or the player is in the Western Shore or the player is in Erytheia:
		say "Now now, there'll be plenty of time to splash water on everything after you've finished your chores." instead;
	else:
		say "There's no water here!" instead.
		
Instead of wetting the mop:
	say "Unnecessary, it's self-replenishing!"
	
quit the game rule response (A) is "So far you have scored [score] out of 12 points and achieved the rank of [rank].[paragraph break]Are you sure you want to quit? ".

Use MAX_VERBS of 500.	

Whistling is an action applying to nothing. Understand "whistle" as whistling. 

Carry out whistling:
	say "You purse your lips together and blow, but no sound comes out. You've never been able to whistle properly. It's why you took choir as a child, so you could sing in lieu of whistling while you work."

Understand "check score" as requesting the score.

Dreaming is an action applying to nothing. Understand "dream" as dreaming.

Check dreaming:
	if the player is not in Keryneia?:
		say "Dreaming when you're awake is like sneezing with your eyes open - probably manageable, but pointless to try when you've got chores to attend to!" instead;
	else:
		continue the action.
		
Carry out dreaming:
	say "A fluffy, hazy image of [one of]electric sheep[or]a sea of troubles[or]an undiscover'd country[or]a yellow brick road[or]a rabbit carrying a pocket watch[or]a red pill and a blue pill[purely at random] drifts through your mind."

can't push unpushable things rule response (A) is "You find that a very silly idea and think it best not to entertain it any longer.".

block pushing in directions rule response (A) is "You find that a very silly idea and think it best not to entertain it any longer.".

Understand "lie in [something]" as entering.

Spitting is an action applying to one thing. Understand "spit on [something]" and "spit in [something]" as spitting.

Check spitting:
	if the noun is the shit:
		say "No, you wouldn't, even into the spittoon. You don't want to add to the filth!" instead;
	else:
		continue the action.
		
Report spitting:
	say "Absolutely not! You're not a barbarian!"

Understand "rest" and "doze" and "doze off" as sleeping.

Understand the commands "question" and "interrogate" as "ask".

Pointing is an action applying to one visible thing. Understand "point at [something]" or "indicate [something]" or "point out [something]" as pointing.

Report pointing:
	say "No, it's rude to point. You're not a barbarian!"
	
Cooking is an action applying to one topic. Understand "cook [text]" and "bake [text]" and "fry [text]" and "sear [text]" and "broil [text]" and "boil [text]" as cooking.

Report cooking:
	say "You're not a chef or a baker or a drug manufacturer, so you can't cook anything."
	
Painting is an action applying to one topic. Understand "paint [text]" and "draw [text]" and "write [text]" and "perform [text]" and "mold [text]" as painting.

Report painting:
	say "You're no artist of any kind, and besides, you have none of the proper tools."
	
Painting nothing is an action applying to nothing. Understand "paint" and "draw" and "write" and "perform" and "mold" as painting.

Report painting nothing:
	say "You're no artist of any kind, and besides, you have none of the proper tools."

Understand "lick [something]" as tasting.	

block drinking rule response (A) is "You can't drink [regarding the noun][those]!".
	
can't eat unless edible rule response (A) is "You can't eat [regarding the noun][those]!".
	
can't take scenery rule response (A) is "What, do you think you're super strong or something?".

can't take what's fixed in place rule response (A) is "What, do you think you're super strong or something?".

Understand the commands "punch" and "kick" as something new.

Punching is an action applying to one thing. Understand "punch [something]" and "slap [something]" and "kick [something]" as punching.

Report punching:
	say "With these muscles? Hah! That wouldn't do anything except trigger your asthma."
	
report jumping rule response (A) is "You jump, twirl around, and nearly trip over your two left feet.".

Understand "dance" and "twirl" and "leap" and "swirl" and "bounce" and "prance" as jumping.
	
Understand "acne" and "limbs" as yourself. 
	
Wheezing is an action applying to nothing. Understand "wheeze" and "gasp" and "cough" and "burp" and "get sick" and "get dizzy" and "sneeze" and "break out in hives" as wheezing.

Report wheezing:
	say "Yes, you're pretty much already doing that involuntarily."
	
Understand the command "wave" as something new.
	
Waving hello is an action applying to nothing. Understand "wave" and "wave hand" and "wave hands" as waving hello.

Instead of waving hello:
	say "You wave.".
	
Shaking is an action applying to one carried thing. Understand "wave [something preferably held]" and "shake [something preferably held]" and "wave [something preferably held] around" as shaking.

Check shaking:
	if the noun is the flag:
		if the feral pig is in the location:
			try throwing the flag at the feral pig instead;
		else:
			say "Waving the white flag of surrender already, are you?" instead;
	else:
		say "You wave [the noun] around for a little while and begin to feel foolish." instead.
	
Calling is an action applying to one topic. Understand "call [text]" and "phone [text]" and "telephone [text]" as calling.

Check calling:
	say "You have no telephone, since this game is set in ancient Greece." instead.
	
Using is an action applying to one thing. Understand "use [something]" as using. 

Check using:
	say "The verb 'use' is too general for me to understand. What are you trying to do specifically?" instead.
	
Understand "see" as looking.
	
block buying rule response (A) is "Nobody is selling [those]!".
	
Instead of setting the safe to anything:
	say "You'll have to spin it to a number rather than set it to anything. ('Spin safe to 1234' for instance.)".
	
block saying sorry rule response (A) is "Oh, no need to apologize!".

Instead of swinging the forest trees:
	say "Are you Tarzan? No, I thought not.".
	
Instead of cutting:
	if the noun is the roses:
		say "Well they're already detached from the ground, but you could try cutting them you suppose." instead;
	else:
		say "That's not a plant you can prune." instead.
	
Check smelling:
	if the noun is a person:
		say "No, that would be very rude indeed. You're not a barbarian!" instead;
	else:
		say "It's weird to go around sniffing things randomly." instead.
	
Instead of waking yourself:
	try waking up instead.
	
block waking up rule response (A) is "You pinch yourself. Ouch! But clearly, this is not a dream.".
	
Instead of squeezing something:
	try pushing the noun instead.
	
can't search unless container or supporter rule response (A) is "Are you a TSA agent? No, I thought not. Examining is sufficient for your purposes.".
	
Instead of consulting something about anything:
	if the noun is a person:
		try asking the noun about anything instead;
	else:
		say "The [noun] isn't an encyclopedia, you can't look things up in it." instead.

Instead of thinking:
	say 	"Of course! It's what you do best." instead.

Building is an action applying to one topic. Understand "build [text]" and "make [text]" and "create [text]" as building.

Check building:
	say "You're not an engineer! If you want to make something, you'll have to go step-by-step and use more specific verbs." instead.

Making is an action applying to nothing. Understand "make" and "build" as making.

Check making:
	say "What do you want to build?" instead.

Crying is an action applying to nothing. Understand "cry" and "wail" and "sob" and "break down" and "weep" as crying.

Check crying:
	try dying instead.
	
Panicking is an action applying to nothing. Understand "panic" and "sweat" and "be afraid" and "fear" and "get fearful" and "get afraid" and "be fearful" and "have a panic attack" and "shiver with fear" as panicking.

Report panicking:
	say "In the wise words of the Hitchhiker's Guide to the Galaxy, 'Don't Panic!'" 
	
Relaxing is an action applying to nothing. Understand "relax" and "calm down" and "breathe" and "calm" and "quiet" and "quiet down" and "pipe down" and "meditate" as relaxing.

Report relaxing:
	say "You try to calm down but, as is often the case, somehow make yourself more anxious in the process."
	
Skiing is an action applying to nothing. Understand "ski" and "skate" and "snowboard" as skiing.

Check skiing:
	if the player is in Mount Erymanthos:
		say "You don't have the proper equipment." instead;
	else:
		say "This isn't the proper terrain for that." instead. 
		
Rolling is an action applying to nothing. Understand "roll" and "roll down hill" and "roll down mountain" as rolling.

Check rolling:
	if the player is in Mount Erymanthos:
		say "In addition to a possibly life-threatening number of scrapes and bruises, that would probably give you a nasty case of vertigo." instead;
	else:
		say "There's no incline to roll down here." instead. 
	
Sighing is an action applying to nothing. Understand "sigh" and "give up" and "ugh" and "argh" and "jeez" and "jesus christ" as sighing.

Report sighing:
	say "I'm sorry you're frustrated, but try not to despair!"
	
Stopping is an action applying to nothing. Understand "stop" and "stop moving" and "halt" and "cease" and "stand still" as stopping.

Check stopping:
	say "You haven't done anything!" instead.

Use American dialect.

Rule for printing a parser error when the latest parser error is the can't see any such thing error:
	say "You clean your spectacles just to make sure, but you can't see any such thing." instead.
	
Rule for printing a parser error when the latest parser error is the not a verb I recognise error:
	say "There are a lot of verbs I understand, but that's not one of them." instead.
	
Rule for printing a parser error when the latest parser error is the I beg your pardon error:
	say "What did you want to do?" instead.
	
Rule for printing a parser error when the latest parser error is the didn't understand error:
	say "Sorry, I didn't understand that sentence." instead.

Check listening:
	if a beastly person is in the location:
		say "You hear nothing unexpected other than the terrifying [if Ladon is in the location or the lion is in the location or the Minotaur is in the location]roars[else if the player is in the Gates of Hades]growls[else if the feral pig is in the location]squeals[else]screeches[end if] of the monster[if a beastly person in the location is plural-named]s[else][end if] in front of you.[if the player is in the Garden of the Hesperides][line break]Oh, and that strange ethereal hum coming from the mouth of the cave to the northeast.[end if]" instead;
	else:
		say "You hear nothing unexpected other than some slight tinnitus in your left ear.[if the player is in the Garden of the Hesperides][line break]Oh, and that strange ethereal hum coming from the mouth of the cave to the northeast.[end if]" instead
		


Check pulling something:
	try pushing the noun instead.
	
Singing is an action applying to nothing. Understand "sing" and "croon" and "belt" as singing.

Report singing:
	say "You begin to belt out an ancient tune your mother used to sing to you when you were small:[paragraph break][italic type]I will find my way[line break]I can go the distance[line break]I'll be there someday[line break]If I can be strong[line break]I know every mile[line break]Will be worth my while[line break]I would go most anywhere[line break]To feel like I belong[paragraph break][Roman type]A little cheesy perhaps, but you've always gotten the strange sense that these lyrics were written specifically with you in mind."

Celebrating is an action applying to nothing. Understand "whoop" and "hooray" and "yay" and "yippee" and "wahoo" and "woohoo" and "woo" and "celebrate" and "play" and "rock out" and "have fun" and "party" and "laugh" and "cheer" and "lol" and "lmao" and "rofl" and "roflmao" and "lmbo" and "roflmbo" as celebrating.
	
After reading a command:
	remove exclamation points.
	
After reading a command:
	if the player's command includes "spectacles":
		say "There's no need to refer to your spectacles.";
		reject the player's command.
		
After reading a command:
	if the player's command includes "glasses":
		say "There's no need to refer to your spectacles.";
		reject the player's command.
		
Report celebrating:
	say "I'm glad you're enjoying yourself!". 
	
Understand the command "shout" as something new.

Yelling is an action applying to nothing. Understand "yell" and "yelp" and "howl" and "bellow" and "shout" and "scream" and "shriek" and "roar" and "call out" and "call" as yelling.

Check yelling:
	if the player is in Amazonia and hippolyta-unconscious is true:
		try waking Hippolyta instead;
	else if the player is in Nemea and the lion is in Nemea and lion-bottle is true:
		say "Shh! The lion sleeps tonight!" instead;
	else:
		continue the action.

Report yelling:
	say "A difficult feat when you're constantly asthmatic, but you manage it. You have now started to develop a sore throat." 

After printing the name of a meaty thing while listing contents of yourself:
	say " (being led along by a piece of rope attached to the beast)".

Swearing is an action applying to nothing. Understand "fuck" and "shit" and "motherfucker" and "motherfuckers" and "cocksucker" and "cocksuckers" and "bitch" and "bitches" and "cunt" and "cunts" and "ass" and "assholes" and "asses" and "Oedipus" and "piss" and "fucker" and "fucking asshole" and "asshole" and "bloody hell" and "hell" and "Hades" and "fucking hell" as swearing.

Report swearing:
	say "You hear some annoyed rumblings of thunder off in the distance, as if your father Zeus had just told you to watch your language."
	
Hiding is an action applying to nothing. Understand "hide" as hiding.

Check hiding:
	if Ladon is in the location:
		say "Ladon the dragon certainly qualifies as one of the most frightening animals you've ever encountered (your knees are buckling so badly you fear they'll fall off), but unfortunately, there's nowhere to hide." instead;
	else if the hydra is in the location:
		say "The hydra is without a doubt the most terrifying monster you've ever seen. You're nearly crying with fear and panic, but unfortunately, there's nowhere to hide." instead.

Report hiding:
	say "Despite your meek appearance and numerous phobias, you are not a coward. You are resolved to face your tasks head-on like any true hero should, unless they're really really REALLY scary."

Rule for printing a parser error when the latest parser error is the can only do that to something animate error: 
	say "You can only do that to something animate -- this isn't a Disney cartoon!".

Rule for printing a parser error when the latest parser error is the can't talk to inanimate things error: say "You can only talk to something animate -- this isn't a Disney cartoon!" 

Talking is an action applying to one thing. Understand "talk to [something]" and "speak to [something]" as talking.

Check talking:
	if the noun is a person:
		continue the action;
	else:
		say "You can only do that to something animate -- this isn't a Disney cartoon!" instead.
		
Carry out talking:
	say "[italic type]Author's Note: In order to talk to people, try saying something specific like 'ask/tell SOMEONE about SOMETHING' or 'show/give SOMETHING to SOMEONE' or 'ask SOMEONE for SOMETHING' or 'SOMEONE, go east.'[Roman type][line break]".

Odysseusing is an action applying to nothing. Understand "odysseus" and "ulysses" as odysseusing. 

Carry out odysseusing:
	say "Isn't he a sailor?"
	
Perseusing is an action applying to nothing. Understand "perseus" as perseusing. 

Carry out perseusing:
	say "Isn't he an executioner?"
	
Orpheusing is an action applying to nothing. Understand "orpheus" as orpheusing.

Carry out orpheusing:
	say "Isn't he a musician?"

Xyzzying is an action applying to nothing. Understand "xyzzy" and "say xyzzy" as Xyzzying.

Check Xyzzying:
	if the player is in a Labyrinth or the player is in the Minotaur's Room or the player is in the Troll Room or the player is in the Grating Room or the player is in the Treasure Room or the player is in the Strange Hallway:
		say "There is a loud *pop* and you suddenly find yourself in...";
		move the player to Crete;
	else if the player is in a Dead End:
		say "There is a loud *pop* and you suddenly find yourself in...";
		move the player to Crete;
	else:
		say "There is a loud *pop* but nothing else happens."


Check waking someone:
	if the noun is the lion and lion-bottle is true:
		say "No, you don't want to wake him. It appears that the lion will sleep tonight." instead;
	else if the noun is Hippolyta and hippolyta-unconscious is true:
		say "If the Amazon warrior can't wake her with her constant shouts in between furious chest compressions, you doubt anything YOU'D try to do would make a difference. Unless you can figure out some way to make some medicine, fast." instead;
	else:
		say "It appears [the noun] [are] already awake." instead.
		
Understand "capture [something]" as taking.
		
Instead of tasting anything:
	try eating the noun instead.
		
Check rubbing something:
	if the noun is a person:
		continue the action;
	else:
		say "It's not a genie's lamp." instead.
		
A person can be frenetic or static. A person is usually static. Ladon and the feral pig and the golden hind and some Stymphalian birds and some carnivorous horses and the lion and the Minotaur are frenetic.

A person can be important or unimportant. A person is usually unimportant. Diomedes and Cerberus and Charon and Eurystheus and some spirits are important.

Rule for printing inventory details of the bottle of Benadryl:
	stop.
	
Rule for printing room description details of the desk:
	stop.
	
Rule for printing room description details of the wastebasket:
	stop.
		
Instead of giving the bottle of Benadryl to someone:
	if the second noun is the hydra:
		say "There are too many heads and drugging each one would just make it mad.";
	else if the second noun is frenetic:
		say "You try to toss some pills [if the second noun is plural-named]their[else if the second noun is a woman]her[else]his[end if] way but [the second noun] [if the second noun is plural-named]are[else]is[end if] moving around too much so you can't get near enough to drug [if the second noun is plural-named]them[else if the second noun is a woman]her[else]him[end if].";
	else if the second noun is important:
		say "If you tried to drug [the second noun] you'd probably get arrested!";
	else if the second noun is Hippolyta:
		if hippolyta-unconscious is true:
			say "She's already unconscious!";
		else:
			continue the action;
	else if the second noun is yourself:
		try eating the bottle of Benadryl instead;
	else:	
		say "You don't want to put [the second noun] to sleep![if the second noun is Hippolyta] Besides, you'd probably get arrested if you tried.[end if]".
		
Instead of taking the bottle of Benadryl:
	if the player carries the bottle of Benadryl:
		try eating the bottle of Benadryl instead;
	else:
		continue the action.
		
Drugging it with is an action applying to two things. Understand "drug [something] with [something]" as drugging it with.

Check drugging it with:
	if the noun is not a person:
		say "You can only drug something animate -- this isn't a Disney cartoon!" instead;
	else if the second noun is the bottle of Benadryl:
		try giving the bottle of Benadryl to the noun instead;
	else:
		say "You can't drug someone with that!" instead.
		
Does the player mean drugging something with the bottle of Benadryl:
	it is very likely.
		
Persuasion rule for asking people to try doing something:
	if the person asked is the lion and lion-bottle is true:
		say "The lion, being fast asleep, has no choice but to ignore you.";
	else if the person asked is Hippolyta and hippolyta-unconscious is true:
		say "Hippolyta, being unconscious, has no choice but to ignore you.";
	else:
		say "Like all good heroes (or wannabe heroes), you command no servants or followers, being merely a pure-hearted servant of the people yourself. So [the person asked] rightly [if the person asked is plural-named]disregard[else]disregards[end if] your flippant request.";
	persuasion fails.
	
block answering rule response (A) is "[The noun] look[if the noun is not plural-named]s[end if] at you quizzically, not quite understanding what it was you just said to [them].".
	
Asking it to is an action applying to one thing and one topic. Understand "ask [something] to [text]" as asking it to.

Check asking it to:
	if the noun is not a person:
		say "You can only do that to something animate -- this isn't a Disney cartoon!" instead.
		
Carry out asking it to:
	say "Like all good heroes (or wannabe heroes), you command no servants or followers, being merely a pure-hearted servant of the people yourself. So [the noun] rightly [if the noun is plural-named]disregard[else]disregards[end if] your flippant request.".
	
Instead of answering someone that "hello":
	say "Let's just assume you've gotten all the greetings out of your system already, for brevity's sake."
	
Instead of answering someone that "hi":
	say "Let's just assume you've gotten all the greetings out of your system already, for brevity's sake."
	
Instead of answering someone that "goodbye":
	say "Let's just assume you've gotten all the parting words out of your system already, for brevity's sake."
	
Instead of answering someone that "bye":
	say "Let's just assume you've gotten all the parting words out of your system already, for brevity's sake."
	
Check taking someone:
	if the noun is the cow or the noun is the Cretan Bull:
		continue the action;
	else if the noun is yourself:
		say "A difficult feat indeed. You are almost never self-possessed." instead;
	else:			
		say "What, do you think you're super strong or something?" instead.
	
Praying is an action applying to nothing. Understand "pray" and "recite a prayer" and "pray to the Gods" as praying.
	
Carry out praying:
	say "You raise a prayer to the Gods that your quest be a successful one. After you finish your blessing, you hear a slight rumbling of thunder in the distance and a whisper on the wind, which combine to form a low voice only you can hear - [italic type]If you are desperately in need of assistance in this game, call out for 'help' my child, and all your questions shall be answered.[Roman type][paragraph break]The thunder and wind cease and the voice is gone."

When play begins:
     choose row 1 in Table of Basic Help Options;
     now description entry is "Welcome to [Italic type]Hercules![Roman type] So glad you could make it.[paragraph break]Hercules is a text-based adventure (also known as interactive fiction) computer game similar to those of the 1980s, before computer games could come with advanced graphics. If you're unfamiliar with text adventures, I hope this game will help you learn to love them. If you find yourself completely at sea to start, look up 'Instructions for Play' on the previous menu, a great beginner's guidebook for how to navigate these kinds of games. It's written by Emily Short, a legend in the Interactive Fiction world.[paragraph break]If you need a hint on a specific puzzle, I have included all of them that you might need in the 'Hint System' on the previous page. However, I'll caution you to use these sparingly - the puzzles in the game will be a lot more satisfying if you solve them yourself, or almost completely by yourself. The game is no fun and over very quickly if you just scroll through the menus until you've created a makeshift walkthrough.[paragraph break]Last but certainly not least, I couldn't have made this game without the help of a plethora of people, and you can read all about their brilliance and patience with me in the 'Acknowledgements' section of the main menu. [paragraph break]And with that, I wish you all an enjoyable and stimulating rest of the game - thank you so much for your support!"

When play begins:
	choose row 4 in Table of Stuckness Advice;
	now description entry is "Play with someone else. Two heads are often better than one. If that doesn't work, try emailing the author or (better yet) posting a request for hints on the forum https://intfiction.org.  For best results, put the name of the game you want help with in the subject line; then leave a page or so of blank spoiler space (so that no one will read about where you got to in the game unless they've already played it), and describe your problem as clearly as possible.  Someone will probably be able to tell you how to get around it"

Check kissing anything:
	if the noun is yourself:
		say "Figuring out how to do that would be more impressive than solving all the puzzles in this game!" instead;
	else if the noun is a person:
		say "Even if you wanted to, you didn't bring any lip balm with you, so it wouldn't be a pleasant experience for anyone involved." instead;
	else:
		say "You can only do that to something animate -- this isn't a Disney cartoon!" instead.
		
Understand the command "hug" as something new.

Hugging is an action applying to one thing. Understand "hug [something]" as hugging.

Check hugging:
	if the noun is not a person:
		say "You find that a very silly idea and think it best not to entertain it any longer." instead;
	else if the noun is yourself:
		say "Self love is indeed important. You give yourself a great big bear hug. Don't worry, Hercules, you're doing great!" instead;
	else if the noun is Eurystheus:
		say "You walk up to your cousin and begin to greet him with an embrace, but he stops you quickly, disgust painted on his features. He elects to give you a short pat on the head instead." instead;
	else if the noun is Iolaus:
		say "You greet your nephew with a great big bear hug and a small jolt of electricity runs up your back. You give a loud yelp which soon turns into a glare as your nephew reveals the joy buzzer he had hidden in his palm. He gives you a smirk and pockets the gadget." instead;
	else:
		continue the action.
		
Report hugging:
	say "You feel uncomfortable hugging anyone who isn't family.".
	
Fucking is an action applying to one thing. Understand "have sex with [something]" as fucking.

Understand the commands "screw" and "blow" as something new.
Understand "screw [something]" and "nail [something]" and "blow [something]" and "drill [something]" and "do [something]" as fucking.

Understand "fuck [something]" and "cum in [something]" and "jerk off on [something]" and "jerk off to [something]" and "masturbate on [something]" as fucking.

Check fucking:
	say "Restrain yourself, this is a family game." instead.
	
Masturbating is an action applying to nothing. Understand "masturbate" and "jerk off" and "shoot my wad" and "spank the monkey" as masturbating.

Check masturbating:
	say "Restrain yourself, this is a family game." instead.

Swimming is an action applying to nothing. Understand "swim" as swimming.

Instead of swimming:
	if the ocean is in the location:
		say "You left your arm floats at home, and you can't swim without them.";
	else if the player is in Lake Lerna:
		say "You left your arm floats at home, and you can't swim without them.";
	else if the player is in the Underworld or the player is in the Gates of Hades:
		say "You left your arm floats at home, but you doubt you'd be willing to step into the Styx even if you had them. The waters are undoubtedly unfit for living souls.";
	else:
		say "There's no water here!"

Instead of climbing anything:
	say "You can't climb that, and even if you could, it would make you asthmatic."

Release along with the source text and a library card and a website. 
Release along with Cover Art ("The scrawny Hercules standing amid a slew of monsters and characters.") and an interpreter.

Use scoring.
The maximum score is 12.

Getting existential is an action applying to nothing. Understand "who am i" and "what person am I" as getting existential.

Report getting existential:
	say "You're Hercules, of course! The king of the Gods, Zeus, is your father and the mortal Alcmene is your mother. [6 as a footnote] People don't generally think that much of you right now (possibly due to your many ailments and phobias), but you know deep down you have the power to become a great hero one day!"

The description of the player is "You've never been one for vanity, but you give yourself a good once-over. Your limbs are scrawny and weak, almost spaghetti-noodle like, and your acne hasn't improved since middle school. Your spectacles slide down your nose so much that you've gotten into a habit of just pushing them back up again, and your height is considerably below average. Sure you may not be much to look at, but you'd rather be brainy than brawny any day. Give me a good instruction manual and some Albuterol and nothing is impossible![if the player is wearing the lion pelt and the player is wearing the flag and the player is wearing the free T-shirt][paragraph break]In addition to your regular clothes, you are wearing an oversized sweatshirt composed of a lion's skin and fur, on top of which is a bloody cotton T-shirt you nabbed from a random lost-and-found box, and your face is covered with a large dirty cartoon flag from a toy gun. Good thing the fashion police aren't real...[else if the player is wearing the lion pelt and the player is wearing the flag and the score is greater than 5][paragraph break]In addition to your regular clothes, you are wearing an oversized sweatshirt composed of a lion's skin and fur, and covering your face with a large dirty cartoon flag from a toy gun.[else if the player is wearing the lion pelt and the player is wearing the flag and the score is less than 6][paragraph break]In addition to your regular clothes, you are wearing an oversized sweatshirt composed of a lion's skin and fur, and covering your face with a large cartoon flag from a toy gun.[else if the player is wearing the lion pelt and the player is wearing the free T-shirt][paragraph break]In addition to your regular clothes, you are wearing an oversized sweatshirt composed of a lion's skin and fur, on top of which is a bloody cotton T-shirt you nabbed from a random lost-and-found box.[else if the player is wearing the flag and the player is wearing the free T-shirt][paragraph break]In addition to your regular clothes, you are wearing a bloody cotton T-shirt you nabbed from a random lost-and-found box and covering your face with a large dirty cartoon flag from a toy gun.[else if the player is wearing the flag and the score is less than 6][paragraph break]In addition to your regular clothes, you are wearing a large cartoon flag from a toy gun as a mask over your face.[else if the player is wearing the flag and the score is greater than 5][paragraph break]In addition to your regular clothes, you are wearing a large dirty cartoon flag from a toy gun as a mask over your face.[else if the player is wearing the free T-shirt][paragraph break]In addition to your regular clothes, you are wearing a bloody cotton T-shirt you nabbed from a random lost-and-found box.[else if the player is wearing the lion pelt][paragraph break]In addition to your regular clothes, you are wearing an oversized sweatshirt composed of a lion's skin and fur.[else] [end if]"

The notify score changes rule is not listed in any rulebook.

Before looking for the first time, say "'Hi! My name's Hercules, and I want to be a hero!'[paragraph break]That was your opening line to the Gods on the glowing marble steps of Mount Olympus. There was a beat of silence as your words rang through the air – and then a roaring, hysterical fit of laughter that could not be quelled. [paragraph break]You can't really blame them, you suppose - you don't exactly fit the heroic mold. You're near-sighted, scrawny, constantly allergic, and have far more phobias than a demigod should. Your spiteful stepmother Hera discounts you out of hand, and even your father Zeus is skeptical at best. But you know you can be as great as the Gods themselves if only someone would just give you a chance![paragraph break]As luck would have it, the day after your meeting with the Gods, your cousin Eurystheus offered you a temp job. Finally, you've been given a chance to prove yourself, and you'll be sure not to squander this opportunity! Let's see, this to-do list he gave you can't be all that hard..."  

The player holds a list. The player holds a bottle of Benadryl. The bottle of Benadryl is an edible container. The bottle of Benadryl is openable and closed. Understand "pills" and "pill" and "tablets" and "tablet" and "medicine" and "drugs" and "drug" and "allergy medication" and "medication" and "allergy" and "allergy medicine" and "antihistamine" and "antihistamines" as the bottle of Benadryl.

Instead of opening the bottle of Benadryl:
	say "Not now, it hasn't been 24 hours since your last dose. And you always take your pills on the dot, like clockwork.[paragraph break][italic type]Author's Note: If you want to give Benadryl tablets to people or put Benadryl tablets inside something, you can just treat the bottle of Benadryl as though it were the tablets inside the bottle.[Roman type][line break]"

Benadryl-seen is a truth state that varies. Benadryl-seen is false.

Instead of examining the bottle of Benadryl:
	say "Your trusty bottle of Benadryl tablets for your allergies. You have to take them on the dot every 24 hours — too little and you'll break out in hives and a constant stream of sneezes, too much and you'll fall right asleep. You never leave the house without this bottle and your asthma inhaler.[paragraph break][One of]Wait a second, where is your asthma inhaler? Shit. Guess you're working without a net now.[or]...until now, you guess. *sigh*[line break][stopping]";
	now Benadryl-seen is true.

Instead of eating the bottle of Benadryl:
	say "Not now, it hasn't been 24 hours since your last dose. And you always take your pills on the dot, like clockwork.".

Twelve-labors is a truth state that varies. Twelve-labors is false. 

Instead of examining the list: 
	say "'To-Do List: [line break]#1. ʃlay the Nemean Lion. [if the score is greater than 0]XXX[end if] [line break]#2. Destroy the Lernean Hydra. [if the score is greater than 1]XXX[end if] [line break]#3. Capture the Ceryneian Hind of Artemis. [if the score is greater than 2]XXX[end if] [line break]#4. Capture the Erymanthian Boar. [if the score is greater than 3]XXX[end if] [line break]#5. Clean the Augean ʃtables. [if the score is greater than 4]XXX[end if] [line break]#6. ʃlay the ʃtymphalian Birds. [if the score is greater than 5]XXX[end if] [line break]#7. Capture the Cretan Bull. [if the score is greater than 6]XXX[end if] [line break]#8. ʃteal the Mares of Diomedes. [if the score is greater than 7]XXX[end if] [line break]#9. Obtain the girdle of Hippolyta. [if the score is greater than 8]XXX[end if] [line break]#10. Obtain the cattle of the monster Geryon.[no line break][if twelve-labors is false and the score is less than 10]' [1 as a footnote][end if][if the score is greater than 9] XXX[end if][run paragraph on][if twelve-labors is true and the score is less than 11][line break]#11. ʃteal an apple from the Garden of the Hesperides. [line break]#12. Capture and bring back Cerberus from the Underworld.' [line break][line break]You're beginning to suspect that your cousin doesn't really need any of these chores done...[line break][line break][else if the score is 11][line break]#11. ʃteal an apple from the Garden of the Hesperides. XXX [line break]#12. Capture and bring back Cerberus from the Underworld.' [line break][line break]You're beginning to suspect that your cousin doesn't really need any of these chores done.[line break][line break][else if the score is greater than 11][line break]#11. ʃteal an apple from the Garden of the Hesperides. XXX [line break]#12. Capture and bring back Cerberus from the Underworld. XXX' [line break][line break]All your tasks are complete! You should hurry back to Eurystheus and tell him you've finished. [line break][line break][else if initial-complete is false][line break][line break]What a peculiar set of chores. Apparently your cousin doesn't need any groceries or anything... [paragraph break][line break]Well anyway, time to get to work! You'd better do these in the order they're written or else you'll give yourself a panic attack. You get very anxious when things are out of order.[line break][else][no line break][quotation mark][line break][line break]All your tasks are complete! You should hurry back to Eurystheus and tell him you've finished. He'll be so proud...[line break][line break][end if]".
	

		
Before going south from Tiryns:
	if the score is less than 1:
		say "You feel a slight uptick in your anxiety before going in this direction, almost as if you're not sure you're going the right way, but nonetheless venture off to...";
	else:
		continue the action.
		
Before going east from Lerna:
	if the score is less than 1:
		say "You feel a slight uptick in your anxiety before going in this direction, almost as if you're not sure you're going the right way, but nonetheless venture off to...";
	else:
		continue the action.
		
Before going northwest from Nemea:
	if the score is less than 2:
		say "You feel a slight uptick in your anxiety before going in this direction, almost as if you're not sure you're going the right way, but nonetheless venture off to...";
	else:
		continue the action.
		
Before going northwest from Stymphalia:
	if the score is less than 2:
		say "You feel a slight uptick in your anxiety before going in this direction, almost as if you're not sure you're going the right way, but nonetheless venture off to...";
	else:
		continue the action.
		
Before going northeast from Mount Erymanthos:
	if the score is less than 2:
		say "You feel a slight uptick in your anxiety before going in this direction, almost as if you're not sure you're going the right way, but nonetheless venture off to...";
	else:
		continue the action.	
		
Before going west from Stymphalia:
	if the score is less than 3:
		say "You feel a slight uptick in your anxiety before going in this direction, almost as if you're not sure you're going the right way, but nonetheless venture off to...";
	else:
		continue the action.
		
Before going southwest from Keryneia:
	if the score is less than 3:
		say "You feel a slight uptick in your anxiety before going in this direction, almost as if you're not sure you're going the right way, but nonetheless venture off to...";
	else:
		continue the action.
		
Before going northeast from Elis:
	if the score is less than 3:
		say "You feel a slight uptick in your anxiety before going in this direction, almost as if you're not sure you're going the right way, but nonetheless venture off to...";
	else:
		continue the action.
		
Before going west from Elis:
	if the score is less than 4:
		say "You feel a slight uptick in your anxiety before going in this direction, almost as if you're not sure you're going the right way, but nonetheless venture off to...";
	else:
		continue the action.
		
Before going northeast from Stymphalia:
	if the score is less than 7:
		say "You feel a slight uptick in your anxiety before going in this direction, almost as if you're not sure you're going the right way, but nonetheless venture off to...";
	else:
		continue the action.
		
Before going east from the Peloponnesian Shore:
	if the score is less than 8:
		say "You feel a slight uptick in your anxiety before going in this direction, almost as if you're not sure you're going the right way, but nonetheless venture off to...";
	else:
		continue the action.

Main Road is a room. "You are on a plain dirt road leading east to the land of Tiryns, where your cousin Eurystheus serves as king."

The plain road is a backdrop. The plain road is in the Main Road. The description of the plain road is "Just a plain dirt road travelling from east to west."

The dirt is a backdrop. The dirt is in the Main Road. The description of the dirt is "Just some dirt on a plain dirt road."

Instead of taking the dirt:
	say "No, you already have enough of it caked on the bottom of your shoes."

Hercules's House is west of the Main Road. "If you've somehow got yourself back here without messing with the source code for this game, something is seriously wrong and I apologize profusely. The main road is to the east and I suggest you go back that way and continue with your adventure."

Instead of going west from the Main Road:
	say "[if Benadryl-seen is true]You briefly consider making a run	back to your place to grab the inhaler, but decide against it. Your cousin is counting on you! Besides, the Gods would probably take it as a sign of weakness if you back-track now after coming so far on your adventure.[else]That way lies your house, but you have a funny feeling you won't be going back there for quite some time. At least, not in the course of this game.[end if]".
	
Understand the commands "attack" and "destroy" and "kill" and "murder" and "hit" and "thump" and "break" and "smash" and "torture" and "wreck" and "cut" and "slice" and "stab" and "skewer" and "hurt" and "slash" and "chop" and "burn" and "slay" and "beat" and "crack" and "fight" as something new.

Attacking it with is an action applying to one visible thing and one carried thing. Understand "attack [something] with [something preferably held]" as attacking it with.

Understand the commands "destroy" and "kill" and "murder" and "hit" and "thump" and "break" and "smash" and "torture" and "wreck" and "cut" and "slice" and "stab" and "skewer" and "hurt" and "slash" and "chop" and "slay" and "beat" and "crack" and "fight" and "scratch" and "bludgeon" as "attack".

A tool is a kind of thing. 

Check attacking it with:
	If the second noun is not a tool:
		say "You can't attack something with that." instead;
	else if the second noun is the noun:
		say "You can't attack something with itself." instead;
	else if the noun is yourself:
		try dying instead;
	else:
		continue the action.		

Report attacking it with:
	say "With these muscles? Hah! That wouldn't do anything except trigger your asthma.".
	
Shaving it with is an action applying to two things. Understand "shave [something] with [something preferably held]" and "flay [something] with [something preferably held]" as shaving it with. 

Understand the command "skin" and "peel" as "shave".

Does the player mean shaving something with the knife:
	it is very likely.
	
Does the player mean shaving something with the lion pelt:
	it is very likely.
	
Check shaving it with:
	If the second noun is not sharp:
		say "You can't shave something with that." instead;
	else if the second noun is the noun:
		say "You can't shave something with itself." instead;
	else if the noun is yourself:
		say "No, you can't sadly. You've never been able to grow even a whisker of beard." instead;
	else if the noun is a person:
		say "Easier said than done. It's very doubtful [the noun] will let you." instead;
	else:
		continue the action.
		
Report shaving it with:
	say "That can't be shaven. (Or is it shorn? Anyway, it can't be shorn either.)"
	
Tiryns is east of the Main Road. "You are in the glorious kingdom where your cousin serves as ruler! The [palaces] on the east edge of town (including the palace of your cousin, the king) are all magnificently ornate, but [the townsfolk] milling about you don't seem very happy; in fact they all seem downright depressed. Must be a case of the Mondays.[paragraph break]You can just glimpse the edges of the grasslands of Nemea to the north and the marshes of Lerna to the south. You can also visit the city palace of Tiryns to the east, or go back down the main road to the west."

Understand "palace" as the palaces.

The palaces are a backdrop. The palaces are in Tiryns and the City Palace. The description of the palaces is "They're all magnificently ornate, but your cousin Eurystheus's palace stands alone in terms of both height and opulence. Which makes sense you suppose, since he is the king after all."

Instead of entering the palaces:
	If the player is in Tiryns:
		try going east instead;
	else:
		say "You're already in the City Palace!"

Instead of examining the palaces:
	if the player is in the City Palace:
		try looking instead;
	else:
		continue the action.

The townsfolk are people in Tiryns. "Some townsfolk are milling about here, and seem to be generally avoiding the palaces on the east edge of town." The townsfolk are plural-named. The description of the townsfolk is "Everyone's brow is furrowed... it reminds you of the terrible headaches you used to get on chariot rides. A good double-dose of aspirin should do the trick."

Tirynsland is a backdrop. Tirynsland is in Tiryns and the Main Road and Nemea and the City Palace and Lerna. Understand "Tiryns" and "kingdom" as Tirynsland. 

Instead of examining Tirynsland:
	if the player is in Tiryns:
		try looking instead;
	else:
		say "You can't see the kingdom from [if the player is in the City Palace]inside[else]here[end if]. You'll have to go [if the player is in the City Palace]west[else if the player is in Nemea]south[else if the player is in Lerna]north[else]east[end if] to see it."

Check asking the townsfolk about anything:
	say "The townsfolk are unsettled by strangers['] questions and hurry off down the road at a faster pace." instead.
	
Check telling the townsfolk about anything:
	say "The townsfolk are unsettled by strangers['] declarations and hurry off down the road at a faster pace." instead.
	
Check giving anything to the townsfolk:
	say "The townsfolk are unsettled by strangers['] gifts and hurry off down the road at a faster pace." instead.
	
Check showing anything to the townsfolk:
	say "The townsfolk are unsettled by strangers['] presentations and hurry off down the road at a faster pace." instead.

The City Palace is east of Tiryns. "This magnificent building serves as the place of government for all of Tiryns. Although it's one of the prettier buildings you've ever seen, you can't help feeling a slight cold chill whenever you enter it, an almost ghostly air.[paragraph break]The only exit you can see is to the west." Eurystheus is a person in the City Palace. "Your cousin Eurystheus is here, wearing a [large pointy crown] and sitting on a [large gray-metal velvet-inlaid throne].". The large gray-metal velvet-inlaid throne is scenery in the City Palace. Understand "chair" and "massive chair" as the large gray-metal velvet-inlaid throne. Eurystheus wears the large pointy crown. 

The description of the large gray-metal velvet-inlaid throne is "Just your average, run-of-the-mill large gray-metal velvet-inlaid throne. You don't see anything very special about it."

The mis-aligned tile is scenery in the City Palace. Understand "floor" and "trap door" and "trapdoor" and "tiling" and "piece of tiling" as the mis-aligned tile.

Instead of opening the mis-aligned tile:
	try going down instead.

Instead of examining the mis-aligned tile:
	try going down instead.

The description of the large pointy crown is "It's clearly somewhat heavy, made of gold and rubies, and extends into three sharp points. Your cousin wears it well."

The description of Eurystheus is "Your cousin's eyes gleam with yellow malice, his long fingers are steepled and glitter with silver rings, his black pointed goatee drips with oil, and there is a softly menacing chuckle emanating from his lips, as if he's waiting for just the right moment to pounce for blood. [line break][line break]What a good-natured guy! You hope he'll be pleased with your performance on his list. If you do well enough he might even recommend you to father!"

The silver rings are undescribed things. The silver rings are plural-named. Eurystheus wears the silver rings. Understand "ring" as the silver rings. 
	
The description of the silver rings is "You can't make out the inscriptions or determine the metal of any of them, but they look cold and sharp. Not your style, but your cousin wears them well."

Understand "kiss [something]" and "make out with [something]" as kissing.

Instead of kissing the silver rings:
	say "You don't have much dignity but you have more dignity than that."

Check asking Eurystheus about anything:
	say "Your cousin chuckles sneeringly at your inane question." instead.
	
Check telling Eurystheus about anything:
	say "Your cousin chuckles sneeringly at your inane statement." instead.
	
Check giving anything to Eurystheus:
	say "Your cousin chuckles sneeringly at your inane offer." instead.
	
Check showing anything to Eurystheus:
	say "Your cousin chuckles sneeringly at your inane display." instead.
	
Check throwing something at something:
	say "No, it's rude to pointlessly throw things." instead.
	
Instead of entering the large gray-metal velvet-inlaid throne:
	say "Are you the King of Tiryns? No, I thought not."
	
Understand "cousin" and "king" and "King Eurystheus" and "goatee" as Eurystheus.

Looking behind is an action applying to one thing. Understand "look behind [something]" and "look around [something]" and "peek behind [something]" and  "peek around [something]" as looking behind.

Check looking behind:
	say "You don't see the point of doing that." instead.
	
Instead of looking behind the large gray-metal velvet-inlaid throne:
	say "Eurystheus's advisors seem to have gone for now."
	
A person can be friendly or hostile or beastly. A person is usually hostile. The cow and the Cretan Bull are friendly. The carnivorous horses, Cerberus, the feral pig, the hydra, Ladon, the lion, the Minotaur, and the Stymphalian birds are beastly.
	
Check touching someone:
	if the noun is friendly:
		say "You pet [the noun]. It scratches its belly in its sleep and purrs softly." instead;
	else if the noun is the Stymphalian birds:
		try taking the Stymphalian birds instead;
	else if the noun is beastly:
		say "Do you WANT to get eaten?" instead;
	else if the noun is yourself:
		say "Restrain yourself, this is a family game." instead;
	else:
		say "No, you'd better not. It might be taken the wrong way." instead.
		
		

Chapter 2 - The Nemean Lion

The gun is a tool. The gun is nowhere. Understand "shoot [something] with [gun]" as attacking it with. Understand "revolver" and "toy gun" and "toy" and "handgun" and "firearm" and "black" as the gun.

Shooting is an action applying to one thing. Understand "shoot [something]" as shooting.

Check shooting:
	if the noun is the gun and the player carries the gun:
		say "[if gun-attacked is false]Shooting randomly at nothing would be a great way to get yourself killed quickly.[else]You already tried to shoot the gun. All it got you was this nifty flag.[line break]" instead;
	else:
		if the player carries the gun:
			try attacking the noun with the gun instead;
		else:
			say "You're not carrying anything you can shoot with![line break]" instead.

The description of the gun is "[if gun-attacked is true]The toy still looks like a[else]A[end if] simple black revolver, as far as you can tell.[if gun-attacked is true][paragraph break]Clearly you don't really know your firearms.[end if]"

Shooting it at is an action applying to two things. 

Understand "shoot [something] at [something]" as shooting it at.

Check shooting it at:
	if the noun is not the gun:
		say "You can't shoot with that.";
	else:
		try attacking the second noun with the noun instead.

Lion Preparation is a scene. Lion Preparation begins when the player is in City Palace for the first turn. 

When Lion Preparation begins:
	say "Your cousin's eyes gleam wickedly as you enter. 'Ho, cousin! Have you started on that list I gave you? Not... too difficult for you, is it?' He gives an evil chuckle and his advisors, invisible behind the massive chair, chuckle sycophantically along with him. 'Well, perhaps I can give you some assistance to get started. You can have my old gun if you like. I should warn you though, it's not very... predictable.' His advisors bellow with laughter. He thrusts a small handgun at your feet. You pick it up.";
	now the player carries the gun.

Nemea is north of Tiryns. "The [wild grasslands] of Nemea are a common tourist site for explorers and adventurers alike. Mainly because of the lions. [paragraph break]From here you can go northwest towards the cursed land of Stymphalia, west to the city of Elis, or back to Tiryns to the south.[if the lion is nowhere][else if the lion is in Nemea and lion-bottle is false][paragraph break]Speaking of lions, there's a great mangy [lion] here now, watching you warily and growling softly.[else][paragraph break]Speaking of lions, there's a great mangy [lion] here now, sleeping like a baby and snoring like a power drill.[end if]" 

The wild grasslands are a backdrop. The wild grasslands are in Nemea and Elis and Tiryns. The description of the wild grasslands is "[if the player is in Elis]You can only make out a short line of yellow grass, you'll have to go east to see more.[else if the player is in Tiryns]You can only make out a short line of yellow grass, you'll have to go north to see more.[else]Just a large grassland full of yellow grass, almost like a savannah.[end if]" 

Instead of taking the wild grasslands:
	say "No, you don't think you should be spending your time picking grass right now.".

Understand "grassland" and "grass" and "grasses" and "grass lands" and "grass land" and "yellow" and "yellow grass" and "Nemea" as the wild grasslands.

The lion is a person in Nemea. "A great mangy lion is here,[if lion-bottle is false] watching you warily and growling softly.[else] sleeping like a baby and snoring like a power drill.[end if]". Understand "Nemean lion" as the lion.

The skin is a wearable thing. The fur is a wearable thing. The lion wears the skin. The lion wears the fur. The skin is undescribed. The fur is undescribed. The description of the fur is "The lion sports a long coat of yellow hair.". Understand "coat" and "hair" and "lion's fur" as the fur. The description of the skin is "The lion's skin hangs a bit loose on its torso, but it still looks ferocious.". Understand "lion's skin" and "hide" and "lion's hide" as the skin.

Instead of attacking the skin with the knife:
	try shaving the lion with the knife instead.
	
Instead of attacking the fur with the knife:
	try shaving the lion with the knife instead.
	
Instead of shaving the skin with the knife:
	try shaving the lion with the knife instead.
	
Instead of shaving the fur with the knife:
	try shaving the lion with the knife instead.

Check giving anything to the lion:
	if lion-bottle is true:
		say "Shh! The lion sleeps tonight!" instead;
	else:
		say "The lion roars a mighty roar of refusal and you quail in fright." instead.
		
Check telling the lion about anything:
	if lion-bottle is true:
		say "Shh! The lion sleeps tonight!" instead;
	else:
		say "The lion roars a mighty roar of understanding and you quail in fright." instead.
		
Check asking the lion about anything:
	if lion-bottle is true:
		say "Shh! The lion sleeps tonight!" instead;
	else:
		say "The lion answers by roaring a mighty roar and you quail in fright." instead.
		
Check showing anything to the lion:
	if lion-bottle is true:
		say "Shh! The lion sleeps tonight!" instead;
	else:
		say "The lion roars a mighty roar of interest and you quail in fright." instead.

The description of the lion is "The Nemean lion is a wild and ferocious beast, capable of striking terror into the heart of the bravest warrior.[if lion-bottle is true] Or it would be capable of that if it were awake, which it's not.[else] And you're not even that.[end if]"

A thing can be sharp or dull. A thing is usually dull.

The knife is a sharp tool in Nemea. "There is also a knife strewn on the ground here, probably a remnant from the last poor soul who tried to defeat this beast." 

Understand "plastic" and "plastic knife" as the knife.

The description of the knife is "Plastic. Great."

The flag is a thing. The flag is nowhere. The description of the flag is "A large white flag made of sterilized cloth fabric with the word 'BANG' written on it in zany cartoon letters.[if the score is greater than 5] It looks beaten and bedraggled, like it's seen better days.[end if]".

The flag is wearable.

Lion-bottle is a truth state that varies. Lion-bottle is false. 

Instead of giving the bottle of Benadryl to the lion:
	if lion-bottle is false:
		say "You shake out a few pills and offer them to the lion, who snatches them up with glee and wolfs them down. After a few minutes, the lion yawns, showing his massive teeth, and falls to the ground in a deep slumber.[line break]";
		now lion-bottle is true;
		now the lion is friendly;
	else:
		say "From the beast's great snores it seems like he's had enough.".

Gun-attacked is a truth state that varies. Gun-attacked is false.

Instead of attacking anything with the gun:
	If the noun is not the gun:
		If gun-attacked is false:
			say "You pull the trigger of your gun and a large flag with the word 'BANG' written on it in zany cartoon letters pops out and falls to the ground.[if the location is the City Palace][line break]Eurystheus and his advisors are positively howling with laughter. Your cousin nearly falls off the throne as tears of joy stream down his face.[end if]";
			now the flag is in the location;
			now gun-attacked is true;
		else:
			say "You already tried to shoot the gun. All it got you was this nifty flag.";
	else:
		continue the action.
			
After wearing the flag:
	say "You tie the flag behind your ears and wear it like a makeshift mask.".
	
Check attacking the lion with a tool:
	if lion-bottle is false:
		say "With these muscles? Hah! That wouldn't do anything except trigger your asthma. Besides, any time you try to wave [the second noun] threateningly at the beast, it gives a mighty roar and you quail with fright." instead;
	else:
		continue the action.
		
Instead of shaving the lion with the knife:
	if the player wears the flag and lion-bottle is true:
		say "You tighten the flag tied behind your ears in preparation and then ready your plastic knife. Scraping it back and forth along the lion's hide while keeping your nose covered with your makeshift mask to prevent you sneezing, you manage to extract the entire fur pelt from the lion's sleeping body. The silly-looking naked lion begins shivering a little in the cold. You take off its claws with the knife as well and attach them to your new garment. It is now sure to prove useful for completing your list items. You give it one last satisfied look and sweep it on. (Fur side out so you don't start sneezing.) At the sweeping sound, the lion wakes slightly, but seeing its own skin bearing down on it, it gives a quick yelp and runs back into the grasslands, never to be seen again. You discard the toy gun and the dull knife, both tools having fulfilled their purpose.[line break][line break][italic type]Author's Note: to attack something while wearing the lion pelt in the future, type 'Attack SOMETHING with the lion pelt' or 'Attack SOMETHING with claws'[Roman type][line break]";
		increase the score by 1;
		now the lion is nowhere;
		now the knife is in the lost-and-found box;
		now the gun is in the lost-and-found box;
		now the player is wearing the lion pelt;
		follow the notify score changes rule;
		try requesting the score;
	else if lion-bottle is true:
		say "You don't have the strength to stab into the beast, but you begin to shave off the sleeping lion's hide with your knife. Suddenly you are overcome with a hurricane of sneezes. It seems you are allergic to the lion's fur! Unless you can find a way to keep its hair from tickling your nose, you'll never be able to skin it.";
	else:
		continue the action.
		
Instead of attacking the lion with the knife:
	if lion-bottle is false:
		continue the action;
	else if the player wears the flag:
		say "With these muscles? Hah! Even while the beast is sleeping you don't have the strength to stab into the lion with the knife. As you consider it though, you notice that the lion's fur is a bit overgrown and its skin seems to be hanging loose on its torso. It could use a haircut.";
	else:
		say "With these muscles? Hah! Even while the beast is sleeping you don't have the strength to stab into the lion with the knife. As you consider it though, you notice that the lion's fur is a bit overgrown and its skin seems to be hanging loose on its torso. It could use a haircut.".
	
The lion pelt is a sharp tool. The lion pelt is wearable. The lion pelt is nowhere. Understand "claws" as the lion pelt. Understand "lion skin" and "skin" and "lion's skin" and "lion's fur" and "fur" and "claw" and "lion fur" and "sweatshirt" and "gloves"  as the lion pelt.	

The description of the lion pelt is "A thick lion's skin which you've fashioned into a kind of oversized, hooded sweatshirt-glove combo, with the mane being the hood. You've managed to extract the claws too and fastened them to the fingers of the pelt's makeshift gloves.[paragraph break]The garment is a bit hot while being worn and loose hairs makes your nose itch constantly, but you figure its benefits outweigh its costs for the moment."

Instead of attacking something with the lion pelt:
	if the player is not wearing the lion pelt:
		say "You have to be wearing the lion pelt to attack with it.[line break]";
	else:
		continue the action.
		
Instead of pushing something:
	if the noun is in Thrace:
		if Diomedes is in Thrace:
			say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
		else:
			continue the action;
	else if the noun is a person:
		say "No, that would be very rude indeed. You're not a barbarian!";
	else:
		say "With these muscles? Hah! That wouldn't do anything except trigger your asthma.".
		
Instead of pushing the lion:
	if lion-bottle is true:
		try waking the lion instead;
	else:
		continue the action.	
	
test lion with "e/ e/ w/ n/ give benadryl to lion/ take knife/ shoot lion/ take flag/ wear flag/ shave lion"

Understand the commands "stroke" and "pet" and "tap" as "touch".


Chapter 3 - The Lernean Hydra

Lerna is south of Tiryns. "You are in the land of marshes and wildflowers, commonly known by residents as Lerna. [paragraph break]To the east is the famous lake of the same name, and residence of the fabled Lernean Hydra, the monster that can't be spliced! You can also go back north to Tiryns or to the [shorelines] to the west and southeast." The box of matches is a tool in Lerna. "Hey your box of matches is here! You were wondering where you left them. [2 as a footnote]"

The shorelines are a backdrop. The shorelines are in Lerna and the Peloponnesian Shore and the Western Shore and Amazonia and the Garden of the Hesperides. Understand "shoreline" and "shore" as the shorelines. 

Instead of examining the shorelines:
	if the player is in the Peloponnesian Shore or the player is in the Western Shore:
		try looking instead;
	else:
		say "You can't see the shoreline from here. You'll have to go [if the player is in the Lerna]west or southeast[else if the player is in Amazonia]west[else]east[end if] to see it."

The description of the box of matches is "It's just a small red matchbook with some matches inside. Small writing on the box says 'made with love and care by the Cyclopes of [italic type]Hephaestus, Inc[Roman type].'"

Understand "match" and "matchbook" and "matchbox" and "match box" and "match book" as the box of matches.

Burning it with is an action applying to two things. Understand "burn [something] with [something]" as burning it with.

Does the player mean burning something with the box of matches:
	it is very likely.

Check burning it with:
	if the second noun is the box of matches:
		try attacking the noun with the box of matches instead;
	else:
		say "You can't burn something with that." instead.

Understand the command "light" as something new. 

Lighting is an action applying to one thing. Understand "light [something]" and "strike [something]" as lighting.

Check lighting:
	If the noun is not the box of matches:
		say "You can't light that." instead;
	else:
		say "No, you can see pretty well thanks to your spectacles and the bright sun of Greece. IF you were to try anything with the box of matches right now (and that's a big if), you'd try to burn things with it." instead.
		
Carry out lighting:
	say "You light [the noun]."

Check attacking something with the box of matches:
	if the noun is the box of matches:
		continue the action;
	else if the noun is yourself:
		try dying instead;
	else if the noun is a person:
		say "No... you're afraid of fire, so you like to avoid it if at all possible. Besides, you're definitely clumsy enough to miss [the noun] and burn yourself instead!" instead;
	else:
		say "No... you're afraid of fire, so you like to avoid it if at all possible." instead.
	
Instead of attacking the flag with the box of matches:
	say "No... but maybe if it was an American flag. Your fear of fire is no match for the fire in the hearts of all people who wish to see the workers of the world rise up and seize the means of production from their oppressors."

Lake Lerna is east of Lerna. "This is a beautiful, clear, [expansive lake] in the middle of the marshes, quite the scenic overlook. The only way from here is back west to Lerna proper." Iolaus is a person in Lake Lerna. Understand "blonde dreadlocks" and "dreadlocks" and "tattoos" and "tattoo" and "leaf" and "marijuana leaf" and "marijuana" as Iolaus. "You can see your troublemaking, skater nephew Iolaus here, grinning stupidly." The hydra is a neuter person in Lake Lerna. "This stunning view is only slightly marred by the largest, most terrifying monster you've ever seen in your life, the Lernean Hydra, emerging from the center of the lake." 

The knit cap is an undescribed wearable thing. Iolaus wears the knit cap. The description of the knit cap is "You shudder to think what devices of destruction might be lying underneath that knit cap."

The toxic-looking purple goo is a thing. The indefinite article is "some". The toxic-looking purple goo is nowhere. 

The marshes are a backdrop. The marshes are in Lerna and Lake Lerna and Tiryns. The description of the marshes is "Pretty wildflowers and swampy, mossy algae [if the player is in Tiryns]can be seen just on the edge of the southern horizon.[else]dot these marshy lands.[end if]". Understand "wildflowers" and "algae" and "flowers" and "flower" and "marsh" and "swamp" and "moss" and "Lerna" as the marshes.

Instead of taking the marshes:
	say "No, you don't want any marshy plant-life, it would soak your trousers and you'd probably be allergic to it anyways."

Understand "monster" and "lizard" and "heads" and "necks" as the hydra.

The expansive lake is scenery in Lake Lerna. Understand "water" and "Lake Lerna" as the expansive lake.

Instead of entering the expansive lake:
	try swimming instead.

Instead of drinking the expansive lake:
	say "It tastes all right, actually, but has a slightly gooey consistency that puts you off."
	
Instead of tasting the expansive lake:
	try drinking the expansive lake instead.

The description of the expansive lake is "The bluest water you've ever seen."

The description of Iolaus is "Your slacker nephew. He perfectly fits the stereotype of a skater dude, complete with blonde dreadlocks, knit cap, several tattoos (one of a marijuana leaf), and the inability to perform tricks on his skateboard. His two true passions that you've surmised are blowing things up and lighting things on fire.[if Iolaus carries something][paragraph break]Iolaus is carrying [a list of things carried by Iolaus].[end if]"

Understand "nephew" and "skater" and "slacker" as Iolaus.

Does the player mean giving something to Iolaus:
	it is very likely.
	
Does the player mean showing something to Iolaus:
	it is very likely.
	
Does the player mean asking Iolaus about something:
	it is very likely.
	
Does the player mean asking Iolaus for something:
	it is very likely.
	
Does the player mean telling Iolaus about something:
	it is very likely.

The description of the hydra is "It's almost impossible to describe. A nightmarish, gooey purple lizard with 5ft fangs and a swirling mass of multiple heads and necks. Larger than physics would think possible. And it's staring right at you.[paragraph break]Seven of the monster's heads notice you ogling it and let out a chorus of tortured, screeching cries. You nearly pass out from fear.".

Instead of giving the box of matches to Iolaus:
	say "Iolaus takes them eagerly, a manic glint in his eyes.";
	now Iolaus carries the box of matches.
	
Check asking Iolaus about anything:
	say "Iolaus grins at you stupidly and says 'Whatever, man. Got anything I can blow up?'" instead.
	
Check telling Iolaus about anything:
	say "Iolaus nods at you as you tell your tale but you can soon start to see his eyes glazing over. His fingers twitch as if searching for the trigger of a bomb." instead.
	
Check showing anything to Iolaus:
	say "'Huh, does it blow anything up?'" instead.
	
Check giving anything to Iolaus:
	if the noun is the box of matches:
		continue the action;
	else:
		say "'Nah, thanks but no thanks Uncle Herc. Not dangerous enough for me.' And he gives you a sly smile." instead.
	
Instead of asking Iolaus about "the hydra":
	if the hydra is nowhere:
		say "'Man, that was siiiick, right Uncle Herc? Too bad it's dead though, would love to see what would happen if we stuck some dynamite in it.'";
	else:
		say "'Pretty gnarly, right Uncle Herc? It'd be so sick to see that thing blown up.'".
		
Instead of asking Iolaus about "hydra":
	if the hydra is nowhere:
		say "'Man, that was siiiick, right Uncle Herc? Too bad it's dead though, would love to see what would happen if we stuck some dynamite in it.'";
	else:
		say "'Pretty gnarly, right Uncle Herc? It'd be so sick to see that thing blown up.'".
		
Instead of asking Iolaus about "monster":
	if the hydra is nowhere:
		say "'Man, that was siiiick, right Uncle Herc? Too bad it's dead though, would love to see what would happen if we stuck some dynamite in it.'";
	else:
		say "'Pretty gnarly, right Uncle Herc? It'd be so sick to see that thing blown up.'".

Check asking the hydra about anything:
	say "Five different heads let out a screeching cry and you wet yourself. Talking will get you nowhere." instead.
	
Check telling the hydra about anything:
	say "Five different heads let out a screeching cry and you wet yourself. Talking will get you nowhere." instead.
	
Check showing anything to the hydra:
	say "Five different heads let out a screeching cry and you wet yourself. Talking will get you nowhere." instead.
	
Check giving anything to the hydra:
	say "Five different heads let out a screeching cry and you wet yourself. Bartering will get you nowhere." instead.
	
Check attacking the hydra with a tool:
	say "With these muscles? The hydra is just squishy enough that you MIGHT be able to do it with the right weapon. But [the second noun] isn't one of those weapons. That would just make you asthmatic." instead.
	
Understand "puddle" and "ball" and "silly putty" and "poisonous" and "toxic" and "poison" and "slime" and "liquid" and "poisonous liquid" as the toxic-looking purple goo.

Instead of attacking the hydra with the lion pelt:
	If Iolaus carries the box of matches:
		say "You slash off the soft, gelatinous heads of the hydra with the claws on your lion pelt. Meanwhile, your crazy nephew bounces across to each head as soon as you sever it and burns the stumps so they can't grow back. [paragraph break]Soon all that remains of the hydra is a puddle of some toxic-looking purple goo.";
		now the hydra is nowhere;
		now the toxic-looking purple goo is in Lake Lerna;
		increase the score by 1;
		follow the notify score changes rule;
		try requesting the score;
	else if the player wears the lion pelt:
		say "Thankfully, the hydra's form is soft and gooey, so the sharp claws of your lion pelt are juuust strong enough to slash off a nearby head, despite your lack of muscles. After about 30 seconds, three more heads sprout from the stump and let out a screeching cry. Your knees turn to jelly.";
	else:
		continue the action.
		
Instead of taking the toxic-looking purple goo:
	If the player is wearing the lion pelt:
		say "You gingerly pick up the poisonous liquid in your pelt-covered arms. It sticks together like silly putty and is easy to carry around, but you'd better not get any of this on your skin.";
		continue the action;
	else:
		say "No way are you picking that up without wearing some kind of protective gear!".
		
test hydra with "s/ s/ take box/ e/ give box to Iolaus/ kill hydra with lion pelt/ take goo"

Instead of asking Iolaus about "[the box of matches]":
	if the hydra is nowhere and Iolaus carries the box of matches:
		say "Iolaus hesitates and then shrugs. 'I guess I don't need them anymore... take good care of them for me, Uncle Herc,' and with a slightly wistful look in his eyes, he hands back the matches.";
		now the player carries the box of matches;
	else if Iolaus carries the box of matches:
		say "He grins wickedly at you. 'I'm not giving them back yet. We got work to do, Uncle Herc.' He eyes the hydra hungrily.";
	else:
		say "Iolaus's eyes move longingly over to the box of matches. 'I know they're yours, but do you mind if I borrow them? You know how I love starting fires.'".
		
Instead of asking Iolaus for the box of matches:
	try asking Iolaus about "[the box of matches]" instead.

Instead of taking the box of matches:
	if Iolaus carries the box of matches:
		say "The box of matches appears to be loaned to Iolaus for now. You'll have to ask him for it if you want it back.";
	else:
		continue the action.
		
Instead of telling Iolaus about "[the box of matches]":
	say "'I know man, they're wicked cool. Do you know how many fires I could start with these?' His eyes glint with excitement.".

Instead of showing the box of matches to Iolaus:
	say "Iolaus's eyes move longingly over to the box of matches. 'I know they're yours, but do you mind if I borrow them? You know how I love starting fires.'".

The description of the toxic-looking purple goo is "[if the player carries the toxic-looking purple goo]A ball of poisonous purple goo, held together like silly putty. You're very careful not to get any of the goo on your bare skin.[else]Just a puddle of toxic-looking purple goo.[end if]"

Check touching the toxic-looking purple goo:
	if the player is not wearing the lion pelt:
		say "Not without some kind of protective covering." instead;
	else:
		continue the action.

Chapter 4 - The Ceryneian Hind

Keryneia is northwest of Stymphalia. "Keryneia is a holy land, a peaceful [woodland] filled with fresh wild air. They say that the fabled Ceryneian golden hind, blessed by Artemis herself, wanders these parts from time to time. The cursed land of Stymphalia lies to the southeast and the tip of Mount Erymanthos is visible to the southwest."

The woodland is a backdrop. The woodland is in Keryneia and Keryneia?. The description of the woodland is "Green and sunny and tranquil."

The golden hind is in Keryneia. "A golden hind prances beautifully through the woodland here.[first time] [3 as a footnote][only]". The golden hind is a woman. 

Instead of touching the golden hind:
	try taking the golden hind instead.
	
Instead of attacking the golden hind with anything:
	try punching the golden hind instead.
		
Instead of punching the golden hind:
	if the golden hind is in Keryneia:
		try taking the golden hind instead;
	else:
		continue the action.

Check asking the golden hind about anything:
	say "The deer gives no reply but continues traipsing silently across the lovely woodland." instead.
	
Check telling the golden hind about anything:
	say "The deer ignores you and continues traipsing silently across the lovely woodland." instead.
	
Check giving anything to the golden hind:
	say "The deer ignores your gift and continues traipsing silently across the lovely woodland." instead.
	
Check showing anything to the golden hind:
	say "The deer ignores you and continues traipsing silently across the lovely woodland." instead.

The description of the golden hind is "A silent, beautiful deer bathed in a calming golden light."

Understand "deer" and "light" and "stag" and "doe" and "golden deer" and "golden stag" and "golden doe" as the golden hind. 

Keryneia? is a room. "Is this Keryneia?... well, anyway, it's a holy land, a peaceful woodland filled with fresh wild air. They say that the fabled Ceryneian golden hind, blessed by Artemis herself, wanders these parts from time to time. The cursed land of Stymphalia lies to the southeast and the tip of Mount Erymanthos is visible to the southwest."

Understand "pinch [something]" and "poke [something]" as waking.

Instead of waking up when the player is in Keryneia?:
	say "You awake with a start. That was one of the strangest dreams you've ever had... if it really was a dream...";
	now the golden hind is in Keryneia;
	now the player is in Keryneia.

Instead of going in Keryneia?:
	say "You run a little ways in that direction but somehow remain back in the same place.".

The golden pendant is a thing. The golden pendant is nowhere. The description of the golden pendant is "Where did you get this from? You have no memory of receiving it from anyone... you examine the front of the jewel and notice a small 'A' engraved in black lettering. Then you examine the back and notice a small sticker: 'CAUTION: Made with specially Hephaestusized gold. DO NOT place near campfires, metal will absorb flames.'"

Instead of wearing the golden pendant:
	say "No, it's not your style. You're more into practical neckwear like flash drives and surgical braces."

Instead of taking the golden hind when the player is in Keryneia:
	say "It slips just out of your reach, as uncatchable as a dream."
	
Instead of sleeping when the player is in Keryneia:
	if the score is less than 2:
		say "You begin to drift off, entranced by the dance of the golden hind, but your increased levels of anxiety keep you stubbornly awake. You have a gnawing feeling you should be doing something else for now....";
	else if the score is greater than 2:
		continue the action;
	else:
		say "You drift off, entranced by the dance of the golden hind, and lay down for a quick nap...";
		now the golden hind is in Keryneia?;
		now the player is in Keryneia?.
	
Instead of taking the golden hind when the player is in Keryneia?:
	say "It slips just out of your reach at first. But then you speed up so that you are matching pace with the glorious beast, running faster than any human has gone before, without the slightest trace of asthma on your lips. And at long last you manage to lay a hand on a tuft of its golden fur. As you do, the beast is transformed, growing more and more humanoid until the goddess Artemis stands before you. 'You have done well, young hero,' she murmurs quietly, staring at your pimples with fascination as you gaze at her golden brilliance, agape. 'While you may not have the agility to catch my creature in reality, you may do so in the wild realm of your subconscious. Our reality is shaped by our dreams, our impossible ambitions. You'd do well to remember that, young hero. You have more power than you think.' And the next instant, you wake with a start. The golden hind is gone.";
	now the player is in Keryneia;
	now the golden hind is nowhere;
	now the player carries the golden pendant;
	now the feral pig is in Mount Erymanthos;
	increase the score by 1;
	follow the notify score changes rule;
	try requesting the score.
	
Understand the command "catch" as "take".
	
test hind with "w/ n/ n/ nw/ nw/ take hind/ sleep/ take hind"

Chasing is an action applying to one thing. Understand "chase [something]" and "run after [something]" or "follow [something]" as chasing.

Check chasing:
	if the noun is not a person:
		say "You can't chase that." instead;
	else if the noun is not the golden hind:
		say "You'd get too asthmatic to try something like that! Who do you think you are, some sort of track star?" instead;
	else:
		continue the action.
		
Report chasing:
	say "You attempt to run after the golden hind but it slips just out of your reach, as uncatchable as a dream."
	
Instead of chasing the golden hind:
	if the player is in Keryneia?:
		try taking the golden hind instead;
	else:
		continue the action.


Chapter 5 - The Erymanthian Boar

Mount Erymanthos is west of Stymphalia. "You manage to hike up Mount Erymanthos with much effort and gasping, despite it being really only a small hill.[if the score is less than 4] They say that somewhere up this snowy summit lies the Erymanthian boar, which no hunter has yet caught.[end if][paragraph break]To the northeast is a holy, glowing land, to the east is a dismal, cursed land, and to the southwest you can just make out the edge of the city of Elis." 

The holy glowing land is a backdrop. The holy glowing land is in Mount Erymanthos and Keryneia and Keryneia?. The dismal cursed land is a backdrop. The dismal cursed land is in Mount Erymanthos and Stymphalia. The description of the dismal cursed land is "It looks pretty dark and bleak, but you can't make out much of it from here.". The description of the holy glowing land is "It looks pretty peaceful and bright, but you can't make out much of it from here.". Understand "Keryneia" and "peaceful" as the holy glowing land. Understand "Stymphalia" and "gloomy" as the dismal cursed land.

Instead of examining the dismal cursed land:
	if the player is in Stymphalia:
		try looking instead;
	else:
		continue the action.
		
Instead of examining the holy glowing land:
	if the player is in Keryneia or the player is in Keryneia?:
		try looking instead;
	else:
		continue the action.

The cityscape is a backdrop. The cityscape is in Mount Erymanthos and Nemea and Elis. Understand "Elis" and "city" as the cityscape.

The description of the cityscape is "You can only see a few houses, you'll have to go [if the player is in Nemea]west[else]southwest[end if] to see more."

Instead of examining the cityscape:
	if the player is in Elis:
		try looking instead;
	else:
		continue the action.

The snow is scenery in Mount Erymanthos. The description of the snow is "There's just a little dusting of unusually icy, clean snow on the top of the summit, though it seems to be enough for animals to romp around in judging by the frenetic footprints.". Understand "flakes" and "snowbank" and "footprints" as the snow.

Instead of eating the snow:
	say "It does look unusually clean and icy cold, but it looks like animals have been running around in it, so you wouldn't chance it."
	
Instead of drinking the snow:
	say "It does look unusually clean and icy cold, but it looks like animals have been running around in it, so you wouldn't chance it."

Instead of taking the snow:
	say "No, you already have enough of it annoyingly soaking through your socks and shoes."

Understand "hill" as the mountain.

Mount Erymanthos is southwest of Keryneia.

The feral pig is a person. The feral pig is in Mount Erymanthos. "A feral pig is squealing and romping around in the snow here." Understand "boar" and "Erymanthian boar" and "Erymanthian" and "erymanthian" and "horns" and "horn" as the feral pig.

Instead of touching the feral pig:
	try taking the feral pig instead.

Instead of taking the feral pig:
	say "You dive at the feral pig but it squeals and bolts out of your grasp at the last second. Stubborn little critter."

Check asking the feral pig about anything:
	say "The pig ignores you and continues to run around squealing and romping in the snow." instead.
	
Check telling the feral pig about anything:
	say "The pig ignores you and continues to run around squealing and romping in the snow." instead.
	
Check showing anything to the feral pig:
	if the noun is the flag:
		try throwing the flag at the feral pig instead;
	else:
		say "The pig ignores you and continues to run around squealing and romping in the snow." instead.
	
Check giving anything to the feral pig:
	say "The pig ignores you and continues to run around squealing and romping in the snow." instead.

The description of the feral pig is "It's a bit smaller and cleverer than you've heard in stories, but this must be the Erymanthian Boar. It's ugly and fast and has sharp horns at the top of its head, almost like a bull's. What a strange creature."

Understand "wave [something] at [something]" as throwing it at.

The frozen ham is a thing. The frozen ham is nowhere. The description of the frozen ham is "Essentially it's just a small hunk of dead pig encased in a giant ice cube, but 'frozen ham' is a good, semi-descriptive shorthand for it. The water that forms the ice cube looks like it'd be pretty refreshing in liquid form, a beverage to cleanse the soul even."

Understand "pig" and "dead pig" and "hunk" and "ice cube" and "ice" and "cube" and "water" and "ice water" and "cleansing" and "meat" as the frozen ham.

Instead of eating the frozen ham:
	say "It's not really the kind of ham you get at the grocery store, it's just a small hunk of dead pig encased in a giant ice cube."
	
Instead of smelling the frozen ham:
	say "It does not smell appetizing."
	
Instead of drinking the frozen ham:
	say "It's in ice form right now. Besides, the cleansing water has been tainted with the hunk of dead pig, so you probably wouldn't drink it even if it were a liquid."

Instead of throwing the flag at the feral pig:
	if the player is wearing the flag:
		say "You'll need to take it off first.";
	else if the score is less than 3:
		say "You hold the flag on its side and prepare to wave it at the boar like a toreador, but your increased levels of anxiety cause your hands to start shaking and you drop the flag instead. You have a gnawing feeling you should be doing something else for now....";
		now the flag is in Mount Erymanthos;
	else:
		say "You wave the flag at the boar and it starts to get angry. It rushes at the flag but you make sure to stand to the side as it plows into the one frigid snowbank behind you. The pig squeals for a few minutes and then goes silent. You watch as it stiffens while the minutes go by, until all that's left of it is a frozen ham.";
		now the feral pig is nowhere;
		now the frozen ham is in Mount Erymanthos;
		increase the score by 1;
		follow the notify score changes rule;
		try requesting the score.
		
Check throwing the flag at anything:
	say "Waving the white flag of surrender already, are you?" instead.
	
test boar with "sw/ take off flag/ throw flag at feral pig"

Every turn:
	if the player is in Mount Erymanthos and the feral pig is in Mount Erymanthos:
		let pig romp be a random number between 1 and 3;
		if pig romp is 3:
			say "The pig oinks, kicks up some snow with its hooves, and charges at the white snowdust clouds with glee, obsessed with the crystalline flakes.".
	 

Chapter 6 - The Augean Stables

Elis is west of Nemea. "This bustling land is full of [merchants] hawking their wares and haggling over prices.[paragraph break]To the east you can just make out the edge of the Nemean [grasslands] on the horizon, west lie the city stables. A [mountain] looms to the northeast, and the [isle] Erytheia lies to the northwest, across the [ocean]." Elis is southwest of Mount Erymanthos. 

The isle is a backdrop. The isle is in Elis and Erytheia. Understand "island" and "shore" and "shoreline" and "Erytheia" as the isle. 

Instead of examining the isle:
	if the player is in Erytheia:
		try looking instead;
	else:
		say "You can't see the isle from here. You'll have to take a ferry due northwest to see it."

The stables are a backdrop. The stables are in Elis. Understand "Augean" and "Augean stables" and "stable" as the stables. 

Instead of examining the stables:
	say "You can't make out very much of the stables from here, they're a ways off to the west.".

The ocean is a backdrop. Understand "water" and "sea" and "salty" and "salty sea" and "salty ocean" and "blue-green" as the ocean. The ocean is in Elis and Erytheia and the Peloponnesian Shore and the Western Shore and Crete. The description of the ocean is "[if the player is in the Western Shore]Slightly more tumultuous than most of the ocean waters on beaches nearby.[else]Calm and gentle as far as oceans go, at least on this beach.[end if] The water is a rich blue-green."

Instead of entering the ocean:
	try swimming instead.

Instead of drinking the ocean:
	say "Yuck, too salty!" instead.
	
Instead of tasting the ocean:
	try drinking the ocean instead.

The mountain is a backdrop. The mountain is in Elis and Mount Erymanthos and Stymphalia and Keryneia. The description of the mountain is "It's really not much more than a large hill, but for you, any slight incline seems mountainous." 

Instead of climbing the mountain:
	say "Or you could just walk towards it."

The merchants are people in Elis. "Some merchants are hawking their wares here." The merchants are plural-named. The description of the merchants is "Everyone is yelling different prices and pulling at various foodstuff and metalwork and vases, you can hardly keep track of all the merchants['] hustle and bustle. It's making you a bit dizzy just looking at them. [paragraph break]The only pattern you notice is that they all seem to be [if stables-clean is false]avoiding[else]gravitating towards[end if] the stables to the west."

The wares are scenery in Elis. Understand "vases" and "vase" and "metalwork" and "foodstuff" as the wares. 

Check taking the wares:
	try asking the merchants about "wares" instead.
	
Check touching the wares:
	try taking the wares instead.
	
Check buying the wares:
	try taking the wares instead.
	
Check examining the wares:
	try examining the merchants instead.

Check asking the merchants about anything:
	say "You'd rather not get trampled within the crowds of the marketplace." instead.
	
Check telling the merchants about anything:
	say "You'd rather not get trampled within the crowds of the marketplace." instead.
	
Check giving anything to the merchants:
	say "You'd rather not get trampled within the crowds of the marketplace." instead.
	
Check showing anything to the merchants:
	say "You'd rather not get trampled within the crowds of the marketplace." instead.

Before going northwest in Elis:
	if the score is less than 9:
		say "You get a spike of anxiety, as though you're unsure you should be sailing in this direction, but the ride is fairly short and the symptoms are just manageable enough for you to book passage on a ferry headed for...";
	else:
		say "You quash your fears of seasickness and book passage on a ferry headed for...".

The Augean Stables is west of Elis. "[if stables-clean is false]This is, without a doubt, the grossest place you've ever been in. Shit is everywhere. Literally. [paragraph break]Chittering like shit-covered demons are the famed [carnivorous horses] that reside in these stables, but thankfully the layers of feces are so thick they can't get to you. [paragraph break]The mountains of manure are clearly mostly composed of horse dung, but you also smell the unmistakable stench of human dung, giant dung, crab dung, any kind of dung you can possibly imagine. And that's not even mentioning the snot, the fertilizer, the spittoons, and the dead bodies. Anything gross you can think of is present here, covered in [shit]. Thankfully, there is an exit, back east to the city center.[else]This is, without a doubt, the most beautiful place you've ever been in. Sparkles are everywhere. Literally. [paragraph break]Chittering like smooth, seductive demons are the famed [carnivorous horses] that reside in these stables, thankfully held fast by strong, twinkling rainbow chains.[paragraph break]The gleaming finished wood of the walls and stable doors is the most eye-catching part of the room, but you can also see many other beautifully arranged [sparkling amenities], such as gorgeous satin and leather saddles, shining hair polish, marble floors, and impeccable riding gear. And that's not even mentioning the decorations, the polished stone, the gilded tapestries, and the silver ornaments. Anything beautiful you can think of is present here, covered in diamonds. The only exit is back east to the city."

Instead of inserting the frozen ham into the shit:
	say "No, it won't clean anything while it's just one large block of ice."
	
Instead of putting the frozen ham on the shit:
	try inserting the frozen ham into the shit instead.
	
Report dropping the frozen ham when the player is in the Augean Stables:
	say "Dropped, but it won't clean anything while it's just one large block of ice."

Instead of smelling the shit:
	say "You nearly pass out. What were you thinking?"
	
Instead of eating the shit:
	say "You'd rather die."
	
Instead of entering the shit:
	try eating the shit instead.
	
Instead of touching the shit:
	try taking the shit.
	
Instead of tasting the shit:
	try eating the shit.
	
Instead of rubbing the shit:
	try taking the shit.
	
Dying is an action applying to nothing. Understand "die" and "end it" and "end it all" and "end me" and "pass out" and "faint" as dying.

Carry out dying:
	say "Tempting, but you fight the urge."

The description of the shit is "The horror! The horror!".

The description of the mop is "The mop is already damp with a little water and soap. A sticker on the side of the mop reads 'MAGIMOP™ courtesy of [italic type]Hephaestus, Inc[Roman type]. With this one-of-a-kind Replenisher model, you'll never need a bucket again! (Note: Hephaestus, Inc is not responsible for any accidentally soaked or damaged property.)'"

Instead of drinking the mop:
	say "Grosss!!"
	
Drying is an action applying to one thing. Understand "dry [something]" and "dust [something]" as drying.

Check drying:
	say "You don't know where your towel is." instead.
	
Instead of drying the ocean:
	if the player carries the mop:
		try cleaning the ocean with the mop instead;
	else:
		say "Even if you had a towel or a magical mop, you couldn't dry up an entire body of water!"
		
Instead of drying the expansive lake:
	if the player carries the mop:
		try cleaning the expansive lake with the mop instead;
	else:
		say "Even if you had a towel or a magical mop, you couldn't dry up an entire body of water!"
		
Instead of drying the river Styx:
	if the player carries the mop:
		try cleaning the river Styx with the mop instead;
	else:
		say "Even if you had a towel or a magical mop, you couldn't dry up an entire body of water!"
		
Instead of drying the mop:
	say "Impossible, it's magically self-replenishing!"
	
Instead of inserting something into the ocean:
	say "And watch it get washed away forever? No thanks."
	
Instead of inserting something into the river Styx:
	say "And watch it get washed away forever? No thanks."
	
Instead of inserting something into the expansive lake:
	say "And watch it get washed away forever? No thanks."

Some carnivorous horses are people in the Augean Stables. The description of the carnivorous horses is "As you stare at them, they immediately begin to chitter up to you and gnash their teeth. You drop back quickly, hyperventilating. You think it's probably best to avoid these creatures."

Check asking the carnivorous horses about anything:
	say "As you attempt to approach the beasts, they immediately begin to chitter up to you and gnash their teeth. You drop back quickly, hyperventilating. You think it's probably best to avoid these creatures." instead.
	
Check telling the carnivorous horses about anything:
	say "As you attempt to approach the beasts, they immediately begin to chitter up to you and gnash their teeth. You drop back quickly, hyperventilating. You think it's probably best to avoid these creatures." instead.
	
Check giving anything to the carnivorous horses:
	say "As you attempt to approach the beasts, they immediately begin to chitter up to you and gnash their teeth. You drop back quickly, hyperventilating. You think it's probably best to avoid these creatures." instead.
	
Check showing anything to the carnivorous horses:
	say "As you attempt to approach the beasts, they immediately begin to chitter up to you and gnash their teeth. You drop back quickly, hyperventilating. You think it's probably best to avoid these creatures." instead.

The shit is a thing in the Augean Stables. "An absolutely massive pile of shit is here, covering practically everything." Understand "poop" and "feces" and "manure" and "caca" and "layers" and "poo" and "dung" and "fertilizer" and "droppings" and "turds" and "crap" and "snot" and "dead bodies" and "dead body" and "spittoons" and "spittoon" and "stables" and "doorframe" and "shelf" and "floor" and "floors" and "wall" and "walls" and "stable" and "mountain" and "mountains" and "doorway" as the shit.

Does the player mean cleaning the stables with something:
	it is very unlikely.
	
Does the player mean cleaning something with the mop:
	it is very likely.

Instead of taking the shit:
	say "Gross... no, you're way too germaphobic to try to do this with your hands. You'd never be able to wash out the smell, let alone the actual substance."

The hammer is a tool. The hammer is in the Augean Stables. "The corner of a [hammer] is peaking out from a high shelf above the massive piles of poop. It's just barely in reach."

The description of the hammer is "A medium-sized hammer. It probably gives you a slight bonus to your bludgeoning damage, but considering your noodly arms, probably not more than a +0.5."

The mop is a thing in the Augean Stables. "There is a [mop] hanging outside the doorframe." A thing can be soapy or dry. A thing is usually dry. The mop is soapy. Understand "magimop" and "replenisher" and "soap" as the mop.

Understand the command "clean" as something new.

Cleaning it with is an action applying to two things. Understand "clean [something] with [something]" as cleaning it with. Understand the command "wipe" as something new. Understand the commands "wipe" and "wash" as "clean".

Understand "hands" and "hand" and "limbs" as yourself. 

Check cleaning it with:
	if the second noun is yourself:
		say "You don't think you'd get very far using only your hands." instead;
	else if the second noun is dry:
		say "You can't clean with that!" instead;
	else if the noun is shit:
		say "Futile. Utterly, completely futile. You'd probably pass out from the effort." instead;
	else if the noun is the carnivorous horses:
		if stables-clean is true:
			say "They don't need to be cleaned." instead;
		else:
			say "Futile. Utterly, completely futile. You'd probably pass out from the effort." instead;
	else:
		say "[if the noun is plural-named]They don't need to be cleaned.[else]That doesn't need to be cleaned.[end if]" instead.
		
Carry out cleaning it with:
	say "[if the noun is plural-named]They don't need to be cleaned.[else]That doesn't need to be cleaned.[end if]".
	
Instead of cleaning the dead Stymphalian birds with the mop:
	say "You clean up the disgusting bird carcasses with the mop, leaving the cursed forest floor clean once again. As you work, you notice the grass underneath the mess has shifted to spell out a message: [paragraph break]'Don't feed the trolls, clean the trolls! Visit the island of Crete, to the west south and east. Advertisement brought to you by the unionized janitorial Cyclopes of [italic type]Hephaestus, Inc.[Roman type]'[paragraph break]Then, as soon as you manage to read the message, it disappears. How strange.";
	now the dead Stymphalian birds are nowhere.
	
Instead of cleaning the hammock with the mop:
	if the score is greater than 5:
		say "You scrub the hammock with the mop and remove some of the dried goo stains and bird feathers, leaving it slightly less bedraggled.";
	else:
		continue the action.
		
Instead of cleaning the flag with the mop:
	if the score is greater than 5:
		say "You scrub the flag with the mop and remove some of the dried goo stains and bird feathers, leaving it slightly less bedraggled.";
	else:
		continue the action.
	
Mop-joke is a truth state that varies. Mop-joke is false.
	
Instead of cleaning the ocean with the mop:
	say "You dry up the ocean completely with your mop!";
	now mop-joke is true.
	
Instead of cleaning the river Styx with the mop:
	say "You dry up the river Styx completely with your mop!";
	now mop-joke is true.
	
Instead of cleaning the expansive lake with the mop:
	say "You dry up the expansive lake completely with your mop!";
	now mop-joke is true.
	
Mop Punchline is a recurring scene. Mop Punchline begins when mop-joke is true for 3 turns.

When Mop Punchline begins:
	say "Fooled you, didn't I? You can't mop a body of water, silly!";
	now mop-joke is false.
	
Mop Punchline ends when mop-joke is false.

Instead of attacking the mop with a tool:
	say "There'd be no sense breaking your mop unless you wanted to create a wooden stake. But there's no need for such a weapon - you're not Buffy Summers!".
	
Instead of attacking something with the mop:
	if the noun is the shit or the noun is the dead Stymphalian birds or the noun is the caved-in rocks or the noun is the deep scratches:
		try cleaning the noun with the mop instead;
	else if the noun is the carnivorous horses:
		if stables-clean is true:
			say "As you attempt to approach the beasts, they immediately begin to chitter up to you and gnash their teeth. You drop back quickly, hyperventilating. You think it's probably best to avoid these creatures." instead;
		else:
			try cleaning the noun with the mop instead;
	else if the noun is the golden hind:
		try taking the golden hind instead;
	else if the noun is the lion and lion-bottle is true:
		say "[The noun] receive[if the noun is plural-named][else]s[end if] a violent bath.[if the noun is a person] [They] [are] now very annoyed. Or at least, [they] would be if [they] were awake, which [they're] not.[end if]";
	else if the noun is Hippolyta and hippolyta-unconscious is true:
		say "[The noun] receive[if the noun is plural-named][else]s[end if] a violent bath.[if the noun is a person] [They] [are] now very annoyed. Or at least, [they] would be if [they] were conscious, which [they're] not.[end if]";
	else if the noun is yourself:
		say "You receive a violent bath, but fail to off yourself with the mop.";
	else:
		say "[The noun] receive[if the noun is plural-named][else]s[end if] a violent bath.[if the noun is a person] [They] [are] now very annoyed.[end if]"
	
Mopping is an action applying to one thing. Understand "mop [something]" as mopping.

Check mopping:
	if the player carries the mop:
		try cleaning the noun with the mop instead;
	else:
		say "You don't have a mop!" instead.
		
Hammering is an action applying to one thing. Understand "hammer [something]" as hammering.

Check hammering:
	if the player carries the hammer:
		try attacking the noun with the hammer instead;
	else:
		say "You don't have a hammer!" instead.

The strip of bacon is an edible thing. "A strip of bacon is here, lying sadly in front of the doorway." The strip of bacon is nowhere. The description of the strip of bacon is "A single slice of fried pig meat is all that's left of the Erymanthian boar.". Understand "fried" and "meat" as the strip of bacon.

Instead of smelling the strip of bacon:
	say "It smells rather alluring, like great fried meat always does."

Instead of eating the strip of bacon:
	say "It does smell rather alluring, but you're on a low-acid diet so you can't partake." 

Stables-clean is a truth state that varies. Stables-clean is false.

Some sparkling amenities are things. "The whole stable glitters with cleanliness and sparkling amenities." The sparkling amenities are nowhere. Understand "rainbow chains", "stables", "stable", "chains", "satin saddles", "leather saddles", "saddles", "shining hair polish", "hair polish", "polish", "marble floors", "marble", "satin", "rainbow", "leather", "shining", "sparkles", "impeccable riding gear", "riding", "gear", "impeccable", "riding gear", "decorations", "polished stone", "polished", "stone", "gilded tapestries", "gilded", "tapestries", "diamonds", "silver", "ornaments", "stable amenities", "doorframe", "shelf", "finished wood", "wood", and "silver ornaments" and "floor" and "floors" and "wall" and "walls" and "diamond" and "doorway" as the sparkling amenities.

Digging is an action applying to nothing. Understand "dig" as digging.

Check digging:
	if the player is in the Augean Stables and stables-clean is false:
		say "Gross... no, you're way too germaphobic to try to do this with your hands. You'd never be able to wash out the smell, let alone the actual substance." instead.
		
Report digging:
	say "The ground is too hard here, and you don't have a shovel."

Instead of swinging the hammer:
	if the player carries the hammer:
		say "You give it a whirl, trip over your two left feet, and fall down[if the player is in the Augean Stables], right into the pile of shit. Gross!![line break][else]. Ugh.[line break][end if][line break]You quickly return to your feet.";
	else:
		say "You don't have that."

Instead of taking the sparkling amenities:
	say "Better leave all these stable amenities be, you don't want to mess anything up."
	
The description of the sparkling amenities is "Absolutely gorgeous!".
	
Instead of attacking the frozen ham with the box of matches:
	if the player is in the Augean Stables:
		say "You're on the right track, but you can't quickly melt something that big, you'll have to break it into chunks somehow first.";
	else:
		say "Not here! All that would give you is some wet, dripping frozen ham."

Instead of attacking the frozen ham with the hammer:
	if the player is in the Augean Stables and the player carries the box of matches and the score is 4:
		say "You hammer the ice cube surrounding the ham. Soon, ice covers the floor of the stables and you are left with a rather cold ham, which the carnivorous horses soon distract themselves with. You flare up a match and flick it onto the icy floor. The ice begins to rapidly melt until the whole room is flooded. (It was a really large ice cube.) You open the door, and the water floods out, leaving the room sparkling clean. Your hammer and box of matches were washed away by the water, and all that's left of the ham is a small strip of bacon lying sadly in front of the doorway.";
		now the frozen ham is in the lost-and-found box;
		now the shit is nowhere;
		now the sparkling amenities are in the Augean Stables;
		now the matches are in the lost-and-found box;
		now the hammer is in the lost-and-found box;
		now stables-clean is true;
		now the strip of bacon is in the Augean Stables;
		increase the score by 1;
		follow the notify score changes rule;
		try requesting the score;
	else if the player is in the Augean Stables and the score is 4:
		say "You're on the right track, but you're going to need some heat to melt the ice once it's in pieces across the room.";
	else:
		say "Not here! All that would give you is some pieces of ice ham.".

test stables with "take frozen ham/ e/ se/ s/ s/ e/ ask Iolaus about the box of matches/ w/ n/ n/ nw/ w/ sw/ w/ take hammer/ attack frozen ham with hammer"
  

Chapter 7 - The Stymphalian Birds

Stymphalia is northwest of Nemea. "This is a gloomy land full of only [forest trees] and the terrifying pterodactyl-like birds of prey known as the [if the Stymphalian birds are in Stymphalia]Stymphalian birds.[else if the dead Stymphalian birds are in Stymphalia]Stymphalian birds, who are currently lying dead in a heap on the forest floor.[else]Stymphalian birds, who are currently nowhere to be seen, thank the Gods.[end if] Many believe it to be a cursed place.[paragraph break]From here you can cross the forest and travel to the land of Thrace to the northeast, to the holy land of Keryneia to the northwest, or scale the [mountain] to the west. You can also go back to Nemea to the southeast." Some Stymphalian birds are people in Stymphalia. "The Stymphalian birds fly in an ominous circle above you, searching for suitable prey." Understand "bird" and "Stymphalian bird" as the Stymphalian birds. Some forest trees are fixed in place things in Stymphalia. "Some gloomy forest trees dot the landscape here." The description of the Stymphalian birds is "Terrifying, pterodactyl-like birds of prey. These are unmistakably the famed Stymphalian birds. Their teeth you're sure will give you nightmares for years...".

A thing can be first or last. A thing is usually last. The forest trees are first. 

Rule for choosing notable locale objects for Stymphalia:
	repeat with item running through first things in Stymphalia: 
		set the locale priority of the item to 1;
	repeat with item running through last things in Stymphalia: 
		set the locale priority of the item to 5.

Instead of dropping the strip of bacon:
	if the player is in Stymphalia:
		say "You drop the strip of bacon but quickly pick it up again after noticing the Stymphalian birds start to swoop down towards the alluring scent.";
	else:
		continue the action.

The description of the forest trees is "These tall, forboding trees are pretty much the only plant life in Stymphalia that you can see. Some of the ones nearest you have some low-hanging knobs. One could consider tying some decorations to the trees to try and make them more festive, but it'd probably be a lost cause.". 

Understand "affix [something] to [something]" as tying it to.

Understand "knobs" and "branches" and "tree" and "forest tree" and "knob" and "branch" as the forest trees.

Luring it with is an action applying to two things. Understand "lure [something] with [something]" as luring it with.

Carry out luring it with:
	Try giving the second noun to the noun instead.

Check asking some Stymphalian birds about anything:
	say "One of the birds squawks at you and its screech sounds like death. You cower before it and check to make sure your eardrum is still intact." instead.
	
Check telling some Stymphalian birds about anything:
	say "One of the birds looks at you quizzically and then squawks at you and its screech sounds like death. You cower before it and check to make sure your eardrum is still intact." instead.
	
Check showing anything to some Stymphalian birds:
	say "One of the birds squawks a refusal at you and its screech sounds like death. You cower before it and check to make sure your eardrum is still intact." instead.
	
Check giving anything to some Stymphalian birds:
	say "One of the birds squawks a refusal at you and its screech sounds like death. You cower before it and check to make sure your eardrum is still intact." instead.
	
Instead of giving the strip of bacon to some Stymphalian birds:
	say "If you just handed the strip of bacon to the birds, they'd swoop down and bite your hands off, and then probably eat you too! Maybe you could try to catch them in some sort of makeshift snare?"
	
Instead of showing the strip of bacon to some Stymphalian birds:
	say "If you just handed the strip of bacon to the birds, they'd swoop down and bite your hands off, and then probably eat you too! Maybe you could try to catch them in some sort of makeshift snare?"

The hammock is an open unopenable enterable container. "A hammock is here, tied to two of the gloomy trees. The hammock contains [a list of things in the hammock]." The hammock is fixed in place. The hammock is nowhere. The description of the hammock is "A large white flag tied to the knobs of two trees.[if the score is greater than 5] It looks beaten and bedraggled, like it's seen better days.[end if]"

Understand "flag" as the hammock.

Check putting something on the hammock:
	try inserting the noun into the hammock instead.

Instead of entering the hammock:
	say "Ah yes, because your idea of a perfect afternoon is lounging in a cursed forest[if the Stymphalian birds are in Stymphalia] beneath a swarm of violent sharp-toothed birds. [else if the dead Stymphalian birds are in Stymphalia] amidst a pile of blood-soaked goo-covered bird carcasses. [else] in the cold, beneath some gnarled, forboding trees. [end if]Just the thought of that horror makes you reach for your inhaler. You really should have remembered to bring it with you..."

Instead of climbing the forest trees:
	say "No WAY. You're far too afraid of heights, and clumsy enough that you're liable to slip and break your neck."

Instead of taking the hammock:
	try untying the hammock instead.

A thing can be stringy or stiff. A thing is usually stiff. The hammock is stringy. 

Untying is an action applying to one thing. Understand "untie [something]" as untying.

Check untying:
	If the noun is stiff:
		say "That's not tied to anything at the moment." instead;
	else:
		continue the action.
		
Carry out untying:
	say "You untie [the noun] and pocket it.";
	now the player carries the noun.

Instead of untying the hammock:
	say "You untie the hammock from the forest trees[if something is inside the hammock], take out the contents,[end if] and pocket the flag once more.";
	now the player carries everything inside the hammock;
	now the hammock is nowhere;
	now the player carries the flag.

Instead of tying the flag to the forest trees:
	say "You tie the flag to the knobs of two trees, creating a nice little hammock.";
	now the flag is nowhere;
	now the hammock is in Stymphalia.
	
Instead of putting the flag on the forest trees:
	try tying the flag to the forest trees.
	
Instead of inserting the Stymphalian birds into the hammock:
	say "They're flying too high. You're going to have to lure them down with something."
	
Instead of taking the Stymphalian birds:
	say "They're flying too high. You're going to have to lure them down with something."
	
Instead of attacking the Stymphalian birds with anything:
	say "They're flying too high. You're going to have to lure them down with something.".
	
Instead of inserting the toxic-looking purple goo into the hammock:
	if the player is wearing the lion pelt:
		continue the action;
	else:
		say "You're going to need some protective covering in order to do that.".
		
Some dead Stymphalian birds are some things. "The dead Stymphalian birds on the ground are beginning to rot." The description of the dead Stymphalian birds is "Gross... the blood-soaked, goo-covered bird carcasses are decomposing. You'd better stay clear of them." The dead Stymphalian birds are nowhere.
	
Instead of inserting the strip of bacon into the hammock:
	if the toxic-looking purple goo is in the hammock and the player is wearing the lion pelt:
		say "You smother the bacon in the toxic-looking purple goo, carefully protecting your hands with the edge of the hammock. The birds seem to sense the food even from their height, and their wicked eyes glow scarlet. As a flock, they dive downwards and crash into the hammock, gobbling up the bacon that lies within. One by one they begin to choke and sputter and their faces turn the same color as the goo. Eventually you are left with a tattered, rumpled hammock surrounded by dead Stymphalian birds.";
		now the toxic-looking purple goo is in the lost-and-found box;
		now the strip of bacon is in the lost-and-found box;
		now some Stymphalian birds are nowhere;
		now the dead Stymphalian birds are in Stymphalia;
		increase the score by 1;
		follow the notify score changes rule;
		try requesting the score;
	else if the toxic-looking purple goo is in the hammock:
		say "You can't risk touching the goo with your bare hands!";
	else:
		say "Then they'd just swoop down, eat the bacon, and leave. And you'd be down one strip of bacon and up zero Stymphalian birds.".
		
Instead of taking the dead Stymphalian birds:
	say "Picking up blood-soaked, goo-covered bird carcasses is where you hope anyone would draw the line sanitarily speaking, even if they weren't a massive germaphobe like yourself."
		
test stymphalia with "take bacon/ e/ ne/ e/ tie flag to trees/ put goo in hammock/ put bacon in hammock"

Check putting the toxic-looking purple goo on anything:
	say "You don't see the point in poisoning [those]." instead.
	
Poisoning is an action applying to one thing. Understand "poison [something]" as poisoning.

Check poisoning:
	if the player does not carry the toxic-looking purple goo:
		say "You aren't carrying any poison!" instead.
		
Carry out poisoning:
	try putting the toxic-looking purple goo on the noun instead.

Instead of putting the toxic-looking purple goo on the strip of bacon:
	if the player is in Stymphalia:
		say "No, that would just make a mess of things. The goo would go all over the place, and enough of the mixture might get on your hands that the birds would swoop down and chew your fingers off! It'd be ideal if you had a separate container to mix them in.";
	else:
		continue the action.
		
Instead of putting the strip of bacon on the toxic-looking purple goo:
	if the player is in Stymphalia:
		if the toxic-looking purple goo is in the hammock:
			try inserting the strip of bacon into the hammock instead;
		else:
			say "No, that would just make a mess of things. The goo would go all over the place, and enough of the mixture might get on your hands that the birds would swoop down and chew your fingers off! It'd be ideal if you had a separate container to mix them in.";
	else:
		continue the action.

can't put onto what's not a supporter rule response (A) is "There'll be time to fiddle around with your possessions later - you have work to do!".

Chapter 8 - The Cretan Bull

Riding is an action applying to one thing. Understand "ride [something]" as riding.

Check riding:
	if the noun is not a person:
		say "You can only do that to something that moves -- this isn't a Disney cartoon!" instead;
	else if the noun is vegetarian:
		say "Something tells you that you should restrain yourself from attempting to ride [the noun]." instead;
	else:
		continue the action.
		
Report riding:
	say "You could probably mount the beast if you really wanted to (albeit with a lot of effort and panting), but the poor thing would probably just collapse from exhaustion if you tried. It really is a pitiful creature."
	
Instead of entering a person:
	try riding the noun instead.
		
The Peloponnesian Shore is southeast of Lerna. "You have reached the southern shore of Greece, a [sand]-covered land with [rocky shoals] near the ocean. Ferries come and go to the island of Crete to the southeast, or you can journey east to the closely-guarded [jungles] of the Amazons. You can also head back to Lerna to the northwest."

The jungles are a backdrop. The jungles are in the Peloponnesian Shore and Amazonia. Understand "jungle" and "greenery" and "creatures" and "wild creatures" and "wild" and "Amazonia" as the jungles. The description of the jungles is "Lush greenery and wild creatures can be seen [if the player is in Amazonia]here[else]in that direction[end if], all protected of course by the Amazon warriors, the bravest soldiers in all of Greece."

The rocky shoals are scenery in the Peloponnesian Shore. Understand "rock" and "rocks" and "hard rocks" and "classic rocks" and "classic" and "hard" as the rocky shoals. The description of the rocky shoals is "They're not hard rocks, more like classic rocks."

The ferries are a backdrop. The ferries are in Crete and the Peloponnesian Shore and Elis and Erytheia. Understand "ship" and "ships" and "boats" and "boat" and "ferries" and "ferry" as the ferries. The description of the ferries is "There are a few ferries here that seem out-of-commission for now and one ferry that is docked and boarding.".

The island is a backdrop. The island is in Crete and the Peloponnesian Shore. Understand "Crete" and "isle" as the island.

Instead of examining the island:
	if the player is in Crete:
		try looking instead;
	else:
		say "You can't see Crete from here. You'll have to take a ferry southeast to see it."

Instead of riding the ferries:
	try entering the ferries instead.
	
Instead of taking the ferries:
	try entering the ferries instead.

Instead of entering the ferries:
	if the player is in Crete or the player is in Elis:
		try going northwest instead;
	else:
		try going southeast instead

The sand is a backdrop. Understand "coarse sand" and "coarse" as the sand. The sand is in the Peloponnesian Shore and the Western Shore and Crete. The description of the sand is "It's just sand."

Instead of taking the sand:
	say "No, you already have enough of it annoyingly caught within your socks and shoes."

Crete is southeast of the Peloponnesian Shore. "This is a lovely little beach, with lush [grass farmlands] and [sandy dunes] coming together in harmony. You've heard there's a wild labyrinth to the west or you can go back to the mainland to the northwest.". 

The grass farmlands are a backdrop in Crete. The description of the grass farmlands is "The rolling hills are positively idyllic! It's as though they were sculpted by a wizard casting ancient magical spells.". The sandy dunes are a backdrop in Crete. The description of the sandy dunes is "The pristine beaches are positively idyllic! It's as though they were sculpted by a wizard casting ancient magical spells.".

The Cretan Bull is a portable person. The indefinite article of the Cretan Bull is "the". Understand "cataracts" as the Cretan Bull. The description of the Cretan Bull is "A very dull-eyed, plodding creature with cataracts in its eyes from age. You doubt this one will be chasing flags again anytime soon. You pet it briefly and it barely registers your fingers." The Cretan Bull is in Lab3.

The lost-and-found box is a fixed in place container in Lab3. The lost-and-found box is open and unopenable. Understand "large box" and "blue box" and "large blue box" and "large" and "blue" as the lost-and-found box.

Instead of searching the lost-and-found box:
	let L be the list of things in the lost-and-found box;
	sort L in random order;
	say "In the lost-and-found box [if the lost-and-found box contains less than two things]is[else]are[end if] [if the lost-and-found box contains nothing]nothing[else][L with indefinite articles]."
	
Instead of examining the lost-and-found box:
	let L be the list of things in the lost-and-found box;
	sort L in random order;
	say "It's very large, heavy, blue, and made of metal. Small lettering on the side of the box reads:[line break][line break][italic type]LABYRINTH LOST-AND-FOUND BOX[line break]Courtesy of Hephaestus, Inc, now a proud member of the Frobozz Corporation.[Roman type][paragraph break]In the lost-and-found box [if the lost-and-found box contains less than two things]is[else]are[end if] [if the lost-and-found box contains nothing]nothing[else][L with indefinite articles][end if].".

The map is in the lost-and-found box. The description of the map is "The map keeps changing, but right now it appears to be a very detailed map of the faraway land of [one of]Narnia[or]Middle Earth[or]Earthsea[or]Westeros[or]Azeroth[or]Discworld[or]Oz[or]Fillory[or]Hyrule[or]Prydain[or]Orisha[or]Asgard[or]Amber[or]Tatooine[or]Vulcan[at random]."

The compass is in the lost-and-found box. The description of the compass is "You have no paper that you need to draw circles on, so you can't imagine this will be of much use to you."

The free T-shirt is a wearable thing in the lost-and-found box. The description of the free T-shirt is "A plain white tee with gold and brown lettering. The front of the shirt reads 'I visited the Labyrinth of Crete and got out alive!' The back has a few dried bloodstains dotting the plain white cotton.". Understand "tee" and "shirt" as the free T-shirt.

The GPS tracking device is a thing in the lost-and-found box. The description of the GPS tracking device is "It's out of batteries, so it won't be of much use to you."

The movie reel is a thing in the lost-and-found box. The description of the movie reel is "It's an original copy of Tod Browning's [italic type]London After Midnight[Roman type]."

The parachute is a thing in the lost-and-found box. The description of the parachute is "It's an old parachute with the name 'D. B. Cooper' stitched on the side, along with a picture of famous movie director Tommy Wiseau.".

The broken phaser is a thing in the lost-and-found box. The description of the broken phaser is "It's a blaster like the ones used on [italic type]Star Trek[Roman type], but it doesn't seem to fire. A small sticker on the side reads 'Property of Area 51'."

The old coin of Hades is a thing in the lost-and-found box. The description of the old coin of Hades is "An ancient coin from the Underworld, made of onyx."

Some red rolled-up string is a thing in the lost-and-found box. The description of some red rolled-up string is "A small piece of red thread, all rolled up in a swirl." Understand "thread" as the red rolled-up string. The indefinite article of the red rolled-up string is "some".

Minotaur-string is a truth state that varies. Minotaur-string is false.

Before going to Lab5:
	if the player carries the red rolled-up string:
		say "[first time]As you make your way in that direction, you notice that the red rolled-up string pulses slightly and turns a duller shade of red. You hear a very faint dial-up tone... perhaps the extensive maze has taken its toll on the magical thread.[only]";
		now minotaur-string is true.

Unrolling is an action applying to one thing. Understand "unroll [something preferably held]" and "unwind [something preferably held]" as unrolling.

Check unrolling:
	if the noun is not the red rolled-up string:
		say "That doesn't need to be unrolled." instead.
		

		
After going from Lab3 for the first time:
	try looking;
	say "Outstanding. Just what every text adventure needs. Another fucking maze.".
		
Carry out unrolling:
	if the player is in Lab3:
		say "You unwind a little bit of the red string, and it suddenly comes to life! It wriggles its little body animatedly towards the [if minotaur-string is true]east[else]south[end if] before rolling itself back up again.";
	else if the player is in Lab1:
		say "You unwind a little bit of the red string, and it suddenly comes to life! It wriggles its little body animatedly towards the [if minotaur-string is true]south[else]east[end if] before rolling itself back up again.";
	else if the player is in the Troll Room:
		say "You unwind a little bit of the red string, and it suddenly comes to life! It wriggles its little body animatedly towards the bloodstains and deep scratches in a 'wax on/ wax off' motion before rolling itself back up again.";
	else if the player is in Lab2:
		say "You unwind a little bit of the red string, and it suddenly comes to life! It wriggles its little body animatedly [if minotaur-string is true]towards the west[else]upwards[end if] before rolling itself back up again.";
	else if the player is in Lab4:
		say "You unwind a little bit of the red string, and it suddenly comes to life! It wriggles its little body animatedly [if minotaur-string is true]upwards[else]towards the west[end if] before rolling itself back up again.";
	else if the player is in Lab5:
		say "You unwind a little bit of the red string, and it suddenly comes to life! Its little body goes haywire, and it wriggles first to the southwest, north, east, and finally southwest before rolling itself back up again.";
	else if the player is in Lab6:
		say "You unwind a little bit of the red string, and it suddenly comes to life! Its little body goes haywire, and it wriggles first upwards, downwards, west, and finally east before rolling itself back up again.";
	else if the player is in Lab7:
		say "You unwind a little bit of the red string, and it suddenly comes to life! Its little body goes haywire, and it wriggles first to the west, east, upwards, and finally south before rolling itself back up again.";
	else if the player is in Lab8:
		say "You unwind a little bit of the red string, and it suddenly comes to life! Its little body goes haywire, and it wriggles first to the southeast, west, northwest, and finally northeast before rolling itself back up again.";
	else if the player is in Lab9:
		say "You unwind a little bit of the red string, and it suddenly comes to life! Its little body goes haywire, and it wriggles first to the west, south, southwest, and finally southeast before rolling itself back up again.";
	else if the player is in Lab10:
		say "You unwind a little bit of the red string, and it suddenly comes to life! Its little body goes haywire, and it wriggles first to the south, northwest, southwest, and finally west before rolling itself back up again.";
	else if the player is in Lab11:
		say "You unwind a little bit of the red string, and it suddenly comes to life! Its little body goes haywire, and it wriggles first downwards, south, southwest, and finally north before rolling itself back up again.";
	else if the player is in Lab12:
		say "You unwind a little bit of the red string, and it suddenly comes to life! Its little body goes haywire, and it wriggles first to the west, south, southwest, and finally east before rolling itself back up again.";
	else if the player is in Lab13:
		say "You unwind a little bit of the red string, and it suddenly comes to life! Its little body goes haywire, and it wriggles first upwards, south, southwest, and finally east before rolling itself back up again.";
	else if the player is in Lab14:
		say "You unwind a little bit of the red string, and it suddenly comes to life! Its little body goes haywire, and it wriggles first southwest, east, north, and finally downwards before rolling itself back up again.";
	else if the player is in Lab15:
		say "You unwind a little bit of the red string, and it suddenly comes to life! Its little body goes haywire, and it wriggles first northeast, east, north, and finally northwest before rolling itself back up again.";
	else:
		say "You unwind a little bit of the red string, and it suddenly comes to life! Its little body does a vibrant dance to the tune of 'Stayin['] Alive' before rolling itself back up again."

Before going west from Crete for the first time:
	if the player does not carry the mop:
		now the mop is in the lost-and-found box.

Rule for printing the name of the lost-and-found box while not inserting or removing or examining:
	say "lost-and-found box";
	omit contents in listing.

Understand "pet [person]" as touching.

Instead of throwing the flag at the Cretan Bull:
	say "Nothing. Not even a blink. This is one sorry old bull.".

Instead of touching the Cretan Bull:
	say "You pet the Cretan Bull. It barely registers your fingers and continues staring at nothing."

Check asking the Cretan Bull about anything:
	say "The mute bull ignores you." instead.
	
Check telling the Cretan Bull about anything:
	say "The mute bull ignores you." instead.
	
Check showing anything to the Cretan Bull:
	say "The mute bull ignores you." instead.
	
Check giving anything to the Cretan Bull:
	say "The mute bull ignores you." instead.

Instead of going southeast from the Peloponnesian Shore:
	If the score is less than 6:
		say "You step onto the dock where a ferry is boarding but are suddenly overcome with a nasty spike of anxiety and vertigo! The thought of being on a boat for that long when you don't even think you need to be heading in that direction just yet is unmanageable.";
	else:
		say "You quash your fears of seasickness, book a ticket on the ferry, and sail swiftly to...";
		continue the action.
		
Instead of going northwest from Crete:
	say "You quash your fears of seasickness, book a ticket on the ferry, and sail swiftly to...";
	continue the action.

Instead of taking the Cretan Bull for the first time:
	say "You take the rope attached to the dull-eyed bull and begin leading it along. That was easy.";
	increase the score by 1;
	follow the notify score changes rule;
	try requesting the score;
	now the player carries the Cretan Bull.
	
Check taking the Cretan Bull:
	if the player carries the Cretan Bull:
		say "You already have that.[line break]" instead;
	else:
		say "You take the rope attached to the dull-eyed bull and begin leading it along.[line break]";
		now the player carries the Cretan Bull;
		stop the action.
		
After dropping the Cretan Bull:
	say "You drop the rope attached to the dull-eyed bull and leave it be." 
			
test bull with "se/ s/ s/ se/ se/ w/ take bull"

A Labyrinth is a kind of room. The printed name of a Labyrinth is usually "Labyrinth". The description of a Labyrinth is usually "This is a Labyrinth of twisty little passages, all alike.". Lab1, Lab2, Lab3, Lab4, Lab5, Lab6, Lab7, Lab8, Lab9, Lab10, Lab11, Lab12, Lab13, Lab14, Lab15, and Lab16 are Labyrinths. 

A Dead End is a kind of room. The printed name of a Dead End is usually "Dead End". The description of a Dead End is usually "You have come to a dead end in the Labyrinth.". DE1, DE2, DE3, and DE4 are Dead Ends.

Lab3 is west of Crete. Nothing is west of Lab3. Lab1 is north of Lab1. Lab3 is south of Lab1. Nothing is north of Lab3. Lab4 is east of Lab3. Lab3 is west of Lab4. Lab2 is west of Lab1. The Troll Room is east of Lab1. Lab4 is west of Lab2. DE1 is east of Lab2. Lab2 is south of DE1. Nothing is west of DE1. Lab2 is down from Lab3. Lab1 is south of Lab3. Lab2 is north of Lab4. Nothing is east of Lab4. Lab5 is up from Lab4. The skeleton key is a thing in Lab5. The description of the skeleton key is "A large key with a skull and crossbones emblazoned on its face. There is a small inscription too (a poem?) written on the wide face of the key in strange lettering. It reads:[paragraph break][italic type]I shall tell you of a heX[line break]You cannot live without[line break]through storms and blizZards it was said[line break]by wiZards and bY scouts[Roman type]". DE2 is east of Lab5. Nothing is up from Lab5. Lab4 is north of Lab5. Nothing is south of Lab4. Lab6 is southwest of Lab5. Nothing is northeast of Lab6. Lab6 is west of Lab6. Lab7 is east of Lab6. Lab5 is down from Lab6. Lab8 is east of Lab7. Lab8 is west of Lab8. Lab7 is northeast of Lab8. Nothing is southwest of Lab7. DE3 is southeast of Lab8. Nothing is northwest of DE3. Lab8 is north of DE3. Lab9 is south of Lab7. "This is a maze of twisty little passages, all alike.[if the player carries the lion pelt or the player wears the lion pelt][paragraph break]Your lion's pelt claws begin to glow with a soft blue glow.[end if]". Nothing is north of Lab9. Lab7 is south of Lab9. Nothing is north of Lab7. Lab10 is west of Lab9. Nothing is east of Lab10. Lab7 is south of Lab10. Lab9 is west of Lab10. Lab10 is northwest of Lab10. Lab11 is up from Lab6. Lab6 is north of Lab11. Lab12 is south of Lab11. Nothing is north of Lab12. Lab15 is west of Lab12. Lab13 is south of Lab12. Lab11 is east of Lab12. Lab11 is east of Lab13. Nothing is north of Lab13. Lab15 is up from Lab13. Lab12 is northwest of Lab15. Lab15 is down from Lab11. Nothing is up from Lab15. Lab14 is west of Lab11. Lab13 is east of Lab11. Lab12 is east of Lab14. Lab5 is down from Lab14. Lab15 is southwest of Lab14. Lab11 is up from Lab14. DE4 is north of Lab14. 

Definition: A number is a scorer if the remainder after dividing it by 169 is 0. 

Zorkcount is a number that varies. Zorkcount is initially 0.

Google Zork Increment is a recurring scene. Google Zork Increment begins when the player carries the skeleton key and the player is in a labyrinth.

When Google Zork Increment begins:
	increment the zorkcount.
	
Google Zork is a recurring scene. Google Zork begins when the zorkcount is a scorer and the zorkcount is not 0. 

When Google Zork begins:
	say "Wandering around the Labyrinth for as long as you have, you are gripped with a sudden sense of ancient familiarity. You have a bizzare urge to 'googleimage zorkmaze1,' which is exceedingly odd, since you have no idea what either of those words mean.".

Definition: A number is triangular if the remainder after dividing it by 3 is 0.
			
Every turn when the player is in the Troll Room for the first turn:
	if the player carries the Cretan Bull:
		say "The Cretan Bull ambles up to the bloodstains and starts trying to lick them clean. You think you see the stains stir slightly, but then you blink and they're still.";
	else if the Cretan Bull is in the Troll Room:
		say "The Cretan Bull ambles up to the bloodstains and starts trying to lick them clean. You think you see the stains stir slightly, but then you blink and they're still.".
		
Instead of eating the deep scratches:
	say "That's not how you clean off bloodstains! Who are you, Edward Cullen?"
	
Instead of drinking the deep scratches:
	say "That's not how you clean off bloodstains! Who are you, Edward Cullen?"

The Troll Room is east of Lab1. "This is a small room with [caved-in rocks] blocking passages to the east and south. The only exit is a forbidding hole leading west. Bloodstains and [deep scratches] (perhaps made by an axe) mar the walls.". Some caved-in rocks are fixed in place things in the troll room. The description of the caved-in rocks is "The rocks are carved with a picture of a laughing man singing 'Trololololol!' How strange...".

Instead of cleaning the caved-in rocks with the mop:
	say "'Ow, ow!' the picture on the rock protests. 'Not me you idiot, I'm a carving, not a stain! I'm already as clean as can be!' You stop attempting to clean the caved-in rocks.".
	
Instead of cleaning the deep scratches with the mop:
	say "'Thank you for trying to clean off these walls. We appreciate your patronage,' the picture made by the scratches and stains exclaims with a smile. 'You've won the key to our hearts, which as always lies up above the west south and east. Have a nice day, courtesy of the unionized janitorial Cyclopes of [italic type]Hephaestus, Inc.[Roman type]' You stop attempting to clean the scratches and stains.".
	
Instead of cleaning the deep scratches with yourself:
	say "'Thank you for trying to clean off these walls. We appreciate your patronage,' the picture made by the scratches and stains exclaims with a smile. 'You've won the key to our hearts, which as always lies up above the west south and east. Have a nice day, courtesy of the unionized janitorial Cyclopes of [italic type]Hephaestus, Inc.[Roman type]' You stop attempting to clean the scratches and stains.".

The deep scratches are fixed in place things in the Troll Room. "Bloodstains and deep scratches mar the walls." Understand "bloodstains" and "blood" and "stains" and "stain" as the deep scratches. The description of the deep scratches is "The scratches and bloodstains form a picture of a laughing man singing 'Trololololol!' How strange...".

The Grating Room is northeast of Lab15. "You are in a small room near the Labyrinth. There are twisty passages in the immediate vicinity.[line break]Above you is a [grate] with a skull-and-crossbones lock." 


The skeleton key unlocks the grate. Understand "lock" and "skull" and "crossbones" and "skull and crossbones" as the grate. Understand "skull" and "crossbones" and "skull and crossbones" as the key.

The description of the grate is "It has a skull-and-crossbones lock on it."

The Minotaur's Room is southeast of Lab9. "You have come to the very center of the Labyrinth[if hole-created is true], at which lay a ferocious [Minotaur]. All that remains of the beast is the Minotaur-shaped hole in the eastern wall. There is an exit to the northwest, a small [grate] in the corner, and a stairway leading up. [else]. There is an exit to the northwest, a small [grate] in the corner, and a stairway leading up.[end if]". 

The Minotaur is a person in the Minotaur's Room. "The Minotaur is here, snarling and stamping its hooves." The description of the Minotaur is "Head of a bull, body of a man. The quintessential Greek monster. Wait, wasn't he killed by someone?"

The grate is up from the Grating Room. The Minotaur's Room is up from the grate. The grate is a door. 

The grate is locked. 

Instead of throwing the flag at the Minotaur:
	say "The Minotaur scoffs at your attempt. 'Like I'm going to fall for that one again!'".

Instead of asking the Minotaur about "Theseus":
	try theseusing.
	
Instead of telling the Minotaur about "Theseus":
	try theseusing.

Check asking the Minotaur about anything:
	say "The Minotaur roars at you. 'I'm a Minotaur, not a Sphinx!' he bellows." instead.
	
Check telling the Minotaur about anything:
	say "The Minotaur roars at you. 'I'm a Minotaur, not a Muse!' he bellows." instead.
	
Check giving something to the Minotaur:
	say "The Minotaur roars at you. 'I'm a Minotaur, I can't be bribed!' he bellows." instead.
	
Check showing something to the Minotaur:
	say "The Minotaur roars at you. 'I'm a Minotaur, I can't be bribed!' he bellows." instead.
	
Every turn when the minotaur is in the location and the turn count is triangular:
	say "The Minotaur charges at you but you leap aside at the last second, panting for air.".

Instead of going up from the Minotaur's Room:
	if the Minotaur is in the Minotaur's Room:
		say "The Minotaur roars and blocks your way.";
	else:
		continue the action.
		
Instead of going down from the Minotaur's Room:
	if the Minotaur is in the Minotaur's Room:
		say "The Minotaur growls and blocks your way.";
	else:
		continue the action.
		
Hole-created is a truth state that varies. Hole-created is false. 

Strange Hallway is a room. "You are walking down a weird, ethereal passageway going from east to west, on both sides of which are Minotaur-shaped holes." Crete is east of the Strange Hallway. The Minotaur's Room is west of the Strange Hallway. Nothing is east of Crete. 

The holes are a backdrop. The holes are nowhere. The description of the holes is "[if the player is in the Minotaur's Room]It is[else]They are[end if] Minotaur-shaped."

Understand "hole" as the holes.
		
Instead of going east from the Minotaur's Room:
	if hole-created is false:
		say "You can't go that way.";
	else:
		say "You move down the passage the Minotaur made in the wall to...";
		now the player is in the Strange Hallway. 
		
Theseusing is an action applying to nothing. Understand "theseus" as theseusing.

Carry out theseusing:
	say "Isn't he a navigator?"
	
The Holey Area is a region. The Minotaur's Room is in the Holey Area. The Strange Hallway is in the Holey Area

Instead of theseusing:
	if the player is in the Minotaur's Room:
		if hole-created is false:
			say "The Minotaur, hearing the name of its old enemy, crashes through the eastern wall of the room and vanishes from sight.";
			now the minotaur is nowhere;
			now hole-created is true;
			now the holes are in the Holey Area;
		else:
			continue the action;
	else:
		continue the action.

The Treasure Room is up from the Minotaur's Room. "No thieves in sight. [first time]All that lies in front of you is a [jewel-encrusted egg].[only]"

The jewel-encrusted egg is a closed openable container in the Treasure Room. The description of the jewel-encrusted egg is "It looks very valuable, and glitters with jewels. It has hinges on the side which makes you think it can be opened." The leaflet is a thing in the jewel-encrusted egg. 

Zork-yes is a truth state that varies. Zork-yes is false. 

Instead of examining the leaflet:
	say "'[bold type]Congratulations![Roman type][line break][line break]If you are reading this message, that means you've travelled through my Labyrinth and beaten my Minotaur. [line break][line break]You might have already realized this if you've gotten this far, but my Labyrinth is based on a maze from one of the first text-based adventure games, Zork I: The Great Underground Empire. Please play that game if you haven't already; it will give you many hours of old-school, frustrated fun. [line break][line break]For completing this bonus puzzle that has absolutely nothing to do with the actual plot of the game, I thank you immensely for wasting your own time and bequeath upon you the highest rank from Zork I, the rank of Master Adventurer, in addition to your previous titles. Try checking your score if you don't believe me. [line break][line break]Please enjoy the rest of the game![line break][line break]Sincerely,[line break]Daedelus, architect of the Labyrinth.'[line break][line break]As soon as you finish reading the strange leaflet, it erupts into blue flames. You give a yelp and drop it, but almost as soon as it hits the ground, it vanishes without a trace. You quickly search your possessions and the surrounding areas and find that the egg has mysteriously vanished as well.";
	now the jewel-encrusted egg is nowhere;
	now the leaflet is nowhere;
	now zork-yes is true.
	
Test labyrinth with "test lion/ test hydra/ test hind/ test boar/ test stables/ test stymphalia/ test bull"
	

Chapter 9 - The Mares of Diomedes

Thrace is northeast of Stymphalia. "Thrace is a farming town mostly, with the only real shop being that of the metalworker Diomedes. [paragraph break]Upon entering the store you find yourself in a quaint-looking [office], complete with [desk], [calendar], and [wastebasket]. But the focal point of the room is the gigantic [if the safe is open]open [end if][safe] that takes up about a third of the space.[if the safe is open] Inside the safe you can see [a list of things in the safe].[end if][paragraph break]From here you can only cross back to the southwest, as there is nothing but farmland beyond." Diomedes is a person in Thrace. "Diomedes is here, scowling at you from behind his [desk]." Understand "metalworker" as Diomedes. The safe is a container in Thrace. Understand "large" and "onyx" and "large onyx safe" and "large onyx" as the safe. The safe is closed and fixed in place and openable. 

Instead of taking the golden pendant:
	if the score is greater than 7 and the golden pendant is in the safe:
		say "Wow, you're a mean one aren't you! You retrieve the pendant from the safe, deciding not to pay Diomedes for his mares after all.";
		continue the action;
	else:
		continue the action.
		
After inserting the golden pendant into the safe:
	if the score is greater than 7:
		say "Aw, what a nice guy. It seems you've had a change of heart and have decided to pay Diomedes for his mares after all.[paragraph break]You put the golden pendant into the safe."

The office is a backdrop in Thrace. The description of the office is "Very quaint.". Understand "shop" and "store" as the office.

The farmland is a backdrop. The farmland is in Thrace and Stymphalia. Understand "Thrace" and "farming" and "farming town" as the farmland. 

Instead of examining the farmland:
	if the player is in Thrace:
		say "The farmland is decidedly uninteresting.";
	else:
		say "You can only see a small strip of farmland from here. You'll have to go northeast to see more."

Instead of entering the safe:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else if the safe is closed:
		say "The safe is closed.";
	else:
		say "Are you a mare of Diomedes? No, I thought not."

The description of Diomedes is "Diomedes is a short, proud metalworker with burly arms and a mean scowl. He has bushy eyebrows and short-cropped farmer's hair and seems to want nothing to do with people, despite running the only public shop for miles around. He carries himself as though he were some sort of tyrannical, curmudgeonly king."

A mare is a kind of portable supporter. Podargos the mare, Lampon the mare, Xanthos the mare, and Deinos the mare are mares in the safe. The calendar is a thing in Thrace. The calendar is fixed in place. Understand "page" as the calendar. Understand "nametag" as a mare.

Instead of putting anything on a mare:
	if the noun is not wearable:
		say "It doesn't look like that would fit the mare's style.";
	else if the noun is not the golden pendant:
		say "Could look cool, but it probably wouldn't do much.";
	else:
		continue the action.

The description of a mare is "A miniature mechanical mare, composed entirely of metal. It almost looks like some sort of robotic action figure. It has a small metal nametag on its breast."

After taking a mare:
	say "The mare, still spell-bound by the pendant, barely notices you pick it up and put it in your pocket.".

The description of the safe is "So large it takes up nearly all of the excess space in the office. You find a serial number on the side and a sticker saying 'made with love and care by the Cyclopes of [italic type]Hephaestus, Inc[Roman type].' It's got no physical lock, only a spinning mechanism. Looks like you can spin it to a four-digit number to open it.". Understand "dial" and "lock" and "mechanism" and "serial number" and "number" and "sticker" and "combination" as the safe.
	
Instead of taking the safe:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		continue the action.

Check asking Diomedes about anything:
	say "Diomedes gives a little glare and says, 'Don't ask me!'" instead.
	
Instead of asking Diomedes about "[Diomedes]":
		say "Diomedes grunts and glares at you, as though annoyed you would dare ask him about himself or the shop he runs. 'I'm a metalworker, boy, and this is my shop. I'm too busy to be answering stupid questions, so unless you have something to show me, I suggest you leave. And DON'T touch anything,' he growls at the end for good measure.".
		
Instead of asking Diomedes about "himself":
		say "Diomedes grunts and glares at you, as though annoyed you would dare ask him about himself or the shop he runs. 'I'm a metalworker, boy, and this is my shop. I'm too busy to be answering stupid questions, so unless you have something to show me, I suggest you leave. And DON'T touch anything,' he growls at the end for good measure.".
		
Instead of asking Diomedes about "shop":
		say "Diomedes grunts and glares at you, as though annoyed you would dare ask him about himself or the shop he runs. 'I'm a metalworker, boy, and this is my shop. I'm too busy to be answering stupid questions, so unless you have something to show me, I suggest you leave. And DON'T touch anything,' he growls at the end for good measure.".
		
Instead of asking Diomedes about "the shop":
		say "Diomedes grunts and glares at you, as though annoyed you would dare ask him about himself or the shop he runs. 'I'm a metalworker, boy, and this is my shop. I'm too busy to be answering stupid questions, so unless you have something to show me, I suggest you leave. And DON'T touch anything,' he growls at the end for good measure.".
		
Instead of asking Diomedes about "the office":
		say "Diomedes grunts and glares at you, as though annoyed you would dare ask him about himself or the shop he runs. 'I'm a metalworker, boy, and this is my shop. I'm too busy to be answering stupid questions, so unless you have something to show me, I suggest you leave. And DON'T touch anything,' he growls at the end for good measure.".
		
Instead of asking Diomedes about "office":
		say "Diomedes grunts and glares at you, as though annoyed you would dare ask him about himself or the shop he runs. 'I'm a metalworker, boy, and this is my shop. I'm too busy to be answering stupid questions, so unless you have something to show me, I suggest you leave. And DON'T touch anything,' he growls at the end for good measure.".
	
Check showing anything to Diomedes:
	say "Diomedes gives a little grunt and says, 'Not interested.'" instead.
	
Check telling Diomedes about anything:
	say "Diomedes gives a little grunt and says, 'Not interested.'" instead.
	
Check giving anything to Diomedes:
	say "Diomedes gives a little grunt and says, 'Not interested.'" instead.

Instead of examining the calendar:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		continue the action.
		
Instead of examining the desk:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		continue the action.
		
Instead of taking the desk:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		continue the action.
		
Instead of taking the calendar:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		say "No, it's tacked firmly to the wall.".

		
Instead of examining the safe:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		continue the action.
		
The description of the calendar is "The Olympics winner for last month, a cocky member of the Athenian Owls, gives a flashy grin above the dates. He holds a gold medal and his beautiful muscles glisten with oil. You suppose you'll have to turn the page to see this month's Olympian. [4 as a footnote]"

Instead of turning the calendar:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		say "You don't want to mess with Diomedes's stuff any more than you have to. Even if the calendar is on last month for some reason...".

Spinning it to is an action applying to one thing and one number. 

Check spinning it to: 
	if the noun is not the safe:
		say "[The noun] [do] not spin." instead;
	else:
		if Diomedes is in Thrace:
			say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes." instead;
		else if the number understood is positive and the number understood is less than 10000:
			continue the action;
		else:
			say "The safe dial only goes up to 9999." instead.
	

Report spinning it to: say "Click! and nothing else happens."

Understand "spin [something] to [a number]" as spinning it to.

Instead of spinning the safe to something:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		continue the action.
		
Spinning is an action applying to one thing.

Check spinning: 
	if the noun is not the safe:
		say "[The noun] [do] not spin." instead;
	else:
		if Diomedes is in Thrace:
			say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes." instead;
		else:
			say "You'll have to specify a number. ('Spin safe to 1234' for instance.)" instead.
	

Report spinning: say "Click! and nothing else happens."

Understand "spin [something]" as spinning.
		
The desk is an openable closed container in Thrace. The desk is fixed in place. The wastebasket is a container in Thrace. The wastebasket is fixed in place. The crumpled piece of paper is a thing in the wastebasket. 

The description of the wastebasket is "Just a regular plastic wastebasket." Understand "basket" and "waste" and "garbage" and "trash" and "trashcan" and "trash can" and "bin" as the wastebasket.

Instead of inserting anything into the wastebasket:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		continue the action.

The description of the desk is "It's a normal writing desk and seems somewhat out of place in a metalworker's shop. It opens at the top."

The folded note is a thing in the desk. 

Instead of examining the folded note:
	now the safe number is a random number between 3000 and 3999;
	say "'What the devil is my safe number again? I swear I left that note somewhere... if I could only force myself to remember.... could it be... [a random number from 1000 to 1999]? No... maybe [a random number from 2000 to 2500]? Okay, you know all of last year's, maybe it could still be one of those? In order, they were [a random number from 9000 to 9999], [a random number from 5000 to 5999], [a random number from 8000 to 8999], [a random number from 2501 to 2999], [a random number from 5000 to 5999], [a random number from 5000 to 5999], [a random number from 1000 to 1999], [a random number from 2000 to 2500], [a random number from 3000 to 3999]... and then I forget. I know it's not [a random number from 7000 to 7999] I just changed that last week. Hmm okay your passwords in order THIS year were [a random number from 5000 to 5999], [a random number from 8000 to 8999], [a random number from 9000 to 9999], [a random number from 2501 to 2999].... oh Gods, this is useless. I wasn't stupid enough to put it as [the safe number] again, was I? That was last month's for crying out loud! Maybe it's my mom's birthday [a random number from 1000 to 1031], or the beginning of my SSN, [a random number from 4000 to 4999]? Ugh... I'll never remember it, it's hopeless.'[one of][or][5 as a footnote][stopping][line break]".

The description of the crumpled piece of paper is "'Usable Backup Codes for your Large Onyx Safe™[line break]Delivered by Hephaestus, Inc.[line break]PLEASE ONLY PROGRAM THESE IN CASE OF EMERGENCY[line break][a random number from 5000 to 5999][line break][a random number from 5000 to 5999][line break][a random number from 1000 to 1999][line break][a random number from 2000 to 2500][line break][a random number from 3000 to 3999][line break][a random number from 4000 to 4999][line break][a random number from 2000 to 2500][line break][a random number from 7000 to 7999][line break][a random number from 9000 to 9999][line break][a random number from 5000 to 5999][line break][a random number from 8000 to 8999][line break][a random number from 2501 to 2999][line break][a random number from 5000 to 5999][line break][a random number from 5000 to 5999][line break][a random number from 1000 to 1999][line break][a random number from 2000 to 2500][line break][a random number from 3000 to 3999][line break][a random number from 4000 to 4999][line break][a random number from 2000 to 2500][line break][a random number from 7000 to 7999][line break][a random number from 9000 to 9999][line break][a random number from 5000 to 5999][line break][a random number from 8000 to 8999][line break][a random number from 2501 to 2999]'[one of][or] [5 as a footnote][stopping]"

Instead of examining the crumpled piece of paper:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		continue the action.

Instead of searching anything in Thrace:
	if the player carries the noun:
		continue the action;
	else if the noun is the wastebasket:
		continue the action;
	else if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		continue the action.
		
Instead of taking the wastebasket:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		say "Are you a garbage collector? No, I thought not.".
		
Instead of examining the wastebasket:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		continue the action.
		
Instead of opening the desk:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		continue the action.
		
Instead of touching anything in Thrace:
	 if the player carries the noun:
		continue the action;
	else if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		continue the action.
		
Instead of taking the crumpled piece of paper:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		continue the action.
		
Instead of opening the safe:
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		if the safe is closed:
			say "The safe opens only when spun to the correct 4-digit combination.";
		else:
			say "It's already open!".	
		
The safe number is a number that varies.

Instead of spinning the closed safe to the safe number: 
	if Diomedes is in Thrace:
		say "'Hands off,' growls Diomedes, glaring at you with his ugly brown eyes.";
	else:
		now the safe is open; 
		say "Clonk! and the safe door swings slowly open, revealing [a list of things in the safe].".
		
Instead of spinning the open safe to a number:
	say "It's already open!".		
	
Instead of showing the Cretan Bull to Diomedes:
	say "Diomedes looks over the dull, plodding creature and scoffs. 'Bah! Please. I have many mechanical bulls in my workshop out back that are superior to that loathsome specimen.'"
	
Instead of asking Diomedes about "Cretan Bull":
	if the player carries the Cretan Bull:
		say "Diomedes looks over the dull, plodding creature and scoffs. 'Bah! Please. I have many mechanical bulls in my workshop out back that are superior to that loathsome specimen.'";
	else:
		continue the action.
		
Instead of asking Diomedes about "bull":
	try asking Diomedes about "Cretan Bull".
		
Instead of telling Diomedes about "Cretan Bull":
	if the player carries the Cretan Bull:
		say "Diomedes looks over the dull, plodding creature and scoffs. 'Bah! Please. I have many mechanical bulls in my workshop out back that are superior to that loathsome specimen.'";
	else:
		continue the action.
		
Instead of telling Diomedes about "bull":
	try telling Diomedes about "Cretan Bull".
		
Instead of giving the Cretan Bull to Diomedes:
	say "Diomedes looks over the dull, plodding creature and scoffs. 'Bah! Please. I have many mechanical bulls in my workshop out back that are superior to that loathsome specimen.'".
	
Instead of asking Diomedes about "mechanical bulls":
	If the player carries the Cretan Bull:
		say "Diomedes's nostrils flare. 'Don't believe me do you? Well just give me a minute and I'll fetch them from the back,' and with that, he disappears into a small room that you can't see from behind the desk.";
		now Diomedes is nowhere;
	else:
		say "Diomedes looks at you nervously, as though wondering how you knew about that, but says nothing."
		
Instead of asking Diomedes about "mechanical bull":
	If the player carries the Cretan Bull:
		say "Diomedes's nostrils flare. 'Don't believe me do you? Well just give me a minute and I'll fetch them from the back,' and with that, he disappears into a small room that you can't see from behind the desk.";
		now Diomedes is nowhere;
	else:
		say "Diomedes looks at you nervously, as though wondering how you knew about that, but says nothing."
	
Instead of asking Diomedes about "bulls":
	If the player carries the Cretan Bull:
		say "Diomedes's nostrils flare. 'Don't believe me do you? Well just give me a minute and I'll fetch them from the back,' and with that, he disappears into a small room that you can't see from behind the desk.";
		now Diomedes is nowhere;
	else:
		say "Diomedes looks at you nervously, as though wondering how you knew about that, but says nothing."
		
Instead of asking Diomedes about "mechanical":
	If the player carries the Cretan Bull:
		say "Diomedes's nostrils flare. 'Don't believe me do you? Well just give me a minute and I'll fetch them from the back,' and with that, he disappears into a small room that you can't see from behind the desk.";
		now Diomedes is nowhere;
	else:
		say "Diomedes looks at you nervously, as though wondering how you knew about that, but says nothing."

Instead of taking Podargos the mare:
	if the golden pendant is on Podargos the mare:
		continue the action;
	else if the player does not carry Podargos the mare:
		say "You begin to pick up Podargos the mare, but the mechanical monster tosses its titanium mane, gives a short whinny, and then breathes a giant golden fireball at you! You manage to just dodge, but you lose your grip on the mare.";
	else:
		continue the action.
		
Instead of putting the golden pendant on Podargos the mare:
	say "You carefully take your golden pendant and place it around the mare's neck. It seems somehow spell-bound by the beautiful piece of jewelry.";
	now the golden pendant is on Podargos the mare.
		
Instead of taking Lampon the mare:
	if the golden pendant is on Lampon the mare:
		continue the action;
	else if the player does not carry Lampon the mare:
		say "You begin to pick up Lampon the mare, but the mechanical monster flashes its LED eyes, gives a short whinny, and then breathes a giant scarlet fireball at you! You manage to just dodge, but you lose your grip on the mare.";
	else:
		continue the action.
	
Instead of putting the golden pendant on Lampon the mare:
	say "You carefully take your golden pendant and place it around the mare's neck. It seems somehow spell-bound by the beautiful piece of jewelry.";
	now the golden pendant is on Lampon the mare.
	
Instead of taking Xanthos the mare:
	if the golden pendant is on Xanthos the mare:
		continue the action;
	else if the player does not carry Xanthos the mare:
		say "You begin to pick up Xanthos the mare, but the mechanical monster bares its copper teeth, gives a short whinny, and then breathes a giant orange fireball at you! You manage to just dodge, but you lose your grip on the mare.";
	else:
		continue the action.
	
Instead of putting the golden pendant on Xanthos the mare:
	say "You carefully take your golden pendant and place it around the mare's neck. It seems somehow spell-bound by the beautiful piece of jewelry.";
	now the golden pendant is on Xanthos the mare.
	
Instead of taking Deinos the mare:
	if the golden pendant is on Deinos the mare:
		continue the action;
	else if the player does not carry Deinos the mare:
		say "You begin to pick up Deinos the mare, but the mechanical monster stamps its brass hooves, gives a short whinny, and then breathes a giant yellow fireball at you! You manage to just dodge, but you lose your grip on the mare.";
	else:
		continue the action.
	
Instead of putting the golden pendant on Deinos the mare:
	say "You carefully take your golden pendant and place it around the mare's neck. It seems somehow spell-bound by the beautiful piece of jewelry.";
	now the golden pendant is on Deinos the mare.
	
Before putting the golden pendant on something:
	if the golden pendant is on something:
		say "You'll have to take the golden pendant first.";
		stop the action;
	else:
		continue the action.
		
Before taking the golden pendant:
	if the golden pendant is on a mare:
		say "[if the golden pendant is on Podargos the mare]Podargos[else if the golden pendant is on Lampon the mare]Lampon[else if the golden pendant is on Xanthos the mare]Xanthos[else]Deinos[end if] follows the glittering jewel with his eyes as you remove it from his neck, but he remains docile.";
	else:
		continue the action.
	
Understand "mares" as a mare.

Instead of putting the golden pendant on the mares of Diomedes:
	say "Putting the pendant on the mares of Diomedes would achieve nothing at this point. The mares are used to you now, so you can pick them up and drop them freely."
	
Stolen Mares is a scene. Stolen Mares begins when the player carries Podargos the mare and the player carries Lampon the mare and the player carries Xanthos the mare and the player carries Deinos the mare for the first time.

Some mares of Diomedes are some things. The mares of Diomedes are nowhere. The description of the mares of Diomedes is "Four miniature mechanical mares, composed entirely of metal. They look like robotic action figures and their metal nametags read Podargos, Lampon, Xanthos, and Deinos."

Understand "Podargos" and "Lampon" and "Xanthos" and "Deinos" as the mares of Diomedes.

After dropping the mares of Diomedes:
	say "You drop the mares of Diomedes as a set, not wanting to lose track of them."
	
After taking the mares of Diomedes:
	say "You pick up the mares of Diomedes as a set, not wanting to lose track of them."

When Stolen Mares begins:
	say "You've managed to steal the mares of Diomedes! You'd better hurry away before he gets back. [line break][line break]You put all the notes back as you found them and decide to place the golden pendant in the safe, hoping that will serve as at least some form of payment.";
	now Podargos the mare is nowhere;
	now Lampon the mare is nowhere;
	now Xanthos the mare is nowhere;
	now Deinos the mare is nowhere;
	now the golden pendant is in the safe;
	now the crumpled piece of paper is in the wastebasket;
	now the folded note is in the desk;
	now the desk is closed;
	now the player carries the mares of Diomedes;
	increase the score by 1;
	follow the notify score changes rule;
	try requesting the score.
	

test mares1 with "xyzzy/ nw/ nw/ n/ n/ nw/ ne/ show bull to diomedes/ ask diomedes about bulls/ open desk/ take folded/ read folded/ spin safe to [safe number]"

test mares2 with "open safe/ put pendant on lampon/ take lampon/ take pendant/ put pendant on xanthos/ take xanthos/ take pendant/ put pendant on deinos/ take deinos/ take pendant/ put pendant on podargos/ take podargos"
	
	

Chapter 10 - The Girdle of Hippolyta

Rule for printing a parser error when the latest parser error is the nothing to do error and the player is in Amazonia and hippolyta-unconscious is true:
	say "There's nothing here which is immediately available, but you might try taking anything you can see, even if it seems decorative or attached to something else. This is an emergency, after all!"	

Amazonia is east of the Peloponnesian Shore. "This vast jungle has a natural ferocity to it that makes one's hair stand on end. A sense of mysticism, beauty, and raw power is palpable here. The only exit you can see is back the way you came, to the west."

The Amazon warrior is a woman in Amazonia. "An Amazon warrior is here, tall and toned and incredibly fierce. [if hippolyta-unconscious is true]She is currently performing rapid chest compressions on Queen Hippolyta as she lies unconscious. [else]She could probably crush your skull in with one flex of her thighs, and her beauty is such that you would gladly let her.[end if][first time][paragraph break]She smiles as you arrive. 'We foresaw a visitor. I have instructions to not let anyone see Hippolyta unless they can show me the mares of Diomedes.' She looks at you expectantly.[only]"

The description of the Amazon warrior is "One of the strongest people you've ever met, without a doubt. [if hippolyta-unconscious is true]She's currently performing chest compressions on her leader, Hippolyta, perhaps a little too rapidly. But that will only serve as a stall. Hippolyta needs some kind of medicine, fast![end if]"

Administering CPR is an action applying to nothing. Understand "administer CPR" and "do chest compressions" and "perform CPR" and "perform chest compressions" and "do CPR" as administering CPR.

Check administering CPR:
	if the player is in Amazonia and hippolyta-unconscious is true:
		try waking Hippolyta instead;
	else:
		continue the action.

Report administering CPR:
	say "There's nobody in distress here!" 

A thing can be coffeeable or uncoffeeable. A thing is usually uncoffeeable. The bottle of Benadryl is coffeeable.

Hippolyta is a woman. "Hippolyta is here, [if hippolyta-unconscious is true]slumped and unconscious beside[else]lounging regally on[end if] an [ornate throne] of [vines] and [roses] set atop a mound of [moss] and [glowing dirt]." Hippolyta wears the girdle. The glowing dirt, some vines, and the moss are coffeeable undescribed things. Some roses are undescribed things. The description of some roses is "The roses look very delicate. You would have difficulty holding them without slashing them with your lion pelt claws."

Some roses are nowhere. Some rose powder is nowhere.

Bowing is an action applying to nothing. Understand "bow" as bowing.

Report bowing:
	say "There's no need to bow at the moment, you're not in the presence of royalty.".
	
Check bowing:
	if Eurystheus is in the location:
		say "You give a very respectful bow to your cousin, the King of Tiryns, whose advisors you can suddenly hear snickering behind the throne. 'Lower,' says your cousin, an amused sneer playing on his lips. 'And while you're at it, you should kiss my ring too.' The advisors positively howl with laughter." instead;
	else if Hippolyta is in the location:
		if hippolyta-unconscious is false:
			say "You give a very respectful bow to Hippolyta, the Queen of the Amazons. A soft smile appears in her eyes and she bids you stand. 'I appreciate your respect, young hero, but the Amazons have long since done away with these needless formalities. Please, simply ask of me what you will and treat me as your equal.'" instead;
		else:
			say "There's no need to bow at the moment, you're not in the presence of royalty. (Or at least, not in the presence of conscious royalty.)" instead;
	else if Diomedes is in the location:
		say "There's no need to bow at the moment. As much as Diomedes might disagree, you're not really in the presence of royalty, so you see no reason to feed his ego." instead.
		
Kneeling is an action applying to nothing. Understand "kneel" as bowing.

Report kneeling:
	say "There's no need to kneel at the moment, you're not in the presence of royalty.".
	
Check kneeling:
	if Eurystheus is in the location:
		say "You kneel in front of your cousin, the King of Tiryns, whose advisors you can suddenly hear snickering behind the throne. 'Lower,' says your cousin, an amused sneer playing on his lips. 'And while you're at it, you should kiss my ring too.' The advisors positively howl with laughter." instead;
	else if Hippolyta is in the location:
		if hippolyta-unconscious is false:
			say "You respectfully kneel in front of Hippolyta, the Queen of the Amazons. A soft smile appears in her eyes and she bids you stand. 'I appreciate your respect, young hero, but the Amazons have long since done away with these needless formalities. Please, simply ask of me what you will and treat me as your equal.'" instead;
		else:
			say "There's no need to kneel at the moment, you're not in the presence of royalty. (Or at least, not in the presence of conscious royalty.)" instead;
	else if Diomedes is in the location:
		say "There's no need to kneel at the moment. As much as Diomedes might disagree, you're not really in the presence of royalty, so you see no reason to feed his ego." instead.

The glowing dirt is a coffeeable undescribed thing. The indefinite article is "some". Some vines are a coffeeable undescribed thing. The moss is a coffeeable undescribed thing. The indefinite article is "some". The moss is nowhere. The glowing dirt is nowhere. Some vines are nowhere. 

The description of the moss is "Just a lively bit of jungle greenery."

The description of some vines is "They're thin jungle vines, but they look pretty sturdy."

The description of the glowing dirt is "This rich earthy loam seems to be glowing with the power of the Amazons."

The description of Hippolyta is "[if hippolyta-unconscious is true and Hippolyta wears the girdle]Hippolyta still radiates power and grace even in unconsciousness. But there's no time to waste. She needs some kind of medicine, fast![else if hippolyta-unconscious is false and Hippolyta wears the girdle]Hippolyta radiates power and grace like nobody you've ever met. Her signature girdle flashes green from her waist.[else]Hippolyta radiates power and grace like nobody you've ever met.[end if]"

Understand "queen" and "Queen Hippolyta" as Hippolyta.

Understand "belt" as the girdle.

Warrior-guard is a truth state that varies. Warrior-guard is true. 

Check asking the Amazon warrior about anything:
	If warrior-guard is true:
		say "She raises an eyebrow, amused, but there is no reply." instead;
	else:
		say "'Now is not the time or place for that question.'" instead.
		
Check telling the Amazon warrior about anything:
	If warrior-guard is true:
		say "There is a slight, amused smile, but no reply." instead;
	else:
		say "'Now is not the time or place for discussion.'" instead.
	
Check giving anything to the Amazon warrior:
	If warrior-guard is true:
		say "The Amazon warrior frowns, suddenly very serious. 'I sincerely hope you are not trying to bribe me.'" instead;
	else:
		say "The Amazon warrior refuses your gift. 'Now is not the time or place for that.'" instead.
		
Check showing anything to the Amazon warrior:
	If warrior-guard is true:
		say "The Amazon warrior frowns, suddenly very serious. 'I sincerely hope you are not trying to bribe me.'" instead;
	else:
		say "The Amazon warrior waves away your display. 'Now is not the time or place for that.'" instead.
		
The ornate throne is a fixed in place thing. The ornate throne is nowhere. The description of the ornate throne is "An object radiating power, just like Hippolyta. Some [vines] and [roses] still curl about its surface, and a mound of [moss] and [glowing dirt] serves as its base."

Instead of entering the ornate throne:
	say "Are you the Queen of the Amazons? No, I thought not."

A thing can be medicinal or normal. A thing is usually normal. The moss and the glowing dirt and some roses and some vines are medicinal things. 

Instead of taking a medicinal thing:
	if the player is in Amazonia:
		if the player carries the noun or Amazonian Coffee is happening:
			say "No, you don't need any more.";
		else if the noun is some roses:
			if the player carries the rose powder or Amazonian Coffee is happening:
				say "No, you don't need any more.";
			else if hippolyta-unconscious is false:
				say "You can't pluck things from the throne with Hippolyta standing right there!";
			else:
				continue the action;
		else if hippolyta-unconscious is false:
			say "You can't pluck things from the throne with Hippolyta standing right there!";
		else:
			continue the action;
	else:
		continue the action.
	
Instead of showing the mares of Diomedes to the Amazon warrior:
	if warrior-guard is true:
		now Hippolyta is in Amazonia;
		now the glowing dirt is in Amazonia;
		now some roses are in Amazonia;
		now some vines are in Amazonia;
		now the moss is in Amazonia;
		now the ornate throne is in Amazonia;
		now the mares of Diomedes are nowhere;
		now warrior-guard is false;
		say "She takes the mares, examines them briefly, then nods her head and rushes off into the forest without a word. You are breathless by the time you catch up with her through the jungle and feel that you desperately need your inhaler. But as you look around you realize that you are in the court of [Hippolyta], Queen of the Amazons, who sits on an [ornate throne] of [vines] and [roses] on a mound of [moss] and [glowing dirt], in the midst of the deepest part of the jungle. You feel very honored--very few mortal men have seen this sight!";
	else:
		continue the action.
		
Instead of giving the mares of Diomedes to the Amazon warrior:
	if warrior-guard is true:
		now Hippolyta is in Amazonia;
		now the glowing dirt is in Amazonia;
		now some roses are in Amazonia;
		now some vines are in Amazonia;
		now the moss is in Amazonia;
		now the ornate throne is in Amazonia;
		now the mares of Diomedes are nowhere;
		now warrior-guard is false;
		say "She takes the mares, examines them briefly, then nods her head and rushes off into the forest without a word. You are breathless by the time you catch up with her through the jungle and feel that you desperately need your inhaler. But as you look around you realize that you are in the court of [Hippolyta], leader of the Amazons, who sits on an [ornate throne] of [vines] and [roses] on a mound of [moss] and [glowing dirt], in the midst of the deepest part of the jungle. You feel very honored--very few mortal men have seen this sight!";
	else:
		continue the action.
	
Hippolyta-unconscious is a truth state that varies. Hippolyta-unconscious is false. 

Does the player mean asking the Amazon warrior about "[girdle]":
	it is very unlikely.
	
Does the player mean asking the Amazon warrior for the girdle:
	it is very unlikely.

Instead of asking Hippolyta about "[girdle]" for the first time:
	say "Hippolyta smiles at you and comments, 'Straight to the point as I expected, young hero. I know you require this item for your quest. You have proven yourself very worthy, having won possession of the mares, those meanest animals ever created by mortals. The time has come for me to--'[paragraph break]But suddenly she is cut off, as the land in front of her begins to glow a bright blue and the light condenses around a matronly woman in a flowing blue ballgown and a blindingly white tiara. You'd know that jealous face anywhere - it's your stepmother Hera. She sneers menacingly at you and says 'So the bastard pipsqueak managed to get this far through luck and cowardice. Pathetic. Well, you may have swindled Hippolyta but you won't swindle me! If she's not woman enough to keep the girdle from you, I feel I must step in,' and with that Hera turns around and shoots a quick jolt of electricity at Hippolyta, who falls down, unconscious. Turning to the Amazon warrior, she says, 'Now you know who is responsible for the fall of your leader, girl. Do with him what you will!' and shooting you another last menacing sneer, disappears in a puff of cloud-gray smoke.[paragraph break]The Amazon warrior cries out and rushes to her queen to try and aid her. Then she turns back to you and growls, 'You'd better make some medicine to help her out, or you're finished, boy....' and immediately begins chest compressions.";
	now hippolyta-unconscious is true.
	
Instead of asking Hippolyta for the girdle:
	if the score is less than 9:
		try asking Hippolyta about "[the girdle]" instead;
	else:
		continue the action.
	
Check asking Hippolyta about anything:
	if hippolyta-unconscious is true:
		say "She's unconscious right now! She needs some kind of medicine." instead;
	else:
		say "Hippolyta smiles at you cryptically, but there is a cool dominance to the smile, like the smile you might give to a lost puppy who runs up to you on the street." instead. 
		
Check telling Hippolyta about anything:
	if hippolyta-unconscious is true:
		say "She's unconscious right now! She needs some kind of medicine." instead;
	else:
		say "Hippolyta chuckles at you cryptically, but there is a cool dominance to the chuckle, like the chuckle you might give to a three-year-old child when they tell you about their day." instead. 
		
Check showing anything to Hippolyta:
	if hippolyta-unconscious is true:
		say "She's unconscious right now! She needs some kind of medicine." instead;
	else:
		say "Hippolyta nods at you cryptically, but there is a cool dominance to the nod, like the nod you might give to a kitten presenting its dead mouse for approval." instead. 
		
Check giving something to Hippolyta:
	if hippolyta-unconscious is true:
		say "She's unconscious right now! She needs some kind of medicine." instead;
	else:
		say "'I require no offerings from you, young hero.'" instead.
		
Instead of pushing Hippolyta:
	if hippolyta-unconscious is true:
		try waking Hippolyta instead;
	else:
		continue the action.	
		
The rose powder is a coffeeable thing. The indefinite article is "some". The description of the rose powder is "A powder composed of the slashed-up petals of a lovely rose."
		
Instead of attacking some roses with the lion pelt:
	say "You slash the roses into rose powder.[line break]";
	now some roses are in Amazonia;
	now the player carries some rose powder. 
	
The clay bowl is a container. The description of the clay bowl is "You can just make out an inscription all along the side of the container. It reads 'Combine the elements of earth and life, wrap them both up with the tree's strength, tight. Sprinkle it all with the powder of love, and drench the mixture in the sleep from above. Then you will create the Amazon Coffee, that elixir of gods that tastes better than toffee.'"

Instead of taking something:
	if the noun is in the clay bowl:
		say "You've already ground it into the clay bowl, no need to remove it.";
	else:
		continue the action.
		
Bowl Found is a scene. Bowl Found begins when the player carries the glowing dirt for the first time.

When Bowl Found begins:
	now the clay bowl is in Amazonia;
	say "As you pick up some of the glowing dirt, you notice an empty [clay bowl] lying beneath it within the mound. It must have been a religious ornament at some point in the distant past.".
	
Medicine-fetching is a truth state that varies. Medicine-fetching is false. 
	
Instead of going west in Amazonia:
	if hippolyta-unconscious is true and the bottle of Benadryl is in Amazonia and the the lion pelt is in Amazonia:
		say "'You're not going anywhere until she's better,' growls the Amazon warrior in between chest compressions.";
	else if hippolyta-unconscious is true and the player carries the bottle of Benadryl and the the lion pelt is in Amazonia:
		say "'You're not going anywhere until she's better,' growls the Amazon warrior in between chest compressions.";
	else if hippolyta-unconscious is true and the player carries the bottle of Benadryl and the player carries the lion pelt:
		say "'You're not going anywhere until she's better,' growls the Amazon warrior in between chest compressions.";
	else if hippolyta-unconscious is true and the bottle of Benadryl is in Amazonia and the player carries the lion pelt:
		say "'You're not going anywhere until she's better,' growls the Amazon warrior in between chest compressions.";
	else if hippolyta-unconscious is true and the bottle of Benadryl is in Amazonia and the player wears the lion pelt:
		say "'You're not going anywhere until she's better,' growls the Amazon warrior in between chest compressions.";
	else if hippolyta-unconscious is true and the player carries the bottle of Benadryl and the player wears the lion pelt:
		say "'You're not going anywhere until she's better,' growls the Amazon warrior in between chest compressions.";	
	else if hippolyta-unconscious is true:
		say "'You're not going anywhere until she's better,' growls the Amazon warrior in between chest compressions. [paragraph break]'I'm just going to get some medicine, I promise I'll be back soon!' you protest frantically.[paragraph break]'Any medicine you find out there won't be strong enough! You'd better get back here or you're finished, boy.' With those words running through your mind, you speed off to the[line break]";
		now medicine-fetching is true;
		continue the action;
	else:
		continue the action.
		
Every turn:
	if the player is in Amazonia and medicine-fetching is true:
		say "The Amazon warrior looks up at you between chest compressions and glares. 'Took you long enough. She needs medicine, now!'";
		now medicine-fetching is false.
		
Amazonian Coffee is a scene. Amazonian Coffee begins when hippolyta-unconscious is true and the clay bowl contains the rose powder and the clay bowl contains the glowing dirt and the clay bowl contains the moss and the clay bowl contains some vines and the clay bowl contains the Benadryl tablets.

Instead of inserting something into the clay bowl:
	if the noun is coffeeable:
		continue the action;
	else:
		say "No, it doesn't look like that goes in there.".

After inserting something into the clay bowl:
	say "You grind [the noun] into the clay bowl."

Grinding is an action applying to two things. Understand "grind [something] into [something]" and "grind [something] in [something]" as grinding.

Check grinding:
	if the second noun is not the clay bowl:
		say "You can't grind something into that." instead;
	else:
		try inserting the noun into the second noun instead.

When Amazonian Coffee begins:
	now hippolyta-unconscious is false;
	now the clay bowl is nowhere;
	now the moss is in Amazonia;
	now some vines are in Amazonia;
	now the glowing dirt is in Amazonia;
	say "As you mix the last of your ingredients into the clay bowl, you hear a whooshing sound and a brilliant green flash emits from the container. The resulting substance feels hot and heavy in the bowl, is black as night, and smells like lightning. You rush over to Hippolyta and pour the coffee down her throat. Her eyes open instantly, and she jolts up so quickly that the bowl flies through the air and smashes against the ground, broken.[paragraph break]'Hippolyta!' cries the Amazonian warrior and she gives her leader a fierce hug before helping her up. As Hippolyta comes to, her eyes begin to focus and she breaks out in a smile. 'Well, hero, I think at this point you've MORE than proven yourself worthy of the belt of the Amazons,' and she takes off her girdle and hands it to you.";
	now the player carries the girdle;
	increase the score by 1;
	follow the notify score changes rule;
	try requesting the score.
	
The Benadryl tablets are nowhere. The indefinite article of the Benadryl tablets is "some".

The description of the Benadryl tablets is "They are some ground-up Benadryl tablets from your trusty bottle of Benadryl."

Instead of inserting the bottle of Benadryl into the clay bowl:
	now the Benadryl tablets are inside the clay bowl;
	say "You grind some Benadryl tablets into the clay bowl.[line break]".

The description of the girdle is "A flashy green belt[if the score is greater than 8] with a small price tag on the inside leather. 'Worth 5 drachma' it reads.[else].[end if]"

Instead of wearing the girdle:
	say "No, it's not your style. You're more into practical waistwear like cell phone clips and fanny packs."

Test girdle with "sw/ se/ s/ s/ se/ e/ show mares to Amazon warrior/ ask Hippolyta about girdle/ take dirt/ take bowl/ take moss/ take vines/ take roses/ attack roses with pelt/ put dirt in bowl/ put moss in bowl/ put vines in bowl/ put rose powder in bowl/ put benadryl in bowl"

Chapter 11 - The Cattle of the Monster Geryon

Haggling is an action applying to nothing. Understand "haggle" as haggling.

Check haggling:
	If Geryon is in the location:
		say "Yes, it does rather look as though the monster would like to haggle. You could try buying something, selling something, or asking it about various products if you like." instead;
	else if the merchants are in the location:
		say "You'd rather not get trampled within the crowds of the marketplace." instead;
	else:
		say "It doesn't look as though there's anyone here who particularly wants to haggle.[if a person is in the location] However, I suppose you could try to ask someone about an item just to make sure.[end if]"

Erytheia is northwest of Elis. "This is a lovely scenic isle with friendly [palm trees], a neatly-tended [ranch] area, and [ocean] as clear as you've ever seen. The only exit you can see is back the way you came, to the southeast." Geryon is a neuter person in Erytheia. "There is a three-headed monster here[if cow-gotten is false] holding a [cow][end if]. You know the monster's name to be Geryon.". Geryon carries a cow. The cow is a female animal. The cow is portable.

Selling is an action applying to one thing. Understand "sell [something preferably held]" as selling.

Before selling something:
	if the player does not carry the noun:
		say "(first taking [the noun])";
	else:
		continue the action.

Check selling:
	if the player does not carry the noun:
		try silently taking the noun;
		if rule succeeded:
			try selling the noun instead;
		else:
			stop the action;
	else if Geryon is in the location:
		continue the action;
	else if the merchants are in the location:
		say "You'd rather not get trampled within the crowds of the marketplace." instead;
	else:
		say "You can see no buyers." instead.
		
Carry out selling:
	try showing the noun to Geryon instead.
		
Understand "monster" as Geryon.

Does the player mean giving something to the Cretan Bull:
	it is very unlikely.
	
Does the player mean giving something to the cow:
	it is very unlikely.
	
Does the player mean showing something to the Cretan Bull:
	it is very unlikely.
	
Does the player mean showing something to the cow:
	it is very unlikely.
	
Does the player mean asking the Cretan Bull for something:
	it is very unlikely.
	
Does the player mean asking the cow for something:
	it is very unlikely.

The description of the cow is "A small and thin-looking beast with the trademark udders and black and white splotches of a cow. It doesn't look particularly healthy or appealing but it's the only cattle you [if the player is in Erytheia]can see[else]saw[end if] within the entire ranch." Understand "cattle" as the cow.

The ranch is scenery in Erytheia. The description of the ranch is "Very neatly tended."

The palm trees are fixed in place things in Erytheia. "Some friendly palm trees dot the landscape here." The description of the palm trees is "Very friendly." Understand "tree" as the palm trees.

Instead of tying the flag to the palm trees:
	say "This would be a lovely spot for a hammock, but the trees here are too far apart for you to create one successfully."

Understand "pay for [something]" as buying.

Instead of buying the cow:
	if Geryon carries the cow:
		try asking Geryon for the cow instead;
	else:
		continue the action.
		
Instead of buying the coin purse:
	try asking Geryon for the coin purse.
	
Instead of buying the coins:
	try asking Geryon for the coins.

Instead of climbing the palm trees:
	say "No WAY. You're far too afraid of heights, and clumsy enough that you're liable to slip and break your neck."

Instead of asking Geryon about "[Geryon]":
	say "'The name's Geryon, Geryon is me. You be buyin or sellin?'"
	
Instead of asking Geryon about "himself":
	say "'The name's Geryon, Geryon is me. You be buyin or sellin?'"
	
Instead of touching the cow:
	say "You pet the cow and it gives a weak little 'moo,' nuzzling up to your fingers a bit."

Check asking the cow about anything:
	say "The cow lows softly at you." instead.
	
Check telling the cow about anything:
	say "The cow lows softly at you." instead.
	
Check showing anything to the cow:
	say "The cow lows softly at you." instead.
	
Check giving anything to the cow:
	say "The cow lows softly at you." instead.
	
The description of Geryon is "The monster Geryon seems more genial than you've heard. It's ugly, sure, with three heads (two of which don't seem to do anything), trollish features, patchy hair and a strong odor, but it isn't openly hostile towards you. It's currently using one of its six hands to count the [coins] in its [coin purse]."
	
Some coins are in the coin purse. Some coins are undescribed. The description of the coins is "Golden drachma, you believe.". Understand "golden drachma" and "drachma" and "gold" and "golden" as some coins.

Geryon carries a coin purse. The description of the coin purse is "It's Gucci, you believe."

Instead of taking the coin purse:
	say "Geryon bares its sharp yellowed teeth at you with all three of its heads, looking like a truly hostile monster for the first time. 'That'd be a mistake, that would, yes sir it would.'"
	
Instead of taking some coins:
	say "Geryon bares its sharp yellowed teeth at you with all three of its heads, looking like a truly hostile monster for the first time. 'That'd be a mistake, that would, yes sir it would.'"
	
Check asking Geryon about anything:
	say "'I don't know about nothin['] much except the goods I sell meself.'" instead.
	
Instead of asking Geryon about "[the coin purse]":
	say "'[']S Gucci, that is. I'll give it to yer for 10 million drachma and not a penny less.'".
	
Instead of asking Geryon for the coin purse:
	say "'[']S Gucci, that is. I'll give it to yer for 10 million drachma and not a penny less.'".

Instead of asking Geryon about "[the coins]":
	say "'Me golden drachma. Not for sale.'".
	
Instead of asking Geryon for the coins:
	say "'Me golden drachma. Not for sale.'".
	
Check telling Geryon about anything:
	say "'Sounds interestin... is it worth anything?'" instead.
	
Instead of telling Geryon about "[the cow]":
	If Geryon carries the cow:
		say "'I know that already - it's me cow, after all!'";
	else:
		say "'It's yers now, kid, do with it what you want.'"
		
Instead of telling Geryon about "[the coins]":
	say "'I know that already - they're me coins, after all!'".
	
Instead of telling Geryon about "[the coin purse]":
	say "'I know that already - it's me coin purse, after all!'".
	
Check showing anything to Geryon:
	say "'On a cursory glance it don't seem to be worth much, but I'll take it if yer offering.'" instead.
	
Check giving anything to Geryon:
	say "'Free samples? Sure!' The monster begins to grab [the noun] before you quickly re-think your decision and snatch it back. 'Aww... no take-backsies! Please?'" instead.

Time-one is a truth state that varies. Time-one is true. Time-two is a truth state that varies. Time-two is false. Time-three is a truth state that varies. Time-three is false. Time-four is a truth state that varies. Time-four is false. 

Instead of asking Geryon for the cow:
	try asking Geryon about "[the cow]" instead.

Instead of asking Geryon about "[the cow]":
	If Geryon carries the cow:
		If time-one is true:
			say "'You want me cow? No sir, I'm not parting with this one, no sir, this one's magic see. So I can't sell it to you for anything less than 80000 drachma.'";
			now time-one is false;
			now time-two is true;
		else if time-two is true:
			say "You tell the monster you can't afford that much and it scratches its left head. 'Well now, all right then, I'm not supposed to do this, but for first-time customers we used to have a bargain 90% off deal, and I suppose I could go back to that. So now it can be yers for only 8000 drachma. What a bargain!'";
			now time-two is false;
			now time-three is true;
		else if time-three is true:
			say "The monster scoffs as you say that's also too expensive. 'Cheapskate, eh? Well I suppose I could double the 90% deal but I'd have to consult with th['] higher-ups first,' and it reaches into its pocket to pull out an old Blackberry flip phone. It talks on it for a few minutes in a garbled, ancient monster language and then puts it away. 'Okay, they say I can do it. Only 800 drachma... I really shouldn't be doing this, but I'm telling youse, it's really an incredible bargain!'";
			now time-three is false;
		else:
			say "Geryon has had enough of your price range. The monster bellows 'Good Gods, kid, do ya have anything on ya of any value at all?'";
			now time-four is true;
	else:
		say "'It's yers now, kid, do with it what you want.'"
		
The receipt is a thing. The receipt is nowhere. The description of the receipt is "It's a very professional-looking store receipt you received from the monster Geryon along with your cow."

Instead of taking the cow:
	if Geryon carries the cow:
		say "'Hey, hey! Hands off th['] merchandise. If yer want me cow, you're going to have to pay for it!'";
	else:
		continue the action.

Initial-complete is a truth state that varies. Initial-complete is false. Cow-gotten is a truth state that varies. Cow-gotten is false.

Instead of showing the girdle to Geryon:
	if time-four is true:
		say "'I'll take it but I still won't give yer the co--' Geryon begins, but then its eyes sparkle as it finally notices the price tag. 'Is tha['] truly the girdle of Hippolyta yer have there?' it wonders aloud. 'It would make a splendid addition to me belt collection...' The monster's eyes go blank for a split second and then it seems to make up its mind.  'Alright, fine. It's a damn crime what you've got me to do, I might be fired if the higher-ups ever find out, but I'll do it. Here's yer stinkin['] cow, just give me that dang girdle.' And it hands over the cow and your receipt (printed out almost instantly from an unseen electronic device in its pocket) just as you hand it the girdle.";
		now the player carries the cow;
		now Geryon carries the girdle;
		now the player carries the receipt;
		now initial-complete is true;
		now cow-gotten is true;
		increase the score by 1;
		follow the notify score changes rule;
		try requesting the score;
	else:
		continue the action.
		
Instead of giving the girdle to Geryon:
	if time-four is true:
		say "'I'll take it but I still won't give yer the co--' Geryon begins, but then its eyes sparkle as it finally notices the price tag. '[']S that truly the girdle of Hippolyta yer have there?' it wonders aloud. 'It would make a splendid addition to me belt collection...' The monster's eyes go blank for a split second and then it seems to make up its mind.  'Alright, fine. It's a damn crime what you've got me to do, I might be fired if the higher-ups ever find out, but I'll do it. Here's your stinkin['] cow, just give me that dang girdle.' And it hands over the cow and your receipt (printed out almost instantly from an unseen electronic device in its pocket) just as you hand it the girdle.";
		now the player carries the cow;
		now Geryon carries the girdle;
		now the player carries the receipt;
		now initial-complete is true;
		now cow-gotten is true;
		increase the score by 1;
		follow the notify score changes rule;
		try requesting the score;
	else:
		continue the action.
		
Check taking the cow:
	if cow-gotten is false:
		say "That seems to belong to Geryon." instead;
	else if the player carries the cow:
		say "You already have that.[line break]" instead;
	else:
		now the player carries the cow;
		say "You take the rope attached to the cow and begin leading it along.[line break]" instead.
		
After dropping the cow:
	say "You drop the rope attached to the cow and leave it be." 

	
Instead of going southeast in Erytheia:
	if the score is less than 10:
		say "You are about to leave when you hear a soft whine from behind. You turn around to see Geryon shifting its feet nervously. 'Don't you want to haggle[if time-one is false] a bit more[end if]?' it says, pouting.";
		if the score is 9:
			if the player carries the girdle:
				stop the action;
			else:
				say "[line break]Part of you wants to, but you have a sneaking suspicion you don't have everything you need to haggle properly, so you book passage on a ferry back towards...";
				continue the action;
		else:
			say "[line break]Part of you wants to, but you've got a lot left on your list, so you think you'd better book passage on a ferry back towards...";
			continue the action;
	else:
		say "You book passage on a ferry back towards...";
		continue the action.
		

Test cattle with "w/ nw/ n/ n/ w/ nw/ ask Geryon about cow/ ask Geryon about cow/ ask Geryon about cow/ ask Geryon about cow/ give girdle to Geryon/ se/ e/ s/ e/ give list to Eurystheus"

Instead of telling Eurystheus about "the list":
	say "'Show it to me if you think you're finished, otherwise go away and do my bidding, twerp.'"
	
Instead of telling Eurystheus about "list":
	say "'Show it to me if you think you're finished, otherwise go away and do my bidding, twerp.'"
	
Instead of asking Eurystheus about "the list":
	say "Eurystheus rolls his eyes and says, 'Of course I know about that list you imbecile, I'm the one who gave it to you!'"
	
Instead of asking Eurystheus about "list":
	say "Eurystheus rolls his eyes and says, 'Of course I know about that list you imbecile, I'm the one who gave it to you!'"

Instead of showing the list to Eurystheus:
	if initial-complete is true:
		try giving the list to Eurystheus instead;
	else if finished-yes is true:
		try giving the list to Eurystheus instead;
	else:
		say "Eurystheus chuckles sneeringly at you as he reads over your list and quickly hands it back. 'You still have [if twelve-labors is true][12 minus the score][else][10 minus the score][end if] item[s] left to do, cousin. Better hop to it. You're not... giving up are you?' He bursts into a fit of cackling laughter and the advisors hidden behind his throne promptly join in."

Instead of giving the list to Eurystheus:
	if initial-complete is true:
		say "Eurystheus looks over your list and reads your notes on how you completed each task. Soon he grows red with rage. 'You little twerp!!' he squeaks. 'How could you possibly have done all of these tasks? They were supposed to be IMPOSSIBLE.' You can feel his spittle land on your cheek. Then as he reads over the tasks some more he begins to grin a maniacal grin and his eyes cloud over seeing something you can't. For a moment you think you glimpse the ghost of Hera whispering in your cousin's ear, but when you blink, she's gone, so you must have imagined it.[paragraph break]Eurystheus suddenly rises from his chair and announces 'You have done... well, cousin, but I am afraid I cannot accept two of these tasks. You see, you had the help of your nephew Iolaus when slaying the Hydra, and you only captured the Erymanthian Boar by slaying it--neither was truly done by your hand alone. Thus, your ten labors are only eight in number.' He gives a little snicker standing on his throne. 'Therefore I am adding two more to your list. Let's see how you do with THESE tasks. I hope you're not too... burnt out,' and with that, he plops back into his chair, cackling at a joke you're not understanding. You retrieve the new list from your cousin.";
		now twelve-labors is true;
		now initial-complete is false;
	else if finished-yes is true:
		say "Eurystheus sees that you've completed your final tasks and begins to seethe, but as soon as he catches sight of Cerberus (vicious even whilst shrunken within his magical cage), he breaks out in a cold sweat. Suddenly overcome with fear at the thought of your power, he calls for his guards, who all surround you at spearpoint. You break out in hives and grow white as a sheet as you try to register your cousin's betrayal. The guards begin to slowly close in and you think the end has come at last...[paragraph break]All of a sudden, the door bursts in and a small army erupts into the palace. You recognize most of them as the Amazon warriors, led by the guard who helped you save Hippolyta, but you glimpse a few other familiar faces in the mix, such as the goddess Artemis glowing gold and showering arrows at Eurystheus's footsoldiers, or the monster Geryon somehow looking to sell extra spears in the midst of the battle, or of course your nephew Iolaus who worryingly got ahold of a few sticks of dynamite somehow. Eurystheus's guards, while numerous, are far outnumbered by the horde of intruders and soon drop their weapons in surrender.[paragraph break]As the struggle ends you see Hippolyta emerge from the crowd and lope over to you, a magisterial spring in her step. 'I thought you might need my assistance young hero. Your heart is noble but your skill in battle is... deficient.' You are not at all offended by the more-than-fair criticism. 'However, it is not solely for you that I've assembled this mighty force today. Remember!' and now she is shouting to the whole crowd. 'Let the Goddess Hera be forever warned-- nobody attacks me and walks away unscathed!' The Amazons let out a cheer and you see one of them slap your cousin across the face. There is a sudden booming from the heavens above and you can almost hear the queen of the Sky give a muffled scream of defeat. [paragraph break]You celebrate victory over Eurystheus with your nephew and the Amazons late into the night, feasting on fresh meat and wine. Just as you have retired for the night, you feel yourself rise into the heavens and suddenly you are in front of your father, Zeus, a little old man with a heavy white beard, a cane, and horn-rimmed spectacles. 'You have done well, my son,' he intones wisely. 'And now you may live with me in my palace, if you so choose! Well? What do you say?' You take a moment to breathe, since rising up to Mount Olympus like that was pretty asthma-inducing, but eventually you manage a weak smile. Your father chortles slightly. 'Oh and of course, I remembered to bring your inhaler,' and with a snap of his fingers, your baby-blue inhaler with the giraffes on it appears in your fist. The sight of your long-lost medicine immediately calms you, and you contemplate your immense accomplishment of having completed all your Labors without it. For the first time in your life, you feel strong. [line break]";
		end the story finally saying "Congratulations! You're an Honorary God on Mount Olympus.";
	else:
		say "Eurystheus chuckles sneeringly at you as he reads over your list and quickly hands it back. 'You still have [if twelve-labors is true][12 minus the score][else][10 minus the score][end if] item[s] left to do, cousin. Better hop to it. You're not... giving up are you?' He bursts into a fit of cackling laughter and the advisors hidden behind his throne promptly join in.".

Chapter 12 - The Apples of the Hesperides

The Western Shore is west of Lerna. "The western shore of Greece. Nothing but coarse sand and the salty ocean can be seen here. The dangerous Garden of the Hesperides is all that lies west of here, otherwise you can go back to Lerna to the east."

Instead of going west in Western Shore:
	If twelve-labors is false:
		say "No way! They say the garden is guarded by a terrifying dragon named Ladon. You're not going that way unless you absolutely have to, especially with your anxiety and muscular deficiencies.";
	else:
		say "You're shaking in your boots as you approach...";
		continue the action.

The Garden of the Hesperides is west of the Western Shore. "This is a beautiful, heavenly garden, with an [enormous tree] filled with apples in the center. The air is completely warm, pristine, and pleasant, almost the opposite air as is present in the City Palace of Tiryns. [paragraph break]You can go back to the western shore to the east and there is a cave-like structure to the northeast which is emitting a low-pitched ethereal hum. In the distance, you can also see a [strange staircase] leading downwards, perhaps to some God-like otherworldly plane of existence.[if Ladon is not in the Garden of the Hesperides][paragraph break]The enormous apple tree, now fully in view thanks to Ladon's absence, looks very enticing, with its branches full of divine red apples.[end if]"

The strange staircase is scenery in the Garden of the Hesperides. Understand "stair" and "steps" as the strange staircase.

Understand "stairs" and "strange stairs" and "stairway" and "strange stairway" as the strange staircase. The description of the strange staircase is "The steps seem to appear and disappear from the otherworldly staircase and you get the strange sense that they go down as far as is possible to go down."

Instead of taking the strange staircase:
	try going down instead.
	
Instead of climbing the strange staircase:
	try taking the strange staircase instead.

The cave is a backdrop. The cave is in the Garden of the Hesperides and the Shrine of the Oracle at Delphi. The description of the cave is "[if the player is in the Garden of the Hesperides]As you turn your attention to the cave, you notice wisps and curls of smoke seeping from its mouth, and the low-pitched ethereal hum seems to grow a bit louder.[else]Very dark and forboding.[end if]"

Understand "hum" and "smoke" as the cave.

Instead of going northeast from the Garden of the Hesperides:
	if Ladon is in the Garden of the Hesperides:
		say "The dragon blocks your way and roars. You manage to dodge its fiery attack as it turns the grass where you were standing to ash. Boy, you really should have brought your inhaler with you on these errands.";
	else:
		continue the action.
		
The Shrine of the Oracle at Delphi is northeast of the Garden of the Hesperides. "You have entered a dark and forboding cave. The only exit is back the way you came, to the southwest. [paragraph break]There is a [golden shrine] here."

The golden shrine is a portable supporter in the Shrine of the Oracle at Delphi. The description of the golden shrine is "It's a small golden statue of a meditating girl cupping her hands, as though presenting an offering. Her hands are fairly large, creating a low shelf. A small sticker on the edge of the statue reads 'DO NOT TOUCH.'"

Instead of entering the golden shrine:
	say "Are you planning on offering yourself up to the Oracle at Delphi? No, I thought not."

Understand "shelf" and "hands" and "girl" and "statue" and "sticker" as the golden shrine.

Instead of taking the golden shrine:
	say "'Do not touch, please,' a bored voice drawls from nowhere. 'Place your payment on the shrine. Something monstrous, something divine.'"
	
Instead of touching the golden shrine:
	say "'Do not touch, please,' a bored voice drawls from nowhere. 'Place your payment on the shrine. Something monstrous, something divine.'"
	
Instead of pushing the golden shrine:
	try touching the golden shrine.
	
Prophecy is a scene. Prophecy begins when the red apple is on the golden shrine and the receipt is on the golden shrine and less than 3 things are on the golden shrine. 

The ticket stub is a thing. The ticket stub is nowhere. The description of the ticket stub is "'ADMIT ONE: HADESTOWN (NOW A TONY AWARD-WINNING BROADWAY MUSICAL!)'"

Prophecy-told is a truth state that varies. Prophecy-told is false.

When Prophecy begins:
	say "'Payment accepted,' drawls the voice, and the objects on the shrine disappear. 'Let the prophecy begin.' And suddenly, your mind is filled with a startling image of you in the City Palace of Tiryns. Right next to the throne you notice that a piece of the floor tiling has been mis-aligned. You try to shift it and the tile becomes a trapdoor, opening into a dark staircase downwards. You travel down and down and down and down until you reach...[paragraph break]The vision clears and you find yourself once again in front of the shrine, although it looks slightly different than before. The bored voice from nowhere intones 'Thank you for visiting the Shrine of the Oracle at Delphi. Remember that Tuesdays are 50% off for first-timers. Have a nice day.'";
	now the red apple is in the Waiting Area;
	now the receipt is nowhere;
	now prophecy-told is true;
	now the ticket stub is on the golden shrine.

The Underworld is down from the Garden of the Hesperides.

Instead of dropping a meaty thing:
	if Ladon is in the location or the player is in the Gates of Hades:
		say "And watch your livestock be turned into kibble? No way!";
	else:
		continue the action.

Instead of giving a meaty thing to someone:
	if the second noun is Ladon or the second noun is Cerberus:
		say "And watch your livestock be turned into kibble? No way!";
	else:
		continue the action.

Instead of going down from the Garden of the Hesperides:
	if Ladon is in the Garden of the Hesperides:
		say "The dragon blocks your way and roars. You manage to dodge its fiery attack as it turns the grass where you were standing to ash. Boy, you really should have brought your inhaler with you on these errands.";
	else:
		say "You attempt to step on the first step but your foot goes right through the stairway! You step back hastily. Looks like only spirits can go down the strange staircase.".

Ladon is a person in the Garden of the Hesperides. "There is a monstrous, terrifying dragon named Ladon here."

Check asking Ladon about anything:
	say "The dragon roars a mighty roar and your knees become jelly. You'll never be able to reason with it..." instead.
	
Check telling Ladon about anything:
	say "The dragon roars a mighty roar and your knees become jelly. You'll never be able to reason with it..." instead.
	
Check giving anything to Ladon:
	say "The dragon roars a mighty roar and your knees become jelly. You'll never be able to reason with it..." instead.
	
Check showing anything to Ladon:
	say "The dragon roars a mighty roar and your knees become jelly. You'll never be able to reason with it..." instead.
	
Instead of showing the chewed bone to Ladon:
	say "The dragon sits up and starts panting at the sight of the bone, but soon shakes off the strange behavior, roaring a mighty roar. Your knees become jelly. You'll never be able to reason with it...".
	
Instead of giving the chewed bone to Ladon:
	say "The dragon sits up and starts panting at the sight of the bone, but soon shakes off the strange behavior, roaring a mighty roar. Your knees become jelly. You'll never be able to reason with it...".
	
Instead of throwing the chewed bone at Ladon:
	say "It does seem rather like the dragon is itching to run after something, but you can't just throw it right at him, he'd just eat it and then eat you. Besides, with your muscles? Hah! That wouldn't do anything except trigger your asthma."

The description of Ladon is "You are spellbound by the long black claws, lizardly wagging tail, vicious sharp white teeth, crimson skin, and smokey, billowing breath emanating from the dragon's nostrils. The beast seems restless, and its great, bat-like wings shiver and fidget in anticipation of chasing after something."

Understand "dragon" and "the dragon" and "lizard" as Ladon.

The chewed bone is in the Garden of the Hesperides. The description of the chewed bone is "Ugh... it's still got some flecks of meat on it. You long for the days when plastic knives were all you found from luckless adventurers."

Instead of eating the chewed bone:
	say "Are you a dragon or a dog? No, I thought not."

The enormous tree is a supporter in the Garden of the Hesperides. "[if Ladon is in the Garden of the Hesperides]An enormous tree is brimming with heavenly apples here, but it's partially obscured by the dreadful dragon.[else]The enormous apple tree, now fully in view thanks to Ladon's absence, looks very enticing, with its branches full of divine red apples." The enormous tree is fixed in place. Understand "tree" and "appletree" and "apple tree" and "glorious tree" and "glorious" and "enormous apple tree" as the enormous tree. Understand "apple" as the red apple.

Instead of putting something on the enormous tree:
	say "You find that a very silly idea and think it best not to entertain it any longer."
	
Picking is an action applying to one thing. Understand "pick [something]" and "pluck [something]" as picking.

Check picking:
	if the noun is the wild grasslands:
		try taking the wild grasslands instead;
	else if the noun is not the red apple:
		say "[Those] can't be plucked." instead;
	else if the noun is not on the enormous tree and the player is in the Garden of the Hesperides:
		say "No, stealing one piece of forbidden fruit is enough. You don't want to be like Eve." instead.
		
Carry out picking:
	try taking the noun instead.		

Does the player mean taking the enormous tree:
	it is very unlikely.
	
Does the player mean eating the enormous tree:
	it is very unlikely.
	
Does the player mean tasting the enormous tree:
	it is very unlikely.

The red apple is an undescribed thing. The red apple is on the enormous tree. The description of the enormous tree is "You can see a [red apple] hanging from every branch of this glorious tree. They all look simply divine."

Understand "apple" as the red apple. The description of the red apple is "The apple looks absolutely divine, almost too perfect. You expect Snow White to come running any minute now."

Instead of smelling the red apple:
	say "It smells crisp and clean and heavenly, but you're on a low-acid diet so you can't partake.".

Instead of eating the red apple:
	say "The red apple looks absolutely scrumptious but you're on a low-acid diet so you can't partake."

Instead of throwing the chewed bone at the strange staircase:
	if Ladon is in the Garden of the Hesperides:
		say "You manage to chuck the chewed bone down the strange staircase and watch it bounce down each step. Ladon gives a fiery, excited bark and flies after it down the stairs, tail wagging as he flies.";
		now Ladon is nowhere;
		now the chewed bone is in the Gates of Hades;
	else:
		say "You're not in the mood to play fetch right now."
	
Instead of throwing the chewed bone at the enormous tree:
	if Ladon is in the Garden of the Hesperides:
		say "Ladon stands between you and the apple tree, so he'd catch it immediately.";
	else:
		say "You're not in the mood to play fetch right now."
		
Instead of throwing the chewed bone at the cave:
	if Ladon is in the Garden of the Hesperides:
		say "The cave isn't very far away, so that wouldn't keep Ladon occupied very long.";
	else:
		say "You're not in the mood to play fetch right now."
		
Instead of throwing the chewed bone at the red apple:
	if Ladon is in the Garden of the Hesperides:
		say "Ladon stands between you and the apple tree, so he'd catch it immediately.";
	else:
		say "You're not in the mood to play fetch right now."
		
Apple Theft is a scene. Apple Theft begins when the player carries the red apple for the first time. Apple-taken is a truth state that varies. Apple-taken is false.
		
When Apple Theft begins:
	increase the score by 1;
	follow the notify score changes rule;
	try requesting the score;
	now apple-taken is true.
	
After deciding the scope of the player:
	if the location is the Garden of the Hesperides:
		place the red apple in scope;
	else if the location is Amazonia and warrior-guard is false:
		place some vines in scope;
		place some roses in scope;
		place the moss in scope;
		place the glowing dirt in scope.

Rule for reaching inside a room:
	if the noun is the red apple:
		allow access;
	if the noun is a medicinal thing:
		allow access.
		
Check taking the red apple:
	If Ladon is in the Garden of the Hesperides:
		say "The dragon blocks your way and roars. You manage to dodge its fiery attack as it turns the grass where you were standing to ash. Boy, you really should have brought your inhaler with you on these errands." instead;
	else if the player is in the Garden of the Hesperides and the player carries the red apple:
		say "No, stealing one piece of forbidden fruit is enough. You don't want to be like Eve." instead;
	else if the player is in the Garden of the Hesperides and the red apple is not on the enormous tree and the red apple is not in the Garden of the Hesperides:
		say "No, stealing one piece of forbidden fruit is enough. You don't want to be like Eve." instead;
	else if the player is in the Garden of the Hesperides and apple-taken is true and apple-dropped is false:
		say "No, stealing one piece of forbidden fruit is enough. You don't want to be like Eve." instead;
	else:
		now apple-dropped is false;
		continue the action.	
		
Apple-dropped is a truth state that varies. Apple-dropped is false.

Before dropping the red apple:
	now apple-dropped is true.
	
test apples with "w/ s/ w/ w/ take bone/ throw bone at strange staircase/ take red apple"

Chapter 13 - Cerberus of Hades

Underworld-found is a truth state that varies. Underworld-found is false.

Before going down from the City Palace:
		say "[if underworld-found is false]You discover a trapdoor composed of mis-aligned tile right beside your cousin's throne! You inconspicuously open it and follow the stairs down, down, down, down, until you finally reach...[else]You inconspicuously open the trapdoor and follow it down, down, down, down, until you finally reach...[end if]";
		now underworld-found is true.

The Underworld is down from the City Palace. "This is the realm of Hades, God of Death, who sorts through the souls of the deceased and decides who goes to Elysium (good), Asphodel (neutral), or Tartarus (bad) after they die. A simple brown staircase leads up."

The simple brown staircase is a backdrop. The simple brown staircase is in the Underworld and the City Palace. The description of the simple brown staircase is "[if the player is in the City Palace and underworld-found is false]You can't see any such thing.[else if the player is in the City Palace]You can't see any such thing. (Because you closed the hidden trapdoor on the way back up.)[else]This is the staircase you just took, which leads back up to the City Palace.[end if]". Understand "stairs" and "stair" and "stairway" as the simple brown staircase. 

Instead of taking the simple brown staircase:
	if the player is in the Underworld:
		try going up instead;
	else:
		if underworld-found is true:
			try going down instead;
		else:
			say "You can't see any such thing."
			
Instead of climbing the simple brown staircase:
	try taking the simple brown staircase instead.

The City Palace is up from the Underworld.

Before going up from the Underworld:
	say "You go back up the stairway up, up, up, up until you reach the trapdoor and go back into the...".

Charon is a person in the Underworld. "You can see the skeleton boatman, Charon, here, ready to transport deceased souls across the river Styx [if the player is in the Underworld]to the east.[else]to the west.[end if][first time][paragraph break]Who knew that all this time the Underworld was right underneath your cousin's house? What kind of symbolism could that be, you wonder.[only]"

Understand "boatman" and "boat man" and "skeleton" and "skeleton boatman" and "skeleton boat man" and "ghoul" as Charon.

The river Styx is a backdrop. The river Styx is in the Underworld and the Gates of Hades. Understand "water" and "bubbles" and "swirls" as the river Styx.

The description of the river Styx is "A spooky, mist-covered river which the recently deceased cross to reach the entrance to the land of the dead. It bubbles and swirls ominously as you approach."

Instead of entering the river Styx:
	try swimming instead.

The boat is a backdrop. The boat is in the Underworld and the Gates of Hades. Understand "raft" and "ferry" and "sanded raft" and "sanded" and "ship" as the boat. 

Instead of taking the boat:
	try entering the boat instead.
	
Instead of riding the boat:
	try entering the boat instead.

Instead of entering the boat:
	if the player is in the Underworld:
		say "Charon stops you. 'Payment,' the ghoul intones, and a picture forms inside your mind of a ticket stub.";
	else:
		try going west instead.

The description of the boat is "[if the player is in the Gates of Hades]The raft is still here, moored up on the side of the Styx. Charon waits upon it, idly scrolling through his phone. He sees you staring at him and quickly puts it away.[else]The boat really is not much more than a sanded raft with upturned ends. It is rickety-looking and probably not the most stable ride in the world, but the only way to cross the Styx is to have Charon ferry you across.[end if]"

Instead of going east from the Underworld:
	say "You can't cross the river Styx by yourself! The water is lethal! Besides, you can't swim without your arm floats, which you left at home."

The description of Charon is "All you can see of Charon is skeleton hands emerging from a [long black cloak] with the face covered. [if the player is in the Gates of Hades]Charon is currently scrolling through his phone while he waits for you on the boat, but he quickly puts it away after noticing you staring at him.[end if]"

Charon wears a long black cloak. The long black cloak is undescribed. The description of the long black cloak is "Very grim-reapery. That's probably where he got the idea, you figure.". Understand "robe" and "black robe" and "long black robe" as the long black cloak.

Check asking Charon about anything:
	say "[if the player is in the Underworld]'Payment,' the ghoul intones, and a picture forms inside your mind of a ticket stub.[else]'Oh the questions of the living...' the ghoul drawls.[end if]" instead.
	
Check telling Charon about anything:
	say "[if the player is in the Underworld]'Payment,' the ghoul intones, and a picture forms inside your mind of a ticket stub.[else]'Oh the chattering of the living...' the ghoul drawls.[end if]" instead.
	
Check showing anything to Charon:
	say "[if the player is in the Underworld]'Payment,' the ghoul intones, and a picture forms inside your mind of a ticket stub.[else]'Oh the vanity of the living...' the ghoul drawls.[end if]" instead.
	
Check giving anything to Charon:
	say "[if the player is in the Underworld]'Payment,' the ghoul intones, and a picture forms inside your mind of a ticket stub.[else]'Oh the propositions of the living...' the ghoul drawls.[end if]" instead.
	
Instead of giving the old coin of Hades to Charon:
	say "[if the player is in the Underworld]The ghoul frowns at you morosely. 'We gave those up years ago. New system is ticket stubs,' and a picture forms inside your mind of said ticket stub.[else]Charon nods and hands the coin back to you. 'The old system was better. Less paperwork.'[end if]"
	
Instead of showing the old coin of Hades to Charon:
	say "[if the player is in the Underworld]The ghoul frowns at you morosely. 'We gave those up years ago. New system is ticket stubs,' and a picture forms inside your mind of said ticket stub.[else]Charon nods. 'The old system was better. Less paperwork.'[end if]"
	
Instead of giving the ticket stub to Charon:
	say "'Payment accepted,' the ghoul intones, and lets you cross on the raft.[line break]";
	now the ticket stub is nowhere;
	now Charon is in the Gates of Hades;
	now the player is in the Gates of Hades.

The Gates of Hades is east of the Underworld. "This is the entrance to the part of the Underworld where all the dead souls go. You can see several [spirits] guarding an [iron gate] to the south and leering at the wretched [souls] who pass through it to the three realms."

Some spirits are people in the Gates of Hades. "You can see several [spirits] guarding the [iron gate] and leering at the wretched [souls] who pass through it to the three realms.". The description of the spirits is "The spirits leer down at the wretched souls below and cackle at their misfortune." Understand "demons" and "demon" and "spirit" as the spirits.

Check asking some spirits about anything:
	say "They cackle at your misfortune." instead.
	
Check telling some spirits about anything:
	say "They cackle at your misfortune." instead.
	
Check giving anything to some spirits:
	say "They leer at your pitiful offering." instead.
	
Check showing anything to some spirits:
	say "They leer at your pitiful display." instead.

Some souls are people in the Gates of Hades. The description of the souls is "Poor, unfortunate souls.". Understand "deceased" and "recently-deceased" and "ghosts" and "dead people" and "soul" as the souls.

Check asking some souls about anything:
	say "They do nothing but moan at you in a spooky, warbly language you can't understand. Poor, unfortunate souls." instead.
	
Check telling some souls about anything:
	say "They do nothing but moan at you in a spooky, warbly language you can't understand. Poor, unfortunate souls." instead.
	
Check giving anything to some souls:
	say "Gifts are for the living." instead.
	
Check showing anything to some souls:
	say "Displays are for the living." instead.

Before going west from the Gates of Hades:
	say "You get in the boat and Charon hands you back your ticket. 'New special today, unlimited passes back to the Land of the Living for the Day of the Dead....' the ghoul drones. You hold in your seasickness as you're ferried back to the entrance of the...";
	now Charon is in the Underworld;
	now the player carries the ticket stub.
	
Instead of going south from the Gates of Hades:
	say "Cerberus leaps in front of you and barks a terrifying bark! You back away quickly as the malevolent spirits laugh at your pitiful attempt. Best not to try that route again until you're dead."
	
The Waiting Area is south of the iron gate. "If you've somehow got yourself back here without messing with the source code for this game, something is seriously wrong and I apologize profusely. The Gates of Hades are to the north and I suggest you go back that way and continue with your adventure." 

The iron gate is south of the Gates of Hades. The iron gate is a door. The iron gate is locked. The description of the iron gate is "A vast gate made of what looks to be wrought iron. Spikes point up at the top of it and cross-hatching bars line the bottom and middle of the structure. However, you see some of the recently-deceased glide through it like it's made of waterfall. It's clearly only meant to keep out the living."

Cerberus is a person in the Gates of Hades. "Cerberus, the guard dog of Hades, stands in front of the iron gate to the south, his three heads slobbering and his eyes black with malice." Understand "guard" and "hound" and "bloodhound" and "blood hound" and "dog" and "guarddog" and "guard dog" as Cerberus.

The description of Cerberus is "He's a [if finished-yes is false]large[else]small[end if] three-headed bloodhound. [if finished-yes is false]He'd be kind of cute if he wasn't 40ft tall with teeth the size of you. You shiver with fear.[else]He's kind of cute![end if]"

Check asking Cerberus about anything:
	say "[if finished-yes is false]The wary guard dog growls at you with two of its heads (one is panting to remain cool) and you back away slowly...[else]Cerberus gives you an annoyed 'Yip!' from within the cage. You laugh.[end if]" instead.
	
Check telling Cerberus about anything:
	say "[if finished-yes is false]The wary guard dog growls at you with two of its heads (one is panting to remain cool) and you back away slowly...[else]Cerberus gives you an annoyed 'Yip!' from within the cage. You laugh.[end if]" instead.
	
Check giving anything to Cerberus:
	say "[if finished-yes is false]The wary guard dog growls at you with two of its heads (one is panting to remain cool) and you back away slowly...[else]Cerberus gives you an annoyed 'Yip!' from within the cage. You laugh.[end if]" instead.
	
Check showing anything to Cerberus:
	say "[if finished-yes is false]The wary guard dog growls at you with two of its heads (one is panting to remain cool) and you back away slowly...[else]Cerberus gives you an annoyed 'Yip!' from within the cage. You laugh.[end if]" instead.

The small doggie cage is a thing in the Gates of Hades. The small doggie cage is an openable open transparent container. 

Instead of showing the small doggie cage to Eurystheus:
	say "Eurystheus appears to be trying very hard not to look at the small doggie cage for some reason."
	
Instead of giving the small doggie cage to Eurystheus:
	say "Eurystheus appears to be trying very hard not to look at the small doggie cage for some reason."

Instead of entering the small doggie cage:
	if the player is in the Gates of Hades:
		say "Are you the guard dog of Hades? No, I thought not.";
	else:
		continue the action.

Instead of closing the small doggie cage:
	say "It looks like you'd be able to close it with a little effort as the door to the cage is made of a surprisingly light material you can't quite place. But you can't close it with Cerberus watching you this intently."
	
Instead of opening the small doggie cage:
	if the small doggie cage is open:
		continue the action;
	else:
		say "No, you don't want to let Cerberus out!".

The description of the small doggie cage is "[if finished-yes is false]Small for giants, I meant. It's about 50ft high.[else]The cage has shrunk down to a regular doggie-cage size, as has Cerberus.[end if]"

Instead of taking the small doggie cage:
	if finished-yes is false:
		say "What, do you think you're super strong or something?";
	else:
		continue the action.

Instead of pushing the small doggie cage:
	if finished-yes is true:
		say "You push the cage and Cerberus gives an annoyed 'Yip!' from within.";
	else:
		continue the action.

Finished-yes is a truth state that varies. Finished-yes is false. 

A thing can be meaty or vegetarian. A thing is usually vegetarian. The cow is meaty. The Cretan Bull is meaty. 

Chewtoys is a number that varies. Chewtoys is initially 0.

Before inserting anything into the small doggie cage:
	now chewtoys is 1;
	continue the action.
	
Before taking anything inside the small doggie cage:
	now chewtoys is 1;
	continue the action.
	
Before removing anything from the small doggie cage:
	now chewtoys is 1;
	continue the action.

Every turn when the player is in the Gates of Hades:
	If chewtoys is 1:
		if the small doggie cage contains at least one vegetarian thing:
			if the small doggie cage contains at least one meaty thing:
				say "Cerberus charges at the cage, sensing a feast, but there are enough distractions within the cage for him to be a little more aware of himself, and he stops you before you can close the cage, bolting out of the container and barking in displeasure at your attempted trickery.";
				now chewtoys is 0;
			else:
				say "Cerberus charges at the cage, but finding no fresh meat, immediately runs outside again.";
				now chewtoys is 0;
		else:
			if there is more than one meaty thing in the small doggie cage:
				say "Cerberus charges at the cattle in the doggie cage, and while he is gorging himself on an abundance of fresh meat, you shut the cage as quietly as you can. As soon as the cage clangs shut, it automatically shrinks to a regular doggie-cage size. You pick it up[if the player does not carry the list] along with your list[end if], take the raft back to the entrance (returning your ticket as you do so - you won't need it anymore), and go back up to the City Palace.";
				now Cerberus is inside the small doggie cage;
				now the player carries the small doggie cage;
				now the small doggie cage is closed;
				now the Cretan Bull is nowhere;
				now the cow is nowhere;
				now the player carries the list;
				now chewtoys is 0;
				now the player is in the City Palace;
				now Charon is in the Underworld;
				now finished-yes is true;
				increment the score;
				follow the notify score changes rule;
				try requesting the score;
			else if there is nothing in the small doggie cage:
				continue the action;
				now chewtoys is 0;
			else:
				say "Cerberus charges at the cage, sensing a feast, but there is not quite enough meat for him to gorge himself on, and so he stops you before you can close the cage, bolting out of the container and barking in displeasure at your attempted trickery.";
				now chewtoys is 0;
	else:
		continue the action.
		
Chapter 14 - Appendices
	
test cerberus with "ne/ put apple on shrine/ put receipt on shrine/ take stub/ sw/ e/ e/ n/ e/ down/ give stub to Charon/ put cow in cage/ put Cretan Bull in cage/ give list to eurystheus"

test game1 with "test lion/ test hydra/ test hind/ test boar/ test stables/ test stymphalia/ test bull/ test mares1"

test game2 with "test mares2/ test girdle/ test cattle/ test apples/ test cerberus"

Table of Rankings
Score	Rank
0	"Nerdy Cousin"
1	"Lion Tamer"
2	"Hydra Decapitator"
3	"Dream Catcher"
4	"Boar Toreador"
5	"Janitorial Juggernaut"
6	"Pigeon Poisoner[if zork-yes is true] and Master Adventurer[end if]"
7	"Bull Whisperer[if zork-yes is true] and Master Adventurer[end if]"
8	"Trojan Hacker[if zork-yes is true] and Master Adventurer[end if]"
9	"Medicinal Magician[if zork-yes is true] and Master Adventurer[end if]"
10	"Superb Salesman[if zork-yes is true] and Master Adventurer[end if]"
11	"Dragon Player[if zork-yes is true] and Master Adventurer[end if]"
12	"[if the story has ended]Honorary God and [end if]Legendary Hero[if zork-yes is true] and Master Adventurer[end if]"


Table of Footnotes
assignment	note
1	"For some reason your cousin's capital S's always look like F's. I guess you'll just have to guess which one is correct...[line break]"
2	"Not that you ever really used them. They were a late birthday present from your stepmother Hera, who knew you were afraid of fire... you get the sense she doesn't like you very much.[line break]"
3	"A hind is a deer. (A female deer.) This one's bathed in a ray. (A drop of golden sun.) I wouldn't want you to think you were wandering the land searching for a giant floating butt.[line break]"
4	"You don't know who this month's Olympics winner is off-hand, of course. Unsurprisingly, you have no use for frivolous sporting events.[line break]"
5	"Weren't these numbers different the last time you read them? You blink. Yep, definitely different. You curse your dyslexia and try to focus on the note more intently.[line break]"
6	"A scandal which caused Zeus's wife Hera, the queen of the Sky, to get really mad at Alcmene and you. (Though never her husband, which seems strange, since he was the one truly in the wrong.) You think perhaps this is the genesis of Hera's intense dislike of you to this day.[line break]"
7	"You've never ever seen yellow-spotted lizards like these. Not even in the movie [italic type]Holes[Roman type].[line break]"
8	"Whatever you throw at it, it seems like the monkey isn't coming down.[line break]"
9	"Perhaps you need to consider that these actually are NOT the droids you're looking for.[line break]"
10	"Okay, you've had your fun now, stop reading the footnotes.[line break]"
11	"Seriously, I mean it![line break]"
12	"Anybody want a peanut?[line break]"
13	"There is no such footnote.[line break]"
14	"Really now, there is no such footnote.[line break]"
15	"There is no such footnote.[line break]"
16	"Okay, you get one final easter egg. Happy? After this moment you're really just wasting your own time, and I'm not to be held responsible for that. Enjoy the rest of the game![line break]"

To say rank:
	choose row score plus 1 in Table of Rankings;
	say "[rank entry]".


To say (footnote - a number) as a footnote:
	if footnote > number of filled rows in the Table of Footnotes:
		say "Programming error: footnote assignment out of range."; 
	otherwise:
		choose row footnote in the Table of Footnotes;
		if there is an assignment entry:
			say "(Footnote [assignment entry])";
		otherwise:
			say "Programming error: no such assignment entry.".
			
Looking up a footnote is an action applying to one number.
	
Understand "footnote [number]" and "read footnote [number]" and "x footnote [number]"  and "look up footnote [number]" and "examine footnote [number]" as looking up a footnote. 

Check looking up a footnote:
	if the number understood > 16:
		say "There is no such footnote." instead;
	else if the number understood < 1:
		say "Footnotes are numbered from 1." instead;
	else:
		continue the action.

Carry out looking up a footnote:
	choose row with assignment of number understood in the Table of Footnotes;
	say "[note entry]".	
	
Footnoting is an action applying to nothing. Understand "footnote" and "read footnote" and "examine footnote" and "x footnote" and "look up footnote" as footnoting.

Carry out footnoting:
	say "To look up a footnote, just specify the one you're looking up. If you want to look up footnote 2 for example, just say 'read footnote 2' or 'x footnote 2' or even just 'footnote 2'."
	
Chapter 15 - Hint System
	
Include Basic Screen Effects by Emily Short. Include Menus by Emily Short. Include Basic Help Menu by Emily Short. Include Punctuation Removal by Emily Short.


Table of Basic Help Options (Continued)
title	subtable	description	toggle
"Hint System"	Table of Labors	--	--
"Acknowledgements"	--	"The first full (very very very) rough incarnation of [Italic type]Hercules![Roman type] was written in 2016 or 2017 by me, Leo Weinreb, while attending the University of Chicago. It was the first game I ever designed.[paragraph break]That proto-version involved only two playtesters: Anton Bures, my father, and John 'Chip' Lekberg, a friend from school. Since then the game has gotten smoother and kinder, exploded in scale and complexity, and been amended with crucial and thorough revisions.[paragraph break]These indispensible improvements are all thanks to a small but dedicated group of people who took time out of their busy daily lives to help me make my game the best it could possibly be: my dear parents Anton Bures and Jenya Weinreb, my friends Chip Lekberg, Emily Watzl, and Rhiannon Hoffman, and some absolutely brilliant volunteers from the Interactive Fiction Community Forum: Mike Carletta, Christopher Merriner, and Garry Francis, whose suggestions and playthrough edits were essential in allowing me to put forth a more polished finished product. I am eternally grateful to all of you. <3"	--

Table of Labors
title	subtable	description	toggle
"What do I do at the beginning?"	Table of Whattodo	""	hint toggle rule
"How do I retrieve my inhaler?"	Table of Inhaler	""	hint toggle rule
"I keep getting anxiety attacks!"	Table of Anxiety	""	hint toggle rule
"How do I slay the lion?"	Table of Lion	""	hint toggle rule	
"How do I destroy the hydra?"	Table of Hydra	""	hint toggle rule
"How do I capture the hind?"	Table of Hind	""	hint toggle rule
"Help! I can't scale the mountain!"	Table of Mountain	""	hint toggle rule
"How do I capture the boar?"	Table of Boar	""	hint toggle rule
"How do I clean these disgusting stables?"	Table of Stables	""	hint toggle rule
"How do I slay the Stymphalian birds?"	Table of Birds	""	hint toggle rule
"How do I get the Cretan Bull?"	Table of Bull	""	hint toggle rule
"Help! I'm trapped in a Labyrinth!"	Table of Labyrinth Maze	--	--
"How do I steal the mares of Diomedes?"	Table of Diomedes' Mares	""	hint toggle rule
"How do I get rid of the yellow-spotted lizards?"	Table of Lizards	""	hint toggle rule
"How do I obtain Hippolyta's girdle?"	Table of Girdle	""	hint toggle rule
"How do I steal cattle from the monster Geryon?"	Table of Cattle	""	hint toggle rule
"I'm stuck on one of the final puzzles!"	Table of Final Tasks	--	--

Table of Anxiety
hint	used
"Yes, that'll happen from time to time."	a number
"Your anxiety will prevent you from doing a number of things at various times. But there's an easy way to circumvent that."
"Your inhaler was left at home, so that's out of the question."
"Have you noticed what it says when you get an uptick or spike of anxiety?"
"Hercules isn't sure you're going the right way. And it's always right before you enter certain rooms at certain times."
"Have you tried... not entering those rooms at those times?"
"Have you checked your list?"
"If you try to solve the Labors in order, anxiety will not hinder your progress through the game. If anxiety hinders you on a certain direction or puzzle, try again when you're further along with your list."

Table of Inhaler
hint	used
"Oh no! Looks like you've remembered your allergy medication, but not your inhaler. What are you going to do?"	a number
"Have you tried running back to your house to get it?"
"Your house is west of the Main Road where you started."
"No, guess you can't go and fetch it. Have you tried praying?"
"Glad to see you back here again! Okay, maybe you can just make some Albuterol yourself?"
"Hmm... you have to go step-by-step it seems... what are the ingredients to Albuterol?"
"A doctor would know. Is there a doctor nearby?"
"No, but your cousin's a king. Maybe he would know a good doctor?"
"No, he wouldn't. And even if he did, he wouldn't tell you."
"You can't find a doctor. Too bad."
"You're going to have to complete the game without your inhaler! A tall order, but I think you can do it. :)"

Table of Labyrinth Maze
title	subtable	description	toggle
"Get me out of here!"	Table of Getting Out	""	hint toggle rule
"Is there anything else I can find in the Labyrinth?"	Table of Bonus Puzzle	""	hint toggle rule

Table of Getting Out
hint	used
"Whoops! Seems you’ve twisted yourself around and are a bit stuck in the Labyrinth."	a number
"This Labyrinth is a maze, similar to old text-adventure mazes you'd find in games like Zork. Back in those days, people had no choice but to use the objects they'd accumulated, dropping them in each room of the maze before moving in order to map out how every room in the maze connected. (I call this the Hansel-and-Gretel method.)"
"You can do the same in this maze (that's what the magical lost-and-found box is for, to give you a bunch of new and old objects!) but there are easier ways to navigate it."
"You might've found one other way already if you tried cleaning up the dead Stymphalian birds with the mop. Skip the next hint if you haven't cleaned up the birds."
"If you cleaned up the birds, the ground told you to 'Visit the island of Crete, to the west south and east.' Since you went west to enter the maze, if you go south and then east, you'll reach the Troll Room. Skip the next four hints to figure out what to do there."
"The other way to navigate the maze involves using one of the new objects in the lost-and-found box." 
"Can you maybe do something with the red rolled-up string?"
"Have you tried unrolling it?"
"The string gives you directions to the Troll Room. Just unroll it in each room of the maze and go in the direction it says."
"Once you're in the Troll Room, the bull tries to lick off the bloodstains. You should try cleaning them as well, but not with your tongue."
"If you try mopping the bloodstains (or wiping them with your hands), the picture tells you you've won 'the key to our hearts, which as always lies up above the west south and east'"
"Going west, then south, then east, and then UP from the Troll Room leads you to a room with a skeleton key. (You also could have gone east and then up while Hansel-and-Greteling and found the key that way.)"
"Have you examined the key?"
"The capitalization of this message is the strangest part about it."
"The capital letters form the nonsense string XYZZY!"
"In the oldest text-based adventure game, Colossal Cave Adventure (which Zork is based on), the spell in the game is xyzzy. It's a teleportation spell, and is used as a cheat code in a lot of other places."
"Typing xyzzy will take you back to Crete. (You could've typed this in any part of the maze earlier to skip the troll puzzle AND the key puzzle.) Getting back to Crete is all you need to do to finish the rest of the game! Congratulations!"

Table of Bonus Puzzle
hint	used
"The short answer: yes. There is a bonus puzzle here!"	a number
"You can use the Hansel-and-Gretel method to map out the rooms past the skeleton key room, but it will take a while. Patience is definitlely a virtue if you use this method."
"There is another method that involves the red rolled-up string. Have you tried unrolling it in the key room?"
"The string goes haywire! The vastness of the maze must be distorting its signals somehow. But there still might be method to the madness. Try to follow some of the directions it specifies."
"Most directions lead in circles, but the last direction it gives every time takes you on a very specific route."	
"Those who’ve played Zork will sense even more familiarity than before as they go through the maze. This maze is exactly the same layout as the first maze in Zork 1!"
"If you go sw, then e, then s from the key room, your claws will start to glow blue. The sword in Zork also glowed blue in this room."
"Go southeast. What was once the Cyclops Room is now the Minotaur’s Room."
"What was the solution to the Cyclops puzzle again?"
"'Odysseus', another Greek hero! But that won’t work here."
"Odysseus was an old enemy of the Cyclops. Who’s an old enemy of the Minotaur?"
"Say 'Theseus'"
"Going east will take you to the strange hallway and then back to Crete, where you’ll have to start over again. (Luckily there’s no thief to take your stuff if you have to go around again.)"
"Going up will take you to the Treasure Room, just like in Zork! But there are no thieves, only the jeweled egg."
"What did you have to do with the jeweled egg in Zork?"
"Open it and read the leaflet. Congrats!"
"If you explore the rest of the maze, you can also get to the Grating Room, just like in Zork." 
"You can follow the FIRST directions the string gives to get there. If you're using Hansel and Gretel, you just need to go up, then sw, u, d, ne from the start."
"Examine the grate. Just like in Zork, you have to use the skeleton key."
"Unlocking the grate gives you another way up to the Minotaur’s Room!"


Table of Lion
hint	used
"The lion is right there in Nemea! But how do you slay it?"	a number
"The knife isn't working!"
"You'll never be able to defeat the lion with just brute force. You need to gain an edge somehow."
"Have you examined your Benadryl?"
"Benadryl is great for allergies, but it’s also great at making you really sleepy, especially if you take more than you're supposed to."
"Try giving the Benadryl to the lion."
"Hmm, but the knife still isn't working. You can't stab into the beast, but maybe you can use the knife in a different way?"
"The lion needs a haircut. Try shaving it with the knife. (Or cutting its hair with the knife.)"
"Okay, so you're allergic to the fur. Surprise, surprise. You need some sort of mask to prevent hair getting on you."
"Have you found the gun?"
"Try visiting your cousin if you haven't yet. (East of Tiryns.)"
"Have you tried shooting the gun at something?"
"Cool, now you have this nifty flag!"
"Maybe it could be used as a mask?"
"Wear it. Then shave the lion."


Table of Whattodo
hint	used
"Explore a little bit maybe!"	a number
"You were given a hint about why you’re here in the intro."
"Have you checked your inventory?"
"Examine the list."
"You must complete the famous Twelve Labors of Hercules to win the game! First stop, the Nemean Lion. (Which, as expected, resides in Nemea.)"

Table of Hydra
hint	used
"The Lernean hydra is of course in Lake Lerna. But how do you kill it?"
"If you try to slash it with your claws, three heads grow back in place of the one you slashed."
"Did you get the box of matches in Lerna?"
"You can’t burn the hydra yourself, you’re afraid of fire."
"What else is in Lake Lerna? Maybe there's something here that can help you?"
"Or someONE here that can help you?"
"You need help from your nephew Iolaus. Maybe try asking him about the hydra?"
"Have you tried examining Iolaus?"
"In addition to blowing things up, Iolaus likes setting things on fire!"
"What does Iolaus think about the matches?"
"Give the matches to Iolaus."
"But you can't ask Iolaus to burn the hydra for you. You command no followers, it wouldn't be right."
"He may just do it of his own accord if give him a reason to leap into the fray."
"Attack the hydra with the lion pelt now. Your pyromaniac nephew, now carrying the matches, will cauterize the stumps of the hydra heads as you slash them." 
	

Table of Hind
hint	used
"The Ceryneian Hind is in Keryneia now. (Since Cs and Ks are the same in ancient Greek.) Go nw of Nemea to get to Stymphalia, then nw again."	a number
"You can’t catch it though."
"Or attack it. You’re too weak."
"If you try to just take it you'll see it’s as uncatchable as a dream."
"You’ve already taken your Benadryl today. (You can make sure of this fact by trying to eat the pills.)"
"Maybe it’s time for a nap."
"Sleep. (Hercules will no longer be too anxious to sleep.)"
"It's the same place, but something's off. You must be dreaming!"
"Ever have a dream where you do something you can’t possibly do in real life?"
"Take the hind."

Table of Mountain
hint	used
"Uh oh! Looks like you've gotten too asthmatic and are unable to scale the mountain anymore."	a number
"How did this happen?"	
"Well, leaving your inhaler behind can't have helped."
"But there's nothing to be done about that now." 
"The game keeps saying you're breathless and need a drink of water."
"Have you tried to find some water?"
"There's snow at the bottom of the mountain. But you can't drink it."
"Have you tried digging at the bottom of the mountain?"
"Aha! An ice pick and an online instruction manual."
"In order to use the ice pick, it seems you have to watch the instruction manual located at https://bit.ly/3BPMyFY."
"Did you watch the video?"
"You're being very silly reading all of this. Despite his asthma, Hercules never has a problem hiking up Mount Erymanthos and neither do you. Stop reading the hints and play the rest of the game!"


Table of Boar
hint	used
"Mount Erymanthos is southwest of Keryneia. The boar is there now."
"Have you tried just taking it?"
"No, that would be too easy, wouldn’t it. Have you tried examining it?"
"Examining it shows us that it is indeed the Erymanthian Boar. It has weird horns though, sort of like a bull? That's odd."
"Most bulls are attracted to red colors. But this isn’t a bull."
"Wait and watch what it does for a while."
"This pig is attracted to white colors. But it knows to not head into the snow straight on."
"Do you have something on you that’s white?"
"The flag is white. Maybe you can wield it like a toreador."
"Try waving the flag, or waving it at the pig. (Hercules will no longer be too anxious to wave the flag.)" 


Table of Stables
hint	used
"The Augean Stables are west of Elis, which is southwest of the mountain."	a number
"God that’s disgusting. But at least there are a few new tools here."
"How are you ever going to clean this up? A simple mop can't be the answer, can it?"
"No, it’s futile. The mop is a red herring."
"The other tool in this room is a hammer. Hammers break things." 
"What do you have that’s breakable?"
"Ice! Ice is breakable! AND it cleans things! (Well, water cleans things, and this water seems unusually clean.)"
"Try breaking the frozen ham with the hammer. (Specifically, while in the Augean Stables.)"
"You need some fire to melt the frozen ham chunks and create water."
"What do you have that makes fire?"
"What DID you have that makes fire?"
"The box of matches. Iolaus has them. You need to go back to Lake Lerna."
"He’ll give them back to you, you just need to ask."
"Ask Iolaus for the box of matches."
"Now try attacking the frozen ham with the hammer in the Augean Stables."
	

Table of Birds
hint	used
"The birds are right there in Stymphalia, flying above you!"	a number
"Did you try just taking the birds? Or attacking them with something?"
"That doesn't work, but it says you need to lure them down with something."
"Have you tried giving the birds something? Or luring them with something?"
"If you try to give them the strip of bacon it says you'll need some sort of makeshift snare."
"Have you tried examining the trees?"
"What usually gets tied to trees? Maybe you can tie something to the trees to make a sort of container for your snare?"
"Tie the flag to the forest trees."
"What happens if you try putting the strip of bacon into the hammock?"
"Hercules won’t let you because they’d just swoop down, eat the strip of bacon, and leave."
"The list tells you to SLAY the birds, not just capture them, or even flay them. You need to poison the bacon somehow."
"Do you have the toxic-looking purple goo, the remains of your slain hydra?"
"It’s so poisonous you can’t even touch it!"
"You can’t put the goo on the bacon, it'd be really messy and might be dangerous. Best to just do the obvious."
"Put the purple goo in the hammock. Then put the strip of bacon in the hammock." 
	

Table of Bull
hint	used	a number
"Cretan Bull is somewhere in Crete, southeast of the Peloponnesian Shore. (Hercules will no longer get anxious when you try to take the ferry now.)"
"The bull’s not here. Where could it be?"
"I really hope you don't have to enter the dreaded Labyrinth…"
"Oh there it is!" 
"Couldn’t you just take it? Is it really that simple?"
"Yep, it is! Congrats! :)"


Table of Diomedes' Mares
hint	used
"Diomedes is in Thrace. Thrace is northeast of Stymphalia."	a number
"He won’t let you do much here though. And he won't talk to you unless you show him or ask him about something that'll pique his interest."
"The only thing you didn’t have before the last labor was the bull. Show Diomedes the bull and he mentions his own mechanical bulls."
"Ask him about his mechanical bulls, and he just leaves! Time to do some snooping."
"Did you check the wastebasket? And the desk?"
"Hilariously non-secure of Diomedes. But which number is correct? There are like a bajillion numbers written on these notes!"
"You could just spam them but that’s no fun, and will take tons of time. Did you examine the calendar?"
"Seems like a meaningless bit of flavor. But it’s not. Try reading the description with a different emphasis."
"The Olympics winner from LAST month??"
"Diomedes has forgotten that the month has changed. Or at least, he HAD forgotten that the month changed. In the folded note he mentions a code from last month. That’s the one that opens the safe."
"'Spin safe to NUMBER ON NOTE'"
"Do you have anything that would allow you to take these mares without getting burned?"
"Check your inventory and examine the pendant you got from Artemis."
"But you can't put the pendant on yourself, it's not your style."
"Put the pendant on a mare. Now you can pick it up!"
"Repeat this process for all the mares, first taking the pendant off the mare you just took."

Table of Girdle
hint	used
"Hippolyta is queen of the Amazons. She's in Amazonia, east of the Peloponnesian Shore."
"The warrior won’t let you see her without the mares of Diomedes. So show the mares to the warrior."
"Now Hippolyta’s here! Great! Did you try just asking her for the girdle?"
"Oh, great. Thanks, Hera. Now you have to make some medicine. Have you tried to leave to go get some?"
"Unless you've dropped something crucial, you won't even be allowed to leave. Almost everything you need is right here in Amazonia."
"The only things in Amazonia are the Amazon warrior (who’s already doing everything she can to help) and the ornate throne."
"The description of the throne names several other objects. Try to take them all."
"The dirt uncovers a bowl. You can probably use the bowl to mix up some medicine. But what are the ingredients for it?"
"You can only put some objects in the bowl. The game won’t let you put just any old thing in there."
"Have you examined the bowl? It’s cryptic, but it tells you exactly what ingredients you need."
"'…elements of earth and life…' is the dirt (which is from the earth) and the moss (which is plant life). '…trees strength tight…' is the vines."
"You’d think 'powder of love' would be the roses, but the game won’t let you put that in the bowl. Have you examined the roses?"
"Attack the roses with your claws. Then put the powder in the bowl."
"'Sleep from above' is the last ingredient you need."
"What makes things fall asleep?"
"Your trusty Benadryl. At least, it made the lion sleep, right?"
"Put the Benadryl in the bowl."


Table of Cattle
hint	used
"Geryon resides in Erytheia, northwest of Elis near the Augean Stables."	a number
"Geryon has a cow. Have you tried just taking it?" 
"Ask the monster about its cow."
"That’s WAY too high a price!"
"Try to leave. Clearly it wants to give away its cow, it just wants a good price for it."
"Ask it about the cow again."
"Okay, now we’re getting somewhere. Time to spam the ask button."
"Now you've haggled it down to just wanting something of value! Do you have anything of value?"
"If the game prevents you from leaving, it means you have everything you need to solve the puzzle right now. If you CAN leave, maybe you’ve left something somewhere."
"Examine the girdle."
"Try giving the girdle to Geryon. (You may have tried this before. But it’ll only notice the price tag after you’ve talked it down a bit from the sticker price.)"
	

Table of Final Tasks
title	subtable	description	toggle
"So... I'm done, right?"	Table of Penultimate Questioning	""	hint toggle rule
"How do I steal an apple from the garden?"	Table of The Apples	""	hint toggle rule
"How do I capture Cerberus?"	Table of Cerberus	""	hint toggle rule
"What do I do after I've captured the dog?"	Table of Ultimate Puzzle	""	hint toggle rule

Table of Ultimate Puzzle
hint	used
"You have 12/12 points. You’ve basically won — come on now!"	a number
"What else is there to do?"
"Just give the list to Eurystheus!"


Table of Penultimate Questioning
hint	used
"You’ve completed all your tasks! Right?"	a number
"Examine your list."
"You need to go back to your cousin!"
"Give him the list."


Table of The Apples
hint	used
"Great, two more tasks. Thanks, Eurystheus. The Garden of the Hesperides is west of the Western Shore. Since you have to go there now, Hercules will let you, albeit whilst shaking in your boots."	a number
"Yep, there’s the dragon! It’s pretty fearsome. And more problematically, it prevents you from getting the apple of course. Or from going anywhere except backwards. You'll need to remove it somehow."
"You’re too weak to attack it of course. And there are no snares or nephews nearby to assist you this time. And it can’t be tricked with sleeping pills. Nor can you reason with it."
"Wait, what’s that on the ground? A chewed bone? Gross."
"What happens if you show the bone to Ladon?"
"Have you tried examining the dragon?"
"Tail wagging…looking to chase after something… Ladon looks scary, but he’s basically a dog, in the same way that the Erymanthian Boar was basically a bull!"
"Ladon wants to play fetch."
"Try throwing the chewed bone at Ladon"
"That’s no way to play fetch — you don’t throw your dog the bone directly!"
"Ladon is between you and the apple tree. And the cave is too near."
"But he’s not between you and the strange staircase, which seems to go down quite a ways." 
"Throw the chewed bone at the strange staircase."
"Now just take the apple!"


Table of Cerberus
hint	used
"You can't get to the Underworld by dying or going down the strange staircase. There’s another area you’ve yet to explore. The cave northeast of the Garden."	a number
"Have you tried moving, taking, or touching the shrine?"
"Do you have something divine?"
"The red apple that you just stole comes from the heavenly garden. Put it on the shrine."
"Okay, that's something divine. But you don’t really have anything that could be considered 'monstrous' per se…"
"Unless there could be another meaning to the word 'monstrous'? Such as 'made by a monster'?"
"Put the receipt on the shrine. (Make sure you've left nothing on the shrine except those two items.)"
"Now a ticket stub in on the shrine. Make sure to take it before going back to the City Palace and going down."
"Have you tried getting in the boat? Or talking to Charon?"
"Give him the ticket stub."
"Have you examined the 'small' doggie cage?"
"The small doggie cage is actually large. That's a clue. You can fit anything inside the cage."
"If you put the bone in the cage, Cerberus enters but then leaves, finding no meat."
"Try putting one of your animals in the cage."
"It still doesn't work. Maybe all he needs is another animal?"
"Putting both your animals in the cage gets you even closer to distracting him, but not quite good enough."
"The non-meaty items are distracting Cerberus. Remove everything except the two animals from the cage."


Table of Lizards
hint	used
"Wait, where are all these yellow-spotted lizards coming from?"	a number
"Clearly they’re not supposed to be here. And they’re preventing you from heading in the right direction!"	
"Have you tried shaking them off?"
"No, they just remain glued on. Hmm…"
"Could the lizards be retribution for something?"
"Did you take something from Diomedes’s shop that you shouldn’t have?"
"Maybe something red? And fish-shaped?"
"A red herring perhaps?"
"There are no yellow-spotted lizards. None have ever been present in any version of this game. Nothing is preventing you from moving on with your list. Quit reading the hints and continue your adventure!"












