[b]TRAINING MISSION ALPHA - 'PAPER TRAIL'[/b]

*set training_score 0

The room is cramped, yet filled with light. Consoles line the walls, displaying softly glowing readouts. The seats and kiosks are aimed at a large screen dominating one wall, though it shows nothing but black at the moment. Facing the screen, standing at the central control podium, is a man with brown hair and tanned skin, wearing a button-down shirt and slacks. He's older than you, 50 years or perhaps even 60, but still quite vigorous. Sprightly, even, but he even seems too young for that word.

"First mission, hmm?" he says, watching the black screen. A shudder runs through the room and it dips under your feet, prompting you to grab a handy metal railing. "Sorry," the man says, calmly keeping his place. "This mode of travel can be a bit bumpy at times. I'm sure you'll get the hang of it soon enough, rookie." He lets out a sigh, then he glances at you. "Speaking of which, what should I call you?"

*choice
	#Alex.
		*set name "Alex"
		*goto after_name
	#Avery.
		*set name "Avery"
		*goto after_name
	#Casey.
		*set name "Casey"
		*goto after_name
	#Dakota.
		*set name "Dakota"
		*goto after_name
	#Jamie.
		*set name "Jamie"
		*goto after_name
	#Jessie.
		*set name "Jessie"
		*goto after_name
	#Rowan.
		*set name "Rowan"
		*goto after_name
	#Sage.
		*set name "Sage"
		*goto after_name
	#Rookie is fine, really.
		*set name "Rookie"
		*goto after_name
	#Actually, my name is...
		Input name:
		*label input_name
		*input_text name
		*comment check capitalization
		*if ("${name}" != "$!{name}")
			Your name is $!{name}, is that right?
			*choice
				#Yes.
					*set name "$!{name}"
					*goto after_name
				#No, my name is ${name}, just as I said.
					*goto after_name
				#Er, wait, let me try that again.
					*goto after_name

*label after_name

"Excellent," he says. "${name}. And you can just call me Dan." His smile increases. "We do tend to accumulate names as we go along. I'm sure you will too. Now, then." The large screen suddenly flicks to life, showing a street closely packed with several-story buildings. "Aha! Wait. No." It flicks to another image, then another. "No. No...Ah. Just the thing." A dark alley is nestled between two red brick buildings. The room shudders around you, and Dan turns, giving you a pleasant smile.

"Right," he says. "Here we are, your first mission. Training mission, but still. Excited?"

*fake_choice
	#"Uh..."
		Dan chuckles. "Don't worry. I'm sure you'll do fine."
	#"Yeah, it's great to finally get out of those dusty classrooms!"
		Dan raises his eyebrows. "But, you know the theory is important. We wouldn't let you out here if you hadn't proven yourself in those classrooms. Oh, but then again. There's nothing wrong with being excited." He smiles indulgently.
	#"It's kind of scary to actually be putting everything I learned into practice..."
		Dan nods. "It's good to have respect for the work we do. Being afraid is certainly natural. Still. This should be an easy mission, I have no doubt you'll do fine!"

He steps toward the door--Then, however, he stops. "Wait. All right, let's take a minute, make sure we're ready. Got your comp?"

"Right here." You put your hand over the object strapped to your left wrist.

Your mentor nods. "Don't show it off. They have watches, of course, but phones are still bulky. Translator set to American English? Right." He moves over to a wall and opens a panel, revealing a cabinet stacked with obscure devices. "Beyond a comp, is there anything you'd like?"

*choice
	#"Something to help us blend in?"${ds_diplomacy}${ds_training}
		*set diplomacy +1
		*set training_score +1
		Dan gives you another smile. "Ah, most of that is built into your comp. It'll translate everything for you, although in some time periods it can be unusual to understand [i]every[/i] language you come across. It also has what I refer to as an in-group enhancer; it prompts people to trust you."
		*goto get_tool
	#"A weapon!"${ds_combat}
		*set combat +1
		*set taser 1
		A crease appears in Dan's brow. "A weapon, hm? It's true that we face, well, [i]enemies[/i], but violence is always a last resort. I suppose if you're really worried, though..." He rummages in the cabinet until he withdraws a small device. "A 'stun gun'," Dan says, handing the dark gray box to you. "Perfectly chronistics, although its battery is, let's say, quite powerful for the year. Oh!" He withdraws a similar device from his pocket, then he grabs a battery from the cabinet and slots it in. "Used the other battery last mission to power a vortex scanner!"
		*goto get_tool
	#"Some sort of scanner or tool?"${ds_enigma}${ds_training}
		*set enigma +1
		*set training_score +1
		Dan's smile widens. "Ah, that's what I like to hear! Fixing things, or just getting in to find what you need, that's always a good strategy."
		*goto get_tool

