"Guilded Youth" by Jim Munroe.
Include Vorple Media by The Vorple Project.
Include Questions by Michael Callaghan.
Release along with the "Recording Vorple" interpreter.
Release along with the source text.
Release along with cover art.
Use no scoring.
Understand "* [text]" as a mistake ("Thanks for your feedback!").
Understand "help" or "hint" as a mistake ("You can win this game by using three commands: GO, TAKE and SHOW something TO someone. If you want to go somewhere that seems hard to get to, lead by example!").
Understand "credits" or "about" as a mistake ("Jim Munroe wrote and designed Guilded Youth. Matt Hammill did the art and animation. It started life at TOJam 2012. It uses the marvelous Vorple JavaScript user interface library by Juhana Leinonen, who also helped with coding. Troy Morrissey at Darc Productions helped with the sound. Beta testers: Adam Axbey, Matthew Bin, Raigan Burns, & Wiley Wiggins. Thanks also to the Inform 7 team and the interactive fiction community.").

Section 1 (Variables)

Every turn:
	repeat with follower running through people:
		if follower is joined:
			if follower is not occupied:
				move follower to the location of the player;
				refresh avatar illustrations.

When play begins (this is the setup inventory illustrations rule):
	eval "$('<div></div>').attr('id','inventory').appendTo('body')".
	
When play begins (this is the setup avatar illustrations rule):
	eval "$('<div></div>').attr('id','avatar').appendTo('body')".
	
When play begins (this is the setup header image rule):
	eval "$('<div></div>').attr('id','header_image').appendTo('body')".
	
When play begins:
	go retro;
	clear inventory illustrations;
	clear avatar illustrations;
	refresh avatar illustrations;
	set the header image to "topbar_ascii.gif";
	play mp3 sound file "modem.mp3";
	now Maximus the cleric is in the Adventurers' Lounge;
	now chris is worried;
	now maximus is worried.

To set the header image to (file name - text):
	eval "$('#header_image').html(vorple.media.image('[file name]'))".

The current domain is text that varies. The current domain is "ascii".

A thing has some text called illustration.

A person has some text called illustration.

A thing can be ascii or real. The player is ascii.

A thing has a number called id.
The current inventory illustrations is a list of things that varies.
The current avatar illustrations is a list of things that varies.

When play begins (this is the give things unique ids rule):
	let counter be 0;
	repeat with item running through things:
		now the id of item is counter;
		increase counter by 1.

[The idea here is that items in the list are stored in "current inventory illustrations" list,
and the code updates only those pictures that are added or removed from the list.]
To refresh inventory illustrations:
	let new illustrations be a list of things;
	repeat with item running through things carried by the player:
		if the illustration of item is not "" and the item is not listed in the current inventory illustrations:
			    let filename be indexed text;
			    let filename be "[illustration of item]_[current domain].gif";
  			    display image filename in element "item[id of the item]";
			eval "$('.item[id of the item]').appendTo('#inventory')";
		add item to the new illustrations;
		if the item is listed in the current inventory illustrations:
			remove item from the current inventory illustrations;
	repeat with removable running through the current inventory illustrations:
		eval "$('.item[id of removable]').remove()";
	now the current inventory illustrations is the new illustrations;
		
After taking or dropping:
	refresh inventory illustrations;
	continue the action.

To refresh avatar illustrations:
	let new illustrations be a list of things;
	repeat with character running through people in the location of the player:
		if the illustration of character is not "" and the character is not listed in the current avatar illustrations:
			let filename be indexed text;
			let filename be "[illustration of character]_[current domain].gif";
			display image filename in element "avatar[id of the character]";
			eval "$('.avatar[id of the character]').appendTo('#avatar')";
		add character to the new illustrations;
		if the character is listed in the current avatar illustrations:
			remove character from the current avatar illustrations;
	repeat with removable running through the current avatar illustrations:
		eval "$('.avatar[id of removable]').remove()";
	now the current avatar illustrations is the new illustrations;

[this will empty the list of illustrations so that any changes to the graphics will take place.]
To clear inventory illustrations:
	truncate the current inventory illustrations to 0 entries;
	eval "$( '#inventory' ).empty()".
	
To clear avatar illustrations:
	truncate the current avatar illustrations to 0 entries;
	eval "$( '#avatar' ).empty()".

To go retro:
now player is ascii;
now the current domain is "ascii";
eval "$('#vorpleContainer').removeClass('normal')";
eval "$('#vorpleContainer').addClass('retro')";
eval "$('Body').removeClass('normal')";
eval "$('Body').addClass('retro')";
refresh avatar illustrations;
clear inventory illustrations;
refresh inventory illustrations;
set the header image to "topbar_ascii.gif".

To go normal:
play mp3 sound file "switch.mp3";
now the current domain is "real";
eval "$('#vorpleContainer').removeClass('retro')";
eval "$('#vorpleContainer').addClass('normal')";
eval "$('Body').removeClass('retro')";
eval "$('Body').addClass('normal')";
clear avatar illustrations;
refresh avatar illustrations;
clear inventory illustrations;
refresh inventory illustrations;
set the header image to "topbar_real.gif".

Every turn:
	refresh inventory illustrations;
	refresh avatar illustrations.

Rule for printing the banner text: say "***You have connected to THE GUILD BBS*** " instead. 

After printing the banner text: say "(Guilded Youth v1.1 for the IFComp 2012. HELP and CREDITS are available. Sound enabled on Chrome.)" 

Section 2 (Rooms)

The Adventurers' Lounge is a room. 

Instead of going in the Adventurers' Lounge, say "You're in a place for lounging, not strolling."

Your Front Porch is a room. The description is "[if unvisited]Your front door clicks behind you. You turn to the east, where the Manor beckons.[otherwise]The Manor beckons invisibly to the east.[end if]"

Your door is scenery in Your Front Porch. Understand "porch" as your door. "The unassuming house you live in is a perfect cover. No one would guess a thief lives here, even your parents."

East of Your Front Porch is End of the Street. The description of End of the Street is "[if unvisited]The map was a joke -- you don’t really need a map to find your way, even past midnight. [end if]The forest at the end of the cul-de-sac smells damp and green, leading further to the east."

East of End of the Street is The Woods. The description of The Woods is "[if unvisited]Thanks to the full moon, you only trip once. 

[end if]You’ve lived beside these woods for half of your 14 years. The way on leads east."

Before going east from End of the Street:
	play mp3 sound file "crickets.mp3";
	continue the action.

Trees is scenery in The Woods. Understand "woods" as Trees. "You're fairly sure they'll be sacrificed to the gods of development pretty soon."

Full Moon is scenery in The Woods. "Luna blesses the fingers of thieves, or so you believe."

Instead of climbing in Inside the manor, try silently going down.

East of the Woods is The Field. The description of the Field is "You cross the electrical tower field, feeling rather than hearing its low hum. Superstition stops you from looking up at its wires. You can see the new development in the distance, the cause of your urgent mission, its machines like sleeping behemoths. But your destination is further east."

Wires is scenery in The Field. Understand "tower" or "hum" as wires. "No. One of the few times you've heard your parents fight was over the correlation of cancer rates and electrical towers. Doesn't matter -- once you make a big score you'll move your whole family to another house."

New development is scenery in The Field. Understand "machines" and "behemoths" as New Development. "The very size of the bulldozers seems smug, like a well-fed guard dog."

East of The Field is In Front of the Manor. The description of In Front of the Manor is "[if Harry the Barbarian is joined and Inside the Manor is unvisited]It’s cloudy tonight, and the Manor is more foreboding than yesterday. You wish you brought your flashlight. 

'Whew, what a dump,' says Harry. 'You sure there’s more mags in here?'[end if][If player does not have fork]Even crowded by wild brush, the grandest building in your neighbourhood still has a silent dignity. And to think: a few days from now, it’ll be erased from history.

