*label holt_start

*if (ally_holt > 0)
	You return to the Oklahoma City Zoo in 2014. However, you don't find anything immediately relevant. It might be fun to look at the animals, but you really do have more important things to be doing.
	*goto_scene hub_0 after_hub_info

[b]'FALLING TO THE PLANET'[/b]

You pass through the door and energy crackles around you, pitching you forward.

You land heavily and look up, staring around. All you see is red, red dirt. Standing up, you are surrounded by red. Panic takes a hold of you--Where are you? [i]When[/i] are you? Are you on [i]Mars?[/i]

And then, above you, you see fencing. Ordinary metal chain-link. Standing up straight, you discern that you are in a wide, shallow hole, surrounded by fencing. Nearby you catch sight of a shovel loader.

It's not too hard to climb out of the hole and sneak out of a gate. You find yourself on an asphalt path between grassy areas, more fences arranged in--exhibits? People are wandering by in ones and twos, although the sun is beating down quite heavily. You take a moment to stand in the shade of a tree and brush some of the dirt off your clothes, letting people pass you by.

"All I'm saying is, special die rolls should be given some sort of consideration in the game system."

You glance up to see two men walking by, both with beard and mustache; though, the older has a hat and trail guide sort of look, while the younger has a close-trimmed beard and black clothes that appear completely inappropriate for the season. You blink and look away, then find yourself staring at a young woman with blonde pigtails. Gazing at you, she extends her tongue to lick at an ice cream cone.

A soft beeping comes from your comp.

*page_break Let's hope it's good news!

You turn and walk away from everyone else, examining your comp. Temporal reading: mid-2012. Not only that, there's a Paradox Corps distress signal coming from nearby! Following it, you sneak through an Employees Only door into the staff area of wherever this is. Ultimately you walk up to a door and knock.

In moments the door is opened, revealing a very dark-skinned man with close-cut black hair. He looks somewhere between 30 and 40, and he wears a stained white smock over dark clothing.

The two of you stare at each other, then his gaze falls upon your comp. Hope lights his face, and he grabs your arm, dragging you inside.

"Okay," the man says, closing and locking the door. "What the hell's going on?"

You take a deep breath.

*page_break "Okay, this will take some time..."

"Call me Holt." The pair of you are sitting on metal barrels in a maintenance shack. Around you are workbenches and junk. You've just given Holt the rundown of what's been happening to you. "I'm not a full Corps agent, I haven't gone through the full training. I was recruited as a friendly, because I'm good with electronics." He leans back and looks around. "And as a cover, I fix things for the Oklahoma City Zoo."

"Oklahoma!" you say. "No wonder it's so hot."

A smile flashes across Holt's face, but only for a moment. "This is worrying. An agent was visiting, then they vanished right in front of my eyes. Since then, I haven't been able to get in contact with anyone." He sighs. "Least now I have some idea why."

"So this is a safehouse?" you ask.

Holt shrugs. "Sometimes, yeah."

"Listen," you ask. "I have an idea of what I need to do, but I think you should come back to the safehouse [i]I[/i] use. Is there any reason you can't leave?"

Holt looks around, then he slaps his thighs and stands up. "Now that you mention it, I'd rather hang around some actual Corps folks." He leans down to you. "Somewhere we can be sure not to be overheard."

*page_break "That's a good idea."

*set ally_holt 1

A few devices hauled through the time door later, Holt is looking around the Octagon. Frankie hauls herself out of her chair and walks over to him; they shake hands.

"Frankie," she says.

"Holt." He smiles. "You've got quite the collection here. Mind if I add a couple of things?" He opens his satchel and places a few devices on a table.

Frankie leans over, examining, then she sniffs. "Rubbish."

Holt's brow creases, and he opens his mouth--then he notices the twinkle in her eyes. "Oh, I [i]bet[/i]," he says, laughing. "I should give you a tour of my [i]personal[/i] collection."

"Really?" Frankie folds her arms. "Personal and private?"

Holt coughs, then he glances at you. "I, uh, maybe this isn't the best time."

