[b]TRAINING MISSION BETA - 'ROCK AND ROLL'[/b]

*set training_score 0

You walk down a dim hallway, to a massive metal door labeled 'Hangar 146'. Next to the huge door is a smaller, person-sized one, so you open that and step through.

The hangar is a blank room, paneled in metal. It's wider than the corridor, but what's truly startling is its length. It extends forward a long way...too long for you to see the end, despite softly glowing lamps set in the high ceiling. Sitting in front of you is a car.

You close the door and walk toward the car. It's a blue station wagon, from the 1980s, perhaps. You catch sight of a small metal word attached to the rear--'Celebrity'.

"Oh, the new meat!" The front driver's side window lowers, and a head pokes out. A woman, tanned face framed with short black hair. "About time! Get in!"

"It's ${name}," you say, walking toward the back of the car and behind.

"I said 'Get in', not 'correct me'!" The woman lets out a sigh. "Not that way! Behind me, driver's side rear door!"

"Uh, right." You open the aforementioned door. "You must be 'Mistress Renne'? Are we in a hurry?"

"Yes I am," she says. "And technically no, but I hate wasting time! Come on!"

You duck into the car. As soon as your rear touches the seat, the engine revs; you scramble to get your legs inside before the door slams shut.

*page_break And around you is something unexpected...

You've never been in a 1984 Chevrolet Celebrity, but even so you can tell this isn't a standard model. Where you expected a back seat, you find only your seat and stacks of equipment; the spacious trunk area is taken up by something large, high-tech and humming. A belt straps around your chest and you are turned to the side--the seat is on a track, positioning you in front of the rows of scanners and consoles. There isn't even a passenger seat, only the driver! The wheel and gearshift look original, however.

"Welcome aboard!" Renne says breezily, staring down the tunnel as the car accelerates. "I figured you'd rather be manning the gunner's chair instead of driving. Can you drive, anyway?"

*fake_choice
	#"Uh..."
		Renne laughs. "I figured! You'll probably have to pick up a bunch of hands-dirtying skills like that! That's why you're here with me! Although, you're not going to learn [i]driving[/i] today."
	#"Sure I can drive!...It's not a stick shift, is it?"
		Renne's reply is a snort. "Manual gives you more control! Not that the engine is original, of course. Still, sometimes you need every advantage you can get!" Her foot hard on the pedal, she shifts up and then up again with the smoothness of a racer. "Especially when you're involved in a [i]conflict[/i]."
	#"I've put in my hours racing around the track!"
		"Heh, that's good." Renne tosses you a grin, before returning her attention to the 'road'. For this mission, though, I'll be doing the driving. Safer that way. You'll have something else on your mind." The car accelerates even more.

"Wait," you say, tensing in your seat as the lights whizz by outside. "What sort of mission is this?"

"Continuity didn't tell you?" A grin stretches over Renne's face. "A combat mission!"

A sound intrudes upon your consciousness. At first a hiss, quickly rising in volume and pitch to almost a shriek. Then a crash, and white light fills the car's windows...

*page_break

...Another crash and the light is merely sun.

You crane your neck and stare out the window. The wagon is hurtling over a grassy plain. The light is cheery--no, actually it seems [i]bluer[/i] than that of the Earth's sun. The grass is browner than you might expect, but it [i]is[/i] recognizably grass.

"All right," you yell, but then you realize that the time jump's sound and light show has ceased. Not only that, the engine is near silent. "All right," you say, more quietly. "When and where are we?"

"Somewhere around what you'd call the 30th century," Renne says. "No wait--31st. I always get that mixed up. A distant planet, a few hundred light years from Earth. Of course you can find the exact coordinates in your comp."

"An alien planet," you say. "Populated by humans?"

"There are humans living here, yes." Renne turns the wheel and the car goes into a long turn. "Along with..."

The car crests a ridge and you rise in your seat for a moment before being slammed down again.

*page_break And before you stretches a battlefield.

"They have many names," Renne says, as you lean forward to stare out the windshield. "Biologically Unstable Lifeforms, BULs or BULFs; Amoeboids...I'll always think of them as Meebs; in some time periods it's a slur, but eventually it loses all power to offend."

*choice
	#"So Meebs vs. humans? Who's right? Is this battle justified?"${ds_diplomacy}
		Renne chuckles. "Hard to say. Our objective isn't to help or hinder. We just find the time tech and get out of here.
		*set diplomacy +1
		*goto after_mh
	#"Okay, who do we help win?"${ds_combat}
		Renne laughs. "I like you. But no, we have an objective. We get the time tech and leave."
		*set combat +1
		*goto after_mh
	#"What started this battle?"${ds_enigma}
		*set enigma +1
		Renne shrugs. "Resources, I think. Keep in mind our objective! We have to find the time tech and then leave!"
		*goto after_mh

*label after_mh

Renne drives through the battle, shouting instructions to you. You find yourself trying out several weapons, grimacing as they cause explosions. Most are stun weapons, though. Most.

Finally the car smashes into a bunker. Renne leaps out, and you do as well. You find a number of people cowering there, most of them seeming like non-combatants. "Sorry!" Renne says, holding up her hands. "Sorry. We're looking for someone."

"Please..." A man staggers up to you, holding your shoulder. "Please, you must help us..."

"Of course," you say, turning to him. Then Renne yanks you backward.

A knife slices through the air where you just were, sizzling with some sort of energy. Renne lunges with a punch, the man blocks it. They trade blows for a moment while you watch openmouth, but she twists his arm, the knife clattering to the floor, then she knees him in the stomach.

He falls to the floor and vanishes in a crackle of energy.

A blonde woman, face streaked with blood and sweat, creeps up to you. "We have no idea who he was," she says. "He came in here, forcing us to be quiet."

"Yeah, he wasn't a real refugee," Renne says. She glances around the room, then pushes a few boxes aside. "Oho, what's this!"

It's a large, humming, green glowing thing. "A generator?" you ask.

"Yeah, but it runs on..." She sniffs. "Paradox energy? That's dangerous. We gotta take this."

She unplugs the thing and the lights go out. "All right," she says. "Not my best work, but it's good training for you, right trainee?"

*finish