The Manor looms to the north. You know from experience that there’s a coachhouse behind it, which you could get to by following a rough path to the northeast.[otherwise if player has fork]‘Who the heck were those guys?’ said Harry. ‘Jesus. Creepy.’

You pull out your loot and admire it, a fine three pronged dessert fork. Sterling silver from its weight, and beautiful in the moonlight.

Harry notices the look on your face. 'What are you, a klepto?'

You decide it's time to head home west, away from prying eyes.[end if]"

Before going north from In Front of the Manor:
	if Harry is joined and player encloses fork:
		say "That's enough loot for tonight.";
		stop the action;
	if Chris is joined and player encloses letter opener:
		say "That's enough loot for tonight."
	

Before going northeast from In Front of the Manor:
	if harry is not joined and ryan is not joined and paula is not joined:
		continue the action;
	otherwise:
		say "The coachhouse has already given up its meager treasures.";
		stop the action.

After going north from In Front of the Manor:
	try looking.

After going south from Inside the Manor:
	try looking.
	
Before going south from Inside the Manor:
	if harry is joined  and player does not have fork or player does not have doorknob:
		say "The Manor still has loot for the taking: you can smell it.";
		stop the action;
	if chris is joined and ryan is not occupied:
		say "The Manor still has loot for the taking: you can smell it.";
		stop the action;
	if maximus is joined:
		say "The Manor still has loot for the taking: you can smell it.";
		stop the action.


Before asking harry about "plank/planks/bag/door":
	if location is Portico of the manor:
		try silently going north;
		try looking;
		stop the action;
	else:
		continue the action.

Before asking Chris about "hole/stairs/banister/staircase":
	if location is Inside the manor:
		try silently going up;
		stop the action;
	else:
		continue the action.
		
Before asking Maximus about "hole/stairs/banister/staircase/cellar/wine":
	if location is Inside the manor:
		try silently going down;
		stop the action;
	else:
		continue the action.

Before asking Ryan about "picks/locks/door/lock/pick":
	if location is Inside the Manor:
		try silently going east;
		try looking;
		stop the action;
	else:
		continue the action.


North of In Front of the Manor is Portico of the Manor. The description of Portico of the Manor is "[if Portico of the Manor is unvisited]You remember the first time you and Ryan found this place, he dared you to knock on the front door. You did him one better, opening the door and pushing it open to reveal the dark hall beyond. There was a cold-iron smell that conjured up a vision of shackles wrapped around a skeleton’s wrists. Last year, when you drank your first beer behind the portables, you recognized the smell and realized the abandoned house must have just been a drinking spot for teenagers.

You can still see the dark hall in your mind’s eye, mysterious shapes beckoning just beyond the front threshold. What were they? [end if][if harry is not joined and plank is intact][paragraph break]You won’t be plumbing the Manor's mysteries tonight: large planks of wood are nailed firmly across the front door. You curse under your breath. [else if harry is joined]Harry looks at the planks appraisingly. [else if chris is worried and ryan is joined]Chris stops when she sees the planks and the forcible entry. ‘Whoa, I didn’t know you guys broke in, I thought it was abandoned.’ Doubt flickers across her eyes. ‘My dad’s a cop. It’d kill him if I --’ She shakes her head. Then she notices the notice stapled to the door and relaxes a bit. 'Oh, well. If it's gonna be trashed anyway...'[else if paula is joined and maximus is worried]Max glances at the paper. ‘I’d like to say that my only interest in entering this building is to preserve--’

Paula cuts him off with a stagey yawn.[paragraph break][end if]You can leave the portico to the south, or enter the Manor to the north."

North of Portico of the Manor is Inside the Manor. The description of Inside the Manor is "[if Inside the Manor is unvisited]You cross the threshold into the Manor, and achieve one of your boyhood dreams. You breathe the rarefied air, not sure what it is you smell, but appreciating that you’re the first to have smelled it in... decades?

To the west you hear a shuffling and scratching. Maybe some animals got in?

You look around the space, slowly taking it in. [end if]A curving staircase, badly damaged, used to lead to the second floor. Strange shapes loom throughout the space. Hallways heading off to the east and the west.[if chris is joined and chris does not have pocket watch and Chris is in location] Chris looks around, a smile on her face. She seems intrigued by the hole in the stairs.[else if paula is joined and maximus is joined] It’s familiar ground to you now, but the others look around in awe. 
[end if]"

Staircase is scenery in Inside the Manor. Understand "stairs" and "stair case" as staircase. "There's about six stairs missing, a huge hole leading down into a pitch blackness."

Northeast of In Front of the Manor is Outside the Coachhouse. The description of Outside the Coachhouse is "The double doors are large enough to drive a horse and carriage into, but one of them is missing, leaving an entryway to the north. Or you can return to the front of the Manor to the southwest."

North of Outside the Coachhouse is Inside the Coachhouse. The description of Inside the Coachhouse is "There’s a significant hole in the roof that lets in enough light to look around. You and Ryan have been in here before: until he saw a raccoon here it was practically your clubhouse. It’s pretty well picked over as a result. You can leave to the south." 

The significant hole is scenery in Inside the Coachhouse. "You see a few threads of cloud in the night sky."

Up of Inside the Manor is Upstairs.
Down of Inside the Manor is Downstairs.

Before going north from Portico of the Manor:
	if Harry the barbarian is joined and plank is intact:
		play mp3 sound file "squeak.mp3";
		say "You show Harry the problematic plank and he pulls a well-worn crowbar from his long bag. His chatter as he efficiently wrenches off the wood makes him oblivious to a slight clink you hear... then a rustle... and you'd swear it came from inside the house.
		
You push the door open with a creak...";	
		now the plank is removed;
		continue the action;
		try looking;
	otherwise:
		if plank is intact:
			say "The planks get in the way.";
			stop the action;
		else:
			continue the action.

The cellar hole is scenery in Inside the Manor. Instead of examining the cellar hole:
	try going up.

Before going up from Inside the Manor:
	if Chris is in Inside the Manor and chris does not have pocket watch:	
		say "Chris approaches the hole in the stairs and adjusts her headband. 

She tests the banister first and then hangs from it. You feel your heart lurch as her legs dangle into the hole. ‘When I started gymnastics,’ she says, going hand over hand across the gap. ‘I always used to imagine using my training in an adventure.’ 

‘This is kind of an adventure,’ pipes up Ryan, looking at you for confirmation. ‘Right?’ 

She gets to the other side, and flips her feet out onto solid ground. 

‘Sure, kid,’ she says.  She takes a penlight out of her sweatpants pocket and disappears into the second floor darkness.";	
		now Chris is occupied;
		remove Chris from play;
		stop the action;
	otherwise if maximus is joined and maximus is not occupied:
		now maximus is occupied;
		move rope to Inside the Manor;
		say "You come up to the huge ragged hole in the stairs. Max peers into the hole. ‘Looks like it goes straight to the wine cellar,’ he says, pulling off his backpack.

All business, he pulls out a rope and attaches it to the banister, letting the end dangle down into the inky hole.";
		stop the action;
	otherwise:
		say "You take a few steps up and can go no further. There’s about six stairs missing, a huge hole leading down into a pitch blackness[if rope is in the location] with a rope disappearing into it[end if]. The hand rail bridges the gap and seems pretty sturdy, but not enough to bet your life on.

[if harry is in the location]As you come down, Harry lets out a relieved breath. 'You don’t look like much of a long jumper.'[end if]";
		stop the action.
		
Before going down from Inside the Manor:
	if Chris is in Inside the Manor and chris does not have pocket watch:	
		say "Chris approaches the hole in the stairs and adjusts her headband. 

She tests the banister first and then hangs from it. You feel your heart lurch as her legs dangle into the hole. ‘When I started gymnastics,’ she says, going hand over hand across the gap. ‘I always used to imagine using my training in an adventure.’ 

