[b]TRAINING MISSION OMEGA - 'CUT AND PASTE'[/b]

*set training_score 0

"Ah! ${name}?"

Your examine of Continuity's display is interrupted by the words. You drag yourself away from the blue hologram to see a thin man standing nearby. He appears on the line between middle-aged and elderly, with short gray hair and creased brown skin; he wears a gray jumpsuit, the same you were directed to wear. A slight smile is on his face, though his dark eyes betray little. "Excellent," he says, holding out his hand. "Ready for your last training mission?"

"Oh!" you say. "Of course, sir!" You return the handshake. "And...Who are you? They told me to report here, but..."

"Oh, just call me the Professor." One last squeeze, then he releases his hand and motions with his head. "Shall we go?"

"The Professor?" You almost stumble as you follow. "[i]The[/i] Professor?"

"There are lots of people with tenure around here," he says, walking through the corridors. "From one university or another." He chuckles.

'The Professor', though, is someone even a trainee like [i]you[/i] has heard of! One of the most successful Paradox Corps agents, adept at unraveling the trickiest temporal mysteries. The Professor also has a reputation for using body modification tech to put on a different form for every mission, even a different gender. You're not even sure 'he' is the right pronoun to use.

"So," the Professor says, turning down a hallway you don't recognize. "How's your training going so far?"

*choice
	#"Uh..."
		"That good, huh?" The Professor's mouth quirks in a smile. "It can have that effect on people. Maybe you're not even cut out for this kind of thing. There's no shame in that, you know."
		*goto training_chat
	#"It's not what I expected!"
		"No, it isn't." The Professor gives you an amused look. "Some things just have to be experienced. It's important to keep an open mind."
		*goto training_chat
	#"It's great! I'm learning so much!"${ds_training}
		*set training_score +1
		"Ah! Now that's good to hear." The Professor smiles at you over his shoulder. "What's the point of it all, if not to learn, eh?"
		*goto training_chat

*label training_chat

"Don't worry, though," the Professor says, walking up to a door. "Worrying, after all, does nothing useful. It's just your mind saying 'Hey! Something to pay attention to!'. Well, we already know that." He opens the door and leads you into another corridor; when the door closes behind you, darkness envelops you. Actually there is [i]some[/i] light, from softly glowing fixtures at your feet, but you still feel as though you're going to trip with every step. The Professor slows not a bit, though. "Just keep watching and thinking, you'll do fine." The short corridor comes to an end at another door, which the Professor throws open...

*page_break Light surrounds you.

Not just light, but warmth, sound and even scent dazzle you. You are in a forest, or a swamp. You stand in a grassy clearing on the edge of a slow-moving river. The scene is bright, though the sky is mottled with clouds, sun disappearing and reappearing as they move; the air is hot and humid. The chirps of birds and buzz of insects are neverending.

A large structure towers above you. It's a concrete stone shape, an octagon, wide enough to hold about a dozen rooms, but only tall enough for one floor. It rests on eight great pillars, making a structure easily five stories high. There looks to be one door on the structure, on the side facing you; a rusty metal stairway descends from the door, turning this way and that in several flights, finally diving into the water along with the pillars. A series of wooden boards form a rough walkway from the grassy bank to the stairway.

"Right," the Professor says, starting toward the 'bridge'. "Time's a-wastin'."

*set chosen_options 0

*label stair_quiz