*label get_tool

*set multitool 1

Dan leans in to the cabinet, muttering to himself, voice dampened by the small space. He finally withdraws, holding a short rectangular rod. "You'll definitely need this," he says, handing the metal object to you. "Technically it's a 'multitool'--well, its [i]actual[/i] name is a little more complicated, but we all call them 'tools'. See, twist open this bit and you'll find buttons." He walks you through a few of the tool's functions, mostly interfacing with other technology. "I'm sure this will come in handy. Just remember that it's [i]very[/i] anachronistic, almost always."

"Right!" Dan strides toward the door. "Shall we?"

*page_break "I guess?"

"1994!" Dan walks out into the alley and peers out into the street. "Newbury Street." Turning, he smiles at you. "Boston, Massachusetts, United States of America. Earth."

"I could have guessed most of that," you say. The alley is, fortunately, clean. Turning, you see that the entrance to the time machine has disguised itself as a portable toilet. Terrific. "All right. What are we looking for?"

"Good question!" Dan looks at his 'watch'. You follow his gaze, noticing a map displayed on the tiny screen. "Someone has been traveling through time. Badly. I think they're making just a bit of a mess of things. Which is good, because it makes it easier to track them." He taps the screen. "Without clumsiness like that, your first training mission would be a lot harder."

*page_break "Let's get to it, then."

The man has black hair and epicanthic folds, but pale, sallow skin. Of course that last might be because he's dead.

You step back from the table and look around the morgue. Somehow Dan got you unsupervised access to this corpse, though you're not entirely sure how. "Curious," your mentor says, still leaning over the operating table and waving one of his devices over the body. "Wounds consistent with plasma weapons and force shields. Genetic markers indicate twenty-fifth century origin. Classic Chaos Agent signs."

Finally he glances up at you. "Any questions come to mind, ${name}?"

*choice
	#"Why is he here in 1994? What reason does he have to be here?"${ds_diplomacy}${ds_training}
		*set diplomacy +1
		*set training_score +1
		"Yes, indeed!" Dan switches to a different scanner, this one making a whirring noise as he passes it over the body. "My guess is an emergency time jump. There are energy traces within the wounds as well..."
		*goto after_corpse
	#"Are there plasma weapons around here?"${ds_combat}
		*set combat +1
		"No there are not!" Dan straightens up, nodding. "He must have been in a heated battle in some future time period, before triggering an emergency time jump. And the wounds didn't heal..."
		*goto after_corpse
	#"Where's all his stuff? That's what we're looking for, right?"${ds_enigma}
		*set enigma +1
		Dan raises his eyebrows. "A good question. If, as I believe, this Agent used an emergency time jump to escape a battle, all his personal effects have vanished."
		*goto after_corpse

*label after_corpse

Dan rubs his chin, staring at the body. "Escaping a battle," he murmurs. "But already mortally wounded. Probably died right after landing here. Now, the report says he had clothing, but nothing else. Like us, the Agents usually have devices that self-destruct if they die. [i]Usually[/i], but not [i]always[/i]."

Finally Dan looks at you. "And the time disturbances we've picked up on were more significant than one little emergency jump."

*page_break "So his time machine is out there in Boston somewhere..."

Dan shrugs. "Time machine, or parts thereof. Even a few circuits could be powerful in the right hands." A smile tugs at his lips. "If it's technology, in Boston, I know just where to go. But--oh." He glances at the body, then back at you. "What do you think we should do about this body?"

"Take it for evidence?" you ask.

