*label elizabeth_start

*if (ally_elizabeth > 0)
	Boston and Cambridge are great places to visit, but now that Elizabeth Chen has joined your party, you really don't feel like there's anything else here for you.
	*page_break Back we go...
	*goto_scene hub_0 after_hub_info

*if (item_harness > 0)
	You got the time harness from Elizabeth, but you told her you didn't want to put her in danger.

	*choice
		#I stand by that decision.
			You decide not to contact Elizabeth. However, that means there's no reason to stay in Boston.

			*page_break All right then.
			*goto_scene hub_0 after_hub_info
		#Actually, we need her after all.
			Ms. Chen gave you her phone number last time you were here, and conveniently enough, your comp can interface with the local phone systems. "Ms. Chen?" you say, speaking into your wrist. "It's ${name}."

			"Oh, I just got done talking to you!" she says. "Like five minutes ago. What is it?"

			"I have to say I reconsidered," you reply. "I would like to have you along after all. If you're up to it. I mean, I did say it would be dangerous."

			"Does this mean I get to travel in time?"

			"Some," you say. "It's more work than play right now, you know!"

			"Doesn't matter," she says. "I'm up for it!"

			"Great! Now, which one's your room? I can't remember the number..."

			*set ally_elizabeth 1
			*page_break Elizabeth Chen has joined the party
			*goto_scene hub_0 after_hub_info

Ms. Chen gave you her phone number last time you were here, and conveniently enough, your comp can interface with the local phone systems. "Ms. Chen?" you say, speaking into your wrist. "It's ${name}."

"I need the time harness!"

"Okay!"

*set item_harness 1

"Can I come along?"

*choice
	#"I've thought it over, and...I'm afraid it's just too dangerous. I can't in good conscience have you along."
		There's a long pause. Then, a sigh. "All right," she says. "Just let me know if I can do anything else to help."
		*goto after_chat
	#"I've thought it over, and...While it'll be dangerous, I can't help thinking your help would be very valuable."
		*set ally_elizabeth 1
		"I knew it!" Elizabeth laughs; you detect some relief in her voice. "I won't let you down!"

		"I'm glad to hear it!", you say. "Now, which one's your room? I can't remember the number..."
		*goto after_chat

*label after_chat

*page_break That's that.

*goto_scene hub_0 after_hub_info

*finish