*choice
	*disable_reuse #"Where are we? And when?"
		"Louisiana," the Professor says, shoes banging on the metal of the stairs. "2120, I believe. Land that has been unsettled for quite a while. Sorry about the heat. Well, it's the humidity that gets you."
		*set chosen_options +1
		*goto stair_quiz
	*disable_reuse #"How did we get here?"
		The Professor lets out a snort. "How do you think." Then he throws you a smile, though there is something bland about the expression. "There are many types of time machine. I prefer one that is...subtle."
		*set chosen_options +1
		*goto stair_quiz
	*disable_reuse #"What's our mission? What happens here?"
		The Professor glances up at the structure as you both climb. "As a matter of fact, this is a stop we have to make to prepare ourselves. The actual mission happens a hundred years or so in the future. But in this very place."
		*set chosen_options +1
		*goto stair_quiz
	*disable_reuse #"Where did we come out of?"
		The Professor glances back. "Oh, a crashed escape pod. From a human passenger ship. Nothing too unusual, just convenient." You look back and down and immediately regret it, as the stairs seem even more frail from up here. But you [i]do[/i] notice that you walked out of a metal bunker mostly overgrown with weeds.
		*set chosen_options +1
		*goto stair_quiz
	*if (chosen_options >= 4) #"Why is this so [i]high[/i]?"
		The Professor manages a chuckle, even though he seems a little out of breath as well. "The builders were afraid of flooding, especially with global warming. I'm happy to say the problem never got [i]quite[/i] as bad as they feared. But I'm also happy that they built this place so solidly."
		*goto after_stair

*label after_stair

Finally you stand on the narrow walkway before the door. The Professor knocks. Moments later, the door opens.

You are in a wide room that reminds you of a warehouse, though you are sure it doesn't take up the entire space of the octagon. Yellow lights on the ceiling mimic skylights. Tables are set around the room, each piled high with what at first glance is junk. Old monitors and computers, stacks of discs, cartridges...magnetic tapes?

Sitting behind a desk (itself having three monitors), is a portly woman with close-cut dirty blonde hair and tanned skin. She sits there and watches as the Professor approaches, no expression on her face; as you enter, the door closes. The Professor reaches across and offers his hand; she shakes it. She seems to be chewing something.

"${name}," he says. "This is Francis."

"Please, call me Frankie." She blows a pink bubble, which pops, then she chews it again.

"The pleasure's all mine," you say. "So...uh. Are you an agent?"

"An agent of myself." She grins. "I'm an archivist. I catalog interesting bits of culture, safe alone, out here away from 'civilization'." She actually makes the quotes with her fingers.

"Frankie is sympathetic to our cause," the Professor says. "I find this a pleasant base to work from." Given the humidity and piles of junk, you have to wonder about the Professor's definition of 'pleasant'. "And she's done us innumerable favors in the past."

"On the contrary," Frankie says. "They're quite amenable to numeration. And remuneration, when you feel like it." She grins, still chewing.

"I have it on good authority that you will be compensated well for your services." The Professor smiles. "Well, Frankie. ${name} is a trainee, so we're going on an easy mission."

"You hope," Frankie says.

"Indeed, nothing gets past you. Mostly I just wanted to introduce you two. Well, ${name}? Anything to ask?"

*fake_choice
	#"Archivist? What are you archiving, again?"
		"Culture!" Frankie leans back in her chair and beams. "Television shows, webcomics, netprov logs, args, retro games, memetic units of all kinds!"

		"All right," you say. "I suppose someone has to."
	#"So you sit out here all alone? How do you support yourself?"
		"We don't really have to deal with scarcity nowadays," Frankie says. "That having been said, I did a lot of programming and writing in my younger days. I accumulated enough to buy this plot of land and base--a failed survivalist project. Now with my hydroponic food production slash waste recycling facility, not to mention my generator, I'm pretty much set for life!"

		"For a lot of people this would be a perfect life," you say.
	#"No, I'm just trying to take this all in."
		"Sure," Frankie says. "I'm here if you need anything." She grins.

"You can come back here if you ever need a home base," the Professor says. "For now..."

"Wait!" Both of you turn to look at Frankie. She pushes her chair back and moves it over to a wall; you see a large cabinet with a number of small doors built into it. "Hang on. Q, Q...Here." Frankie pulls open a drawer, then retrieves a small box and hands it over.

The Professor holds it up, and you crane your neck to see. It's just a few inches on each side, wrapped in gray paper almost like a present. On one side are scrawled black letters--'CHIP'. "Interesting," the Professor says. "And we'll need this?"