Dan chuckles. "Good thought, I suppose, but we don't really need anything from it. I've got scans of it, there's nothing unusual. Do you want to haul it back to our ride?"

"Well, no," you say. "We could go there and travel here...never mind, I guess. Then why don't we incinerate it or something?"

Dan smiles. "An interesting idea. Would the authorities be intrigued by a mysterious body disappearing? Or would they be more baffled by a body they couldn't identify? Which would be more suspicious?"

*choice
	#"The mysterious body is suspicious in itself, we have to get rid of it! Didn't you say it was from the 25th century?"
		"I did, but that doesn't matter," Dan says. "It's just ethnic drift and such things. Even in the 25th century humans are still pretty human.
		*goto after_corpse2
	#"If it disappeared, that would make them even more suspicious."${ds_training}
		*set training_score +1
		Dan nods. "An unidentified body--a 'John Doe'--is not that rare. The authorities will do something with it, eventually."
		*goto after_corpse2

*label after_corpse2

Your mentor pulls the sheet back up over the body. "One body out of place is a very small change to the timeline. Barely a ripple, and removing it would draw attention." You glance around the room; you've had it drilled into your head to talk about Corps business in vague terms, but it does look like you're alone here..."We'll leave the body here; we got what we came for." Then Dan shakes his head. "At least, we know better what we're looking for."

*page_break "Then let's keep looking?"

Boston is bisected by the four-lane Massachusetts Avenue. It runs north across a bridge, just wide enough for the cars and a sidewalk on each side. Despite the autumn winds over the river, pedestrian traffic is brisk. Dan leads you along the street and up large, wide stairs into a huge lobby--three floors meeting at galleries around a central domed hall.

Dan catches your eye and motions upward. You crane your head upward to see workers high above, doing something to one of the inscriptions on the stone below the dome. No, there's a [i]facade[/i] replacing one of the inscriptions! You look quizzically back at your mentor. "Ingenuity," he says. "The students are known for it."

The pair of you walk through a long corridor that seems to connect every building in a half-mile radius, then turn off and down a stairway into an equally extended basement hall. "Miniscule fluxes like this are hard to find," Dan says, half-turning his head toward you. "Very small amounts of paradox energy. But we can sometimes pin it down to a room or two. And if we cross-reference with what we're likely to [i]find[/i] in those rooms..." Finally Dan knocks at a door sporting a "CAUTION - LASER LIGHT" sign.

An older man opens the door, brow furrowed, hair as white as his lab coat. "Professor Lund?" Dan says, smiling brightly. "We're here from Technical News Watch? My secretary was supposed to call. Here--" He hands over a card, at which the man stares. "I don't suppose you have a few minutes for an interview?"

The 'professor', still silent, squints at Dan. Then he turns his attention to you. Dan glances at you as well.

*choice
	#"Uh..."
		As you appear unwilling to offer any input, Dan turns back and nods to the man. "We've heard some great things about you and your work."
		*goto after_prof
	#"We've heard great things about you!"${ds_training}
		*set training_score +1
		Dan nods to the professor. "We know your time is valuable, but..."
		*goto after_prof
	#"Oh, just let us in already!"
		Dan laughs and pats you on the shoulder. "Oh, ${name}, always so eager for the story! Great reporter's instincts. Diplomacy could use a bit of work, though."
		*goto after_prof
	#"We've heard you may be working on something really interesting!"${ds_training}
		*set training_score +1
		"And if so, you'll have a great chance to share it with the world!" Dan says.
		*goto after_prof

*label after_prof

After a long moment silence, Prof. Lund takes a deep breath, then he lets it out in a long sigh. "Oh, go on, then," he says, stepping back from the door. "I guess I can spare a [i]few[/i] minutes for my adoring public."

The lab is cluttered with electronic equipment, much of it looking custom-made. At one point it was big enough for three people, but not any more. "We're studying the interaction of various fields," Lund says, sighing as he sinks into a chair. "Electromagnetic and gravitational, mostly."

"Using lasers?" Dan asks.

The professor laughed. "Actually that sign is left over from the lab's previous tenant. I leave it up in case we ever actually use the laser again..."