‘This is kind of an adventure,’ pipes up Ryan, looking at you for confirmation. ‘Right?’ 

She gets to the other side, and flips her feet out onto solid ground. 

‘Sure, kid,’ she says.  She takes a penlight out of her sweatpants pocket and disappears into the second floor darkness.";	
		now Chris is occupied;
		remove Chris from play;
		stop the action;
	otherwise if Maximus is in Inside the Manor:
		try going up;
		stop the action;
	otherwise if rope is in Inside the Manor:
		say "You remember gym class rope climbing last year and decide against it. You’re nimble, but your upper body strength is for shit.";	
		stop the action;
	otherwise:
		say "You peer down into the inky blackness, and decide against it.";
		stop the action.

Before going east from Inside the Manor for the first time:
	say "The formidable door has one of those fancy crystalline doorknobs, which won't turn. It does, however, pull out in your hand and fall to the floor. 

'Whoa, big guy,' Harry says, patting you on the back. 'Easy there. Don’t need to wreck the place.

The doorknob rolls to a stop on the floor.";	
	move the doorknob to the location;
	stop the action.
	
After taking doorknob:
	say "You turn the crystal under the light, feeling its pleasing weight in your hand. As you slip your loot in your pocket, you feel a lightness in your belly.";
	continue the action.

After taking magazine:
	say "You manage to peel it off the floorboards.";
	continue the action.


Before going east from Inside the Manor:
	if Study is locked:
		if Ryan is joined and chris is occupied:
			say "You and Ryan go to the door. Ryan sizes it up as he takes out his picks. ‘Keep an eye out for the cop’s daughter,’ he says, a pick hanging from his mouth as he goes about his work.

A few seconds later, the door to the east is open. Ryan can’t keep a smile off his face, and you pat him on the shoulder.";
			now Study is unlocked;
		else if Ryan is joined and chris is not occupied:
			say "[one of]'Ready to do your magic?' you say to Ryan, motioning at the locked door.[or]You motion at the locked door again.[stopping]His eyes go big and he shakes his head, glancing over at Chris. Oh, right. That comment about her dad being a cop has him spooked. Not that it takes a lot to get him spooked.";
			stop the action;
		else:
			say "It's locked without even a doorknob to rattle futilely.";
			stop the action;
	else if Study is unlocked:
		if maximus is joined:
			say "The door’s closed and locked again. You don’t remember closing it behind you, but maybe you did?";
			stop the action.
						
East of Inside the Manor is the Study. The description of the Study is "This was clearly a library or office of some kind. The walls are lined with bookshelves, empty but for thick layers of dust. There’s a large desk pushed against a wall at a weird angle. You picture the owners packing up and needing to get it out of the way to get something else out of the door.

You can leave to the west." The study can be locked or unlocked. The study is locked.

Instead of pushing desk, say "A few seconds of futile pushing makes it clear why it was left here."

The bookshelves are scenery in the Study. Understand "shelves" or "books" or "book" as bookshelves. "Not a single book left behind."

West of Inside the Manor is the Hallway. The description of the Hallway is "There are birds on the wallpaper, the fragments that remain, their black eyes appearing to watch you.

Further west there looks to be a dining room."

Wallpaper is scenery in the Hallway. Understand "birds" or "eyes" or "bird" as wallpaper. "Bird eyes have always creeped you out. You are fond of magpies, though."

West of the Hallway is the Dining Room. The description of the Dining Room is "There are six people around the large table, the guys from yesterday plus a couple more.  The guy with the strange bangs and suit jacket is at the head of the table beside a goth girl who’s too beautiful to look at directly. The table is laid out beautifully, a candelabra melting onto the white tablecloth, chipped plates trimmed with gold."

Before going west from Hallway:
	if harry is joined:
		say "You make your way towards the dining room, you start to hear hushed voices. Harry kicks something that hits the wall with a metal sound. Your heart jumps as the low voices in the other room pause.

When they start up again you back slowly away, but not before pocketing the object Harry kicked.

You escape through the front door and emerge...";
		move fork to player;
		play mp3 sound file "treasuregetting.mp3";
		move player to In front of Manor;
		move Harry to In front of Manor;
		stop the action;
	otherwise if chris is joined:
		say "[one of]You inch forward a bit and try to catch a glimpse of the dining room occupants. You dip in and out, catching a glimpse of a long haired one, a guy with some kind of suit jacket, and two or three more. They appear to be setting the table...?

You feel Chris’s hand on your arm, pulling you back. 

The clink of dinner plates and cutlery cover up the sounds of conversation.

‘...definitely candles, it gives...’ 

Chris lets go of your arm.[or]You lean in and listen in a bit more.

‘...as if we’re the lords of the Manor. The pinnacle of suburban decadence. Rome before the malls moved in.’

Chris gives you a confused look, and you shrug.[or]No way are you going in there without at least two people to back you up. 'Probably we should get out while the getting's good,' Chris whispers.[stopping]";
		stop the action.

Instead of asking chris about "bulge/gleam/gold/golden" during offline3, say "She shrugs, failing to keep a grin off her face."

Before going west from Inside the Manor:
	if ryan is joined:
		if player does not have letter opener:
			say "'Uh,' Ryan says, 'Sounds like there's people there. Why don't we search the other rooms first?'";
			stop the action;
		otherwise if ryan is in the location:
			say "When Ryan sees you heading towards the noise instead of away, he makes for the exit.

‘Um... band practice, gotta go... nicetomeetyoubye!’ he says. When he gets out of the house he abandons all dignity and just starts running.

Chris gives you a sly smile and walks along with you.";
			move Ryan to Adventurers' Lounge;
			now Ryan is occupied;
			now Ryan is not joined;
			play mp3 sound file "unjoined.mp3";
	otherwise if Harry is joined:
		if player does not have doorknob:
			say "Based on the animal (?) sounds you heard earlier, you decide to leave that for last.";
			stop the action;
	otherwise if Paula is joined and Maximus is occupied:
		say "You stop just outside the dining room in the hallway and peek in. There’s a whole dinner party going on inside. You whisper to Paula that you recognize the guy from yesterday.

‘Yes,’ she says, her face flooding with emotion. ‘So do I.’

Before you can contest, she adjusts her hat, squares her shoulders, and strides into the dining room... taking you with her.";
		move player to Dining Room;
		move Paula to Dining Room;
		refresh avatar illustrations;
		stop the action;
	otherwise if Maximus is joined and maximus is not occupied:
		say "Max stops you. 'First things first: let's find the wine cellar.'";
		stop the action.

Before listening while location is Hallway:
	if Chris is joined:
		try silently going west;
		stop the action;
	else:
		continue the action.

Before going west from In Front of Manor:
	if player has a fork:
		now harry is not joined;
		remove harry from play;
		say "‘As you head for home, Harry keeps on with his blather. ‘Oh, oh yeah. Your Guild character. Don't you think you take it a little too seriously?'[paragraph break]You don't dignify that with an answer.[paragraph break]'Hey how can you be a thief with a good alignment anyway? Isn’t that the opposite?’

You walk faster and leave the Barbarian to struggle along with his large bag, and his ignorance, alone.[paragraph break]***";
		stop the action;
	otherwise:
		say "[if player has pocket watch]You lose track of her and just head for home.[paragraph break]***[else]You're not going home before you get some decent loot.[end if]";
		stop the action.

After going east from the Field:
	try looking;
	if Chris is joined and ryan is not occupied:
		now Chris is not occupied;
		say "There’s a girl in a track suit in front of the Manor. You keep it cool and introduce yourself.

‘Hey I’m Chris,’ she says, then trains her dark eyes on your friend. ‘And I guess you’re Ryan?’