"That's what I hear." Frankie rolls back to her seat, a smirk on her face.

You frown. "Professor, what..."

"That's the thing about time travel, ${name}." The Professor pats you on the shoulder. "Sometimes you don't do things in the right order. But I have faith it'll work out. Now, come on." He leads you through the piles of junk to a door.

Out of the corner of your eye, you catch Frankie waving. "Have fun!"

*page_break And the door leads somewhere else...

But somewhere familiar. You're in the 'escape pod' again, though the lights are dimmer. This time the Professor clicks his comp, lighting up the short corridor. He opens the door and you both step out.

The concrete structure on its pillars is still there, as is the stairway, even more rusted; it doesn't even seem possible to climb up now. The structure looks shorter, but you suspect it's because the water has risen. The contours of the ground have also changed. However, you are still surrounded by swamp and trees. The Professor sets off through the grass.

"Does Frankie still live there?" you ask.

"I don't know," the Professor says. "However, this is the year 2222."

"Oh." You look around. If you hadn't just been in the previous time period, you wouldn't know anything was different; it's just a different arrangement of trees and hillocks. It's more overcast now, though.

*page_break Then you follow the Professor around a tree and you gasp involuntarily.

A great ship rests on the ground. It's as big as a building, a rounded oblong; it doesn't have wings or fins, but there are protruberances whose function you cannot guess at. The Professor walks up to the bottom of the ship and taps on a panel; a door detaches and folds down to make a ramp, up which he walks. You quickly follow.

A metal corridor. Ceiling, walls and even floor, all metal. The pair of you turn a corner--someone almost bumps into you. You can't help but staring; it seems to be a humanoid dog. A dog, almost as tall as a human, walking on two legs, if a bit of a crouch.

(It looks like a terrier, in fact, if you had to put a name. Golden brown fur, though.)

"Who--" The dog blinks and leans in to you. "Are you from Central?" Yes, it's talking.

"We were sent to help," the Professor says.

"Though we weren't totally briefed on the problem," you add. The Professor raises an eyebrow, but you can see a smile tugging at his lips.

"Yeah. Uh." The dog paws at his head. Then he reaches down and takes a tablet from his belt, staring at it. He's wearing a gray jumpsuit identical to yours and the Professor's, though he also sports a belt hung with various tools. "You'd, you'd better come with me." He turns and walks off, slightly hunched.

A few moments pass in silence as the three of you walk. Then the Professor drops back a bit, leaning toward you. "Anything on your mind? We may not have a chance to talk freely for a while."

*fake_choice
	#"Is this, is this a sentient dog? What?"
		"Uplifted." The Professor nods. "Genetic tinkering increased the dogs' intelligence until they could speak, argue for their rights, comprehend the concept of self-reference. You'll probably see more modified beings soon. You're not prejudiced, I hope."
	#"Why is this ship here?"
		"It shouldn't be," the Professor says. "It's having some sort of trouble. Ships like this rarely land on any planet, and never on Earth." His brow creases. "Yet, there's no obvious problem. Well, we'll see."
	#"Why is this something [i]we[/i] get to worry about?"
		"Mm," the Professor murmurs. "In theory we fix problems relating to, well, paradoxes. It's in the name. Still, every now and then I like to help out people who are simply in need. There may be more subtle benefits; call it a lead I'm pursuing. Or call it a whim."

You are led into a larger room with a central console and several screens. It doesn't feel like a bridge, more like the engineering department. When you enter, all conversation stops. 'Conversation' in this case meant a tall man yelling at a dog in a jumpsuit. Both turn to stare at you.

The Professor steps forward. "Don't worry, we're here to help," he says. "I'm the Professor; well, it's a nickname, I haven't actually taught in a while. This is ${name}." You nod. "Now it seems to me that this ship shouldn't even be here."