There's a clatter; you notice a door leading deeper into the lab, with more tables and equipment. Lund raises his eyes to the heavens. "My lab assistant," he says with a sigh. "Well, never mind her. Here, sit down, let's get this over with."

Dan glances at the other room, then he looks at you.

*choice
	#"I'll talk to your assistant, maybe there's a human interest angle."${ds_training}
		*set training_score +1
		"She won't have...oh, fine." Lund waves vaguely. "Do as you like. But if you break anything, it's coming out of your salary." He and Dan share a laugh as you move to the other room.
		*goto talk_elizabeth
	#"I'll interview you, sir! Dan likes to walk around and get a feel for the environment."${ds_training}
		You seat yourself in the offered chair. Lund gives you a quizzical look. Dan merely nods. "${name} will take good care of you, professor," he says. I'll be around."
		"Yes, quite," the professor murmurs, gazing at you.
		*if diplomacy > 0
			*set training_score +1
			You interview the professor, dredging up as much as you can from half-remembered physics classes. He answers your questions smoothly, as if from long practice. You make note of what he says, but you suspect it's not anything substantive. Just when you're running out of questions, Dan returns and nods to you. "How's it going?" he asks. "Excellent, excellent. Well we don't want to take up any more of your time, professor!"
			*goto lab_regroup
		*else
			You stumble through an 'interview'. The professor answers your questions, the crease in his brow deepening as time wears on. Finally he pushes his chair back and stands. "I'm afraid I have no more time for this," he says. "I think you and your 'friend' should be leaving."
			*goto lab_regroup
	#Nod to your mentor and look around the lab, eventually moving into the other room.
		Dan seats himself in the chair and begins 'interviewing' Prof. Lund. They're soon deep in a discussion of theoretical physics. You make your way into the other room, looking around.
		*goto talk_elizabeth

*label talk_elizabeth

This room is less cluttered, not by virtue of having less stuff in it, but by being larger. It's occupied by half a dozen workbenches, an entire repair shop's worth of electronics--and one woman. When you enter, she stares directly at you. She's Asian, with straight black hair; another white labcoat covers most of her clothing. Pulling safety glasses up to her forehead, she frowns at you. "And who are you?"

"I'm ${name}," you say. "We're doing a feature for...some magazine."

"'Some' magazine?" Her eyebrows raise.

"Uh, I've interned at so many places, they all sorta run together!" you say.

At this she actually smiles. "Yeah, I know the feeling. So, a magazine feature?" She rests her elbows against a table, still watching you. "Well [i]my[/i] name, for the feature, is Elizabeth Chen. And this feature is about what, exactly?"

"Something about your work," you say. "Dan had a lead, he didn't tell me where he got it. Have you been doing anything interesting lately?"

She shrugs. "I'm just trying to earn class credit. Mostly I do busywork."

*fake_choice
	#"The work isn't rewarding, then?"
		Ms. Chen's face twists into a grimace. "I think it's a dead end, honestly. We haven't had any positive results. Sure, knowing something [i]doesn't[/i] work is useful, I guess, but I'm sure there are other avenues..." She trails off. "Uh. Sorry."
	#"Professor Lund doesn't give you interesting stuff to work on?"
		Ms. Chen's frown deepens. "Even if the work was interesting, he wouldn't give it to me. I'm just an...an automatic soldering iron. He probably thinks I got into this school by mistake."

*fake_choice
	#"So there really [i]isn't[/i] any good research being done in this lab?"
		She gives a long, elaborate shrug. "It's just...filling in the blanks. Nothing will come of it. I'm not sure the [i]professor[/i] even wants to find anything. I mean, [i]I[/i] could..." She stops, then she shakes her head. "He'll go on and on about his findings, but it doesn't mean anything."
	#"I'm getting the feeling you don't like the way the professor treats you."
		She sighs and looks up at the ceiling. "He doesn't think I can do any [i]real[/i] work," she says, voice low. "I'm sure of it. I've already...I mean, I think he thinks I'm a child. It could be worse, though, it could [i]definitely[/i] be worse. The last guy I went out with made a 'joke' about me in a schoolgirl uniform." Her gaze returns to you, eyes stormy. "I'm not even Japanese! Not that that would make it okay, of course."