Ryan, as usual in the presence of a non-boy, is motionless, so you nod for him.";
	otherwise if Paula is joined:
		now Paula is not occupied;
		say "Paula -- you assume it’s Paula, though she looks more goth than witch -- takes one last drag on her smoke before killing it under a creeper boot. 

‘Hello, boys,’ says Paula in a soft, deep voice. ‘You ready to knock over this joint?’

You nod. 

Paula turns toward the Manor and begins to pull on lacy gloves.".

Before going from Portico of the Manor:
	if chris is joined:
		now chris is not worried;
	if maximus is joined:
		now maximus is not worried;
	continue the action.

After going west from study:
	if player has letter opener and chris is occupied and ryan is joined:
		now chris is not occupied;
		move pocket watch to chris;
		move chris to location of player;
		say "‘There you guys are,’ Chris says grumpily as you come out. She gets up from the bottom of the stairs, where she’s been sitting.

She’s got her arms crossed and a funny look on her face. Despite her efforts, you notice there’s a small bulge in her jacket pocket.

You’re about to ask her about it when there’s a smashing sound to the west, followed by a peel of laughter.

Ryan nearly jumps out of his skin.";
	otherwise:
		continue the action.	
				
Instead of going during DirtyKissing:
	say "That golden gleam stops you in your tracks."

Section 3 (Characters)

Understand the commands "tell" and "say" and "answer" as something new. 

Understand "talk [text]" or "tell [text]" or "answer [text]" or "say [text]" as a mistake ("You'd rather not fill the air with idle chatter. A silent thief is an effective thief. Though if you really need to get something done, you can ASK someone ABOUT something."). 

Persuasion rule for asking someone to try doing something:
	say "You're not one for ordering people about. You can ASK someone ABOUT something if you like."

The description of the player is "Your non-descriptness is perhaps your most important thiefly trait." Harry the Barbarian is a person in The Adventurers' Lounge. The description of Harry the barbarian is "[if player is ascii]Harry the Barbarian is all muscle, all the time.[else]Stocky and jocky.[end if]". The illustration of Harry the Barbarian is "[if harry is joined and player is ascii]j_harry[else]c_harry[end if]". Paula the Mage is a person in The Adventurers' Lounge. The description of Paula the Mage is "[if player is ascii]Paula radiates with green sparkly power.[else]She's a bit taller than you. Black clothes, black makeup. She's like that girl in the Cindy Lauper video.[end if]". The illustration of Paula the Mage is "[if paula is joined and player is ascii]j_paula[else]c_paula[end if]". Ryan the Bard is  a person in The Adventurers' Lounge. The description of Ryan the Bard is "[if player is ascii]A jaunty tunesmith.[else]Ryan's between looks, hasn't really gathered the guts to go punk yet.[end if]".The illustration of Ryan the Bard is "[if ryan is joined and player is ascii]j_ryan[else]c_ryan[end if]".Chris the Paladin is  a person in The Adventurers' Lounge. The description of Chris the Paladin  is "[if player is ascii]Strong, true, a paragon of paladinity.[else]She's wearing a tracksuit and a short haircut. Something about her eyes makes her look ready for a fight.[end if][if chris has the pocket watch] There's something round in her pocket.[end if]". The illustration of Chris the Paladin is "[if Chris is joined and player is ascii]j_chris[else]c_chris[end if]".  Maximus the Cleric is  a person in The Adventurers' Lounge. The description of Maximus the Cleric is "[if player is ascii]An elder in the community, feared and mocked for his wisdom.[else]A thin teen, a smattering of pimples ensuring his clerical chastity: a gift from god?[end if]". The illustration of Maximus the Cleric is "[if maximus is joined and player is ascii]j_maximus[else]c_maximus[end if]". Understand "Max" as Maximus the Cleric. People can be joined. People can be occupied. People can be pinned. People can be worried. People can be smooched.

Understand "bulge" as Chris the Paladin.

Harry is carrying a bag. The description of the bag is "It's long and skinny. Maybe he came from baseball practice?"

Ryan is carrying a schoolbag. The description of the schoolbag is "He's written all the bands he likes on it, attempting to imitate the logo styles on their albums. Some are blacked out as they fall out of favour with him."

Ryan is carrying picks. The description of the picks is "He shoved them in his bag. You just know you're useless with them, but he seems to have the knack."

Ryan is wearing a hat. Instead of examining hat, try silently examining Ryan.

Maximus is carrying a backpack. The description of the backpack is "Army surplus with a dragon well rendered in ballpen blue."
								
The goth girl is scenery in the Dining Room. The description of the goth girl is "Black lipstick and eyeshadow is all you get before you have to avert your eyes. She’s definitely not from your school, or any school that you can imagine. Beside her is a dreadlocked guy with a large beard, picking his teeth with a bone." Instead of kissing goth girl, say "Your boldness has limits."

The dreadlocked guy is scenery in the Dining Room. The description of the dreadlocked guy is "A beard big enough to hide a mouse in. You can smell the patchouli from here. A thin tattooed girl glances over at him frequently."

The thin tattooed girl is scenery in the Dining Room. The description of the thin tattooed girl is "Feathered short hair with bird-like nervous movements to match, but you don't know if it's Paula-inspired."

Erik is scenery in the Dining Room. Understand "people" and "jacket" and "bangs" as Erik. The description of Erik is "You can picture him in front of the mirror trying to get his bangs straight, and being amused when he fucked it up. The suit jacket has fragments of mirror sewn into it."

Drumstick is scenery in the Dining Room. Understand "bird" or "duck" or "food" or "meat" as drumstick. "It's a darker meat than you're used to, but it smells intriguing." Instead of taking drumstick, say "You're not really hungry." Instead of eating drumstick, try taking drumstick.

Goblet is scenery in the Dining Room. Understand "cup" as goblet. "You've always felt like wine was an old people drink, but now you're intrigued." Instead of taking goblet, say "Your boldness has limits."

Candelabra is scenery in the Dining Room. Understand "candles" as candelabra. "There's more candles than abra, and it doesn't look all that steady." Instead of taking candelabra, say "Stealing light sources tends to be noticed."

Section 4 (Objects)

Instead of taking inventory, say "You can see what you're carrying in the left column, and your current party members in the right column."

After taking something:
	play mp3 sound file "[if player is ascii]joined.mp3[otherwise]treasuregetting.mp3[end if]";
	refresh inventory illustrations;
	continue the action.

Instead of giving something to someone, try showing the noun to the second noun. 

Instead of dropping something enclosed by the player:
	say "Your sticky fingeredness won't let you.";
	stop the action.

The sword is scenery in the Adventurers' Lounge. "[if chris is in location]Chris['] sword glows green and true.[otherwise]You don't see that here."

The desk is scenery in the Study. The description of the desk is "The desk was probably too big to get out through the door, so they just left it there. All its drawers are missing. It’s a lovely old wooden specimen, however, and it saddens you it will be smashed to pieces in two days. As you run a fond hand over it, you notice a glint in the inkwell."

The inkwell is part of the desk. Understand "glint" as inkwell. The inkwell is a container. The letter opener is in the inkwell.
Before examining the inkwell:
	if letter opener is in inkwell:
		say "The glint you saw is from a letter opener.  Your lithe fingers tease it out and Ryan crowds around. ‘Oooh, a dagger,’ he says. You reluctantly hand it over.

Ryan feels the edge and then scoffs. ‘Super-dull,’ he says, handing it back.

Your heart lightens and you don’t correct him. You secret it away for closer inspection later.";
		move letter opener to player;
		play mp3 sound file "treasuregetting.mp3";		
		stop the action;
	otherwise:
		say "Empty.";
		stop the action.
		
The rope is scenery.

The bottle of white wine is a container. "There's a bottle of white wine with a dusty label, within arms' reach." Instead of opening wine, try drinking wine. The bottle of red wine is a container. "A bottle of red wine with a dusty label." 