"No it shouldn't!" The tall man straightens up. He wears a white shirt and pants of simple and straight design, although the front of the shirt has two wide bands of gleaming golden embroidery. "I demand that you fix it immediately! I paid good money for these maintenance dogs!"

"Indeed," the Professor says. "Just to get up to speed, who are you?"

An expression of astonishment crosses the tall man's face, momentarily eclipsing his choler. "Anrozan Elinar!" he says, as if flabbergasted that anyone wouldn't know.

"Of course," the Professor says. "And, what's the problem?"

"The engines won't work!" the man proclaims. Actually, the embroidery may be [i]glowing[/i].

"Not getting power?" the Professor asks.

"Oh, they're getting power!"

"Control signals not reaching them?"

"Control subsystems verified," the terrier says.

The Professor frowns. "Errors reported?"

"All systems report 99% working correctly with a 1% margin of error." This morose pronouncement comes from the dog the tall man had been yelling at. He seems more of a Jack Russell, mottled brown and white fur.

"Strange!" the Professor says. "Anything else unusual?"

"Unusual? [i]Unusual?[/i]" Elinar's face reddens.

"Yes, unusual. It's a simple question."

He waves his finger in the Professor's face. "Are you getting [i]smart[/i] with me?"

The Professor regards the finger as though it's a particularly exotic insect. "That's why I'm here. I'm [i]paid[/i] to be smart."

*choice
	#Obviously the Professor can handle this. You're more interested in figuring out what the actual problem is.${ds_enigma}
		*set enigma +1
		"You best be careful," the man hisses. "You step out of line and you'll never work in this sector again!" Blah, blah, blah. So, some system down the line is malfunctioning. And the malfunction is either undetectable or hidden.
		*goto after_tall_man
	#"I have never yet seen yelling solve a problem."${ds_combat}${ds_training}
		*set combat +1
		*set training_score +1
		The tall man's face actually goes past red to purple. He turns his shaking finger on you. "That's it," he hisses. "I'm going to review one of my favorite holo-performances in my cabin. And if this problem isn't solved by the time it's done...you're...all...[i]fired[/i]."

		He stomps out of the room and down the hall.

		The Professor turns to you with raised eyebrows. "Huh. I think you actually got him out of our hair."
		*goto after_tall_man
	#"Sir, ah. Ahem. We'll do our best to solve the problem."${ds_diplomacy}${ds_training}
		*set diplomacy +1
		*set training_score +1
		"If you think of anything that might have happened," you say, "might have influenced the action of the engines, just let us know."

		The man glares between the both of you, then he stalks out of the room. Even the automatic door sounds haughty as it closes.

		The Professor nods to you. "That was nicely diplomatic."
		*goto after_tall_man

*label after_tall_man

The dogs look at the door, then at each other, then they shake their heads.

"Can we look at the engines?" the Professor asks.

The Jack Russell-looking dog makes an elaborate shrug. "Down Corridor L," he says, motioning with his head. The Professor nods and takes the indicated door, so you follow.

"What sort of ship [i]is[/i] this, anyway?" you say, looking around.

"Good question. What kind of ship is this!" The question is directed at a small group of people standing in a corridor that intersects this one.

The leader looks basically humanoid, but she has purple skin--no, actually it's short fur. She also has elongated ears, looking a bit feline. She wears a dark purple halter top and a garment that almost looks like a loincloth; the whole thing gives the impression of being a costume. "Uh, passengers and shipping," she says, staring at the Professor. "I think?"

"We got really good accomodations!" another woman says, this one looking younger and completely human; her slender form is concealed in a white leotard, and her blonde hair is in pigtails.

Behind the women is a tall, skinny, even elongated being, with white skin. This being nods, but doesn't say anything.

"So you're luxury passengers!" the Professor says. He pats the feline woman on the shoulder as he walks past her. "Coming to ask why the ship hasn't taken off yet?"

"Yes!" She falls into step next to you, and the other two follow as well.

"We're on it," the Professor says, leading your group into a larger room filled with humming machinery. "Please don't touch anything."