"Sounds like you're a little discontent," you say.

Ms. Chen blinks and straightens up. "You're not going to print any of that," she says quickly. "I was just, uh, I was just complaining. Everyone complains about their job sometimes, right?"

Before you can reply, Dan pops his head into the room. "I think we've got everything we need for a good story," he says. "Ready to go?"

*page_break "Sure, I guess."

Dan turns and walks back the way you came, past the stair you came down. "What do you think?" he asks.

*choice
	#"I think this lead was a bust. It's a dead end."
		"And why do you say that?" Dan asks, still walking.

		"The lab assistant," you say. "Elizabeth Chen. She was convinced nothing will come of the research. They never had any positive results."

		"I see," Dan says. "Of course, sometimes you don't know until you finish, right?"

		You frown. "Does that mean you think the professor has the...er..."

		"Actually, no," your mentor replies. "[i]I[/i] think Ms. Chen is our best lead now."
		*goto after_interview
	#"I think the lab assistant, Elizabeth Chen, is resentful of how she thinks the professor treats her."
		"Oh?" Dan's smile reveals nothing. "How does he treat her?"

		"Like she can't do any real work," you say.

		"Hmmm," Dan says. "Like a child, or student? I would have expected you to sympathize."

		"Huh?"

		Dan chuckles. "Regardless, I don't think the professor is very good at his job. He wouldn't have any real work to [i]give[/i] her. I think she's likely the one we're [i]actually[/i] looking for."
		*goto after_interview
	#"I think the lab assistant, Elizabeth Chen, is smarter than the professor."${ds_training}
		*set training_score +1
		"Ah." Dan smiles, still walking. "I must confess I wasn't too impressed with the professor, even for someone of this time period. But your opinion of the lab assistant was better?"

		"It was," you reply. "She was, well, chafing under him. She didn't feel respected, and she didn't feel like she had any way to [i]earn[/i] respect."

		"Quite an attitude for someone her age," Dan says.
		*goto after_interview

*label after_interview

*goto final_readiness

*label lab_regroup

Dan turns and walks back the way you came, past the stair you came down. "What do you think?" he asks.

"Hard to say," you reply. "I was a little out of my depth. But I thought..."

"Hm?" Dan glances back at you as you hesitate. "Come on, out with it."

You take a deep breath. "I thought he wasn't talking about anything, anything [i]real[/i]," you say. "I mean, I didn't think he had anything real to talk [i]about[/i]."

"Ah," Dan says, a smile on his face. "That would certainly agree with the opinion of one Ms. Elizabeth Chen."

"The lab assistant?" you ask.

"The same. A student, chafing under the restriction of not having any interesting work to do. Smart, too. Surprisingly smart, in fact; maybe even smarter than the professor."

Your brow furrows. "So the professor isn't the lead...she is?"

"Seems likely!"

*label final_readiness

*page_break

"Now then." Your mentor stops at a pair of metal doors with worn plastic bumpers. He peers out at asphalt, then he glances back at you. "Someone found that bit of equipment--it wasn't necessarily with the, uh, with what we were looking at earlier today. It could have been laying somewhere, anywhere. In a basement hallway, perhaps. Someone picked it up and started playing with it. Someone [i]smart[/i]." He rubs his hands together. "And yet, and yet whoever it is hasn't used it for very [i]much[/i]. No lottery number predictions or anything truly paradoxical like that. Which is interesting." He smiles. "I think we've just about wrapped this case up. Ready?"

*page_break "Ready!"

You breathe heavily as you step up the last step, almost stumbling on the suddenly level floor. "Do all missions have this much walking?"

"Nope." Dan pats you on the shoulder before heading past you, opening the door to a carpeted hallway.

"Why does this dorm have the stairs only on one side of the building?" You follow, looking at the numbers on the doors.

"Actually, the architect had a very specific goal in mind," Dan says. "He wanted every room in the building to have a window facing south. But to the matter at hand." He stops in front of a door, straightens his posture, then knocks.