Instead of showing noun to second noun:
	if second noun is Chris:
		say "[if noun is map]Chris seems skeptical. 'Old houses are cool, but why bother?'[otherwise if noun is magazine]Chris the Paladin's silence is steely.[otherwise if noun is letter opener]'Yep, good find there kid,' says Chris.[otherwise if noun is pocket watch]Chris the Paladin winks at you. 'You keep that warm for me, teef.'[otherwise if noun is doorknob]Chris shrugs. 'Kind of neat, but it's less of an antique than a piece of a door.'[end if]";
	if second noun is harry:
		say "[if noun is map]'Why would you make a map of your own neighbourhood that's dumb' says Harry the Barbarian.[otherwise if noun is fork]'Yeah I was there when you scooped it remember?' says Harry the Barbarian.[otherwise if noun is letter opener]'Are you threatening me? hahahahahaha' says Harry the Barbarian.[otherwise if noun is pocket watch]'My grampa gave me one of those but you gotta wind it every day,' says Harry the Barbarian.[otherwise if noun is doorknob]'Why did you keep that? You gotta junk problem dude,' says Harry.[end if]";
	if second noun is Ryan:
		say "[if noun is fork]'If it's not a tuning fork, I can't use it,' quips Ryan the Bard.[otherwise if noun is magazine]'Dude are you crazy waving that thing around?' says Ryan the Bard.[otherwise if noun is letter opener]'Yeah I saw it in the house, did you sharpen it yet?' says Ryan the Bard.[otherwise if noun is pocket watch]'That's pretty sweet, but my mom would give me the fifth if she saw it,' says Ryan the Bard.[otherwise if noun is map]'I know the way to the Manor, dude!' says Ryan the Bard.[end if]";
	if second noun is Maximus:
		say "[if noun is fork]'Are you stooping to stealing cutlery now?' says Maximus the Cleric.[otherwise if noun is magazine]You don't dare. You'd be kicked from the Guild for sure.[otherwise if noun is letter opener]'You're lucky I know that's not a weapon,' says Maximus the Cleric.[otherwise if noun is map]'Please do not attempt to conspire with me,' says Maximus the Cleric.[otherwise if noun is doorknob]'Are you saying somewhere someone's trapped inside a room with no hope of escape? Much like you in the afterworld, if you fail to repent,' says Maximus the Cleric.[end if]";
	if second noun is Paula:
		say "[if noun is pocket watch]'I already know what time it is, sweety,' says Paula the Mage.[otherwise if noun is magazine]'Oh my, aren't you a naughty little boy,' says Paula the Mage.[otherwise if noun is fork]'Doesn't match my other cutlery,' says Paula the Mage. 'But thanks anyway, sweetie.'[otherwise if noun is map]'A heist seems exciting, but not tonight,' says Paula the Mage.[otherwise if noun is doorknob]'My castle's already fully decorated,' says Paula the Mage.[end if]".
		
Instead of showing map to Ryan during Online:
	now ryan is joined;
	clear avatar illustrations;
	refresh avatar illustrations;
	say "'I'm in!' Ryan whispers. 'It's now or never for the old Manor!'[paragraph break][bold type]***Ryan the Bard has joined your party.***[roman type][paragraph break]";
	play mp3 sound file "joined.mp3";
	move map to Ryan;
	refresh inventory illustrations.

Instead of showing magazine to Harry:
	move magazine to Harry;
	now Harry is joined;
	play mp3 sound file "joined.mp3";
	clear avatar illustrations;
	refresh inventory illustrations;
	refresh avatar illustrations;	
	say "'where did you get this?' whispers Harry. 'this is awesome!'[paragraph break]You explain the Manor and the potential treasures within, if only you had a companion strong enough to breach the gate...[paragraph break][bold type]***Harry the Barbarian has joined your party.***[roman type][paragraph break]".
		
Instead of showing doorknob to Ryan:
	move doorknob to Ryan;
	now Ryan is joined;
	play mp3 sound file "joined.mp3";
	clear avatar illustrations;
	refresh avatar illustrations;	
	refresh inventory illustrations;
	say "‘Cool loot,’ whispers Ryan. He agrees to meet you at your place later tonight. [paragraph break][bold type]***Ryan the Bard has joined your party.***[roman type]".
	
Instead of showing fork to Chris:
	move fork to Chris;
	now Chris is joined;
	play mp3 sound file "joined.mp3";	
	clear avatar illustrations;
	refresh avatar illustrations;
	refresh inventory illustrations;
	say "‘Sounds like Victorian cutlery,’ Chris whispers. Chris agrees to meet you at the Manor later tonight. [paragraph break][bold type]***Chris the Paladin has joined your party.***[roman type][paragraph break]".
	
Instead of showing letter opener to Paula:
	move letter opener to Paula;
	now Paula is joined;
	play mp3 sound file "joined.mp3";
	clear avatar illustrations;
	refresh avatar illustrations;
	refresh inventory illustrations;
	say "'Ooh, pretty pretty...’ she says. Paula agrees to join your raiding party.[paragraph break][bold type]***Paula the Mage has joined your party.***[roman type][paragraph break]".
	
Instead of showing watch to Maximus:
	move watch to Maximus;
	now Maximus is joined;
	play mp3 sound file "joined.mp3";	
	clear avatar illustrations;
	refresh avatar illustrations;
	refresh inventory illustrations;
	say "'An exquisite item,’ Maximus says. ‘It’ll help you tick off the hours you’ll spend in hell for your evil ways.’  

You explain that the Manor is condemned anyway. ‘The Oakville Manor? I know that grand old place...’ Maximus says. He agrees to join your raiding party.[paragraph break][bold type]***Maximus the Cleric has joined your party.***[roman type]".

Beer bottle glass is scenery in Inside the Coachhouse. Understand "brown glass" or "glass" as beer bottle glass.  The description of the beer bottle glass is "Beer bottles, maybe?" Before taking beer bottle glass:
	say "It's shiny in the right light, but it's no loot.";
	stop the action.

The map is a thing in the Adventurers' Lounge. The description of the map is "It's the route from your house to the Manor." The illustration of the map is "i_map".

The doorknob is a thing. Understand "knob" or "door knob" as the doorknob. The description of the doorknob is "Crystal or glass, beautifully cut in either case." The illustration of the doorknob is "i_doorknob".

The fork is a thing. The description of the fork is "It's only slightly tarnished, and will polish up nicely." The illustration of the fork is "i_fork".

The letter opener is a thing. The description of the letter opener is "Pretty bad-ass looking for an antique." The illustration of the letter opener is "i_letteropener".

The pocket watch is a thing. Understand "pocketwatch" or "watch" or "gleam" or "gold" as the pocket watch. The description of the pocket watch is "It's gorgeous, clam-shaped and golden." The illustration of the pocket watch is "i_pocketwatch". The pocket watch can be polished.

The white wine is a thing. The description of the white wine is "The label is hard to read under all the dust." The illustration of the white wine is "i_whitewine".

 There is a magazine in Inside the Coachhouse. Understand "motion" or "flutter" or "corner" or "stack" or "tome" or "forbidden tome" or "forbidden" as a magazine. "A flutter of motion attracts your eye to something in the corner." The description of the magazine is "A magazine concerning ladies of the night. Unquestioningly valuable to many gentlemen of your acquaintance."  The illustration of the magazine is "i_magazine".
 
 Understand the command "read" as something new. Understand "read [something]" as reading. Reading is an action applying to one thing. Instead of reading the magazine, say "A good thief doesn't get high on his own supply." Instead of drinking the white wine, say "A good thief doesn't get high on his own supply."
 
 There is a Notice of Demolition in the Portico of the Manor. Understand "paper" and "sheath" as Notice of Demolition. "A paper in a plastic sheath is stapled to the planks." Instead of taking Notice of Demolition, say "It's stapled with about a million heavy duty staples. Plus, you can read it as it is." The description of Notice of Demolition is "It’s a Notice of Demolition. Ryan overheard his mom talking to her other historical preservation friends about it, apparently there’s some kind of structural damage that makes it dangerous. Personally you think it’s more dangerous to let the cookie-cutter semi-detached monotony ooze slowly over the entire city.