"Honestly, I hate to interrupt," you say. "But, uh."

"Of course, of course." Frankie makes her way back to her seat, smiling. Holt stands where he is, looking up at the ceiling.

*page_break "Now then..."

"Holt, you said you were good with electronics." You hesitate, almost not wanting to hear the response to what you're going to say next. "What I really need right now is a [i]proper[/i] time machine."

"Well I don't know where to find one," Holt says, running a hand over his forehead. Then he looks at you. "Unless...Oh, no way."

"No?" you ask. "Not even a little chance?"

Holt opens his mouth, frowns, hesitates, then finally speaks. "I do know the theory. I've tinkered a bit. But we'd need all sorts of parts."

"We've [i]got[/i] parts," Frankie says from her seat.

Holt frowns. "Very [i]uncommon[/i] parts. Hang on." He takes out a computer and starts tapping at it. After a few minutes he shows you the result of his work, a list of parts. "Most of this we can get easily enough," he says. "In fact, Frankie may have it all here. But the [i]special[/i] parts..." He scrolls down.

*set chosen_options 0

*label before_parts_list

*choice
	*disable_reuse #"Temporal manipulators?"
		"The trickiest," Holt says. "I don't have the slightest idea how to build--"

		You hold up your wrist. "Time door?"

		Holt's eyes widen. "Oh. Right! We could use that for the base. The basic, er, all right then." He nods.

		"That reminds me," you say. "There's a woman in 1994 who found a busted time harness and repaired it. Sort of. It's still pretty damaged. But maybe it has parts we could use."

		"Repaired a time harness? In 1994?" Holt frowns. "She'd have to be a genius."

		You smile. "Think someone like that would be useful to have around?"

		"Uh, yeah. Probably!"
		*set chosen_options +1
		*goto before_parts_list
	*disable_reuse #"A casing and a power source."
		"You've seen the Octagon from outside," Frankie says. "It's sturdy."

		Holt nods. "I have no doubt it's sturdy enough. What do you use for power, though?"

		Frankie leans back in her chair. "A microfusion generator," she says, voice betraying smugness.

		Holt looks at her, then he closes his eyes, moving his lips silently for a moment. "Wait. Uh...All right. That should be enough, barely."
		*set chosen_options +1
		*goto before_parts_list
	*disable_reuse #"A dimensional envelope?"
		You shake your head slowly. A glance at Frankie reveals that she's equally mystified.

		"Hm. Wait!" Holt slaps his thigh. "Maybe I--Okay, leave that for now."
		*set chosen_options +1
		*goto before_parts_list
	*disable_reuse #"A relativistic ephemeris?"
		"A...what?" The phrase recalls something from a temporal theory class, but...

		Holt shakes his head. "It's the thing that translates 'Oklahoma City Zoo, 2012' into time coordinates you can travel to. Without it, you can only travel to places you specifically know the coordinates to."

		"But we can scan where the Professor was scanned from!" you say.

		"Oho!" Holt grins. "All right. A single-shot time machine. We just might be able to pull this off!"
		*set chosen_options +1
		*goto before_parts_list
	*if (chosen_options >= 4) #"Is that it? What about that dimensional envelope?"
		*set visitable_ok1861 1
		Holt nods. "There's also--well, we'll cross that bridge when we come to it. But we really need a dimensional envelope to have any chance. I have a lead, though." He opens a different file on his comp. "My safehouse was used as a base for agents that had Oklahoma's history as their 'territory'. On a recent trip, they recorded readings consistent with dimensional envelope technology, but they didn't have time to properly investigate. Luckily, I have the coordinates right here."

		"Uh-huh," you say. "Where? Or, more importantly, [i]when[/i]?"

		Holt's smile is a touch grim. "Oklahoma, 1861."

		"Then we can go there," you say. "Wait, wasn't something happening around that time?..."
		*goto after_parts_list

*label after_parts_list

*page_break History beckons...

*goto_scene hub_0 after_hub_info

*finish