Your mentor starts waving a device at the various machines. You tiptoe behind him. Your education didn't include starship engines. As you move around a console, you spot someone else, a man wearing a gray jumpsuit--human. He looks up from another machine and smiles at you. "Gotta fix it!" he says.

"Okay," you say.

The man nods and walks past you and the luxury passengers.

"Hm," the Professor says, from somewhere in the maze of machinery. "Nothing seems wrong yet. ${name}, any ideas?"

*choice
	#"So, luxury passengers? Where are you going? What's with the costumes?"${ds_diplomacy}${ds_training}
		*set diplomacy +1
		*set training_score +1
		"We're performers!" The purple feline woman draws herself up to her full height. "Merisian's Magical Menagerie! That's, ah, that's me Merisian."

		"Menagerie?" you ask.

		"We have a few nonhuman performers," Merisian says. "We wanted to sound exotic."

		"Hmmm." The Professor's voice floats back from behind a giant glowing fixture. "A 'menagerie' is traditionally identical to a 'zoo'. Don't you get tired of being set apart from your fellow sapients?"

		Merisian makes a face. "That would happen anyway."

		"What sort of performances do you...perform?" you ask.

		"Simple stuff," Merisian says. "Acrobatics, comedy. What they used to call 'circus'."

		"See?" The blonde girl suddenly climbs up on the white being, who holds completely still for her. She holds onto the white shoulders and raises herself in a handstand, then she starts slowly spreading and closing her legs in various ways.

		"Oh, of course," you say. "But that performance will have to be free. We don't have anything to tip you with..."

		The three performers chuckle. Even the white one manages a dry laugh.
		*goto after_performers
	#"Why is that guy so mad? Does he have any rivals? Would anyone want to hurt him? Is he scared of something?"${ds_combat}
		*set combat +1
		The three look at each other. The girl shrugs, and the feline woman frowns. "I heard some sort of rumor," she says. "His company lost several ships. You heard about the Freeport disaster right?"

		"Sure," the Professor says. You blink.

		"So this is the only ship he has left." She looks around. "Must be stressful for him. He probably wants to make sure everything is perfect."

		"I definitely got the impression he wanted to impress us," the girl says. "Honestly, if I get a bed and a hot meal I'm plenty impressed for the night." They chuckle.

		"But no [i]rivals[/i]," the feline says. "Not that I really follow, uh, shipping company gossip."
		*goto after_performers
	#"The engines are supposed to be working, but they don't get activated. Right? What happens when they try to start them?"${ds_enigma}
		"That's a good question," the Professor says, reappearing from behind some machinery. "How about looking at some logs?"

		"Uh, sure?" you say. "Where are they?"

		"Right here." The Professor taps a monitor. You walk over to look (and the other three crowd around).

		897293871861 - ENGINE IGNITION SEQUENCE START
		897293871865 - ENGINE IGNITION SEQUENCE END
		897293872011 - ENGINE IGNITION SEQUENCE START
		897293872014 - ENGINE IGNITION SEQUENCE END

		"What made them end?" you ask.

		"Control signals," the Professor says. "Someone turned them off. After they got started."

		"Who? Why?"

		"Don't know." He taps the monitor again. "Someone who knew how to hide their tracks." He rubs his chin, muttering. "But they probably were inside the ship anyway."
		*goto after_performers

*label after_performers

"All right, I'm pretty sure the engines were prevented from being activated by someone or something," the Professor says. "Someone who [i]reacted[/i] once the engines were started."

"Reacted," you say. "Strange. But who, and why..."

"Hm." The Professor smiles. "Is there anything else on this ship?"

"Our troupe is small," the feline woman says. "We're the only passengers. Uh...what?" The white being leans over and murmurs something to her. "Oh, he says he saw some cargo being loaded! I wonder what that was?"

"We should find out, shouldn't we?" you ask. The Professor grins.

*page_break Track down that cargo...