The date on it indicates it’s got [if harry is joined]two days[otherwise if chris is joined]one day[otherwise if paula is joined]mere hours[otherwise]three days[end if] to live. If you don’t get to explore it it won’t be the end of the world: just the end of your boyhood dreams. "

A plank is in the Portico of the Manor. Understand "planks" or "wood" or "door" as plank. A Plank is scenery. The description of the Plank is "Yep, the planks have really blocked that door effectively." 

Instead of taking the plank:
	if Harry is joined:
		try going north;
	otherwise:
		say "Nope. Your light fingers are better suited to thieving, not heaving. You're going to need help.".
 Instead of pulling the plank, try taking the plank. Instead of pushing the plank, try taking the plank. Instead of taking off the plank, try taking the plank. The plank can be intact or removed. The plank is intact.

Shapes are in Inside the Manor. Shapes are scenery. Understand "furniture" or "chairs" as shapes. The description of the shapes are "You touch them and a plume of dust is raised -- dust that actually seems thicker than the sheets themselves. [if harry is in the room]Across the room, Harry yanks one off and spends a full minute rubbing his eyes and coughing. For his trouble he’s revealed a couple of unremarkable chairs.[end if]

Your thief’s instincts tell you that there’s nothing but unwanted furniture under the sheets, too old to be fashionable but not old enough to be antique."

Instead of jumping in Inside the Manor: 
	say "Over that hole? No thanks. You'll leave that to the jumping professionals. You could just try GO UP though."

Understand "jump in hole" or "jump over hole" or "jump across hole" as a mistake ("You could just try GO UP.")

Section 5 (Scenes)

Online is a scene. Online begins when play begins. Online ends when  the number of filled rows in the Table of Online Events is 0. Logout is a scene. Logout begins when the number of filled rows in the Table of Online Events is 0. Logout ends when player is real.
Offline is a scene. Offline begins when Logout ends. Offline ends when player is in Outside the Coachhouse and player has the magazine.
Online2 is a scene. Online2 begins when Offline ends. Online2 ends when Harry is joined for two turns. Logout2 is a scene. Logout2 begins when Harry is joined for two turns. Logout2 ends when player is real.
Offline2 is a scene. Offline2 begins when Logout2 ends. Offline2 ends when player has the doorknob and player has the fork and harry is not joined.
Interim is a scene. Interim begins when DirtyKissing ends. Interim ends when watch is polished for three turns.
Online3 is a scene. Online3 begins when Offline2 ends. Online3 ends when chris is joined and ryan is joined. Logout3 is a scene. Logout3 begins when ryan is joined and chris is joined. Logout3 ends when player is real.
Offline3 is a scene. Offline3 begins when Logout3 ends. Offline3 ends when DirtyKissing ends.
Online4 is a scene. Online4 begins when Interim ends. Online4 ends when Paula is joined and Maximus is joined. Logout4 is a scene. Logout4 begins when Paula is joined and Maximus is joined. Logout4 ends when player is real.
Offline4 is a scene. Offline4 begins when Logout4 ends. Offline4 ends when player has white wine.
DirtyKissing is a scene. DirtyKissing begins when player is in Front of Manor and Chris has the pocket watch.
CellarClimb is a scene. CellarClimb begins when maximus is occupied for two turns.
Confrontation is a scene. Confrontation begins when Paula is in Dining Room. Confrontation ends when Paula is in Dining room for nine turns.
Banter is a scene. Banter begins when Ryan is joined and player is in Your Front Porch. Banter ends when Ryan is in In Front of Manor.

When logout begins:
	follow the set open sesame rule.

Every turn when logout is happening (this is the set open sesame rule):
	now current question is "Type LOGOUT to continue.";
	now current prompt is ">";
	now punctuation removal is true;
	ask a closed question, in text mode.

A text question rule (this is the open sesame rule):
	if logout is happening:
		if the current answer is "logout":
			parse;
		otherwise:
			say "Type LOGOUT to continue.".

Stealing is an action applying to one touchable thing. Understand "steal [something]" as stealing. Instead of stealing noun, try taking noun.

Logouting is an action applying to nothing. Understand "logout" as logouting.

Carry out logouting:
	if player is real:
		say "You can't logout of real life, though it's tempting at times.";
	otherwise if online is happening:
		say "It would be better if you got some more party members joined up first.";
	otherwise if online2 is happening:
		say "It would be better if you got some more party members joined up first.";
	otherwise if online3 is happening:
		say "It would be better if you got some more party members joined up first.";
	otherwise if online4 is happening:
		say "It would be better if you got some more party members joined up first.";
	otherwise:
		say "[paragraph break]***DISCONNECTED***[paragraph break]";
		now player is real.

When logout2 begins:
	follow the set open sesame2 rule.

Every turn when logout2 is happening (this is the set open sesame2 rule):
	now current question is "Now that you've got some muscle on board, time for another Manor raid.[paragraph break]Type LOGOUT to continue.";
	now current prompt is ">";
	now punctuation removal is true;
	ask a closed question, in text mode.

A text question rule (this is the open sesame2 rule):
	if logout2 is happening:
		if the current answer is "logout":
			parse;
		otherwise:
			say "Type LOGOUT to continue.".

When logout3 begins:
	follow the set open sesame3 rule.

Every turn when logout3 is happening (this is the set open sesame3 rule):
	now current question is "[one of]That's enough reinforcements for another Manor raid. Type LOGOUT to continue.[or][run paragraph on] [stopping]";
	now current prompt is ">";
	now punctuation removal is true;
	ask a closed question, in text mode.

A text question rule (this is the open sesame3 rule):
	if logout3 is happening:
		if the current answer is "logout":
			parse;
		otherwise:
			say "Type LOGOUT to continue.".

When logout4 begins:
	follow the set open sesame4 rule.

Every turn when logout4 is happening (this is the set open sesame4 rule):
	now current question is "[one of]That's enough reinforcements for another Manor raid. Type LOGOUT to continue.[or][run paragraph on] [stopping]";
	now current prompt is ">";
	now punctuation removal is true;
	ask a closed question, in text mode.

A text question rule (this is the open sesame4 rule):
	if logout4 is happening:
		if the current answer is "logout":
			parse;
		otherwise:
			say "Type LOGOUT to continue.".

Every turn during Offline3:
	If Chris has been in Inside the Manor for four turns:
		try silently going up.

Every turn during Online2:
	If Harry has been in Adventurers' Lounge for three turns and harry does not have magazine:
		say "'Whatcha got there?' says Harry the Barbarian. 'SHOW it TO me!".
		
Instead of going during Confrontation, say "You’d like to, but a glance from Paula pins you in your place."

When Offline begins:
	go normal;
	play mp3 sound file "piano.mp3";
	say "You switch off your C-64, dropping the room into complete darkness. Your eyes adjust quickly, as befits a fifth level thief. In the hallway you wait and listen for the sounds of your parents[’] deep sleep. From the upper floor window you gaze upon your dangerous destination. The Oakville Manor.";
	move player to Your Front Porch;
	refresh avatar illustrations.
		
When Offline ends:
	say "Loot in hand, you head for home, thinking about what your fellow adventurers will say when they see it.[paragraph break][bold type]***[paragraph break]";
	move Harry to the Adventurers' Lounge;
	go retro;
	move player to the Adventurers' Lounge;
	refresh avatar illustrations.