There's vague shuffling behind the door. After a moment it opens, and Elizabeth Chen frowns out at you. "You guys again?" she says sourly. "Haven't you gotten enough for your story?" Her labcoat is gone; she's wearing a gray T-shirt and maroon sweatpants.

"We did have one or two other questions," Dan says. "Somewhat urgent."

"I'm through working for the day," she says. "Go away." She scowls at you from behind the chain holding the door mostly-closed. Dan glances expectantly at you.

*choice
	#"We were very interested in your work. We got the impression you had something you were working on, on your own, that might be much more interesting than what Lund had going!"${ds_diplomacy}${ds_training}
		*set diplomacy +1
		*set training_score +1
		She looks back and forth between the pair of you, then a smile tugs at the corner of her mouth. "I...I guess there [i]might[/i] be something." Suddenly, though, her face pales. "Ah...well..."
		*goto after_interrogate
	#"We're interested in unusual avenues of research. Have you been looking into anything like that? Not like the stuff at your lab."${ds_enigma}
		*set enigma +1
		She looks back and forth, then she bites her lip. "How did you...I mean, there isn't anything like that. Certainly nothing I've felt like sharing with anyone." Her face is pale.
		*goto after_interrogate
	#"We know you've been engaging in clandestine research, Ms. Chen."${ds_combat}
		*set combat +1
		Dan gives you a sharp glance, but he quickly looks back at Ms. Chen. Her face grows pale. "How...I...There's nothing like that. 'Clandestine' research? What?" She forces a laugh. "[i]Everyone[/i] here does research! It's what we [i]do[/i]!"
		*goto after_interrogate

*label after_interrogate

"We don't mean any harm," Dan says, voice quiet. "This might be easier if we spoke in private."

There's a long moment of silence. During this time, you hear a door open somewhere behind you; peeking back, you notice another young woman looking out of her room, blonde pigtails framing a wide-eyed face. Finally Ms. Chen, face tight, unhooks the chain and lets you into her room. You follow Dan inside and let the door close.

It's quite compact. There's a bed and even a sink, then past it an open space with a couch, as well as a desk attached to the wall. And on the desk...

"Aha!" Dan steps forward and waves something over a jumble of electronic parts. "Excellent! Now we'll be able to track it."

"Hey!" Ms. Chen steps up to him, trembling, fists balled. "That's mine!"

"Finders keepers. Indeed." Dan stows his device and smiles at her. "I merely recorded its temporal footprint."

"Temporal...you mean..." She sits down on the bed.

"You knew [i]someone[/i] had to have made it," Dan says, voice soft.

"So. You're just going to take it?" Her face suddenly twists into a glare.

"Hm," Dan says. Then he looks at you. "${name}, what do you think? Anything to add?"

*choice
	#"Uh..."
		"Sorry," Dan says. "This is my trainee. Sort of inexperienced." He rubs the back of his head and looks at the device. "That thing is incredibly anachronistic. It's also in very poor condition."
		*goto after_chronistic
	#"We can't let technology like that stay in this time period."${ds_combat}
		"I guess we're pretty much done with spoilers by now," Dan says. "The trainee is right, basically. Not to mention, the thing isn't in very good condition."
		*set combat +1
		*goto after_chronistic
	#"If she found it, wasn't she supposed to find it all along?"${ds_enigma}
		"Oh, my." Dan's face splits in a grin. "Not necessarily. You're going to have to learn a bit more temporal theory--"

		"The existence of a time machine alters the workings of time," Ms. Chen says. "Once a time machine is invented, it changes time around itself." She looks between the pair of you. "That's right, isn't it? It was the only way the equations would make sense."

		"Hm," Dan says, still smiling. "Very smart indeed." He turns to the jumble of parts and pokes it. "Not enough to fix this completely, though."
		*set enigma +1
		*goto after_chronistic
	#"How did she get it working? She must be a [i]lot[/i] smarter than Lund."${ds_diplomacy}${ds_training}
		*set diplomacy +1
		*set training_score +1
		Dan chuckles, and Ms. Chen even manages a smile. "I agree," your mentor says. "It's badly damaged and barely functioning, but she [i]did[/i] get it working and even use it a few times."
		*goto after_chronistic

*label after_chronistic