You stand in a cargo bay; you, the Professor, three luxury passengers and a maintenance dog, all standing uneasily. Finally the door opens and Elinar stumbles in, panting. He straightens up and his eyes widen, then bulge. "W...What is that?"

"We found it like this," the Professor says. He walks over to the torn-open cargo container. "What's in these boxes?"

"Androids," Elinar says, breathing heavily. "Android shells. Mechanical limbs, facial structure, indistinguishable from humans, but without brains. I sunk all my savings into buying them...high demand on...Saturn's moons..."

The Professor slaps him on the shoulder and peers into the container. "Buy low, sell dear. The good news is, only one is missing. You still got, what, 11, 12?"

"And further good news," you say. "The container was opened from the outside! That means the android hasn't gone rogue, it's just been stolen!"

Elinar gives you a wild look. The Professor tries to hide a smile. "Well then--"

"That's it!" Elinar straightens up and points a shaking finger at the terrier. "You, all of you, are fired!"

"We've done everything we can!" the terrier protests, though it crouches away from the accusing finger. "Everything to make the ship run perfectly!"

"Not just fired!" Elinar takes a step toward the terrier. "Thrown out to live on...Earth!" The dog whimpers.

"Let's not be hasty," the Professor says, though there's a sharpness to his voice. He grabs Elinar's arm and tries pulling him back. The terrier looks around, eyes wide, and his gaze falls on you. It looks like gaining sapience hasn't interfered with dogs' ability to look at you with soulful eyes.

*choice
	#"Wait! The dogs were hired as maintenance staff. Is there anyone [i]else[/i] doing maintenance?"${ds_diplomacy}
		*set diplomacy +1
		Elinar turns to you. "No, just dogs. They came cheap."

		"Then..." You frown. "Then who was that guy I saw in engineering?"

		Now everyone is looking at you. "What guy?" the Professor asks.

		"He was wearing a gray jumpsuit, like, uh, all us staff!" you say. "He said 'Gotta fix it' and left!"

		"We saw him too!" the feline woman says.

		"Hmmm," the Professor says. "All right, maintenance chief. Is there [i]anyone[/i] authorized to do maintenance who isn't a dog? Or any[i]thing[/i]?"

		The dog creeps back toward the wall, glancing around. "Well," he mutters. "There's the robot..."
		*goto after_dog_quiz
	#"If you wanted the ship to run perfectly, you failed. It's not running at all!"${ds_combat}${ds_training}
		*set combat +1
		*set training_score +1
		The dog crouches down further--then suddenly he straightens up, baring his teeth. "We've done everything we can! More than we ever expected to do! Every little thing this--[i]fat human[/i] wanted from us! Daycycle and nightcycle!"

		Even Elinar is taken aback by this outburst. "But," he stammers. "I just wanted..."

		"We even upgraded our maintenance robot!" the dog continues.
		*goto after_dog_quiz
	#"You did everything you could to make the ship run perfectly? Like what, [i]exactly[/i]?"${ds_enigma}${ds_training}
		*set enigma +1
		*set training_score +1
		The dog scratches his head. "Work daycycle and nightcycle," he mutters. "Every little thing this person wanted us to fix. Organized and cleaned everything. Worked on our maintenance robot to get it working perfectly."
		*goto after_dog_quiz

*label after_dog_quiz

"Robot?" you ask.

"Sure," the dog says, fidgeting. "A maintenance robot. Fixes anything."

"Anything?" the Professor asks. "Including androids?"

The terrier ponders. "Probably?"

"What's it look like?" the Professor asks.

"Just metal boxes and limbs. Kinda spindly."

You exchange a glance with the Professor. "If it can fix anything," you say, "that must mean it can [i]interface[/i] with anything?"

The Professor smiles. "And you impressed upon it the importance of fixing [i]everything[/i]. Including your android, which probably had some small defect, which justified getting it out of its box."

"Hey!" Elinar says, finally returning to the conversation. "Those android shells were in perfect condition! The guy assured me--" He stops, then runs his hand through his hair. "Actually, never mind."