When Offline2 begins:
	go normal;
	say "It’s been a strange night so far. If Harry hadn’t been carrying a large bag you never would have picked him out of the crowd getting off the bus. Stocky and talky, the guy’s as verbose in the flesh as he is on the screen, and kept up a running chatter the whole walk over here...";
	move harry to Front of the Manor;
	move player to Front of the Manor;
	refresh avatar illustrations.
		
When Online3 begins:
	go retro;
	move player to the Adventurers' Lounge;
	move Ryan to Adventurers' Lounge;
	refresh avatar illustrations.

When Offline3 begins:
	go normal;
	say "Ryan meets you in front of your house. He’s as jumpy as always. You check to see if he’s brought his picks, and he pulls them briefly out of a schoolbag festooned with band names. [paragraph break]";
	now chris is occupied;
	move Ryan to the Your Front Porch;	
	move player to Your Front Porch;
	refresh avatar illustrations.

When Online4 begins:
	go retro;
	move player to the Adventurers' Lounge;
	move harry to the Adventurers' Lounge;
	now Ryan is not joined;
	now Chris is not joined;
	refresh avatar illustrations.
	
When Offline4 begins:
	go normal;
	say "You meet Max at the edge of the field. He lives not too far away, but neither of you really want to give the other your home address.

He’s a few years older and about a foot taller, but with the build and the cornstalk hair of a scarecrow. He’s carrying a backpack. His voice is as annoying as you imagined from the BBS.

‘You quite sure it’s unpatrolled?’ he says. ‘If it gets traced back to the Guild, they can easily shut us down.’";
	now paula is occupied;
	move Chris to Adventurers' Lounge;
	move player to The Field;
	refresh avatar illustrations.

Before doing something other than logouting, stealing, examining, looking, waiting, showing, giving or taking during Online:
	say "Your access on the BBS only allows you to EXAMINE, LOOK, WAIT, SHOW something TO someone, or TAKE something.

Maximus sees your attempt and smiles smugly, casually [one of]turning invisible[or]transforming into a wyvern and back[or]becoming gaseous[or]causing a catapult to appear and disappear[or]exploding and reassembling[cycling] -- something only a 8th level Guild member could do.";
	stop the action.

Every turn during Online:
	repeat through Table of Online Events:
		say "[event entry][paragraph break]";
		blank out the whole row;
		if number of filled rows in the Table of Online Events is 2:
			remove Harry from play;
			play mp3 sound file "incinerate.mp3";
			refresh avatar illustrations;
		otherwise if number of filled rows in the Table of Online Events is 1:
			if ryan has the map:
				move map to player;
				remove Ryan from play;
				now ryan is not joined;
				play mp3 sound file "unjoined.mp3";
				refresh avatar illustrations;
				refresh inventory illustrations;
		rule succeeds.

Table of Online Events
event
"'hey tony' says Ryan.

'voltron would kill optimus' says Harry.

'he’s like 5 robots in one' says Harry.

'Optimus would have his whole team backing him up,' says Chris.

Maximus floats in on a cloud of glory."
"Paula winks at you. 

'VOLTROOOOOOOOOOOOOON!' says Harry.

Chris transforms into an awesomebot.

Maximus frowns."
"'LESS THAN MEETS THE EYE111' says Harry.

'My child, strive to stay in character,' advises Maximus sternly.

Paula yawns."
"Chris drives circles around Harry.

'i stomp on your stupid ass!' exclaims Harry.

Maximus summons a dragon which proceeds to incinerate Harry the Barbarian and then disappear."
"[if ryan does not have map]'Language and character violations will not be tolerated,' intones Maximus.[otherwise]'oh crap my mom just busted me... sorry can't meet,' whispers Ryan. 

Ryan gives you a map.

Ryan has logged off.[end if]"
"[if ryan is in location]You decide to leave before Maximus kicks you for some violation.[otherwise]Ryan's fickleness only strengthens your resolve.[end if]"

Every turn during Online2:
	if the number of filled rows in the Table of Online2 Events is 0:
		if harry does not have magazine:
			say "The other guild members chatter on. You wonder if there is a way to convince them to join you in a raid on the Manor.";
	repeat through Table of Online2 Events:
		say "[event entry][paragraph break]";
		blank out the whole row;
		rule succeeds.

Table of Online2 Events
event
"'Greetings, thief,' says Maximus.

'2400 baud is totally enough! ' exclaims Harry.

Paula laughs at 4800 baud."
"'Yah Concrete Beach are just snobs, they’re all pirates anyway,' says Chris.

Maximus says a silent prayer for pirates to mend their ways.

'I know they’re pirates, I want the warez!!!' exclaims Harry."

Every turn during Online3:
	repeat through Table of Online3 Events:
		say "[event entry][paragraph break]";
		blank out the whole row;
		rule succeeds.

Table of Online3 Events
event
"Chris is here, shining a sword of great antiquity.

Paula is checking her makeup in the sword’s reflection."
"Maximus is enjoying the lack of barbaric chatter."

Every turn during Online4:
	repeat through Table of Online4 Events:
		say "[event entry][paragraph break]";
		blank out the whole row;
		rule succeeds.

Table of Online4 Events
event
"‘dice are stupid anyway,’ Harry says. ‘no skill.’

Maximus struggles with his vow of serenity.

‘hi tony,’ whispers Paula."
"Harry scratches his bum."

DirtyKissing ends when the pocket watch is polished for two turns. 

Every turn during DirtyKissing:
	if pocket watch is in In Front of the Manor for two turns:
		now Chris is not joined;
		move chris to adventurers' lounge;
		refresh avatar illustrations;
	if player is pinned for exactly two turns:
		say "When you don’t struggle, just smile at her, she rolls off you and takes the letter opener with her. You look up at the sky, the moon barely visible, thinking about how weird it is that you’re lying in the grass in front of the Manor. A few nights from now, it’ll all be gone.

‘What's that handle, mother of pearl?’ Chris says, squinting at it before tossing it onto your chest. ‘You find the coolest stuff in these old houses.’";
		now player is not pinned;
		now pocket watch is polished;
	repeat through Table of DirtyKissing Events:
		say "[event entry][paragraph break]";
		blank out the whole row;
		rule succeeds.

When DirtyKissing ends:
		move Harry to adventurers' lounge;		
		say "The watch sits in your open palm. You look up at Chris, and she’s snapping a hairclip that got dislodged into place.

You have never wanted anything more in your life.

‘Why don’t you hold onto that for me, thief,’ she says, pulling her collar up. ‘My dad would find it eventually.’

She looks at you, a strange smile twisting her lips, and then she runs off into the forest.

You look longingly after her to to the west."
		
Before taking watch:
	if Chris is in In Front of the Manor:
		now player is pinned;
		say "Picking pockets was never your forte.

She grabs your wrist and soon you find yourself on your back, her arm pinning your neck down. ‘Dirty... thief...’ she puffs, smirking, her eyes shining.

Her hands go all over your body, searching for something. Finally her hand rests on a ridge in your pants.

‘Ah hah...’ she crows. ‘What have we here? Holding out on me, you dirty thief?’ She's breathing hard, her face a few inches from yours.";
		move watch to player;
		refresh inventory illustrations;
		play mp3 sound file "treasuregetting.mp3";
		stop the action;
	otherwise if Chris is in Adventurers' Lounge:
		now player is pinned;
		say "You lean over to pick up the watch, and -- bam! -- Chris tackles you from out of nowhere! You find yourself on your back, her arm pinning your neck down. ‘Dirty... thief...’ she puffs, smirking, her eyes shining.

Her hands go all over your body, searching for something. Finally her hand rests on a ridge in your pants.

‘Ah hah...’ she crows. ‘What have we here? Holding out on me, you dirty thief?’ She's breathing hard, her face a few inches from yours.";
		move chris to In Front of the Manor;
		move watch to player;
		play mp3 sound file "treasuregetting.mp3";
		stop the action.