"Is it...unsafe?" Ms. Chen asks. At Dan's nod, she looks down, though you notice she peeks toward the door.

"Expecting someone?" you ask.

"What?" To her credit, she gives you a convincingly baffled look.

"Ah, of course!" Dan says. "You're expecting [i]yourself[/i]. But you won't arrive, will you?"

Ms. Chen struggles to keep her face neutral. "What do you mean, 'I won't arrive'? How do you know?"

"I know this one," you say. "If you have a time machine, you can [i]intend[/i] to visit yourself later. That's the easiest way to avoid paradox. Well, [i]excessive[/i] paradox."

After a moment's silence, Ms. Chen stands up, glaring. "And you won't be able to stop me!"

"Stop you from visiting yourself?" Dan asks. "I might be able to."

"How?"

"Ms. Chen, please don't come back and visit yourself at this moment." Dan smiles.

The young woman bites her lip, then she brushes a hand over her forehead, sighing. "Maybe...maybe it's not working because you're about to confiscate my machine."

"Maybe." Dan regards her. Scrutinizes, even. "But you don't really need it. Why don't you come with us?"

"What?" She stares at him.

*page_break "What?"

Dan nods. "I'm not going to summarize the entire history of the Paradox Corps, but time travel is a dangerous thing. For the safety of humanity, of time and reality itself, those who invent time travel are invited to live and work with us. From all across history, working together. All [i]appreciated[/i] for their talent. Doesn't that sound wonderful?" His eyes gleam.

Ms. Chen hesitates. "I guess," she replies. "But I didn't 'invent'...anything..."

"Well, let me put it this way." Dan picks something up from the desk; a calculator, you notice. "Ah, solar-powered, excellent. If you dropped this in, say, 1800, someone wouldn't have to be [i]too[/i] smart to make it add and subtract. But!" He gestures with the device. "But! If you took the main circuit board [i]out[/i], away from its housing and keys and solar cells--and you dropped [i]that[/i] in 1800, and someone [i]still[/i] worked out how to make it calculate...Ah, now that person [i]would[/i] be a genius!"

Ms. Chen's eyes slowly widen. "You mean..."

*fake_choice
	#"I guess you really are as smart as I thought."
	#"That's fine, but can we really just yank her out of her time?"

Dan nods. "We'll have to make some arrangements. You can live out some of your life here. Part of it, at least. But something more will always be waiting."

"I..." Elizabeth Chen swallows, then she nods. "Thank you."

"Oh, no. Thank [i]you[/i]." Dan peers over at the machine one more time. "I'm curious, though. What were you using it for?"

Suddenly the young woman's cheeks flush. "Uh...studying."

"Studying? Oh, of course! One self studies while the other catches up on sleep. How very humble!" Dan smiles delightedly.

*page_break "I guess that's that..."

After goodbyes are said and a long walk is walked, you and Dan find yourself back in the control room of his time machine. "Someone will get back to Ms. Chen soon," he says, adjusting one of the screens. "Perhaps even as we speak. Time travel, you know. There's just one more thing to take care of..."

*if training_score <= 0
	Dan lets out a sigh. "I can't say I was really impressed with your performance on this mission. Still, it's not like you specifically screwed up." He shrugs. "Maybe it's just a personality mismatch. You'll find the right mentor, I suspect."
	*goto end_training_0
*elsif training_score <= 3
	Dan studies you for a moment, leaning against the console. "I'll be honest," he says. "I think you could have done better on this mission. Well. Not that you bungled it or anything, it was just training." He busies himself with the screen again. "Well, perhaps your other missions will go better."
	*goto end_training_0
*elsif training_score <= 6
	Dan smiles at you. "You did good, kid. Okay, at least. I think we make a good team." He pokes at a screen. "Matter of fact, eventually you may not even need me! Well, it'll be a few years before that happens." He gives you a roguish grin.
	*goto end_training_0
*else
	"That was an excellent performance," Dan says. "I couldn't have asked for a better student! I'm sure you'll become a fine agent once you're through with your training." He pats you companionably on the shoulder, a proud smile on his face. Then he busies himself with the controls again...
	*goto end_training_0

*label end_training_0

*finish