The blonde girl peers over at him. "Did these androids get sold to you out the back of a truck?"

"Okay," you say. "That's fine, but, keeping in mind our [i]objective[/i]. Why did it stop the [i]engines[/i]?"

"Of course it stopped the engines!" the Professor says. "Worst thing you can do to a starship engine is start it up and get it moving! Terrible stresses!"

At this the terrier collapses, sitting on the ground and hanging his head. The feline walks over and sits by him, patting his head.

"All right," you say. "How do we deal with this out-of-control fixer robot?"

"First," the Professor says, "We find it." He takes out a device...and suddenly throws it at a nearby light fixture.

*page_break CRASH

"[i]What the smeg![/i]" Elinar barks. "That's my light! Everything on this ship is mine and you just [i]broke it[/i]!"

"I didn't realize 'You break it, you bought it' was in effect," the Professor says.

Before Elinar can reply the door opens. A man stands there in a gray jumpsuit, his face pleasant and bland. "Gotta fix it!" he says, walking over to the light.

"Is...Is that the robot?" Elinar says, taking a step toward it.

"Gotta fix it!"

"All right," the Professor says. He picks up his device and aims it at the man. "This won't hurt a--"

The man reaches out and grabs the device. It pulls out of the Professor's hand and vanishes into his arm. The Professor stares. "It interfaced with my multitool!" He leans closer. "That's amazing!"

"Someone [i]destroy that robot[/i]!" Elinar yells, clenching his fists.

*choice
	#"Robot, we need your [i]help[/i] to fix something!"${ds_diplomacy}
		*set diplomacy +1
		The robot turns its head. "Gotta fix it!"

		"Right," you say. "An important and valuable piece of equipment needs maintenance!"

		"Specify equipment that needs maintenance!" the robot says.

		"Uh...yourself!"

		There's silence for a moment. Everyone exchanges glances. "Specify maintenance procedure," the robot says.

		"Allow staff to perform maintenance?" you say. "Enter maintenance mode?"

		The robot pauses for merely a second. "Self-maintenance mode entered."

		"I think this should work now," the Professor says, pulling out a second multitool and applying it.
		*goto after_robot
	#"I bet I can overload it with my taser!"${ds_combat}${ds_training}
		*set combat +1
		*set training_score +1
		"But it will probably just interface," the Professor says, still examining the robot as it works on the light.

		"Maybe," you say, pulling out the taser. You apply your own multitool to the device, turning its power up past maximum. "Catch!" You toss the thing.

		The robot catches it without even turning its head. "Gotta fix...iiii..." It shudders, then its movements halt. It stays still for several moments, then suddenly its head snaps up, almost smacking the Professor. "Self-maintenance enabled. Gotta fix it."

		"Overloaded power cell," the Professor says, pulling out another multitool and applying it to the robot. "Not bad."
		*goto after_robot
	#"Robot, you are in need of maintenance!"${ds_enigma}${ds_training}
		*set enigma +1
		*set training_score +1
		The robot stops what it's doing.

		Then, slowly, it turns its head to you.

		"Y-your program has become corrupted," you say. Isn't this how they always did it on those old TV shows? "You tried to fix the engines, but in doing so, you interfered with the [i]function[/i] of the engines. Fixing something means that it performs its function well!"

		The robot is silent for long moments. Finally, though, it speaks: "Self-maintenance required."

		"Good," the Professor says, pulling out a second multitool and applying it to the robot. "This won't hurt a bit."
		*goto after_robot

*label after_robot

The robot falls to its knees and bends its head. "Good," the Professor says. "But the maintenance mode may not last long. How do we make sure it doesn't act up again?"

The terrier shakes his head. "I think its personality chip is corrupted. Those are hard to program. If we had a blank one...I don't think we have a spare."

You blink and stare at the Professor. He raises his eyebrows, digs in a pocket and takes out a small package. Unwrapping the gray paper, he reveals a shrink-wrapped box; it's dense with writing, but it looks like a box you'd find at an electronics store, holding some sort of component. "Like this?" he asks.