Instead of kissing chris:
	if player is pinned:
		say "You can’t -- she’s got you pinned too good, but then she reads your intentions and lets up just... enough... for you to kiss her. When you try to slip her some tongue, she gasps and pins you again. ‘Oh no, oh no you don’t,’ she says, her eyes blazing, covering your mouth with her hand.
		
When you don’t struggle, she rolls off you and takes the letter opener with her. You look up at the sky, the moon barely visible, thinking about how weird it is that you’re lying in the grass in front of the Manor. A few nights from now, it’ll all be gone.

‘What's that handle, mother of pearl?’ Chris says, squinting at it before tossing it onto your chest. ‘You find the coolest stuff in these old houses.’";
		now player is not pinned;
		now pocket watch is polished;
		now player is smooched;
	otherwise:
		say "That's not how you usually express the love you feel for your fellow guild members."

Instead of attacking person:
	if player is pinned and person is Chris:
		say "You can't -- she's got you pinned too good. When you stop struggling, she rolls off you and takes the letter opener with her. You look up at the sky, the moon barely visible, thinking about how weird it is that you’re lying in the grass in front of the Manor. A few nights from now, it’ll all be gone.

‘What's that handle, mother of pearl?’ Chris says, squinting at it before tossing it onto your chest. ‘You find the coolest stuff in these old houses.’";
		now player is not pinned;
		now pocket watch is polished;
	otherwise:
		say "You're no barbarian. Your art is a subtler one."

When DirtyKissing begins:
	move Chris to In Front of Manor;
	move pocket watch to In Front of Manor.

Table of DirtyKissing Events
event
"You leave the house behind.

Chris kneels to tie her running shoe. Her jacket pocket opens wide -- inside is a gold gleam that makes your fingers itch."
"[if player is not pinned]When Chris stands, a golden pocketwatch falls to the ground.

Chris looks at you. 'See ya around, I guess.' She melts into the forest."

CellarClimb ends when maximus has been occupied for two turns.

Every turn during CellarClimb:
	repeat through Table of CellarClimb Events:
		say "[event entry][paragraph break]";
		blank out the whole row;
		rule succeeds.

When CellarClimb ends:
	remove Maximus from play;
	refresh avatar illustrations.

Table of CellarClimb Events
event
"[if location is Inside the Manor]Max, wearing a headband with a light attached, starts to climb down the rope. There’s a tense moment when the banisters squeaks, but it holds fast.

Alone, you and Paula trade a silent look of surprise.

She’s about to say something when a laugh comes from the room to the west. The dining room. And is that the tinkle of cutlery?[end if]"

Every turn during Banter:
	repeat through Table of Banter Events:
		say "[event entry][paragraph break]";
		blank out the whole row;
		rule succeeds.

Table of Banter Events
event
"‘Never actually used them except on the test lock,’ Ryan says, pulling his hat off and waving it at his face. It’s pretty muggy out."
"You describe the kind of keyhole it is as you head over. ‘Oh yeah, those are easier than modern ones.’ He gives you a sly smile. ‘Maybe you wanna give it a shot.’

You punch him in the shoulder at the reminder of your one thiefly failure. You’ve never had a knack for picks. It came up when Ryan wanted to join the Guild as a thief, but luckily he changed his mind and decided his mastery of three chords qualified him as a bard."
"You ask him about the kids at his new school, the Catholic one his mom made him go to. ‘Pretty boring. I’m the only one into hardcore and cool music there,’ he bragplains."
"You ask him if he’s made it downtown to a hardcore show yet. He shrugs. ‘Not yet. They start so late that there’s like no way to get back here before transit stops.’

He shoots a glance at you to see how well this latest excuse works. You keep your face neutral. You can mock him after the job."

Every turn during Confrontation:
	if number of filled rows in the Table of Confrontation Events is 4:
		move Maximus to Dining Room;
		refresh avatar illustrations;
		move bottle of white wine to Dining Room;
		move bottle of red wine to Paula;
	otherwise if number of filled rows in the Table of Confrontation Events is 3:
		remove Maximus from play;
		refresh avatar illustrations;
	repeat through Table of Confrontation Events:
		say "[event entry][paragraph break]";
		blank out the whole row;
		rule succeeds.

Before taking bottle of white wine:
	if number of filled rows in the  Table of Confrontation Events is greater than 3:
		say "Too many people are watching.";
		stop the action.
		
When Confrontation ends:
	say "‘Look, Paul,' started Erik, his voice tired and sad. ‘I--’

‘It’s [italic type]Paula[roman type], you stupid fuck!’ She throws the bottle at him, and the last thing you see before you leave the room is the candelabra falling onto the tablecloth. ";
	if player does not have white wine:
		say "[run paragraph on]You grab the bottle of white wine in the confusion.";
		move bottle of white wine to player;
		play mp3 sound file "treasuregetting.mp3";
		refresh inventory illustrations;
	say "In a rush you see the birds on the wallpaper, the front door still open, the flattened grass in front of you and before too long, you’re back in your bedroom. You take off your clothes, trying to decide if they smell of smoke or just of guilt. 

You stash the wine bottle with your other loot in the briefcase you got for your grade eight graduation. The locks close with a satisfying snap.[if player is smooched]As you put it away you reflect that it doesn't contain your most exciting Manor discovery -- the kiss you stole from Chris.[end if][paragraph break]You’re in your bed when the fire sirens start to wail and the flames are becoming visible on the Manor. It’s sad, but when you consider that the Manor was otherwise facing crowbars and rough hands and wrecking balls in the morning...  better a funeral pyre.";
	set the header image to "topbar_fire.gif";
	end the game in victory.

Table of Confrontation Events
event
"Paula sits down at an empty chair and seats you beside her. There’s no plate, but she reaches across the table and wrenches a drumstick from the bird."
"‘Um... hi,’ says the fellow in the suit jacket. Everyone’s staring at Paula as she gnaws the drumstick, and you will yourself invisible.

She points the drumstick at him and you see a drop of grease fall onto the tablecloth. ‘You stole my idea, Erik. And then you didn’t even invite me.’"
"‘Well, I would say it was our idea,’ says Erik. 

Paula reaches over and takes the closest goblet. Its bespectacled owner pretends he doesn’t notice. She takes a sip and then spits it out, luckily away from you. ‘A white? With duck, Erik?’

Erik grimaces. ‘They were out of--’ 

He stops suddenly, seeing Max in the doorway with a bottle of wine in each hand."
"‘Ah, sommelier,’ Paula waves him over, proving herself an improvisational genious. Max comes, his eyes stunned, and only squeaks a bit as she pulls the dusty bottles from his grasp.

She sets one on the table and reads the label on the other. Max backs away towards the door, and then makes a break for it, his backpack clinking with other bottles."
"‘Ah -- a pinoit noir,’ she says, uncorking it with surprising ease. ‘That’s suitable for duck.’

She goes around the table, picking up a goblet still full of wine. ‘What’s the point in doing something --’ throws the white wine onto the floor, ‘-- if you’re not going to go all the way with it?’ She fills the goblet and bangs it down onto the table, sloshing red, and the candelabra sways a bit. The light in the room sways too."
"‘The rules are the least interesting part of this,’ Erik snaps back. ‘You always take things too far.’

The dreadlocked man gulps down his white and holds it up for Paula, who overfills it. ‘Whoops, I guess I do. I guess it’s why you kicked me out of the freak clique, huh?’"

Test me with "z/z/z/z/z/z/logout/e/e/e/e/ne/n/take magazine/s/sw/show magazine to harry/logout/n/n/u/e/take doorknob/w/w/w/show fork to chris/show doorknob to ryan/logout/e/e/e/e/n/n/u/e/take opener/w/w/w/e/s/s/take watch/hit chris/z/w/show watch to maximus/show opener to paula/logout/e/n/n/u/"