The dog stands, unsteadily, stepping over...Then its eyes widen. "Th, that's it! Exactly! Here, give it to me!" The pair open the box, extract a small black square and slide it into a slot in the robot's neck.

Suddenly the humanoid figure opens out and collapses, clattering to the deck. Within it is a collection of metallic poles and sinews. Lights flash on the thing, then it stands up, assuming a vaguely humanoid form.

"Awaiting orders."

There is a general sigh of exhalation. The feline woman suddenly claps, a bright smile on her face. The Professor chuckles, and he leans down to retrieve his multitool. "Nice work," he says, twirling the thing in the air.

Elinar shakes his head. "Is...is that it? Can we leave?"

"I think so." The Professor nudges the android shell. "This should be fine too. They're a pain to repack, but it looks to be in good condition."

"Excellent," Elinar says. "Then...[i]get off my ship![/i]"

The Professor raises his eyebrows, then he shrugs. "Sure, our work is done here. You're welcome."

"Ugh!" the tall man says. "Dogs and robots and everything going wrong!"

*fake_choice
	#"But this is all your fault!"
		"If you hadn't driven your maintenance workers so hard," you say, "They wouldn't have tried pushing the robot beyond its parameters!"
	#"Maybe this wouldn't have happened if you treated your workers like people!"
		"They may not be human," you say, "But they're obviously sapient! They have emotions and needs just like you!"
	#"How can you expect to stay in business if you don't value your employees?"
		"You can't push workers to their breaking point and expect miracles!" you say. "Every [i]real[/i] employer knows that!"


Suddenly Elinar doesn't want to meet your eyes. "Yeah, whatever," he mutters. "I don't care anymore. I just want to get off this planet! Get off the ship so we can take off! In fact, take that [i]thing[/i] with you!" He waves at the robot, then stalks from the room.

The Professor chuckles. Then the feline woman gets up and gives you a hug. "It's been fun!" she says. "If you ever see Merisian's Magical Menagerie playing, I'll refund your tickets!"

"Thanks," you say, accepting a hug from the girl as well, and even the tall white being.

"Not a bad day's work," the Professor says, patting the terrier on the shoulder. "Should we take the robot?"

"I guess you better," the dog says. "Don't worry, I'll put it in the expense report."

*page_break Later...

You watch the ship rise slowly from the swampy ground, bluish lights shining on its underside. It barely causes a breeze as it zooms upward with increasing speed, soon vanishing into the sky.

The Professor comes up behind you. "All set?"

"Sure." You start walking back to the pod and its door. "So, you took care of that 'Chip'?"

"Uh-huh," he says. "Got it from a space station a hundred years from now. Fortunately technology is modular enough, well, I'm just lucky I knew the right place to get it. Then I went back a week before you met Frankie, and I gave her the box."

You frown. "Doesn't that cause paradox?"

"It does," the Professor says. "But minor paradox. Because it's something that hasn't been resolved yet. You can feel the energy bouncing around in your head as the timeline holds itself stable. It's a strange feeling, but you get used to it." You can hear the smile in his voice as you reach for the door, opening it to reveal Frankie's room and all its junk.

*page_break "Wait..."

"What?" Having just stepped in to Frankie's room, you turn around.

The Professor is standing on the other side of the door, in the dim escape pod corridor. You can see him, though. In fact, he's glowing. Yellow energy crackles over his skin.

His eyes are wide. You stare. "Find the hub!" he gasps, then he slams the door.

There's a muffled crash.

*page_break What?

Behind you, you hear Frankie get up from her chair and run over.

You push the door open. It still leads to the same place, but the Professor isn't there. But there's something on the floor. Leaning down, you examine the small bundle.

A gray jumpsuit and a few devices. You take the jumpsuit, turning the fabric over in your hands. "What..."

"Uhoh," Frankie mutters.

*finish







